Hamurabi

[bplus]

Ken's Lemonade Stand reminded me of the old classic: Hamurabi
https://en.wikipedia.org/wiki/Hamurabi_(video_game)

Here is a QB64 translation of my SmallBASIC translation of that from someone else translation from...

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Hamurabi Classic"
3. 'Hamuradi.bas for SmallBASIC 0.12.8 [B+=MGA] 2017-01-24   translated to QB64 B+ 2019-07-21
4. ' translated from Hamuradi.bas for Tinycat BASIC by felixv7
5. ' whose source to this classic was
6. ' http://apollowebworks.com/russell/samples/hamurabi.html
7.  
8. DIM SHARED land, grain, starved, immigrants, population, rats, planted, yield, price, year, plague, buying, selling, fed
9. land = 1000
10. grain = 2800
11. starved = 10
12. immigrants = 5
13. population = 100
14. rats = 200
15. planted = 300
16. yield = INT(RND * 5) + 1
17. price = INT(RND * 6) + 17
18. year = 1
19. plague = 0
20.  
21. WHILE population > 0
22.     update 'report to H
23.     decisions 'H input
24.     calcStats 'recalc conditions
25. WEND
26. PRINT "Hamurabi, I have bad news. Everyone is dead."
27. PRINT "The city is lost."
28. PRINT "If only you could try again..."
29. END
30.  
31. SUB update ()
32.     CLS
33.     PRINT "Hamurabi,"
34.     PRINT
35.     PRINT "I beg to report that in year "; year
36.     PRINT "The people who starved to death was "; starved
37.     PRINT "The people who came to the city was "; immigrants
38.     IF plague THEN PRINT "The plague killed half of us!!!"
39.     PRINT "                  The population is now "; population
40.     PRINT
41.     PRINT "The bushels we harvested was "; yield * planted
42.     PRINT "as bushels of grain per acre was "; yield
43.     PRINT "but bushels destroyed by rats was "; rats
44.     PRINT "This leaves us with the granary bushels "; grain
45.     PRINT
46.     PRINT "The acres of land owned by the city is "; land
47.     PRINT
48.     PRINT "The price, bushels per acre, is "; price
49.     PRINT
50. END SUB
51.  
52. SUB decisions ()
53.     WHILE 1
54.         INPUT "How much land do you wish to buy? "; buying
55.         buying = INT(ABS(buying))
56.         IF buying = 0 THEN
57.             EXIT WHILE
58.         ELSEIF buying * price <= grain THEN
59.             land = land + buying
60.             grain = grain - buying * price
61.             PRINT "Very well, we are left with "; grain; " bushels."
62.             EXIT WHILE
63.         ELSE
64.             PRINT "But, Hamurabi! We don't have enough grain!"
65.         END IF
66.     WEND
67.  
68.     WHILE 1
69.         INPUT "How much land do you wish to sell? "; selling
70.         selling = INT(ABS(selling))
71.         IF selling = 0 THEN
72.             EXIT WHILE
73.         ELSEIF selling <= land THEN
74.             land = land - selling
75.             grain = grain + selling * price
76.             PRINT "Very well, we now have "; grain; " bushels."
77.             EXIT WHILE
78.         ELSE
79.             PRINT "But, Hamurabi, we only have ", land, " acres!"
80.         END IF
81.     WEND
82.  
83.     WHILE 1
84.         INPUT "How much grain should we feed our people? "; fed
85.         fed = INT(ABS(fed))
86.         IF fed <= grain THEN
87.             grain = grain - fed
88.             EXIT WHILE
89.         ELSE
90.             PRINT "But, Hamurabi! We only have ", grain, " bushels!"
91.         END IF
92.     WEND
93.  
94.     WHILE 1
95.         INPUT "How many acres of land should we seed? "; planted
96.         planted = INT(ABS(planted))
97.         IF planted <= land THEN
98.             IF planted <= grain * 2 THEN
99.                 IF planted <= population * 10 THEN
100.                     EXIT WHILE
101.                 ELSE
102.                     PRINT "But, Hamurabi! We only have "; population; " people!"
103.                 END IF
104.             ELSE
105.                 PRINT "But, Hamurabi! We only have "; grain; " bushels!"
106.             END IF
107.         ELSE
108.             PRINT "But, Hamurabi! We only have "; land; " acres!"
109.         END IF
110.     WEND
111. END SUB
112.  
113. SUB calcStats
114.     DIM immigrants1, immigrants2
115.     yield = INT(RND * 5) + 1
116.     grain = grain + yield * planted
117.     rats = INT(RND * (grain * 0.07))
118.     grain = grain - rats
119.     starved = population - INT(fed / 20)
120.     IF starved < 0 THEN starved = 0
121.     population = population - starved
122.     IF population <= 0 THEN EXIT SUB
123.     immigrants1 = INT(starved / 2)
124.     immigrants2 = INT((5 - yield) * grain / 600 + 1)
125.     immigrants = immigrants1 + immigrants2
126.     IF immigrants > 50 THEN immigrants = 50
127.     IF immigrants < 0 THEN immigrants = 0
128.     population = population + immigrants
129.     plague = RND 'one in 10
130.     IF plague < .1 THEN plague = -1 ELSE plague = 0
131.     IF plague THEN population = INT(population / 2)
132.     price = INT(RND * 6) + 17
133.     year = year + 1
134. END SUB
135.  

Hamurabi fans, let me know if anything got lost in translation.

EDIT: added title

[bplus]

Of course every good king has trusted advisers.

Here is "Hamurabi Helper":

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Hamurabi Helper" 'B+ from SmallBASIC trans 2019-07-21
3. 'Humarabi helper.bas 2017-01-26
4.  
5. DIM p, g, a, bpa, seed, da, dg, feed, excess
6. WHILE 1
7.     PRINT: PRINT "=========================================": PRINT
8.     INPUT "population "; p
9.     INPUT "grain "; g
10.     INPUT "acres "; a
11.     INPUT "bushel per acre price"; bpa
12.     IF a < 10 * p THEN
13.         seed = a
14.     ELSE
15.         seed = 10 * p
16.     END IF
17.     IF g - seed - 20 * p < 0 THEN
18.         IF g - seed - 10 * p < 0 THEN
19.             da = a: dg = g
20.             WHILE da > 20 * p
21.                 da = da - 1 'sell acre
22.                 dg = dg + bpa 'get grain
23.                 IF dg - p * 20 > 0 THEN EXIT WHILE
24.             WEND
25.             PRINT "Sell "; a - da
26.             PRINT "Feed "; 10 * p
27.             PRINT "Seed "; 10 * p
28.         ELSE
29.             feed = g - seed
30.             PRINT "No buy or sell"
31.             PRINT "Feed "; feed
32.             PRINT "Seed "; seed
33.         END IF
34.     ELSE
35.         feed = 20 * p
36.         excess = (g - seed - feed) \ bpa
37.         PRINT "If positive buy else sell? "; excess
38.         PRINT "Feed "; feed
39.         PRINT "Seed "; seed
40.     END IF
41. WEND
42.  

Should this adviser be trusted?

[TempodiBasic]

I find it fantastic!
Thanks to share Bplus

[Ashish]

Cool!

[TempodiBasic]

Just a little mod, but I have an enthusiastic idea to put in field!
As I get some time to spend.
For now there is a spashscreen, a colirized text output,  a playagain function coded by using IF GOTO label

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Hamurabi Classic"
3. 'Hamuradi.bas for SmallBASIC 0.12.8 [B+=MGA] 2017-01-24   translated to QB64 B+ 2019-07-21
4. ' translated from Hamuradi.bas for Tinycat BASIC by felixv7
5. ' whose source to this classic was
6. ' http://apollowebworks.com/russell/samples/hamurabi.html
7.  
8. DIM SHARED land, grain, starved, immigrants, population, rats, planted, yield, price, year, plague, buying, selling, fed
9. start:
10. SplashScreen
11. SLEEP 3
12. Init
13. WHILE population > 0
14.     update 'report to H
15.     decisions 'H input
16.     calcStats 'recalc conditions
17. WEND
18. PRINT "Hamurabi, I have bad news. Everyone is dead."
19. PRINT "100The city is lost."
20. PRINT "If only you could try again..."
21. COLOR 14, 1
22. PRINT "But do you want try again? Y/N";
23. COLOR 7, 0
24. DIM ans AS STRING * 1
25. WHILE NOT ans = "N"
26.     ans = UCASE$(INKEY$)
27.     IF ans = "Y" GOTO start
28. WEND
29. END
30.  
31. SUB Init
32.     land = 1000
33.     grain = 2800
34.     starved = 10
35.     immigrants = 5
36.     population = 100
37.     rats = 200
38.     planted = 300
39.     yield = INT(RND * 5) + 1
40.     price = INT(RND * 6) + 17
41.     year = 1
42.     plague = 0
43. END SUB
44.  
45. SUB update ()
46.     CLS
47.     COLOR 3, 0
48.     PRINT "Hamurabi,"
49.     PRINT
50.     PRINT "I beg to report that in year "; year
51.     PRINT "The people who starved to death was "; starved
52.     PRINT "The people who came to the city was "; immigrants
53.     IF plague THEN PRINT "The plague killed half of us!!!"
54.     PRINT "                  The population is now "; population
55.     PRINT
56.     PRINT "The bushels we harvested was "; yield * planted
57.     PRINT "as bushels of grain per acre was "; yield
58.     PRINT "but bushels destroyed by rats was "; rats
59.     PRINT "This leaves us with the granary bushels "; grain
60.     PRINT
61.     PRINT "The acres of land owned by the city is "; land
62.     PRINT
63.     PRINT "The price, bushels per acre, is "; price
64.     PRINT
65.     COLOR 7, 0
66. END SUB
67.  
68. SUB decisions ()
69.     WHILE 1
70.         INPUT "How much land do you wish to buy? "; buying
71.         buying = INT(ABS(buying))
72.         IF buying = 0 THEN
73.             EXIT WHILE
74.         ELSEIF buying * price <= grain THEN
75.             land = land + buying
76.             grain = grain - buying * price
77.             PRINT "Very well, we are left with "; grain; " bushels."
78.             EXIT WHILE
79.         ELSE
80.             PRINT "But, Hamurabi! We don't have enough grain!"
81.         END IF
82.     WEND
83.  
84.     WHILE 1
85.         INPUT "How much land do you wish to sell? "; selling
86.         selling = INT(ABS(selling))
87.         IF selling = 0 THEN
88.             EXIT WHILE
89.         ELSEIF selling <= land THEN
90.             land = land - selling
91.             grain = grain + selling * price
92.             PRINT "Very well, we now have "; grain; " bushels."
93.             EXIT WHILE
94.         ELSE
95.             PRINT "But, Hamurabi, we only have ", land, " acres!"
96.         END IF
97.     WEND
98.  
99.     WHILE 1
100.         INPUT "How much grain should we feed our people? "; fed
101.         fed = INT(ABS(fed))
102.         IF fed <= grain THEN
103.             grain = grain - fed
104.             EXIT WHILE
105.         ELSE
106.             PRINT "But, Hamurabi! We only have ", grain, " bushels!"
107.         END IF
108.     WEND
109.  
110.     WHILE 1
111.         INPUT "How many acres of land should we seed? "; planted
112.         planted = INT(ABS(planted))
113.         IF planted <= land THEN
114.             IF planted <= grain * 2 THEN
115.                 IF planted <= population * 10 THEN
116.                     EXIT WHILE
117.                 ELSE
118.                     PRINT "But, Hamurabi! We only have "; population; " people!"
119.                 END IF
120.             ELSE
121.                 PRINT "But, Hamurabi! We only have "; grain; " bushels!"
122.             END IF
123.         ELSE
124.             PRINT "But, Hamurabi! We only have "; land; " acres!"
125.         END IF
126.     WEND
127. END SUB
128.  
129. SUB calcStats
130.     DIM immigrants1, immigrants2
131.     yield = INT(RND * 5) + 1
132.     grain = grain + yield * planted
133.     rats = INT(RND * (grain * 0.07))
134.     grain = grain - rats
135.     starved = population - INT(fed / 20)
136.     IF starved < 0 THEN starved = 0
137.     population = population - starved
138.     IF population <= 0 THEN EXIT SUB
139.     immigrants1 = INT(starved / 2)
140.     immigrants2 = INT((5 - yield) * grain / 600 + 1)
141.     immigrants = immigrants1 + immigrants2
142.     IF immigrants > 50 THEN immigrants = 50
143.     IF immigrants < 0 THEN immigrants = 0
144.     population = population + immigrants
145.     plague = RND 'one in 10
146.     IF plague < .1 THEN plague = -1 ELSE plague = 0
147.     IF plague THEN population = INT(population / 2)
148.     price = INT(RND * 6) + 17
149.     year = year + 1
150. END SUB
151.  
152.  
153. SUB SplashScreen
154.     COLOR 14, 0
155.     CLS
156.     LOCATE 3, 12: PRINT "Û   Û " + " ÛÛÛ  " + "Û   Û " + "Û   Û " + "Û   Û " + "ÛÛÛÛ  " + " ÛÛÛ  " + "ÛÛÛÛ  " + " ÛÛÛ  "
157.     LOCATE , 12: PRINT "Û   Û " + "Û   Û " + "ÛÛ ÛÛ " + "ÛÛ ÛÛ " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "  Û   "
158.     LOCATE , 12: PRINT "ÛÛÛÛÛ " + "ÛÛÛÛÛ " + "Û Û Û " + "Û Û Û " + "Û   Û " + "ÛÛÛÛ  " + "ÛÛÛÛÛ " + "ÛÛÛÛ  " + "  Û   "
159.     LOCATE , 12: PRINT "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "  Û   "
160.     LOCATE , 12: PRINT "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "  Û   "
161.     LOCATE , 12: PRINT "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + "  Û   "
162.     LOCATE , 12: PRINT "Û   Û " + "Û   Û " + "Û   Û " + "Û   Û " + " ÛÛÛ  " + "Û   Û " + "Û   Û " + "ÛÛÛÛ  " + " ÛÛÛ  "
163.     COLOR 7, 0
164. END SUB