Rotating Sprites

[Zeppelin]

Hey everyone,
Is it possible to rotate sprites with PUT, e.g. rotating an image to a specific degree.
Or am I going to have to calculate each corner of the images coordinates?

Thanks,
Zep

[RhoSigma]

Have a look on the examples here http://www.qb64.org/wiki/MAPTRIANGLE

[Zeppelin]

RhoSigma,
MAPTRIANGLE doesnt seem to be working for me. Whenever I try to display the sprite, nothing appears (its just black).
Could this be that I'm not using an actual image?

Zep

[bplus]

Hi Zep,

Here is my first test code with Rotozoom mod:

[William33]

I once changed rotozoom, so it lets you draw a part of an image, rotated and scaled:

Code: QB64: [Select]

1. SUB RotoZoom (X AS INTEGER, Y AS INTEGER, Image AS LONG, startx AS INTEGER, starty AS INTEGER, xoffset AS INTEGER, yoffset AS INTEGER, Scale AS SINGLE, Rotation AS SINGLE)
2.     DIM px(3) AS SINGLE: DIM py(3) AS SINGLE
3.     W& = _WIDTH(Image&): H& = _HEIGHT(Image&)
4.     px(0) = (-xoffset + startx) / 2: py(0) = (-yoffset + starty) / 2: px(1) = (-xoffset + startx) / 2: py(1) = (yoffset - starty) / 2
5.     px(2) = (xoffset - startx) / 2: py(2) = (yoffset - starty) / 2: px(3) = (xoffset - startx) / 2: py(3) = (-yoffset + starty) / 2
6.     sinr! = SIN(-Rotation / 57.2957795131): cosr! = COS(-Rotation / 57.2957795131)
7.     FOR i& = 0 TO 3
8.         x2& = Scale * (px(i&) * cosr! + sinr! * py(i&)) + X: y2& = Scale * (py(i&) * cosr! - px(i&) * sinr!) + Y
9.         px(i&) = x2&: py(i&) = y2&
10.     NEXT
11.     _MAPTRIANGLE (startx, starty)-(startx, yoffset - 1)-(xoffset - 1, yoffset - 1), Image& TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
12.     _MAPTRIANGLE (startx, starty)-(xoffset - 1, starty)-(xoffset - 1, yoffset - 1), Image& TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
13. END SUB

[SMcNeill]

I've got a simple little DisplayImage routine which I use for rotating images and such, as illustrated here:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. text = TextToImage("Steve is Awesome!", 16, &HFFFF0000, &HFFFFFF00, 0)
3. text2h = ScaleImage(text, 2, 1) 'twice as high
4. text2w = ScaleImage(text, 1, 2) 'twice as wide
5. text4 = ScaleImage(text, 4, 4) 'four times normal size
6.  
7. DO
8.     angle = (angle + 1) MOD 360
9.     CLS
10.     DisplayImage text, 50, 50, 0, 1
11.     DisplayImage text2h, 50, 100, 0, 1
12.     DisplayImage text2w, 50, 150, 0, 1
13.     DisplayImage text4, 400, 300, angle, 0
14.     _LIMIT 60
15.     _DISPLAY
16. LOOP UNTIL _KEYHIT
17. SYSTEM
18.  
19. SUB DisplayImage (Image AS LONG, x AS INTEGER, y AS INTEGER, angle AS SINGLE, mode AS _BYTE)
20.     'Image is the image handle which we use to reference our image.
21.     'x,y is the X/Y coordinates where we want the image to be at on the screen.
22.     'angle is the angle which we wish to rotate the image.
23.     'mode determines HOW we place the image at point X,Y.
24.     'Mode 0 we center the image at point X,Y
25.     'Mode 1 we place the Top Left corner of oour image at point X,Y
26.     'Mode 2 is Bottom Left
27.     'Mode 3 is Top Right
28.     'Mode 4 is Bottom Right
29.  
30.  
31.     DIM px(3) AS INTEGER, py(3) AS INTEGER, w AS INTEGER, h AS INTEGER
32.     DIM sinr AS SINGLE, cosr AS SINGLE, i AS _BYTE
33.     w = _WIDTH(Image): h = _HEIGHT(Image)
34.     SELECT CASE mode
35.         CASE 0 'center
36.             px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2
37.             px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
38.         CASE 1 'top left
39.             px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0
40.             px(1) = 0: py(1) = h: px(2) = w: py(2) = h
41.         CASE 2 'bottom left
42.             px(0) = 0: py(0) = -h: px(3) = w: py(3) = -h
43.             px(1) = 0: py(1) = 0: px(2) = w: py(2) = 0
44.         CASE 3 'top right
45.             px(0) = -w: py(0) = 0: px(3) = 0: py(3) = 0
46.             px(1) = -w: py(1) = h: px(2) = 0: py(2) = h
47.         CASE 4 'bottom right
48.             px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h
49.             px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
50.     END SELECT
51.     sinr = SIN(angle / 57.2957795131): cosr = COS(angle / 57.2957795131)
52.     FOR i = 0 TO 3
53.         x2 = (px(i) * cosr + sinr * py(i)) + x: y2 = (py(i) * cosr - px(i) * sinr) + y
54.         px(i) = x2: py(i) = y2
55.     NEXT
56.     _MAPTRIANGLE (0, 0)-(0, h - 1)-(w - 1, h - 1), Image TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
57.     _MAPTRIANGLE (0, 0)-(w - 1, 0)-(w - 1, h - 1), Image TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
58. END SUB
59.  
60. FUNCTION TextToImage& (text$, font&, fc&, bfc&, mode AS _BYTE)
61.     'text$ is the text that we wish to transform into an image.
62.     'font& is the handle of the font we want to use.
63.     'fc& is the color of the font we want to use.
64.     'bfc& is the background color of the font.
65.  
66.     'Mode 1 is print forwards
67.     'Mode 2 is print backwards
68.     'Mode 3 is print from top to bottom
69.     'Mode 4 is print from bottom up
70.     'Mode 0 got lost somewhere, but it's OK.  We check to see if our mode is < 1 or > 4 and compensate automatically if it is to make it one (default).
71.  
72.     IF mode < 1 OR mode > 4 THEN mode = 1
73.     dc& = _DEFAULTCOLOR: bgc& = _BACKGROUNDCOLOR
74.     D = _DEST
75.     F = _FONT
76.     IF font& <> 0 THEN _FONT font&
77.     IF mode < 3 THEN
78.         'print the text lengthwise
79.         w& = _PRINTWIDTH(text$): h& = _FONTHEIGHT
80.     ELSE
81.         'print the text vertically
82.         FOR i = 1 TO LEN(text$)
83.             IF w& < _PRINTWIDTH(MID$(text$, i, 1)) THEN w& = _PRINTWIDTH(MID$(text$, i, 1))
84.         NEXT
85.         h& = _FONTHEIGHT * (LEN(text$))
86.     END IF
87.  
88.     TextToImage& = _NEWIMAGE(w&, h&, 32)
89.     _DEST TextToImage&
90.     IF font& <> 0 THEN _FONT font&
91.     COLOR fc&, bfc&
92.  
93.     SELECT CASE mode
94.         CASE 1
95.             'Print text forward
96.             _PRINTSTRING (0, 0), text$
97.         CASE 2
98.             'Print text backwards
99.             temp$ = ""
100.             FOR i = 0 TO LEN(text$) - 1
101.                 temp$ = temp$ + MID$(text$, LEN(text$) - i, 1)
102.             NEXT
103.             _PRINTSTRING (0, 0), temp$
104.         CASE 3
105.             'Print text upwards
106.             'first lets reverse the text, so it's easy to place
107.             temp$ = ""
108.             FOR i = 0 TO LEN(text$) - 1
109.                 temp$ = temp$ + MID$(text$, LEN(text$) - i, 1)
110.             NEXT
111.             'then put it where it belongs
112.             FOR i = 1 TO LEN(text$)
113.                 fx = (w& - _PRINTWIDTH(MID$(temp$, i, 1))) / 2 + .99 'This is to center any non-monospaced letters so they look better
114.                 _PRINTSTRING (fx, _FONTHEIGHT * (i - 1)), MID$(temp$, i, 1)
115.             NEXT
116.         CASE 4
117.             'Print text downwards
118.             FOR i = 1 TO LEN(text$)
119.                 fx = (w& - _PRINTWIDTH(MID$(text$, i, 1))) / 2 + .99 'This is to center any non-monospaced letters so they look better
120.                 _PRINTSTRING (fx, _FONTHEIGHT * (i - 1)), MID$(text$, i, 1)
121.             NEXT
122.     END SELECT
123.     _DEST D
124.     COLOR dc&, bgc&
125.     _FONT F
126. END FUNCTION
127.  
128. FUNCTION ScaleImage& (Image AS LONG, xscale AS SINGLE, yscale AS SINGLE)
129.     w = _WIDTH(Image): h = _HEIGHT(Image)
130.     w2 = w * xscale: h2 = h * yscale
131.     NewImage& = _NEWIMAGE(w2, h2, 32)
132.     _PUTIMAGE , Image&, NewImage&
133.     ScaleImage& = NewImage&
134. END SUB