Re: CONFLICT - A POLITICAL STRATEGIC SIMULATION GAME (STILL IN PROGRESS)

[bplus]

Hi Ron,

Starting with stuff in OnLoad, all that stuff should divided into Menu Screens not saved into arrays

Sub MenuGovernment

Sub MenuForeign ( i before e except when foreign)

Sub MenuMilitary

Sub MenuEconomics

THEN the game loops around probably back to Government so main loop

Do
     Show some news
     Call Government sub - which jobs out to foreign, military, economics ie calls the various sub menu subs
Loop

Each of these Menu subs presents a menu gets a key, executes an action.. so what you are calling DATA statements should be PRINT statements in a SUB Menu, present the Menu, getKey choice execute that action. PS don't offer choices that are no longer available.

You would have to explain in regular English what the Foreign Ministry is supposed to do because I haven't a clue from the variables in that sub.

[bplus]

After running code it seems I am supposed to visit each department and decide something and then next bit of news comes up, why not just make it a round, visit dept 1, then 2, then 3 instead of being told I did that department already?

[bplus]

Good, ours are very similar but I have no idea what you intended for the peace stuff...

Code: QB64: [Select]

1. _TITLE "CONFLICT - SIMULATION GAME" 'started by ron77 on 11-12-2019 - made a working skeleton of subs... need more work to be complited
2. REDIM SHARED news$(0)
3. DIM SHARED GovernmentType$, MilitaryAction$, ForeignAction$, EconomicAction$
4. RANDOMIZE TIMER
5. SCREEN 0
6.  
7. loadNews
8. Opening
9. DO
10.     CLS
11.     PRINT NewsUpdate$
12.     PRINT: INPUT "Press enter when you have read the latest news... "; wayt$
13.     Military
14.     Foreign
15.     Economics
16. LOOP
17.  
18. SUB Opening
19.     cp 4, "COMFLICT - STRATEGIC POLITICAL SIMULATION"
20.     cp 6, "BY RON77"
21.     COLOR 31: cp 8, "PRESS ANY KEY 1 TO BEGIN OR ESC KEY TO EXIT": COLOR 7
22.     k$ = GetKey$("1" + CHR$(27))
23.     IF k$ = CHR$(27) THEN END
24.  
25.     CLS
26.     cp 3, "YOU ARE THE NEWLY ELECTED PRIME MINISTER OF THE STATE OF ISRAEL"
27.     cp 5, "YOU PROMISSED THE ISRAELI VOTERS - 'PEACE AND SECURITY'"
28.     cp 7, "HOWEVER THE MIDDLE EAST IS BURNING FROM TERROR AND INSTABILITY"
29.     cp 9, "HAMAS FROM GAZA AND HIZZBALLA FROM LEBANON AND IRAN ARE THRETHENING"
30.     cp 11, "TO DESTROY ISRAEL AND KILL ALL ISRAELIS"
31.     cp 13, "THE FAITH OF THE ISRAELI NATION IS IN YOUR HANDS"
32.     cp 15, "MAY GOD BE WITH YOU! - GOOD LUCK!"
33.     cp 19, "press any to continue..."
34.     SLEEP
35.  
36.     CLS
37.     cp 3, "WHAT TYPE OF GOVERNMENT WILL YOU MAKE?"
38.     lp 5, 2, "1. MAKE A LEFT WING GOVERNMENT AND TRY TO ACHIVE PEACE WITH THE ARAB WORLD"
39.     lp 6, 2, "2. MAKE A CONSERVATIVE CENTER GOVERNMENT THAT WILL TRY TO MAINTAINE STABILITY"
40.     lp 7, 2, "3. MAKE A RIGHT WING GOVERNMENT THAT WILL FIGHT ISRAEL'S ENEMIES"
41.     cp 9, "PLEASE CHOOSE 1 2 OR 3 KEYS"
42.     TypeGovernment$ = GetKey$("123") '>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> where does this get used????
43. END SUB
44.  
45. SUB Military
46.     CLS
47.     cp 2, "THE MILITARY IS WAITING FOR YOUR ORDERS SIR!"
48.     lp 4, 2, "1. ASSASINATE A KEY FIGURE IN HAMAS\HIZZBALLA\IRAN MILITERY ORGANIZATION"
49.     lp 5, 2, "2. OPEN A LIMITED MILITERY OPERATION AGAINST HAMAS\HIZZBALLA"
50.     lp 6, 2, "3. BOMB STRATEGIC TARGETS IN IRAN TO DESTROY NUCLEAR FACILITIES"
51.     lp 7, 2, "4. TRY TO DISTABLIZED IRAN\HAMAS\HIZZBALLA BY GIVING AID TO REBEL OPOSITION"
52.     lp 8, 2, "5. DO NOTHING FOR THE MOMENT - LET'S WAIT AND SEE HOW THINGS DEVELOP"
53.     cp 10, "CHOOSE 1 2 3 4 OR 5 KEYS"
54.     MilitaryAction$ = GetKey$("12345")
55. END SUB
56.  
57. SUB Foreign
58.     CLS
59.     cp 2, "FOREIGN AFFAIRS MINISTER AT YOUR SERVICE. SIR!"
60.     lp 4, 2, "1. START A SECRET NEGOTIOATION CHANNEL WITH HAMAS\HIZZBALLA\IRAN"
61.     lp 5, 2, "2. ASK THE U.N. SECURITY COUNCIL TO CONDEMN AND SANCTION IRAN\HAMAS\HIZZBALLA"
62.     lp 6, 2, "3. ASK THE U.S. FOR AID"
63.     lp 7, 2, "4. TRY TO INCREASE WORLD SUPPORT FOR ISRAEL BY MAKING A SPEECH IN THE U.N."
64.     lp 8, 2, "5. FIND ALLIES IN OTHER COUNTRIES WHO ARE ENEMIES OF IRAN\HAMAS\HIZZBALLA"
65.     lp 9, 2, "6. DO NOTHING FOR THE MOMENT - LET'S WAIT AND SEE HOW THINGS DEVELOP"
66.     cp 11, "CHOOSE 1 2 3 4 5 OR 6"
67.     ForeignAction$ = GetKey$("123456")
68. END SUB
69.  
70. SUB Economics
71.     CLS
72.     cp 2, "THE ECONOMIC CABINET IS READY TO MEET YOU PRIME MINISTER"
73.     lp 4, 2, "1. INCREASE DEFENCE BUDGET AND RAISE TAXS"
74.     lp 5, 2, "2. DECREASE DEFENCE BUDGET AND LOWER TAXS"
75.     lp 6, 2, "3. LEAVE THE BUDGET AS IT IS FOR NOW"
76.     lp 8, 2, "CHOOSE 1 2 OR 3"
77.     EconomicAction$ = GetKey$("123")
78. END SUB
79.  
80. FUNCTION peace$ (n) ' how to make a function out of a string array!!!
81.     SELECT CASE n
82.         CASE 1: peace$ = "WE HAVE STARTED TO NEGOTIATE SECRETLY WITH THE IRANIANS. PROGRESS IS SLOW. IT WILL TAKE TIME"
83.         CASE 2: peace$ = "WE ARE NEGOTIATING WITH THE IRANIANS BUT IT LOOKS LIKE THEY ARE DELAYING ON PURPOSE TIME WHILE THE NEGOTIATION IS STUCK"
84.         CASE 3: peace$ = "THERE IS CONCERN THAT THE SECRET CHANNEL BETWEEN US AND THE IRANIANS WILL LEAK TO THE PRESS. IF SO THIS MAY PUT AN END TO THE NEGOTIATIONS"
85.         CASE 4: peace$ = "THE NEGOTIATION TEAMS BETWEEN US AND IRAN HAVE DONE SOME PROGRESS... WE NEED MORE TIME"
86.         CASE 5: peace$ = "WE ARE CLOSE TO A PEACE AGREEMENT BETWEEN US AND THE IRANIANS TO END ALL HOSTILITY JUST A FEW MORE DETILES"
87.         CASE 6: peace$ = "WE HAVE A PEACE AGREEMENT READY BETWEEN US AND THE IRANIANS - ARE YOU READY TO SIGN IT?"
88.     END SELECT
89. END FUNCTION
90.  
91. 'FUNCTION peace2$
92. '    'IF agreement = 0 THEN
93. '    IF pco < 6 THEN
94. '        forin(2) = "1. WE ARE CORRENTLY NEGOTIATING SECRETLT WITH IRAN\HAMAS\HIZZBALLA. SHELL WE STOP THE NEGOTITATIONS?"
95. '        'ELSEIF pco = 6 THEN
96. '        '    forin(2) = "1. SIGN A PEACE AGREEMENT WITH IRAN\HAMAS\HIZZBALLA"
97. '        pco = pco + 1
98. '        n$ = peace(pco)
99. '        peace2$ = n$
100. '    ELSEIF pco > 6 THEN
101. '        pco = 6
102. '        'n$ = peace(pco)
103. '        'peace2$ = n$
104. '    ELSEIF pco = 6 THEN
105. '        n$ = peace(pco)
106. '        peace2$ = n$
107. '        forin(2) = "1. SIGN A PEACE AGREEMENT WITH IRAN\HAMAS\HIZZBALLA"
108. '        offSwitch1 = 3
109. '        'agreement = -1
110. '        'Pcount = 0
111. '    END IF
112. '    'ELSEIF agreement = -1 THEN
113. '    '    forin(2) = "1. YOU HAVE SIGNED A PEACE AGREEMENT WITH IRAN\HAMAS\HIZZBALLA SHELL WE BREACK THE AGREEMENT?"
114. '    '    peace2$ = "WE HAVE SIGN A PEACE AGREEMENT WITH ALL OF OUR ENEMIES. NO MORE WAR NO MORE BLOODSHED"
115. '    'END IF
116. 'END SUB
117.  
118. SUB loadNews 'don't try to cp these lines, they are too long
119.     REDIM news$(1 TO 9)
120.     news$(1) = "HAMAS HAS LUNCHED MISSILES TO THE SOUTHEREN BORDER THE PUBLIC DEMANDS ACTION"
121.     news$(2) = "HIZZBALLA HAS ATTACKED A BASE NEAR THE NORTHEN BORDER 2 OF OUR SOLDIERS ARE MISSING - WHAT SHELL BE OUR RESPONSE?"
122.     news$(3) = "IRAN IS BUILDING A NUCLEAR SITE FOR PLUTONIUM WITHIN A FEW YEARS THEY WILL HAVE AN ATOMIC WEPONE AGAINST US - WE MUST DO SOMETHING!"
123.     news$(4) = "HAMAS HAS SECRETLY CONTACTED THE FORINE AFFAIRS OFFICE WITH A MESSAGE THEY WANT PEACE AND STABILITY - SHELL WE NEGOTIATE?"
124.     news$(5) = "THE U.S. PRESIDENT HAS ASKED US TO CONSIDER A PEACE DEAL WITH IRAN - IN RETURN THE U.S. WILL EQUIPTE OUR ARMY WITH THE LATEST WEPONES AND INCREASE THE MILITERY AID"
125.     news$(6) = "OUR ECONOMY IS NOT DOING GOOD WE SPEND TOO MUCH MONEY ON THE MILITERY - WE NEED TO CHOOSE EITHER MORE TAXS OR DECREASE SPENDING"
126.     news$(7) = "IRAN PRESIDENT HAS SAID THAT 'ISRAEL MUST AND WILL BE ERASED FROM THE MAP!' - HOW SHELL WE RESPOND TO THIS PROVOCATION?"
127.     news$(8) = "IRANIAN DIPLOMATES HAVE CONTACTED THE FORINE AFFAIRS AMBASSADOR IN CHILE AND ASKED TO OPEN A SECRET NEGOTIATION - SHELL WE AGREE?"
128.     news$(9) = "OUR ECONOMY IS BOOMING AND FLURISHING WE NEED TO DISIDE EITHER TO INCREASE DEFENCE BUDGET OR MAYBE DECRESE TAXS"
129. END SUB
130.  
131. FUNCTION NewsUpdate$ ()
132.     NewsUpdate$ = news$(INT(RND * 9) + 1)
133. END FUNCTION
134.  
135. 'cp needs s$ to be less that width of screen
136. SUB cp (row, s$)
137.     LOCATE row, INT((_WIDTH - LEN(s$)) / 2): PRINT s$;
138. END SUB
139.  
140. SUB lp (row, col, s$)
141.     LOCATE row, col: PRINT s$;
142. END SUB
143.  
144. FUNCTION GetKey$ (keysToCatch$)
145.     DIM k$
146.     DO
147.         k$ = INKEY$
148.         WHILE LEN(k$) = 0
149.             k$ = INKEY$
150.             _LIMIT 60
151.         WEND
152.     LOOP UNTIL INSTR(keysToCatch$, k$)
153.     GetKey$ = k$
154. END FUNCTION
155.  
156.  

I would guess after meeting with the 3 government departments those departments would handle your orders.
Instead of calling your choices k2$, k3$, k4$...  use Shared MilitaryAction$, ForeignAction$, EconomicAction$ so you can do more coding for those actions if you want.

[bplus]

Hi Ron,

You know we've followed a recipe for creating a menu sub:

Show a title, offer n amount of options then get the users choice coded into a single number or digit... get all the text centered nicely on the page/screen

If you are stuck on what next to do with the game, you could work on problem of writing a generic screen menu function and go back to loading arrays from DATA given a key data lookup (Restore line label) or use the key to pull data out of a txt file like done with ELIZA/Player.

So what we've repeated 3x's, we could do once over and over again in this game and any other like it.

[bplus]

The game is boring when the options remain the same and the news is random, as options and news change according decisions you make in the game, the game could get very interesting.

[bplus]

https://en.wikipedia.org/wiki/Conflict:_Middle_East_Political_Simulator

Oh my! This is an ambitious project!

[bplus]

Code to reduce length of dates1$ function

Code: QB64: [Select]

1. ' code to test dates1$
2. DO
3.     INPUT "Enter a month number 1 to 100 "; mn
4.     PRINT dates1$(mn)
5. LOOP UNTIL mn = 0
6.  
7. FUNCTION month$ (n) 'for dates1$ function
8.     RESTORE 4
9.     FOR i = 1 TO n
10.         READ month$
11.     NEXT
12.    4 DATA JANUARY,FEBRUARY,MARCH,APRIL,MAY,JUNE,JULY,AUGUST,SEPTEMBER,OCTOBER,NOVEMBER,DECEMBER
13. END FUNCTION
14.  
15. FUNCTION dates1$ (months)
16.     m = months MOD 12
17.     IF m = 0 THEN m = 12
18.     dates1$ = month$(m) + "," + STR$(INT((months - 1) / 12) + 2027)
19. END FUNCTION

So it's true, you don't need quotes around strings in DATA, nice.

[bplus]

Hi Ron,

I was curious if I could get a generic MenuChoice% Function going. I did. Here is what your code looks like with that (didn't mess with Foreign because you are changing the options in that sub) Oh I installed a Meet Menu because it is usually just 1 department you want to meet with to respond to latest news (as far as I can tell).

Code: QB64: [Select]

1. _TITLE "CONFLICT - SIMULATION GAME" 'started by ron77 on 11-12-2019 - made a working skeleton of subs... need more work to be complited
2. '11-16-2019 continuing working on the game with help of bplus and my teacher. added functions for more options bottens...
3. 'added time scale for how long the game will be played...
4.  
5. DEFINT A-Z
6. REDIM SHARED news$(0), options$(0) ', un$(0)
7. DIM SHARED GovernmentType, MilitaryAction, ForeignAction$, EconomicAction, PeaceButtonIndicator AS INTEGER, PeaceProssessCounter AS INTEGER
8. DIM SHARED time AS INTEGER
9. RANDOMIZE TIMER
10. SCREEN 0
11. PeaceButtonIndicator = 1
12. PeaceProssessCounter = 1
13. time = 1
14.  
15. loadNews
16. 'UnCouncil
17. Opening
18. DO
19.     CLS
20.     cp 2, dates1$(time): PRINT: PRINT
21.     time = time + 1
22.     PRINT NewsUpdate$
23.     PRINT: INPUT "Press enter when you have read the latest news... "; wayt$
24.     dept = menuChoice("Meet")
25.     SELECT CASE dept
26.         CASE 1: MilitaryAction = menuChoice("Military")
27.         CASE 2: EconomicAction = menuChoice("Economic")
28.         CASE 3: Foreign
29.     END SELECT
30. LOOP UNTIL time = 49
31.  
32. SUB Opening
33.     cp 4, "CONFLICT - STRATEGIC POLITICAL SIMULATION"
34.     cp 6, "BY RON77 AND Bplus AND ITAY"
35.     COLOR 31: cp 8, "PRESS ANY KEY 1 TO BEGIN OR ESC KEY TO EXIT": COLOR 7
36.     k$ = GetKey$("1" + CHR$(27))
37.     IF k$ = CHR$(27) THEN END
38.  
39.     CLS
40.     cp 3, "YOU ARE THE NEWLY ELECTED PRIME MINISTER OF THE STATE OF ISRAEL"
41.     cp 5, "YOU PROMISSED THE ISRAELI VOTERS - 'PEACE AND SECURITY'"
42.     cp 7, "HOWEVER THE MIDDLE EAST IS BURNING FROM TERROR AND INSTABILITY"
43.     cp 9, "HAMAS FROM GAZA AND HIZZBALLA FROM LEBANON AND IRAN ARE THRETHENING"
44.     cp 11, "TO DESTROY ISRAEL AND KILL ALL ISRAELIS"
45.     cp 13, "THE FAITH OF THE ISRAELI NATION IS IN YOUR HANDS"
46.     cp 15, "MAY GOD BE WITH YOU! - GOOD LUCK!"
47.     cp 19, "press any to continue..."
48.     SLEEP
49.  
50.     GovernmentType = menuChoice("Government")
51. END SUB
52.  
53.  
54. SUB Foreign
55.  
56.     IF PeaceButtonIndicator = 2 AND PeaceProssessCounter < 6 THEN
57.         p$ = peace$(PeaceProssessCounter)
58.         'PRINT p$
59.         PeaceProssessCounter = PeaceProssessCounter + 1
60.     ELSEIF PeaceProssessCounter >= 6 THEN
61.         p$ = peace$(PeaceProssessCounter)
62.     END IF
63.  
64.     SELECT CASE PeaceButtonIndicator
65.         CASE 1: PeaceButton$ = "1. START A SECRET NEGOTIOATION CHANNEL WITH HAMAS\HIZZBALLA\IRAN"
66.         CASE 2: PeaceButton$ = "1. WE ARE NEGOTITATHING SECRETLY WITH THE IRANIANS, SHELL WE STOP?"
67.         CASE 3: PeaceButton$ = "1. SIGN A PEACE AGREEMENT WITH IRAN\HAMAS\HIZZBALLA"
68.         CASE 4: PeaceButton$ = "1. BREAK THE PEACE AGREEMENT WITH IRAN\HAMAS\HIZZBALLA"
69.     END SELECT
70.     CLS
71.     cp 2, "FOREIGN AFFAIRS MINISTER AT YOUR SERVICE. SIR!"
72.     lp 4, 2, PeaceButton$
73.     lp 5, 2, "2. ASK THE U.N. SECURITY COUNCIL TO CONDEMN AND SANCTION IRAN\HAMAS\HIZZBALLA"
74.     lp 6, 2, "3. ASK THE U.S. FOR AID"
75.     lp 7, 2, "4. TRY TO INCREASE WORLD SUPPORT FOR ISRAEL BY MAKING A SPEECH IN THE U.N."
76.     lp 8, 2, "5. FIND ALLIES IN OTHER COUNTRIES WHO ARE ENEMIES OF IRAN\HAMAS\HIZZBALLA"
77.     lp 9, 2, "6. DO NOTHING FOR THE MOMENT - LET'S WAIT AND SEE HOW THINGS DEVELOP"
78.     cp 11, "CHOOSE 1 2 3 4 5 OR 6"
79.     PRINT
80.     PRINT p$
81.     PRINT
82.  
83.  
84.     ForeignAction$ = GetKey$("123456")
85.     IF ForeignAction$ = "1" AND PeaceButtonIndicator = 1 THEN
86.         PeaceButtonIndicator = 2
87.     ELSEIF ForeignAction$ = "1" AND PeaceButtonIndicator = 2 AND PeaceProssessCounter < 6 THEN
88.         PeaceButtonIndicator = 1
89.         PeaceProssessCounter = 1
90.     ELSEIF PeaceButtonIndicator = 2 AND PeaceProssessCounter = 6 THEN
91.         PeaceButtonIndicator = 3
92.     ELSEIF ForeignAction$ = "1" AND PeaceButtonIndicator = 3 THEN
93.         PeaceButtonIndicator = 4
94.         PeaceProssessCounter = 7
95.     ELSEIF ForeignAction$ = "1" AND PeaceButtonIndicator = 4 THEN
96.         PeaceButtonIndicator = 1
97.         PeaceProssessCounter = 1
98.     END IF
99.  
100.     IF ForeignAction$ = "2" THEN
101.         PRINT UnCouncil$(INT(RND * 4) + 1)
102.         PRINT
103.         SLEEP
104.     END IF
105.     IF ForeignAction$ = "3" THEN
106.         PRINT UsAid$(INT(RND * 6) + 1)
107.         PRINT
108.         SLEEP
109.     END IF
110. END SUB
111.  
112. FUNCTION peace$ (n) ' how to make a function out of a string array!!!
113.     SELECT CASE n
114.         CASE 1: peace$ = "WE HAVE STARTED TO NEGOTIATE SECRETLY WITH THE IRANIANS. PROGRESS IS SLOW. IT WILL TAKE TIME"
115.         CASE 2: peace$ = "WE ARE NEGOTIATING WITH THE IRANIANS BUT IT LOOKS LIKE THEY ARE DELAYING ON PURPOSE TIME WHILE THE NEGOTIATION IS STUCK"
116.         CASE 3: peace$ = "THERE IS CONCERN THAT THE SECRET CHANNEL BETWEEN US AND THE IRANIANS WILL LEAK TO THE PRESS. IF SO THIS MAY PUT AN END TO THE NEGOTIATIONS"
117.         CASE 4: peace$ = "THE NEGOTIATION TEAMS BETWEEN US AND IRAN HAVE DONE SOME PROGRESS... WE NEED MORE TIME"
118.         CASE 5: peace$ = "WE ARE CLOSE TO A PEACE AGREEMENT BETWEEN US AND THE IRANIANS TO END ALL HOSTILITY JUST A FEW MORE DETILES"
119.         CASE 6: peace$ = "WE HAVE A PEACE AGREEMENT READY BETWEEN US AND THE IRANIANS - ARE YOU READY TO SIGN IT?"
120.         CASE 7: peace$ = "WE HAVE SIGN A PEACE AGREEMENT WITH IRAN\HAMAS\HIZZBALLA. NOT MORE WAR NO MORE BLOODSHED!"
121.     END SELECT
122. END FUNCTION
123.  
124. 'SUB UnCouncil
125. '    REDIM un$(1 TO 4)
126. '    un$(1) = "THE U.N. COUNCIL HAS REJECTED OUR REQUEST FOR CONDEMMING IRAN OT HAMAS OR HIZZBLLA"
127. '    un$(2) = "THE U.N. COUNCIL HAS REVERSED OUR REQUEST AND ADOPTED THE INDONASIAN'S REQUEST FOR CONDOMMING ISRAEL AS AN AGGRESSIVE APARTHIDE RACIST STATE"
128. '    un$(3) = "OUR REQUEST HAS REACHED TO THE SECURITY COUNCIL OF THE U.N. BUT A VETO BY RUSSIA AND CHINA HAS CANCELED ANY CHANCE OF CONDEMMING IRAN OR HIZZBALLA OR HAMAS AS TERROR ORGANIZATIONS"
129. '    un$(4) = "THE SECURITY COUNCIL OF THE U.N. HAD VOTED AGAINST IRAN AND HIZZBALLA AND HAMAS CALLING THEM A TERROR ORGANIZATIONS AND SAYING THAT ISRAEL HAS A RIGHT TO DEFEND ITSELF AND IT'S CITIZENS"
130. 'END SUB
131.  
132.  
133. FUNCTION UnCouncil$ (n)
134.     'REDIM un$(1 TO 4)
135.     SELECT CASE n
136.         CASE 1: UnCouncil$ = "THE U.N. COUNCIL HAS REJECTED OUR REQUEST FOR CONDEMMING IRAN OT HAMAS OR HIZZBLLA"
137.         CASE 2: UnCouncil$ = "THE U.N. COUNCIL HAS REVERSED OUR REQUEST AND ADOPTED THE INDONASIAN'S REQUEST FOR CONDOMMING ISRAEL AS AN AGGRESSIVE APARTHIDE RACIST STATE"
138.         CASE 3: UnCouncil$ = "OUR REQUEST HAS REACHED TO THE SECURITY COUNCIL OF THE U.N. BUT A VETO BY RUSSIA AND CHINA HAS CANCELED ANY CHANCE OF CONDEMMING IRAN OR HIZZBALLA OR HAMAS AS TERROR ORGANIZATIONS"
139.         CASE 4: UnCouncil$ = "THE SECURITY COUNCIL OF THE U.N. HAD VOTED AGAINST IRAN AND HIZZBALLA AND HAMAS CALLING THEM A TERROR ORGANIZATIONS AND SAYING THAT ISRAEL HAS A RIGHT TO DEFEND ITSELF AND IT'S CITIZENS"
140.     END SELECT
141. END SUB
142.  
143. FUNCTION UsAid$ (n)
144.     SELECT CASE n
145.         CASE 1: UsAid$ = "IT IS AN ELECTION YEAR IN THE USA SO YOU ARE SUCCESSFUL IN WINING SUPPORT FOR ISRAEL SENATORS AND CONGRESSMANS PROMISS TO INCRESS AID AND SUPPORT FOR ISRAEL AND AGINST IRAN AND HAMAS AND HIZZBALLA"
146.         CASE 2: UsAid$ = "THE US CONGRESS AND SENATE PASS A LAW TO BAN IRAN AND HAMAS AND HIZZBALLA AND DECLEARE THEM AS TERROR ORGANIZATIONS"
147.         CASE 3: UsAid$ = "YOU ARE INVITED TO THE WHITE HOUSE FOR AN PHOTO-OP WITH THE U.S. PRESIDENT BESIDES THAT YOU ACHIVE ALMOST NOTHING 'WE SUPPORT YOU AND AID YOU ENOGH' SAYS TO YOU THE PRESIDENT BEHIND CLOSE DOORS"
148.         CASE 4: UsAid$ = "THE U.S. PRESIDENT APPEARS IN A PRESS PARTY AND DECLEARE 'ISRAEL HAS THE RIGHT TO DEFEND ITSELF AND ISRAELIS HAVE A RIGHT TO LIVE IN PEACE AND SECURITY"
149.         CASE 5: UsAid$ = "THE U.S.A. IS OCCUPY BY IT'S OWN PROBLEMS. THE U.S. AMBASSADOR TELLS YOU IT'S NOT A GOOD TIME TO ASK FOR AID OF ANY KIND FROM THE U.S."
150.         CASE 6: UsAid$ = "THE U.S.A. GOVERNMENT DICIDED TO INCREASE IT'S FOREIGN AID TO ISRAEL"
151.     END SELECT
152. END FUNCTION
153.  
154. SUB loadNews 'don't try to cp these lines, they are too long
155.     REDIM news$(1 TO 9)
156.     news$(1) = "HAMAS HAS LUNCHED MISSILES TO THE SOUTHEREN BORDER THE PUBLIC DEMANDS ACTION"
157.     news$(2) = "HIZZBALLA HAS ATTACKED A BASE NEAR THE NORTHEN BORDER 2 OF OUR SOLDIERS ARE MISSING - WHAT SHELL BE OUR RESPONSE?"
158.     news$(3) = "IRAN IS BUILDING A NUCLEAR SITE FOR PLUTONIUM WITHIN A FEW YEARS THEY WILL HAVE AN ATOMIC WEPONE AGAINST US - WE MUST DO SOMETHING!"
159.     news$(4) = "HAMAS HAS SECRETLY CONTACTED THE FORINE AFFAIRS OFFICE WITH A MESSAGE THEY WANT PEACE AND STABILITY - SHELL WE NEGOTIATE?"
160.     news$(5) = "THE U.S. PRESIDENT HAS ASKED US TO CONSIDER A PEACE DEAL WITH IRAN - IN RETURN THE U.S. WILL EQUIPTE OUR ARMY WITH THE LATEST WEPONES AND INCREASE THE MILITERY AID"
161.     news$(6) = "OUR ECONOMY IS NOT DOING GOOD WE SPEND TOO MUCH MONEY ON THE MILITERY - WE NEED TO CHOOSE EITHER MORE TAXS OR DECREASE SPENDING"
162.     news$(7) = "IRAN PRESIDENT HAS SAID THAT 'ISRAEL MUST AND WILL BE ERASED FROM THE MAP!' - HOW SHELL WE RESPOND TO THIS PROVOCATION?"
163.     news$(8) = "IRANIAN DIPLOMATES HAVE CONTACTED THE FORINE AFFAIRS AMBASSADOR IN CHILE AND ASKED TO OPEN A SECRET NEGOTIATION - SHELL WE AGREE?"
164.     news$(9) = "OUR ECONOMY IS BOOMING AND FLURISHING WE NEED TO DISIDE EITHER TO INCREASE DEFENCE BUDGET OR MAYBE DECRESE TAXS"
165. END SUB
166.  
167. FUNCTION NewsUpdate$ ()
168.     'cp 2, dates1$(time)
169.     'PRINT
170.     NewsUpdate$ = news$(INT(RND * 9) + 1)
171.     'time = time + 1
172. END FUNCTION
173.  
174. 'cp needs s$ to be less that width of screen
175. SUB cp (row, s$)
176.     LOCATE row, INT((_WIDTH - LEN(s$)) / 2): PRINT s$;
177. END SUB
178.  
179. SUB lp (row, col, s$)
180.     LOCATE row, col: PRINT s$;
181. END SUB
182.  
183. FUNCTION GetKey$ (keysToCatch$)
184.     DIM k$
185.     DO
186.         k$ = INKEY$
187.         WHILE LEN(k$) = 0
188.             k$ = INKEY$
189.             _LIMIT 60
190.         WEND
191.     LOOP UNTIL INSTR(keysToCatch$, k$)
192.     GetKey$ = k$
193. END FUNCTION
194.  
195. FUNCTION month$ (n) 'for dates1$ function
196.     RESTORE 4
197.     FOR i = 1 TO n
198.         READ month$
199.     NEXT
200.    4 DATA JANUARY,FEBRUARY,MARCH,APRIL,MAY,JUNE,JULY,AUGUST,SEPTEMBER,OCTOBER,NOVEMBER,DECEMBER
201. END FUNCTION
202.  
203. FUNCTION dates1$ (months)
204.     m = months MOD 12
205.     IF m = 0 THEN m = 12
206.     dates1$ = month$(m) + "," + STR$(INT((months - 1) / 12) + 2027)
207. END FUNCTION
208.  
209. SUB sAppend (arr() AS STRING, item AS STRING)
210.     REDIM _PRESERVE arr(LBOUND(arr) TO UBOUND(arr) + 1) AS STRING
211.     arr(UBOUND(arr)) = item
212. END SUB
213.  
214. FUNCTION menuChoice% (menu$)
215.     SELECT CASE menu$ 'what list of options do we retore data line to?
216.         CASE IS = "Government": RESTORE Gov
217.         CASE IS = "Military": RESTORE Mil
218.         CASE IS = "Economic": RESTORE Econ
219.         CASE IS = "Meet": RESTORE Meet
220.     END SELECT
221.     REDIM options$(1)
222.     READ options$(1)
223.     DO
224.         READ r$
225.         IF r$ <> "endOfData" THEN sAppend options$(), r$
226.     LOOP UNTIL r$ = "endOfData"
227.     'redim shared Options$() call load Options$ can't get more than 9 options
228.     CLS
229.     lb = LBOUND(options$): ub = UBOUND(options$)
230.     nOptions = ub - lb + 1
231.     row = (25 - nOptions - 4) \ 2
232.     cp row, options$(1) 'option 1 is title
233.     row = row + 2
234.     FOR i = 2 TO ub
235.         lp row, 2, options$(i)
236.         row = row + 1
237.         digit = digit + 1
238.         digits$ = digits$ + _TRIM$(STR$(digit))
239.     NEXT
240.     row = row + 1
241.     cp row, "Please enter the option number of your choice "
242.     menuChoice% = VAL(GetKey$(digits$))
243.     EXIT FUNCTION
244.  
245.     Gov:
246.     DATA WHAT TYPE OF GOVERNMENT WILL YOU MAKE?
247.     DATA 1. MAKE A LEFT WING GOVERNMENT AND TRY TO ACHIVE PEACE WITH THE ARAB WORLD
248.     DATA 2. MAKE A CONSERVATIVE CENTER GOVERNMENT THAT WILL TRY TO MAINTAINE STABILITY
249.     DATA 3. MAKE A RIGHT WING GOVERNMENT THAT WILL FIGHT ISRAEL'S ENEMIES
250.     DATA endOfData
251.  
252.     Meet:
253.     DATA WHO SHALL WE CALL FOR A MEETING TO RESPOND TO LATEST NEWS
254.     DATA 1. MILITARY LEADERS
255.     DATA 2. ECONOMIC EXECUTIVES
256.     DATA 3. FOREIGN AMBASSADORS
257.     DATA endOfData
258.  
259.     Mil:
260.     DATA THE MILITARY IS WAITING FOR YOUR ORDERS SIR!
261.     DATA 1. ASSASINATE A KEY FIGURE IN HAMAS\HIZZBALLA\IRAN MILITERY ORGANIZATION
262.     DATA 2. OPEN A LIMITED MILITERY OPERATION AGAINST HAMAS\HIZZBALLA
263.     DATA 3. BOMB STRATEGIC TARGETS IN IRAN TO DESTROY NUCLEAR FACILITIES
264.     DATA 4. TRY TO DISTABLIZED IRAN\HAMAS\HIZZBALLA BY GIVING AID TO REBEL OPOSITION
265.     DATA 5. DO NOTHING FOR THE MOMENT - LET'S WAIT AND SEE HOW THINGS DEVELOP
266.     DATA endOfData
267.  
268.     Econ:
269.     DATA THE ECONOMIC CABINET IS READY TO MEET YOU PRIME MINISTER
270.     DATA 1. INCREASE DEFENCE BUDGET AND RAISE TAXS
271.     DATA 2. DECREASE DEFENCE BUDGET AND LOWER TAXS
272.     DATA 3. LEAVE THE BUDGET AS IT IS FOR NOW
273.     DATA endOfData
274. END FUNCTION

What is nice about menuChoice is that everything you need for displaying a menu and getting the key choice (in a number now) is there in the function including all the DATA for filling out the specific menus.

EDIT: this line
DATA data end
 is being  changed to this
DATA DATA END so the read loop was not stopping where it was programmed to stop.

Changed lines to endOfData

[bplus]

hi bplus :)

i integreted your improved dates1$ function to the games code and as for the generic MenuChoice% version of the game well...
when i run it i get right away an error message "out of DATA" on "line 224" in any case you are right when you wrote me that i should stick to the previous version (but including the improved dates1$ function) cuz i plan to be able to do dynamic changes to the military sub or economic sub  like i did with the foreign minister sub...

tonight it looks like i'm going to code further the game and by morning sunrise i'll post the code again...

ron77 

Oh ha! The forum code box changed:

DATA data end

to
DATA DATA END

Poor choice of words for end of data line. I will edit previous post.

[SMcNeill]

Oh ha! The forum code box changed:

DATA data end

to
DATA DATA END

Poor choice of words for end of data line. I will edit previous post.

EOD is what I normally use for End Of Data.