Split1000 (simple string parser) Collaboration

[The Librarian]

Split1000 (simple string parser)

Contributor(s): @bplus, @luke, @SMcNeill
Source: qb64.org Forum
URL: https://www.qb64.org/forum/index.php?topic=1073.0
Tags: [string] [parsing]

Description:
This SUB will take a given N delimited string, and delimiter$ and creates an array of N+1 strings using the LBOUND of the given dynamic array to load.

Source Code:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Split demo 2" ' started by B+ on 08-27-2019 to compare to Item$ demo
3. 'new data setup structure to streamline code in setup
4.  
5. SCREEN _NEWIMAGE(400, 300, 32)
6. 'globals seen inside SUBs and FUNCTIONs because SHARED
7. DIM SHARED topIndex AS INTEGER '<< this is how many keywords we have
8. 'VVVV REDIM means dynamic arrays, so can change in setup
9. REDIM SHARED d(1 TO topIndex) AS STRING
10.  
11. 'locals just seen in following main code section
12. DIM i AS INTEGER, j AS INTEGER, w$
13. REDIM LIST$(1 TO 1)
14. setup
15. FOR i = LBOUND(d) TO UBOUND(d) 'all the keywords are first word$ of d() data array
16.     Split d(i), ",", LIST$()
17.     PRINT "Data index:"; i; " "; "String Item:"; LBOUND(LIST$); LIST$(LBOUND(LIST$))
18.     FOR j = LBOUND(LIST$) + 1 TO UBOUND(LIST$)
19.         PRINT SPACE$(15); "String Item:"; j; LIST$(j) 'j-1 counts off the items after the first
20.     NEXT
21.     PRINT: INPUT "Ok... press enter "; w$
22.     CLS
23. NEXT
24.  
25. SUB setup '3rd method of data structure, this is meant to be edited over and over as add to a refine words and substitutes
26.     topIndex = 5 ' <<< make modifications to d() and then update this number, that's it!
27.     REDIM d(1 TO topIndex) AS STRING
28.     d(1) = "Months,January,February,March,April,May,June,July,August,September,October,November,December"
29.     d(2) = "Days,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday,Sunday"
30.     d(3) = "Holidays,NewYears Day,MLK Day,Valentine's Day,Easter,Mother's Day,Memorial Day,Father's Day,Independence Day,Bplus Day,Labor Day,Halloween,Thanksgiving,Christmas"
31.     d(4) = "Test no further words/phrases in this line. (And the next test will do an empty string.)"
32.     d(5) = ""
33. END SUB
34.  
35. 'This SUB will take a given N delimited string, and delimiter$ and creates an array of N+1 strings using the LBOUND of the given dynamic array to load.
36. 'notes: the loadMeArray() needs to be dynamic string array and will not change the LBOUND of the array it is given.
37. SUB Split (SplitMeString AS STRING, delim AS STRING, loadMeArray() AS STRING)
38.     DIM curpos AS LONG, arrpos AS LONG, LD AS LONG, dpos AS LONG 'fix use the Lbound the array already has
39.     curpos = 1: arrpos = LBOUND(loadMeArray): LD = LEN(delim)
40.     dpos = INSTR(curpos, SplitMeString, delim)
41.     DO UNTIL dpos = 0
42.         loadMeArray(arrpos) = MID$(SplitMeString, curpos, dpos - curpos)
43.         arrpos = arrpos + 1
44.         IF arrpos > UBOUND(loadMeArray) THEN REDIM _PRESERVE loadMeArray(LBOUND(loadMeArray) TO UBOUND(loadMeArray) + 1000) AS STRING
45.         curpos = dpos + LD
46.         dpos = INSTR(curpos, SplitMeString, delim)
47.     LOOP
48.     loadMeArray(arrpos) = MID$(SplitMeString, curpos)
49.     REDIM _PRESERVE loadMeArray(LBOUND(loadMeArray) TO arrpos) AS STRING 'get the ubound correct
50. END SUB
51.  

Bplus Edit: bplus version was collaboration of @bplus, @luke, @SMcNeill URL where the original discussion was started by Luke contains his complementary Join function. The above is bplus version with a couple of revisions tweaked into it since first posting.