Simple utility to parse out id and class styles in an html document.

[Pete]

I've been converting some 40 different html pages to a responsive format, and one of the things I had to make was a couple of new style sheets, one being for mobile screens.  After awhile, all the various id and classes get hard to recall, so I made this little utility to parse out all the id and class tags, used in each html page.

The utility is for Windows systems...

1) Makes a list of all the html pages in the directory: c:\mywebpages
2) parses and collects the id and class styles out of the html and places them into an array.
3) Sorts duplicates out of the array.
4) Writes the results to a file called: css-class.txt.
5) Opens css-class.txt in Notepad.

Anyway, it's easy to change the names of the files, directory, etc.; so, if anyone needs such a utility, well, here it is...

Code: QB64: [Select]

1. _SCREENMOVE 0, 0
2. 'WIDTH 80, 43
3. dir$ = "c:\mywebpages\"
4. IF _DIREXISTS(dir$) THEN ELSE PRINT "No such directory: "; dir$: END
5. SHELL _HIDE "dir /b " + dir$ + "*.htm*>tmp.tmp"
6. 'SHELL _DONTWAIT "notepad tmp.tmp"
7. IF _FILEEXISTS("css-class.txt") THEN
8.     LINE INPUT "Overwrite file css-class.txt? (y/n) ", ans$
9.     IF LCASE$(ans$) = "n" THEN END
10. END IF
11. OPEN "css-class.txt" FOR OUTPUT AS #3
12. OPEN "tmp.tmp" FOR INPUT AS #1
13. DO UNTIL EOF(1)
14.     LINE INPUT #1, a$
15.     IF _FILEEXISTS(dir$ + a$) THEN ELSE PRINT "Error...": END
16.     OPEN dir$ + a$ FOR BINARY AS #2
17.     FileLength = LOF(2)
18.     z$ = SPACE$(FileLength)
19.     GET #2, 1, z$
20.     z$ = LCASE$(z$)
21.     DO UNTIL INSTR(z$, "  ") = 0
22.         z$ = MID$(z$, 1, INSTR(z$, "  ") - 1) + MID$(z$, INSTR(z$, "  ") + 1) ' Remove one space.
23.     LOOP
24.     DO UNTIL INSTR(z$, CHR$(13)) = 0
25.         z$ = MID$(z$, 1, INSTR(z$, CHR$(13)) - 1) + MID$(z$, INSTR(z$, CHR$(13)) + 1)
26.     LOOP
27.     DO UNTIL INSTR(z$, CHR$(10)) = 0
28.         z$ = MID$(z$, 1, INSTR(z$, CHR$(10)) - 1) + " " + MID$(z$, INSTR(z$, CHR$(10)) + 1)
29.     LOOP
30.     x$ = z$
31.     cnt = 0: ncnt = 0: REDIM s$(1000), style$(1000)
32.     PRINT a$: PRINT #3, a$
33.     DO UNTIL INSTR(x$, "id=") = 0
34.         x$ = MID$(x$, INSTR(x$, "id=") + 4)
35.         style$ = "#" + MID$(x$, 1, INSTR(x$, CHR$(34)) - 1)
36.         'PRINT style$
37.         cnt = cnt + 1: s$(cnt) = style$
38.     LOOP
39.     x$ = z$
40.     DO UNTIL INSTR(x$, "class=") = 0
41.         x$ = MID$(x$, INSTR(x$, "class=") + 7)
42.         style$ = "." + MID$(x$, 1, INSTR(x$, CHR$(34)) - 1)
43.         'PRINT style$
44.         cnt = cnt + 1: s$(cnt) = style$
45.     LOOP
46.     FOR i = 1 TO cnt
47.         FOR j = 1 TO cnt
48.             IF i <> j THEN
49.                 IF s$(i) = s$(j) THEN
50.                     s$(j) = ""
51.                 END IF
52.             END IF
53.     NEXT j, i
54.     FOR i = 1 TO cnt
55.         IF s$(i) <> "" THEN ncnt = ncnt + 1: style$(ncnt) = s$(i)
56.     NEXT
57.     FOR i = 1 TO ncnt
58.         PRINT #3, style$(i)
59.     NEXT
60.     CLOSE #2
61.     PRINT #3, ""
62. LOOP
63. SHELL _DONTWAIT "notepad css-class.txt"
64.  

Feel free to modify it, expand on it, whatever.

Note that as coded, it lists id results first, followed by class.

Oh, and a big thanks to Amazing Steve for posting that neat load the whole file at once part, some months ago, with the GET statement. That sure beats concatenating with LINE INPUT or using GET with a pre-DIM string, like DIM a as STRING * 1000 and using GET #ff, , until a remainder is all that's left and then dealing with a LOF() math function for that.

Pete