Fireflies

[bplus]

Hey Steve,

Nice speed! where are the halo's? Can memory do alpha?

LOL B+, I had a feeling you would say that. Going wayyyy back to the 80's, arrays haven't really been my friend lol. But I am learning. Thanks for telling me, I'll look into it.

Yeah, I know the feeling, I confess I am a little stuck when it comes to Steve's memory and 3D with GL.

Practice on something simple, you have already worked that you are familiar. This is ideal time for me and memory, thanks Steve!

[SierraKen]

LOL SMcNeill, it looks like you combined my math with B+'s code to make the trails and mountains. Not sure though. If both of you don't care, I'll put your 2 names on the code with mine and put it on my website. But I do need to practice the code as well to learn more. But thank you!

[bplus]

I love it when everybody's name gets to go on the code! :D

Actually one of us should put the halos back up and STxAxTIC  gave me an idea to try, so if you don't mind, I am not done yet. :D

[SierraKen]

LOL OK :)

[bplus]

Oh just a very simple little change in Steve's post, change Glow near the top, CONST
CONST glow = &H1FFFFFFF, ...

Now the flies are angelic! ;-))

[bplus]

And here is STxAxTIC idea to simplify code for much more elegant solution, it worked very well! thank you very much!

Code: QB64: [Select]

1. OPTION _EXPLICIT ' B+ 2019-09-02 with STxAxTIC idea for simplification
2. 'Thanks to Ken for inspiring mod fun!
3. 'Thanks to Bplus on the QB64.org forum for the trail code.
4. 'Made on Aug. 30, 2019 by Ken G. mod by B+
5. '2019-09-01 mod of Fireflies #2 taking fly paths from Bugs on fire and adding Frames array
6. ' for layering partially faded screens to get trails effect WITH a background display!
7. ' 2 experiments have failed to produce desired trails do to my erroneous way of thinking.
8. ' Time to pull out the heavy guns, cds Tools, and test an array like string of x, y locations.
9. ' This might be a little complicated! We will be fading out old locations with transparencies
10. ' rather than drawing over and over again with smoke layers.
11. ' 2019-09-02 #4 mod Fireflies #3 with STxAxTIC idea dump the cds Tools!
12. ' since flies are on a rail, you can backtrack locations from last angle used!
13. ' No need to save the locations in an array! Much more elegant.
14.  
15. '        GLOBALS
16. CONST nFlies = 25, xmax = 800, ymax = 600, cx = 400, cy = 300
17.  
18. TYPE flyType
19.     a AS SINGLE
20.     rr AS SINGLE 'random coeff = radius of flight path
21.     m AS SINGLE
22.     n AS SINGLE
23.     r AS SINGLE
24.     red AS INTEGER
25.     green AS INTEGER
26.     blue AS INTEGER
27. END TYPE
28.  
29. '     LOCALS for main code which is all this is!
30. DIM i AS INTEGER, j AS INTEGER, a, bg&, x, y, ma
31.  
32. _TITLE "Fireflies #4 that glow, trails and background"
33. SCREEN _NEWIMAGE(800, 600, 32)
34. _SCREENMOVE 300, 60
35. RANDOMIZE TIMER
36.  
37. 'prepare background image
38. bg& = _NEWIMAGE(xmax, ymax, 32)
39. drawLandscape
40. _PUTIMAGE , 0, bg&
41. 'setup trans
42. DIM tr(0 TO 49) AS INTEGER
43. FOR i = 0 TO 49
44.     IF i <> 49 THEN tr(i) = INT(i / 3) + 1 ELSE tr(i) = 255
45. NEXT
46. 'setup flies
47. DIM SHARED f(1 TO nFlies) AS flyType
48. FOR i = 1 TO nFlies 'bug maker
49.     f(i).r = RND * 3 + 1 '         radius
50.     f(i).rr = RND * 200 + 250 '    radius of orbit
51.     f(i).m = RND * 25 '            orbit cooff
52.     f(i).n = RND * 25 '            orbit coeff 2
53.     f(i).red = RND * 190 + 60 '    need to separartye color for alpha changes
54.     f(i).green = RND * 190 + 60
55.     f(i).blue = RND * 190 + 60
56.     f(i).a = RND * _PI(2) '        angle in orbit that tracks location of x, y
57. NEXT
58.  
59. DO
60.     _PUTIMAGE , bg&, 0 'cls last screen shot
61.     FOR i = 1 TO nFlies 'move bug
62.         'mod a to radius of flight path  so they move approximately same rate
63.         ma = .15 / f(i).rr
64.         f(i).a = f(i).a + ma 'update f(i).a
65.         'starting from f(i).a draw next 50 flies in this orbit with increasing opacity
66.         FOR j = 0 TO 49 'calc new location and draw
67.             a = f(i).a + j * ma
68.             x = cx + f(i).rr * 1.5 * (COS(f(i).n * a) / 2 + SIN(f(i).m * a) / 3)
69.             y = cy + f(i).rr * 1.25 * (SIN(f(i).n * a) / 2 + COS(f(i).m * a) / 3)
70.             fcirc x, y, f(i).r + 8, _RGBA32(255, 255, 255, .15 * tr(j))
71.             fcirc x, y, f(i).r, _RGBA32(f(i).red, f(i).green, f(i).blue, tr(j))
72.         NEXT
73.     NEXT
74.     IF INKEY$ = CHR$(27) THEN END
75.     _DISPLAY
76.     _LIMIT 200
77. LOOP
78.  
79. 'from Steve Gold standard
80. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
81.     DIM Radius AS INTEGER, RadiusError AS INTEGER
82.     DIM X AS INTEGER, Y AS INTEGER
83.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
84.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
85.     LINE (CX - X, CY)-(CX + X, CY), C, BF
86.     WHILE X > Y
87.         RadiusError = RadiusError + Y * 2 + 1
88.         IF RadiusError >= 0 THEN
89.             IF X <> Y + 1 THEN
90.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
91.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
92.             END IF
93.             X = X - 1
94.             RadiusError = RadiusError - X * 2
95.         END IF
96.         Y = Y + 1
97.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
98.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
99.     WEND
100. END SUB
101.  
102. SUB drawLandscape
103.     'needs midInk, irnd
104.  
105.     DIM i AS INTEGER, startH AS SINGLE, rr AS INTEGER, gg AS INTEGER, bb AS INTEGER
106.     DIM mountain AS INTEGER, Xright AS SINGLE, y AS SINGLE, upDown AS SINGLE, range AS SINGLE
107.     DIM lastx AS SINGLE, X AS INTEGER
108.     'the sky
109.     FOR i = 0 TO ymax
110.         midInk 0, 0, 48, 28, 0, 88, i / ymax
111.         LINE (0, i)-(xmax, i)
112.     NEXT
113.     'the land
114.     startH = ymax - 400
115.     rr = 40: gg = 50: bb = 60
116.     FOR mountain = 1 TO 6
117.         Xright = 0
118.         y = startH
119.         WHILE Xright < xmax
120.             ' upDown = local up / down over range, change along Y
121.             ' range = how far up / down, along X
122.             upDown = (RND * .8 - .35) * (mountain * .5)
123.             range = Xright + irnd%(15, 25) * 2.5 / mountain
124.             lastx = Xright - 1
125.             FOR X = Xright TO range
126.                 y = y + upDown
127.                 COLOR _RGB(rr, gg, bb)
128.                 LINE (lastx, y)-(X, ymax), , BF 'just lines weren't filling right
129.                 lastx = X
130.             NEXT
131.             Xright = range
132.         WEND
133.         rr = irnd%(rr - 15, rr): gg = irnd%(gg - 15, gg): bb = irnd%(bb - 25, bb)
134.         IF rr < 0 THEN rr = 0
135.         IF gg < 0 THEN gg = 0
136.         IF bb < 0 THEN bb = 0
137.         startH = startH + irnd%(5, 20)
138.     NEXT
139. END SUB
140.  
141. SUB midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
142.     COLOR _RGB32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
143. END SUB
144.  
145. FUNCTION irnd% (n1, n2) 'return an integer between 2 numbers
146.     DIM l%, h%
147.     IF n1 > n2 THEN l% = n2: h% = n1 ELSE l% = n1: h% = n2
148.     irnd% = INT(RND * (h% - l% + 1)) + l%
149. END FUNCTION
150.  

[TempodiBasic]

Fireflies last code of Bplus under guide of SxTAxTIxC

 

[SierraKen]

Amazing stuff.

[johnno56]

Very nicely done! Two things I noticed... 1. No more alignments. I have the eye strain to prove it... lol and 2. Looks like Perlin noise landscapes... Cool...

Oh. If you can only code in a rolled up newspaper, you can probably make a game out of this... or maybe not... lol

[SierraKen]

Super Nintendo had a tiny game built-in to it's Mario Paint cartridge where you swat flies with a fly swatter. lol