Blinking colors code on text screen

[Petr]

Hi.
 Why MEM return different colors values in text screen 0 (not the same, which are used with COLOR) for blinking colors?

Expected output is 1, 220, 2, 220, 3, 220.......15, 220, 16, 220, 17, 220, 18, 220 to 31, 220. But program output is different. Why? It is again something with BIT operations? Or is it a resolution (fixed colors are 0 to 15, blinking from half, 128 to 143?)

Color 7 for empty places in text mode is correct, because in mode 0 just foreground can be set and Color 7 is _DEFAULTCOLOR for Screen 0.

Code: QB64: [Select]

1. img = _NEWIMAGE(60, 30, 0)
2. _DEST img
3. REM PRINT _DEFAULTCOLOR
4. FOR o = 0 TO 25
5.     COLOR o
6.     PRINT CHR$(220);
7. NEXT
8. FOR o = 27 TO 31
9.     COLOR o
10.     PRINT CHR$(220);
11. NEXT
12. SCREEN img
13. COLOR 7
14. PRINT "   Text screen contains color values 0 to 31. Press key..."
15. SLEEP
16.  
17. DIM m AS _MEM, C AS _UNSIGNED _BYTE
18. m = _MEMIMAGE(img) 'text screen: Character code (_UNSIGNED _BYTE), Character Color (_UNSIGNED _BYTE)
19.  
20. FOR Code = 0 TO 60 * 30
21.     C = _MEMGET(m, m.OFFSET + Code, _UNSIGNED _BYTE)
22.     PRINT LTRIM$(STR$(C)); ", ";
23.     SLEEP
24. NEXT
25.  

[SMcNeill]

SCREEN 0 has 2 bytes of information for each character on the screen.  One is the ASCII value of the character, the other is the color.

Color is an ASCII value from 0-255..
Foreground color is the first 4 bits, background is the next 3 bits, blinking is the last bit.

00000000 — black on black
10000000 — blinking black on black
01110000 — black on white
11110000 — blinking black on white

*Note:  This is all from memory and order might be reversed, but from what I remember, the principle is there...

I did a tutorial on all this before.  Let me see if I can dig it up once again.  There’s a few simple formulas you can use to get your values, if I can remember them.

Blink = COLOR \ 128
Foreground = Color MOD 16
Background = (Color - 128 * Blink) \ 16

^Those are my guess at the formula, but without testing them with code, I won’t swear they’re 100% correct...  I just took my pills for the day a while ago at breakfast, and I can tell my brain is all fogged up from them.  Give me a few hours for them to settle, and I’ll either hunt down my old tutorial or else work the values out again for you in a demo.  ;)

EDIT:

Note 2: If blinking is off, that last bit is used for extended colors, so you can have 16 foreground, 16 background colors.

Note 3:  To make the value, the color is Blink + 16 * Background + Foreground.

[Petr]

Yeah, you're right! I don't know why, but somehow I caught mistakes in setting the background color, which led me to misjudgment. Really. Information on both colors must be set in one byte. Yes. Please wait for the release of the program, I have to figure it out myself once. Thank you! :)

[SMcNeill]

Testing it, I was right earlier (which is actually surprising as I get soooo many things backwards, or slightly jumbled up, for a few hours after I take my stinking pills).  Here's the briefest of code to show you how the colors are encoded in SCREEN 0:

Code: QB64: [Select]

1. DIM m AS _MEM
2. DIM b AS _UNSIGNED _BYTE
3. m = _MEMIMAGE(0)
4.  
5. COLOR 15 + 16, 3
6. PRINT "A"
7. _MEMGET m, m.OFFSET + 1, b
8. PRINT
9. COLOR 15, 0
10.  
11. PRINT "foreground", b MOD 16
12. PRINT "background", b \ 16 MOD 8
13. PRINT "blink", b \ 128

[FellippeHeitor]

Just a side note: you can disable blinking to enable high intensity bg colors in SCREEN 0 with _BLINK http://www.qb64.org/wiki/BLINK

[Petr]

Thank you, Fellippe.