SaveJPG

[SMcNeill]

For a long  time my little SaveImage routine has been able to save BMP and PNG format images of our screens.  (The last version I shared on the boards is here at: www.qb64.org/forum/index.php?topic=47.msg102649#msg102649 , but it's a little out of date with a few minor error checking corrections added later.  I'll update the newest version soon(tm) so everyone can grab it and make use of it, for those who want to.)

Now, after taking a look at Petr's BMPTOJPG code here: https://www.qb64.org/forum/index.php?topic=47.msg254#msg254 , I've tweaked his work and converted it over to where it's now fit to work as an additional option for SaveImage (or even as a stand alone SaveJPG library).

(Note: A clarification, as pointed out below — Petr’s work is a derivative from others as well. The original source code was written by Artelius, he is the original author. BMPtoJPG is a modification of its program that ships with QB64 in programs / samples / n54 / big / jpegmake.bas )

Give this a few quick test runs and see if it works as advertised on your machines (particularly Linux and Mac OSes), and if nobody has any issues with it, I'll add a little better error trapping (right now we have almost none) and reporting, and then insert it into the SaveImage library so that it'll then be able to save BMP, JPG, or PNG files, as the user/programmer desires.

Anywho, here's the revamped SaveJPG, for your testing and feedback:

Code: QB64: [Select]

1. TYPE JPEGState
2.     FileNo AS INTEGER
3.     YCount AS INTEGER
4.     CbCount AS INTEGER
5.     CrCount AS INTEGER
6.     YDC AS INTEGER
7.     CbDC AS INTEGER
8.     CrDC AS INTEGER
9.     Position AS INTEGER
10.     Leftover AS INTEGER
11.     LeftoverBits AS INTEGER
12. END TYPE
13.  
14. Huff0:
15. DATA 0
16. DATA 1,0
17. DATA 5,1,2,3,4,5
18. DATA 1,6
19. DATA 1,7
20. DATA 1,8
21. DATA 1,9
22. DATA 1,10
23. DATA 1,11
24. DATA 0,0,0,0,0,0,0
25.  
26. Huff1:
27. DATA 0
28. DATA 3,0,1,2
29. DATA 1,3
30. DATA 1,4
31. DATA 1,5
32. DATA 1,6
33. DATA 1,7
34. DATA 1,8
35. DATA 1,9
36. DATA 1,10
37. DATA 1,11
38. DATA 0,0,0,0,0
39.  
40. Huff2:
41. DATA 0
42. DATA 2,1,2
43. DATA 1,3
44. DATA 3,0,4,&H11
45. DATA 3,5,&H12,&H21
46. DATA 2,&H31,&H41
47. DATA 4,6,&H13,&H51,&H61
48. DATA 3,7,&H22,&H71
49. DATA 5,&H14,&H32,&H81,&H91,&HA1
50. DATA 5,&H08,&H23,&H42,&HB1,&HC1
51. DATA 4,&H15,&H52,&HD1,&HF0
52. DATA 4,&H24,&H33,&H62,&H72
53. DATA 0
54. DATA 0
55. DATA 1,&H82
56. DATA 125,&H09,&H0A,&H16,&H17,&H18,&H19,&H1A,&H25,&H26,&H27,&H28,&H29,&H2A,&H34,&H35,&H36
57. DATA &H37,&H38,&H39,&H3A,&H43,&H44,&H45,&H46,&H47,&H48,&H49,&H4A,&H53,&H54,&H55,&H56
58. DATA &H57,&H58,&H59,&H5A,&H63,&H64,&H65,&H66,&H67,&H68,&H69,&H6A,&H73,&H74,&H75,&H76
59. DATA &H77,&H78,&H79,&H7A,&H83,&H84,&H85,&H86,&H87,&H88,&H89,&H8A,&H92,&H93,&H94,&H95
60. DATA &H96,&H97,&H98,&H99,&H9A,&HA2,&HA3,&HA4,&HA5,&HA6,&HA7,&HA8,&HA9,&HAA,&HB2,&HB3
61. DATA &HB4,&HB5,&HB6,&HB7,&HB8,&HB9,&HBA,&HC2,&HC3,&HC4,&HC5,&HC6,&HC7,&HC8,&HC9,&HCA
62. DATA &HD2,&HD3,&HD4,&HD5,&HD6,&HD7,&HD8,&HD9,&HDA,&HE1,&HE2,&HE3,&HE4,&HE5,&HE6,&HE7
63. DATA &HE8,&HE9,&HEA,&HF1,&HF2,&HF3,&HF4,&HF5,&HF6,&HF7,&HF8,&HF9,&HFA
64.  
65. Huff3:
66. DATA 0
67. DATA 2,0,1
68. DATA 1,2
69. DATA 2,3,&H11
70. DATA 4,4,5,&H21,&H31
71. DATA 4,6,&H12,&H41,&H51
72. DATA 3,7,&H61,&H71
73. DATA 4,&H13,&H22,&H32,&H81
74. DATA 7,8,&H14,&H42,&H91,&HA1,&HB1,&HC1
75. DATA 5,9,&H23,&H33,&H52,&HF0
76. DATA 4,&H15,&H62,&H72,&HD1
77. DATA 4,&HA,&H16,&H24,&H34
78. DATA 0
79. DATA 1,&HE1
80. DATA 2,&H25,&HF1
81. DATA 119,&H17,&H18,&H19,&H1A,&H26,&H27,&H28,&H29,&H2A,&H35,&H36,&H37,&H38,&H39,&H3A,&H43
82. DATA &H44,&H45,&H46,&H47,&H48,&H49,&H4A,&H53,&H54,&H55,&H56,&H57,&H58,&H59,&H5A,&H63
83. DATA &H64,&H65,&H66,&H67,&H68,&H69,&H6A,&H73,&H74,&H75,&H76,&H77,&H78,&H79,&H7A,&H82
84. DATA &H83,&H84,&H85,&H86,&H87,&H88,&H89,&H8A,&H92,&H93,&H94,&H95,&H96,&H97,&H98,&H99
85. DATA &H9A,&HA2,&HA3,&HA4,&HA5,&HA6,&HA7,&HA8,&HA9,&HAA,&HB2,&HB3,&HB4,&HB5,&HB6,&HB7
86. DATA &HB8,&HB9,&HBA,&HC2,&HC3,&HC4,&HC5,&HC6,&HC7,&HC8,&HC9,&HCA,&HD2,&HD3,&HD4,&HD5
87. DATA &HD6,&HD7,&HD8,&HD9,&HDA,&HE2,&HE3,&HE4,&HE5,&HE6,&HE7,&HE8,&HE9,&HEA,&HF2,&HF3
88. DATA &HF4,&HF5,&HF6,&HF7,&HF8,&HF9,&HFA
89.  
90. StandardQT:
91. DATA 16,11,10,16,24,40,51,61
92. DATA 12,12,14,19,26,58,60,55
93. DATA 14,13,16,24,40,57,69,56
94. DATA 14,17,22,29,51,87,80,62
95. DATA 18,22,37,56,68,109,103,77
96. DATA 24,35,55,64,81,104,113,92
97. DATA 49,64,78,87,103,121,120,101
98. DATA 72,92,95,98,112,100,103,99
99.  
100. DATA 17,18,24,47,99,99,99,99
101. DATA 18,24,26,66,99,99,99,99
102. DATA 24,26,56,99,99,99,99,99
103. DATA 47,66,99,99,99,99,99,99
104. DATA 99,99,99,99,99,99,99,99
105. DATA 99,99,99,99,99,99,99,99
106. DATA 99,99,99,99,99,99,99,99
107. DATA 99,99,99,99,99,99,99,99
108.  
109. DIM SHARED Pow2(0 TO 15) AS LONG
110. DIM SHARED Cosine(0 TO 7, 0 TO 7) AS SINGLE
111. DIM SHARED ZigZagX(0 TO 63) AS INTEGER, ZigZagY(0 TO 63) AS INTEGER
112. JPEG.Precalc
113.  
114. DIM SHARED Huff(0 TO 255, 0 TO 1, 0 TO 1, 0 TO 1) AS INTEGER
115. DIM SHARED QT(0 TO 7, 0 TO 7, 0 TO 1) AS INTEGER
116. DIM SHARED State AS JPEGState
117.  
118. DIM SHARED Sampling(0 TO 2, 0 TO 1) AS INTEGER
119. Sampling(0, 0) = 2 'Sampling factor (x then y) for luminance
120. Sampling(0, 1) = 2
121. Sampling(1, 0) = 1 'Sampling factor for "blue" chrominance
122. Sampling(1, 1) = 1
123. Sampling(2, 0) = 1 'Sampling factor for "red" chrominance
124. Sampling(2, 1) = 1
125.  
126. '***************************
127. ' LIBRARY START BEFORE HERE
128. '***************************
129. 'Delete file then open for binary
130.  
131.  
132. RANDOMIZE TIMER
133. DIM j AS LONG, l AS LONG, i AS LONG
134. j = _NEWIMAGE(640, 480, 32)
135. SCREEN j
136.  
137. FOR i = 1 TO 100
138.     LINE (RND * 640, RND * 480)-(RND * 640, RND * 480), RND * &HFFFFFF + &HFF000000, BF
139. NEXT
140. LINE (100, 100)-(200, 200), &HFFFFFF00, BF
141. _PRINTSTRING (110, 110), "STEVE!"
142.  
143. SaveJPG "temp.JPG", 0, 100, 100, 500, 400
144. SLEEP
145. CLS
146. l = _LOADIMAGE("temp.JPG", 32)
147. _PUTIMAGE , l
148.  
149. '***************************
150. '   LIBRARY END AFTER HERE
151. '***************************
152.  
153.  
154.  
155.  
156. SUB SaveJPG (file$, image&, startx, starty, finishx, finishy)
157.     DIM D AS LONG, S AS LONG
158.     DIM tempimage AS LONG, genx AS INTEGER, geny AS INTEGER
159.     DIM outfilename AS STRING
160.  
161.     D = _DEST: S = _SOURCE
162.     tempimage = _NEWIMAGE(finishx - startx + 1, finishy - starty + 1, 32)
163.     genx = _WIDTH(tempimage): geny = _HEIGHT(tempimage)
164.     _PUTIMAGE (0, 0)-(genx, geny), image&, tempimage&, (startx, starty)-(finishx, finishy)
165.     _SOURCE tempimage&: _DEST tempimage&
166.     outfilename = file$
167.     OPEN outfilename FOR BINARY AS #1
168.  
169.     'Set quality tables
170.     'The smaller the paramter, the higher the quality
171.     '0.01 is 100% quality
172.     JPEG.StandardQT 0.05, QT()
173.  
174.     'Start image
175.     JPEG.Begin 1, genx, geny, Sampling(), State, QT(), Huff()
176.  
177.  
178.     DIM B(0 TO 7, 0 TO 7) AS INTEGER
179.     DIM SuperY AS INTEGER, SuperX AS INTEGER
180.     DIM BlockY AS INTEGER, BlockX AS INTEGER
181.     DIM OffY AS INTEGER, OffX AS INTEGER
182.     DIM X AS SINGLE, Y AS SINGLE
183.     DIM R AS INTEGER, G AS INTEGER, B AS INTEGER
184.     FOR SuperY = 0 TO geny - 1 STEP 16
185.         FOR SuperX = 0 TO genx - 1 STEP 16: REM vstupni velikost obrazku
186.  
187.             'Output the luminance blocks
188.  
189.             FOR BlockY = 0 TO 15 STEP 8
190.                 FOR BlockX = 0 TO 15 STEP 8
191.                     FOR OffY = 0 TO 7: FOR OffX = 0 TO 7
192.                             X! = OffX + BlockX + SuperX: REM- 63.5
193.                             Y! = OffY + BlockY + SuperY: REM - 63.5
194.  
195.                             R = _RED32(POINT(X!, Y!))
196.                             G = _GREEN32(POINT(X!, Y!))
197.                             B = _BLUE32(POINT(X!, Y!))
198.                             B(OffX, OffY) = JPEG.Y(R, G, B)
199.                     NEXT OffX, OffY
200.                     JPEG.Block.Output B(), State, QT(), Huff()
201.             NEXT BlockX, BlockY
202.  
203.             'Output the blue chrominance block
204.  
205.             FOR OffY = 0 TO 7: FOR OffX = 0 TO 7
206.                     X! = OffX * 2 + SuperX
207.                     Y! = OffY * 2 + SuperY
208.  
209.                     R = _RED32(POINT(X!, Y!))
210.                     G = _GREEN32(POINT(X!, Y!))
211.                     B = _BLUE32(POINT(X!, Y!))
212.                     B(OffX, OffY) = JPEG.Cb(R, G, B)
213.             NEXT OffX, OffY
214.             JPEG.Block.Output B(), State, QT(), Huff()
215.  
216.             'Output the red chrominance block
217.  
218.             FOR OffY = 0 TO 7: FOR OffX = 0 TO 7
219.                     X! = OffX * 2 + SuperX
220.                     Y! = OffY * 2 + SuperY
221.  
222.                     R = _RED32(POINT(X!, Y!))
223.                     G = _GREEN32(POINT(X!, Y!))
224.                     B = _BLUE32(POINT(X!, Y!))
225.                     B(OffX, OffY) = JPEG.Cr(R, G, B)
226.             NEXT OffX, OffY
227.             JPEG.Block.Output B(), State, QT(), Huff()
228.  
229.     NEXT SuperX, SuperY
230.  
231.     JPEG.Finish State
232.  
233.     CLOSE
234.     _DEST D: _SOURCE S
235. END SUB
236.  
237. SUB JPEG.ACHuff (RLE AS INTEGER, AC AS INTEGER, Huff() AS INTEGER, A AS INTEGER, State AS JPEGState)
238.     DIM C AS INTEGER, X AS INTEGER
239.     C = JPEG.Category(AC)
240.     X = RLE * 16 + C
241.     JPEG.PutBinString Huff(X, 1, A, 0), Huff(X, 1, A, 1), State
242.     JPEG.PutRightBinString AC + (AC < 0), C, State
243. END SUB
244.  
245. SUB JPEG.Begin (FileNo AS INTEGER, W AS INTEGER, H AS INTEGER, Sampling() AS INTEGER, State AS JPEGState, QT() AS INTEGER, Huff() AS INTEGER)
246.  
247.     DIM I AS INTEGER, J AS INTEGER, X AS INTEGER, Y AS INTEGER, T AS INTEGER
248.     DIM S AS STRING
249.     State.FileNo = FileNo
250.  
251.     RESTORE Huff0
252.     JPEG.GenerateHuffmanTable Huff(), 0, 0
253.     JPEG.GenerateHuffmanTable Huff(), 0, 1
254.     JPEG.GenerateHuffmanTable Huff(), 1, 0
255.     JPEG.GenerateHuffmanTable Huff(), 1, 1
256.  
257.  
258.     State.YCount = Sampling(0, 0) * Sampling(0, 1)
259.     State.CbCount = Sampling(1, 0) * Sampling(1, 1)
260.     State.CrCount = Sampling(2, 0) * Sampling(2, 1)
261.     State.YDC = 0
262.     State.CbDC = 0
263.     State.CrDC = 0
264.  
265.     State.Position = 0
266.  
267.     State.Leftover = 0
268.     State.LeftoverBits = 0
269.  
270.  
271.     'SOI
272.     PutChar FileNo, 255
273.     PutChar FileNo, 216
274.     'APP0
275.     PutChar FileNo, 255
276.     PutChar FileNo, 224
277.     JPEG.PutWord FileNo, 16
278.     S$ = "JFIF" + CHR$(0): PUT FileNo, , S$
279.     PutChar FileNo, 1
280.     PutChar FileNo, 2
281.     PutChar FileNo, 0
282.     PutChar FileNo, 0
283.     PutChar FileNo, 1
284.     PutChar FileNo, 0
285.     PutChar FileNo, 1
286.     PutChar FileNo, 0
287.     PutChar FileNo, 0
288.  
289.     'DQT
290.     PutChar FileNo, 255
291.     PutChar FileNo, 219
292.     JPEG.PutWord FileNo, 132
293.  
294.     PutChar FileNo, 0
295.     FOR I = 0 TO 63
296.         PutChar FileNo, QT(ZigZagX(I), ZigZagY(I), 0)
297.     NEXT
298.  
299.  
300.  
301.     PutChar FileNo, 1
302.     FOR I = 0 TO 63
303.         PutChar FileNo, QT(ZigZagX(I), ZigZagY(I), 1)
304.     NEXT
305.  
306.  
307.  
308.     'DHT
309.     PutChar FileNo, 255
310.     PutChar FileNo, 196
311.     T = 2 + 4 * (16 + 1)
312.     RESTORE Huff0
313.     FOR I = 1 TO 16 * 4
314.         READ X
315.         FOR J = 1 TO X
316.             READ Y
317.             T = T + 1
318.         NEXT
319.     NEXT
320.  
321.     JPEG.PutWord FileNo, T
322.  
323.     PutChar FileNo, 0
324.     RESTORE Huff0
325.     FOR I = 1 TO 16
326.         READ X
327.         PutChar FileNo, X
328.         FOR J = 1 TO X
329.             READ Y
330.         NEXT
331.     NEXT
332.     RESTORE Huff0
333.     FOR I = 1 TO 16
334.         READ X
335.         FOR J = 1 TO X
336.             READ Y
337.             PutChar FileNo, Y
338.         NEXT
339.     NEXT
340.  
341.     PutChar FileNo, 1
342.     RESTORE Huff1
343.     FOR I = 1 TO 16
344.         READ X
345.         PutChar FileNo, X
346.         FOR J = 1 TO X
347.             READ Y
348.         NEXT
349.     NEXT
350.     RESTORE Huff1
351.     FOR I = 1 TO 16
352.         READ X
353.         FOR J = 1 TO X
354.             READ Y
355.             PutChar FileNo, Y
356.         NEXT
357.     NEXT
358.  
359.     PutChar FileNo, 16
360.     RESTORE Huff2
361.     FOR I = 1 TO 16
362.         READ X
363.         PutChar FileNo, X
364.         FOR J = 1 TO X
365.             READ Y
366.         NEXT
367.     NEXT
368.     RESTORE Huff2
369.     FOR I = 1 TO 16
370.         READ X
371.         FOR J = 1 TO X
372.             READ Y
373.             PutChar FileNo, Y
374.         NEXT
375.     NEXT
376.  
377.     PutChar FileNo, 17
378.     RESTORE Huff3
379.     FOR I = 1 TO 16
380.         READ X
381.         PutChar FileNo, X
382.         FOR J = 1 TO X
383.             READ Y
384.         NEXT
385.     NEXT
386.     RESTORE Huff3
387.     FOR I = 1 TO 16
388.         READ X
389.         FOR J = 1 TO X
390.             READ Y
391.             PutChar FileNo, Y
392.         NEXT
393.     NEXT
394.  
395.     'SOF0
396.     PutChar FileNo, 255
397.     PutChar FileNo, 192
398.     JPEG.PutWord FileNo, 8 + 9
399.     PutChar FileNo, 8
400.     JPEG.PutWord FileNo, H
401.     JPEG.PutWord FileNo, W
402.  
403.     PutChar FileNo, 3
404.  
405.     PutChar FileNo, 1
406.     PutChar FileNo, Sampling(0, 0) * 16 + Sampling(0, 1)
407.     PutChar FileNo, 0
408.     PutChar FileNo, 2
409.     PutChar FileNo, Sampling(1, 0) * 16 + Sampling(1, 1)
410.     PutChar FileNo, 1
411.     PutChar FileNo, 3
412.     PutChar FileNo, Sampling(2, 0) * 16 + Sampling(2, 1)
413.     PutChar FileNo, 1
414.  
415.     'SOS
416.  
417.     PutChar FileNo, 255
418.     PutChar FileNo, 218
419.     JPEG.PutWord FileNo, 12
420.  
421.     PutChar FileNo, 3
422.  
423.     PutChar FileNo, 1
424.     PutChar FileNo, &H0
425.     PutChar FileNo, 2
426.     PutChar FileNo, &H11
427.     PutChar FileNo, 3
428.     PutChar FileNo, &H11
429.  
430.     PutChar FileNo, 0
431.     PutChar FileNo, 63
432.     PutChar FileNo, 0
433.  
434. END SUB
435.  
436. SUB JPEG.Block.Huffman (B() AS INTEGER, LastDC AS INTEGER, Huff() AS INTEGER, A AS INTEGER, State AS JPEGState)
437.     DIM DC AS INTEGER, I AS INTEGER
438.     DIM C AS INTEGER
439.     DC = B(0) - LastDC
440.     JPEG.DCHuff DC, Huff(), A, State
441.     B(64) = -1
442.  
443.     I = 1
444.     DO
445.         C = 0
446.         IF B(I) = 0 THEN
447.  
448.             DO
449.                 I = I + 1
450.                 C = C + 1
451.             LOOP WHILE B(I) = 0
452.             IF I = 64 THEN
453.  
454.                 JPEG.PutBinString Huff(0, 1, A, 0), Huff(0, 1, A, 1), State
455.                 EXIT DO
456.             END IF
457.             WHILE C >= 16
458.  
459.                 JPEG.PutBinString Huff(&HF0, 1, A, 0), Huff(&HF0, 1, A, 1), State
460.                 C = C - 16
461.             WEND
462.  
463.         END IF
464.  
465.  
466.         JPEG.ACHuff C, B(I), Huff(), A, State
467.         I = I + 1
468.     LOOP WHILE I < 64
469. END SUB
470.  
471. SUB JPEG.Block.Output (B() AS INTEGER, State AS JPEGState, QT() AS INTEGER, Huff() AS INTEGER)
472.  
473.     DIM O(0 TO 64) AS INTEGER
474.     State.Position = State.Position + 1
475.     IF State.Position > State.YCount + State.CbCount + State.CrCount THEN State.Position = 1
476.     IF State.Position <= State.YCount THEN
477.         JPEG.Block.Transform B(), O(), QT(), 0
478.         JPEG.Block.Huffman O(), State.YDC, Huff(), 0, State
479.         State.YDC = O(0)
480.     ELSE
481.         JPEG.Block.Transform B(), O(), QT(), 1
482.         IF State.Position <= State.YCount + State.CbCount THEN
483.             JPEG.Block.Huffman O(), State.CbDC, Huff(), 1, State
484.             State.CbDC = O(0)
485.         ELSE
486.             JPEG.Block.Huffman O(), State.CrDC, Huff(), 1, State
487.             State.CrDC = O(0)
488.         END IF
489.     END IF
490.  
491. END SUB
492.  
493. SUB JPEG.Block.Transform (B() AS INTEGER, O() AS INTEGER, QT() AS INTEGER, A AS INTEGER)
494.     DIM U AS INTEGER, V AS INTEGER, X AS INTEGER, Y AS INTEGER
495.     DIM B2(0 TO 7, 0 TO 7) AS SINGLE
496.     DIM T AS SINGLE
497.  
498.     FOR V = 0 TO 7: FOR U = 0 TO 7
499.             T = 0
500.             FOR X = 0 TO 7
501.                 T = T + B(X, V) * Cosine(X, U)
502.             NEXT X
503.             B2(U, V) = T
504.     NEXT U, V
505.  
506.     FOR U = 0 TO 7: FOR V = 0 TO 7
507.             T = 0
508.             FOR Y = 0 TO 7
509.                 T = T + B2(U, Y) * Cosine(Y, V)
510.             NEXT Y
511.             T = T / 4
512.             IF U = 0 THEN T = T / SQR(2)
513.             IF V = 0 THEN T = T / SQR(2)
514.             B(U, V) = CINT(T / QT(U, V, A))
515.     NEXT V, U
516.  
517.     FOR U = 0 TO 63
518.         O(U) = B(ZigZagX(U), ZigZagY(U))
519.     NEXT
520.  
521. END SUB
522.  
523. FUNCTION JPEG.Category% (X AS INTEGER)
524.     DIM T AS INTEGER, I AS INTEGER
525.     T = ABS(X)
526.     WHILE T
527.         T = T \ 2
528.         I = I + 1
529.     WEND
530.     JPEG.Category = I
531. END FUNCTION
532.  
533. FUNCTION JPEG.Cb% (R AS INTEGER, G AS INTEGER, B AS INTEGER)
534.  
535.     JPEG.Cb = -.1687 * R - .3313 * G + .5 * B
536.  
537. END FUNCTION
538.  
539. FUNCTION JPEG.Cr% (R AS INTEGER, G AS INTEGER, B AS INTEGER)
540.  
541.     JPEG.Cr = .5 * R - .4187 * G - .0813 * B
542.  
543. END FUNCTION
544.  
545. SUB JPEG.DCHuff (DC AS INTEGER, Huff() AS INTEGER, A AS INTEGER, State AS JPEGState)
546.     DIM C AS INTEGER
547.     C = JPEG.Category(DC)
548.     JPEG.PutBinString Huff(C, 0, A, 0), Huff(C, 0, A, 1), State
549.     JPEG.PutRightBinString DC + (DC < 0), C, State
550. END SUB
551.  
552. SUB JPEG.Finish (State AS JPEGState)
553.  
554.     DEF SEG = VARSEG(State.Leftover)
555.     IF State.LeftoverBits > 8 THEN
556.         JPEG.PutByte State.FileNo, PEEK(VARPTR(State.Leftover) + 1)
557.         POKE VARPTR(State.Leftover) + 1, State.Leftover AND 255
558.         State.LeftoverBits = State.LeftoverBits - 8
559.     END IF
560.  
561.     IF State.LeftoverBits THEN
562.         JPEG.PutByte State.FileNo, PEEK(VARPTR(State.Leftover) + 1) OR (Pow2(8 - State.LeftoverBits) - 1)
563.     END IF
564.     DEF SEG
565.  
566.     'EOF marker
567.     PutChar State.FileNo, 255
568.     PutChar State.FileNo, 217
569.  
570. END SUB
571.  
572. SUB JPEG.GenerateHuffmanTable (Huff() AS INTEGER, A AS INTEGER, B AS INTEGER)
573.     DIM S AS LONG, I AS INTEGER, J AS INTEGER, T AS INTEGER
574.     DIM X AS INTEGER, Y AS INTEGER
575.     S = -1
576.  
577.     FOR I = 1 TO 16
578.         READ X
579.         FOR J = 1 TO X
580.  
581.             IF S = -1 THEN
582.                 S = 0
583.             ELSE
584.                 S = S + Pow2(T)
585.             END IF
586.  
587.  
588.             READ Y
589.             IF S AND 32768 THEN Huff(Y, A, B, 0) = CINT(S AND 32767&) OR -32768 ELSE Huff(Y, A, B, 0) = S
590.             Huff(Y, A, B, 1) = I
591.             T = 16 - I
592.  
593.         NEXT
594.     NEXT
595. END SUB
596.  
597. SUB JPEG.Precalc
598.     DIM X AS INTEGER, Y AS INTEGER, T AS INTEGER, Dir AS INTEGER, L AS LONG
599.  
600.     L = 1
601.     FOR X = 0 TO 15
602.         Pow2(X) = L
603.         L = L + L
604.     NEXT
605.     FOR Y = 0 TO 7
606.         FOR X = 0 TO 7
607.             Cosine(X, Y) = COS((2 * X + 1) * Y * .1963495)
608.     NEXT X, Y
609.  
610.     X = 0: Y = 0
611.     T = 0
612.     Dir = 0
613.     DO
614.         ZigZagX(T) = X
615.         ZigZagY(T) = Y
616.         T = T + 1
617.         IF T = 64 THEN EXIT DO
618.         IF Dir THEN
619.             IF Y = 7 THEN
620.                 X = X + 1
621.                 Dir = 0
622.             ELSEIF X = 0 THEN
623.                 Y = Y + 1
624.                 Dir = 0
625.             ELSE
626.                 X = X - 1
627.                 Y = Y + 1
628.             END IF
629.  
630.         ELSE
631.             IF Y = 0 THEN
632.                 X = X + 1
633.                 Dir = 1
634.             ELSEIF X = 7 THEN
635.                 Y = Y + 1
636.                 Dir = 1
637.             ELSE
638.                 X = X + 1
639.                 Y = Y - 1
640.             END IF
641.         END IF
642.     LOOP
643.  
644.  
645.  
646. END SUB
647.  
648. SUB JPEG.PutBinString (BS AS INTEGER, Length AS INTEGER, State AS JPEGState)
649.     DIM Temp AS INTEGER
650.  
651.     Temp = BS
652.     State.Leftover = State.Leftover OR JPEG.Shift(Temp, State.LeftoverBits)
653.     State.LeftoverBits = State.LeftoverBits + Length
654.     IF State.LeftoverBits >= 16 THEN
655.         DEF SEG = VARSEG(State.Leftover)
656.         JPEG.PutByte State.FileNo, PEEK(VARPTR(State.Leftover) + 1)
657.         DEF SEG
658.         JPEG.PutByte State.FileNo, State.Leftover AND 255
659.         State.LeftoverBits = State.LeftoverBits - 16
660.         State.Leftover = Temp
661.     END IF
662.  
663. END SUB
664.  
665. SUB JPEG.PutByte (FileNo AS INTEGER, Byte AS INTEGER)
666.     DIM C AS STRING * 1
667.     C = CHR$(Byte)
668.     PUT FileNo, , C
669.     IF Byte = 255 THEN C = CHR$(0): PUT FileNo, , C
670. END SUB
671.  
672. SUB JPEG.PutRightBinString (BS AS INTEGER, Length AS INTEGER, State AS JPEGState)
673.  
674.     DIM Temp AS LONG
675.     IF Length THEN
676.         Temp = (CLNG(BS) AND Pow2(Length) - 1) * Pow2(16 - Length)
677.         IF Temp AND 32768 THEN Temp = Temp OR -65536
678.         JPEG.PutBinString CINT(Temp), Length, State
679.     END IF
680.  
681. END SUB
682.  
683. SUB JPEG.PutWord (FileNo AS INTEGER, Word AS INTEGER)
684.     DIM C AS STRING * 1
685.     C = CHR$(Word \ 256)
686.     PUT FileNo, , C
687.     C = CHR$(Word AND 255)
688.     PUT FileNo, , C
689. END SUB
690.  
691. FUNCTION JPEG.Shift% (I AS INTEGER, N AS INTEGER)
692.     DIM T AS LONG
693.  
694.     IF N = 0 THEN
695.         JPEG.Shift = I
696.         I = 0
697.         EXIT FUNCTION
698.     END IF
699.     T = CLNG(I) AND 65535
700.  
701.     JPEG.Shift = T \ Pow2(N)
702.  
703.     T = (T AND (Pow2(N) - 1)) * Pow2((16 - N) AND 15)
704.     IF T AND 32768 THEN I = CINT(T AND 32767&) OR -32768 ELSE I = CINT(T)
705. END FUNCTION
706.  
707. SUB JPEG.StandardQT (quality AS SINGLE, QT() AS INTEGER)
708.  
709.     DIM I AS INTEGER, X AS INTEGER, Y AS INTEGER, T AS INTEGER
710.     RESTORE StandardQT
711.  
712.     FOR I = 0 TO 1: FOR Y = 0 TO 7: FOR X = 0 TO 7
713.                 READ T
714.  
715.                 QT(X, Y, I) = T * quality
716.  
717.                 IF QT(X, Y, I) = 0 THEN QT(X, Y, I) = 1
718.     NEXT X, Y, I
719.  
720. END SUB
721.  
722. FUNCTION JPEG.Y% (R AS INTEGER, G AS INTEGER, B AS INTEGER)
723.  
724.     JPEG.Y = .299 * R + .587 * G + .114 * B - 128
725.  
726. END FUNCTION
727.  
728. SUB PutChar (FileNo AS INTEGER, Char AS INTEGER)
729.     DIM C AS STRING * 1
730.     C = CHR$(Char)
731.     PUT FileNo, , C
732. END SUB

[SierraKen]

(Post deleted by user.)

[SierraKen]

Here's an example program I made for you using the QB64.org Wiki page example to make a BMP to JPG converter. I don't know enough to know if this will work with Linux or Apple, but I thought I would just toss this in here for Windows people at least. You enter the name of a BMP picture and a new JPG name and then it displays it and saves it as the JPG name.

Here is the Wiki page I got the example from: https://qb64.org/wiki/SAVEIMAGE

(NOTE: I just found out that this isn't a TRUE JPG file, just a BMP with a JPG ending. So my example here is erased.)

[SMcNeill]

Ken, you’re not converting a BMP to a JPG with that code.  You’re simply taking a BMP file and putting a JPG extension on it. 

Try it for yourself from Windows Explorer — use SaveImage to save the file as BMP.  Load it in Paint, or any other program.  It’s a BMP file. 

Once you’re satisfied it’s a BMP file, simply change the extension to JPG and see how it behaves.  If you didn’t know it was a BMP file, you’d think it was JPG.



So how’s it work with a wrong extension?

The JPG decoder reads the file header (from line 36 in your example program above), and sees the metadata info down at line 36 and decodes it internally as BMP.

It’s a hack at best, and not a “true” JPG file.

[SierraKen]

Woah you are right! Dannng all these weeks I thought I could make a JPG. The file length itself says it, I should have known. It's the same exact file length as a BMP. I'll change my couple of programs that save as JPG and either use your JPG code or just use BMP. Probably going to stick with BMP since it's simpler to me. Thank you for telling me!

[SierraKen]

Well, I removed my Paint Pixels program off my website. But I changed my Calendar Maker program to .bmp pictures to save them as. My Paint Pixels program was a bit wobbly anyway. So, I feel better now. Thank you again for telling me.

[Petr]

Hi Steve. Thank you for mentioning me in your post, but I have to add the following. BMPtoJPG is just a modification of the original source code, which I am not the author of. The original source code was written by Artelius, he is the original author. BMPtoJPG is a modification of its program that ships with QB64 in programs / samples / n54 / big / jpegmake.bas

I had to add this here because it would be flaunting a foreign code as my own, that is a practice that I do not deeply recognize.

Thank you for the modification for widespread use. I'll look at her later.

[SMcNeill]

Hi Steve. Thank you for mentioning me in your post, but I have to add the following. BMPtoJPG is just a modification of the original source code, which I am not the author of. The original source code was written by Artelius, he is the original author. BMPtoJPG is a modification of its program that ships with QB64 in programs / samples / n54 / big / jpegmake.bas

I had to add this here because it would be flaunting a foreign code as my own, that is a practice that I do not deeply recognize.

Thank you for the modification for widespread use. I'll look at her later.

Noted.  I’ll have to be certain to mention both you and he in the latest SaveImage Library as well. Like you, I always try to give credit to where it’s due.  ;)