Print Page - OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic

Title: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: TempodiBasic on August 26, 2021, 08:50:40 pm

Hi friends
here a demo that I was doing some time ago.
For now I post the essential module in which I show how to manage data and pass it to OpenGl function that are constrained into _GL() sub.

If I get some feedback of interest I'll complete all the demonstration to get the status of simple complete demo adding sounds, scores, etc etc etc.

Help instructions:
press Enter key to swap between Standard and OpenGl mode (you can recognize it from the shape of ball like hexagon) move pad of players with left/right arrows and A / S.

waiting feedbacks
Thanks to try

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: bplus on August 27, 2021, 08:49:16 am

Hi @TempodiBasic

Not seeing any gl advantage, are you?

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: TempodiBasic on August 28, 2021, 11:43:35 am

Hi Bplus
glad to get your feedback

Yes I confirm the demonstration hasn't the goal to show differences and advantages of OpenGl using GPU vs standard graphic using CPU.
In fact this code shows simply how to accomplish one of the easiest game (Pong) in minimalistic graphic structure using both OpenGl features both standard graphic features.
Why this so simple example?
It seems that in our section of forum dedicated to OpenGl there are so many wonderful 3D graphic examples and no about basic steps with OpenGl...https://www.qb64.org/forum/index.php?board=21.0 (https://www.qb64.org/forum/index.php?board=21.0) so here a skeleton of 2D game engine using OpenGl.
The user beginner in OpenGl can go on in OpenGl practice starting from a simpler position and then can approach to 3D graphic tecniques. Before squareroot he can learn sum and multiplication. ;-)

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: bplus on August 28, 2021, 12:13:27 pm

Well I think it noble and admirable to get _gl conversation going. And it makes sense to me to start with less complex 2D programming. Got to say I don't like your example too much and for discussion lets post the code (even though at moment code boxes suck, let us assume or hope that will be fixed):

Code: QB64: [Select]

Option _Explicit
' OpenGl Pong
DefLng L ' Longs start with L
DefInt I ' Integers start with I
DefStr S ' Strings start with S
DefSng N 'Singles start with N
 
' type of data called OBJECT
Type obj
    X As Integer
    Y As Integer
    Width1 As Integer
    Height As Integer
    Color1 As _Unsigned Long
    Active As Integer
    SpeedX As Integer
    SpeedY As Integer
End Type
 
Const True = -1, False = 0, Left = 19200, Right = 19712, Escape = 27
Const Enter = 13, iPlayer1 = 1, iPlayer2 = 2
Dim lScreen
Dim Shared iKeyb(1 To 2) As Integer
Dim Shared iActiveGl, myScreen As obj, Pad(1 To 2) As obj, Ball As obj
Dim Shared Gc As Integer, Rc As Integer, Bc As Integer, Ac As Integer
Dim Shared InitGl As Integer, iBallGl As Integer
Dim Shared iPadGl1 As Integer, iPadGl2 As Integer
 
lScreen = _NewImage(800, 600, 32) ' graphic
Screen lScreen ' graphic  creating the window of the program
'  wait that window has been created
_Delay 2 'Do While Not _ScreenExists: Loop
_ScreenMove 1, 1
_Title "OpenGl Pong v.1.0: press Enter to switch between normal vs OpenGl mode"
 
 
Init
 
Do While (iKeyb(iPlayer1) <> Escape) Or (iKeyb(iPlayer2) <> Escape)
    GetInput
    ' stardard graphic mode
    If iActiveGl = False Then
        Border
        Showpad iPlayer1
        Showpad iPlayer2
        ShowBall
        Call Message(1, 1, "press Escape to quit, A/S player 1 Left/Right, cursor Left/Right player 2")
        '    Else
        '  GL() graphic mode
 
        ' Nothing to do here  go to _GL()
    End If
 
    ' calculations for new screenshot
    MovePad
    MoveBall
 
    ' this toggles between standard graphic mode and  Gl graphic mode
    If iKeyb(iPlayer1) = Enter Or iKeyb(iPlayer2) = Enter Then iActiveGl = Not iActiveGl
    ' saving CPU usage
    _Limit 20
Loop
End
 
' area GL--------------------------------------------------------------
 
Sub _GL ()
    If iActiveGl = 0 Then Exit Sub
    If InitGl Then InitGlSub
    ClearScreen
 
    If iBallGl = True Then BallGl
    If iPadGl1 Then PADgL1
    If iPadGl2 Then PADgL2
    _glFlush
End Sub
 
Sub BallGl
    Dim nGc, nBc, nRc, nAc
    Dim e As Single, gXb As Single, gYb As Single
    ComponentColor Ball.Color1
    If SetColorGL!(nGc, nBc, nRc, nAc) Then
        _glBegin _GL_TRIANGLE_FAN
        For e = 1 To (_Pi(2)) Step (2 * _Pi / 6)
            gXb = Proportion!(0, _Width, -1, 1, Ball.X + (Ball.Width1 * Cos(e)))
            gYb = Proportion!(0, _Height, 1, -1, Ball.Y + (Ball.Height * Sin(e)))
            _glVertex2f gXb, gYb
        Next e
        _glEnd
    End If
End Sub
 
Sub PADgL1
    Dim nGc, nBc, nRc, nAc
    Dim nx1, nx2, ny1, ny2, dummy
    ComponentColor Pad(iPlayer1).Color1
    If SetColorGL!(nGc, nBc, nRc, nAc) Then
        nx1 = Proportion(0, _Width, -1, 1, Pad(iPlayer1).X)
        ny1 = Proportion(0, _Height, 1, -1, Pad(iPlayer1).Y)
        ny2 = Proportion(0, _Height, 1, -1, Pad(iPlayer1).Y + Pad(iPlayer1).Height)
        nx2 = Proportion(0, _Width, -1, 1, Pad(iPlayer1).X + Pad(iPlayer1).Width1)
        _glBegin _GL_QUADS
        _glVertex2f nx1, ny1
        _glVertex2f nx1, ny2
        _glVertex2f nx2, ny2
        _glVertex2f nx2, ny1
        _glEnd
        ComponentColor _RGB32(0)
        dummy = SetColorGL!(nGc, nBc, nRc, nAc)
        nx1 = Proportion(0, _Width, -1, 1, Pad(iPlayer1).X + 2)
        ny1 = Proportion(0, _Height, 1, -1, Pad(iPlayer1).Y + 2)
        ny2 = Proportion(0, _Height, 1, -1, Pad(iPlayer1).Y + Pad(iPlayer1).Height - 2)
        nx2 = Proportion(0, _Width, -1, 1, Pad(iPlayer1).X + Pad(iPlayer1).Width1 - 2)
        _glBegin _GL_LINE_LOOP
        _glVertex2f nx1, ny1
        _glVertex2f nx1, ny2
        _glVertex2f nx2, ny2
        _glVertex2f nx2, ny1
        _glEnd
 
    End If
End Sub
 
Sub PADgL2
    Dim nGc, nBc, nRc, nAc
    Dim nx1, nx2, ny1, ny2, dummy
    ComponentColor Pad(iPlayer2).Color1
    If SetColorGL!(nGc, nBc, nRc, nAc) Then
        nx1 = Proportion(0, _Width, -1, 1, Pad(iPlayer2).X)
        ny1 = Proportion(0, _Height, 1, -1, Pad(iPlayer2).Y)
        ny2 = Proportion(0, _Height, 1, -1, Pad(iPlayer2).Y + Pad(iPlayer2).Height)
        nx2 = Proportion(0, _Width, -1, 1, Pad(iPlayer2).X + Pad(iPlayer2).Width1)
        _glBegin _GL_QUADS
        _glVertex2f nx1, ny1
        _glVertex2f nx1, ny2
        _glVertex2f nx2, ny2
        _glVertex2f nx2, ny1
        _glEnd
        ComponentColor _RGB32(0)
        dummy = SetColorGL!(nGc, nBc, nRc, nAc)
        nx1 = Proportion(0, _Width, -1, 1, Pad(iPlayer2).X + 2)
        ny1 = Proportion(0, _Height, 1, -1, Pad(iPlayer2).Y + 2)
        ny2 = Proportion(0, _Height, 1, -1, Pad(iPlayer2).Y + Pad(iPlayer2).Height - 2)
        nx2 = Proportion(0, _Width, -1, 1, Pad(iPlayer2).X + Pad(iPlayer2).Width1 - 2)
        _glBegin _GL_LINE_LOOP
        _glVertex2f nx1, ny1
        _glVertex2f nx1, ny2
        _glVertex2f nx2, ny2
        _glVertex2f nx2, ny1
        _glEnd
    End If
End Sub
 
Sub ClearScreen
    _glClear _GL_COLOR_BUFFER_BIT
End Sub
 
Function SetColorGL! (nGc, nRc, nBc, nAc)
    SetColorGL! = False
    nGc = Proportion(1, 255, 0, 1, Gc)
    nRc = Proportion(1, 255, 0, 1, Rc)
    nBc = Proportion(1, 255, 0, 1, Bc)
    nAc = Proportion(1, 255, 0, 1, Ac)
    _glColor3f nRc, nGc, nBc
    SetColorGL! = True
End Function
 
Sub InitGlSub
    'settings viewport for GL screen
    _glViewport myScreen.X, myScreen.Y, myScreen.Width1, myScreen.Height
    Dim nGc, nBc, nRc, nAc
    ComponentColor myScreen.Color1
    If SetColorGL!(nGc, nRc, nBc, nAc) Then
        _glClearColor nRc, nGc, nBc, nAc
    Else
        Print "Error"
    End If
    InitGl = False
End Sub
 
 
' area sub/functions*****************************************************
Function Proportion (imin1, imax1, imin2, imax2, ivalue)
    Dim iDelta1, iDelta2
    iDelta1 = (imax1 - imin1)
    iDelta2 = (imax2 - imin2)
    Proportion = ((ivalue * iDelta2) / iDelta1) + imin2
End Function
 
 
 
Sub ComponentColor (C As _Unsigned Long)
    Gc = _Green32(C)
    Rc = _Red32(C)
    Bc = _Blue32(C)
    Ac = _Alpha32(C)
End Sub
 
Sub Init
    ' window of program
    myScreen.X = 0
    myScreen.Y = 0
    myScreen.Width1 = _Width
    myScreen.Height = _Height
    myScreen.Color1 = _RGB32(200, 200, 50)
    myScreen.Active = True
 
    ' ball
    Ball.X = 400
    Ball.Y = 300
    Ball.Active = True
    Ball.Width1 = 10
    Ball.Height = 10
    Ball.SpeedX = 3
    Ball.SpeedY = 3
    Ball.Color1 = _RGB32(200, 10, 10)
 
    'PAD player1
    Pad(iPlayer1).X = 350
    Pad(iPlayer1).Y = 400
    Pad(iPlayer1).Width1 = 100
    Pad(iPlayer1).Height = 30
    Pad(iPlayer1).Color1 = _RGB32(40, 230, 200)
    Pad(iPlayer1).SpeedX = 0
    Pad(iPlayer1).SpeedY = 0
    Pad(iPlayer1).Active = True
 
 
    'PAD player2
    Pad(iPlayer2).X = 350
    Pad(iPlayer2).Y = 150
    Pad(iPlayer2).Width1 = 100
    Pad(iPlayer2).Height = 30
    Pad(iPlayer2).Color1 = _RGB32(230, 130, 220)
    Pad(iPlayer2).SpeedX = 0
    Pad(iPlayer2).SpeedY = 0
    Pad(iPlayer2).Active = True
 
    'Gl
    InitGl = True
    iBallGl = True
    iPadGl1 = True
    iPadGl2 = True
    iActiveGl = False ' at the start the graphic is normal
End Sub
 
' Graphic normal---------------
Sub Showpad (P As Integer)
    If Pad(P).Active Then
        Line (Pad(P).X, Pad(P).Y)-Step(Pad(P).Width1, Pad(P).Height), Pad(P).Color1, BF
        Line (Pad(P).X, Pad(P).Y)-Step(Pad(P).Width1, Pad(P).Height), _RGB32(0), B
    End If
End Sub
 
Sub ShowBall
    Circle (Ball.X, Ball.Y), Ball.Width1, Ball.Color1
    Paint Step(0, 0), Ball.Color1, Ball.Color1
End Sub
 
Sub Border
    Line (myScreen.X + 1, myScreen.Y + 1)-(myScreen.X + myScreen.Width1 - 1, myScreen.Y + myScreen.Height - 1), myScreen.Color1, BF
End Sub
 
' movement and I/O area-----------------------------
Sub Message (iWhereX As Integer, iWhereY As Integer, sMessage As String)
    Locate iWhereY, iWhereX
    Print sMessage;
End Sub
 
Sub MovePad
    Dim i
    For i = iPlayer1 To iPlayer2 Step 1
        If iKeyb(i) = Right Then Pad(i).X = Pad(i).X + 10
        If Pad(i).X > myScreen.Width1 - Pad(i).Width1 Then Pad(i).X = myScreen.Width1 - Pad(i).Width1
        If iKeyb(i) = Left Then Pad(i).X = Pad(i).X - 10
        If Pad(i).X < myScreen.X Then Pad(i).X = myScreen.X
    Next
End Sub
 
Sub MoveBall
    Ball.X = Ball.X + Ball.SpeedX
    Ball.Y = Ball.Y + Ball.SpeedY
    ' bouncing control
    'vs walls
    If Ball.X < 0 Then Ball.X = Int(Ball.Width1 / 2) + 1: Ball.SpeedX = -Ball.SpeedX
    If Ball.X > myScreen.Width1 - Int(Ball.Width1 / 2) + 1 Then Ball.X = myScreen.Width1 - Int(Ball.Width1 / 2) + 1: Ball.SpeedX = -Ball.SpeedX
    If Ball.Y < 0 Then Ball.Y = Int(Ball.Height / 2) + 1: Ball.SpeedY = -Ball.SpeedY
    If Ball.Y > myScreen.Height - Int(Ball.Height / 2) + 1 Then Ball.Y = myScreen.Height - Int(Ball.Height / 2) + 1: Ball.SpeedY = -Ball.SpeedY
    ' vs player1
    If Abs(Pad(iPlayer1).Y + Int(Pad(iPlayer1).Height / 2) - (Ball.Y + Int(Ball.Height / 2))) < Int((Pad(iPlayer1).Height + Ball.Height) / 2) Then
        If Abs((Pad(iPlayer1).X + Int(Pad(iPlayer1).Width1 / 2)) - (Ball.X + Int(Ball.Width1 / 2))) < Int((Pad(iPlayer1).Width1 + Ball.Width1) / 2) Then
            Ball.SpeedY = -Ball.SpeedY
        End If
    End If
    ' vs player2
    If Abs(Pad(iPlayer2).Y + Int(Pad(iPlayer2).Height / 2) - (Ball.Y + Int(Ball.Height / 2))) < Int((Pad(iPlayer2).Height + Ball.Height) / 2) Then
        If Abs((Pad(iPlayer2).X + Int(Pad(iPlayer2).Width1 / 2)) - (Ball.X + Int(Ball.Width1 / 2))) < Int((Pad(iPlayer2).Width1 + Ball.Width1) / 2) Then
            Ball.SpeedY = -Ball.SpeedY
        End If
    End If
End Sub
 
Sub GetInput
    ' it resets command variables
    iKeyb(iPlayer1) = 0
    iKeyb(iPlayer2) = 0
    ' keyboard input
    iKeyb(iPlayer1) = _KeyHit
    If _KeyDown(115) Or _KeyDown(83) Then iKeyb(iPlayer2) = Right Else If iKeyb(iPlayer2) = Right Then iKeyb(iPlayer2) = False
    If _KeyDown(65) Or _KeyDown(97) Then iKeyb(iPlayer2) = Left Else If iKeyb(iPlayer2) = Left Then iKeyb(iPlayer2) = False
    If _KeyDown(27) Then iKeyb(iPlayer2) = Escape
    If _KeyDown(13) Then iKeyb(iPlayer2) = Enter
    '  Do: Loop Until _KeyHit = 0
    ' mouse input
    ' -->in developing
    'joystick input
    '-->in developing
End Sub
 
 

I think I have enough experience with Ping Pong games that we dont have to compare and complicate code by showing regular version versus gl. I suggest pure stripped down gl version. I also suggest you can use one sub to draw a paddle for either player and is using proportion to find coordinates of paddle really necessary? yuck

It would be nice to play against AI because 2 player is stupid (=not fun, how can 2 people sit at one computer who wants to play against them self?) IMHO.

Also I find a bug with Help getting a blank screen when trying to checkout this:
_glVertex2f

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: bplus on August 28, 2021, 12:21:10 pm

Is this also necessary? and again blank on _glColor3f from Help

Code: QB64: [Select]

Function SetColorGL! (nGc, nRc, nBc, nAc)
    SetColorGL! = False
    nGc = Proportion(1, 255, 0, 1, Gc)
    nRc = Proportion(1, 255, 0, 1, Rc)
    nBc = Proportion(1, 255, 0, 1, Bc)
    nAc = Proportion(1, 255, 0, 1, Ac)
    _glColor3f nRc, nGc, nBc  ' ................................. what's 3f for?
    SetColorGL! = True
End Function
 

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: SMcNeill on August 28, 2021, 12:27:40 pm

' ................................. what's 3f for?

In GL, the numbers and letters at the end specify what you’re passing to your routine.

GlColor3f — the 3 says you’re passing 3 values, the f says they’re floating point values.
GlColor4f — 4 values (Red, Green, Blue, Alpha vs RGB), and they’re floats.
GlColor3i — 3 values (RGB), and they’re integers.

And so on…

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: bplus on August 28, 2021, 12:31:51 pm

OK so the color values 0 to 255 in _RGB32 function have to be converted to 0 to 1 for GL?

And the same goes for coordinates?

If so then maybe yes it is helpful to put the 2 ways side by side in single example. :)

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: SMcNeill on August 28, 2021, 12:37:19 pm

Quote from: bplus on August 28, 2021, 12:31:51 pm

OK so the color values 0 to 255 in _RGB32 function have to be converted to 0 to 1 for GL?

And the same goes for coordinates?

Or you can use GlColor*UB for unsigned byte values, which is basically the RGB32 values that you’d plug into QB64 normally. (Replace * with 3 for RGB, 4 for RGBA)

Float (*f) is a value from 0.0 to 1.0. Integer (*i) …. I don’t remember off the top of my head. Unsigned Byte (*ub) is a value from 0 to 255, which we normally use in QB64.

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: bplus on August 28, 2021, 12:44:41 pm

Yeah wow! I just did quick scan of GL in Help, like a whole other language.

Maybe @FellippeHeitor would like to do some Intro programs for GL?

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: Ashish on August 29, 2021, 02:46:41 am

You can avoid the conversion between normal QB screen coordinates to GL coordinates by using some transformation before
drawing.
for example -

Code: QB64: [Select]

Screen _NewImage(600, 600, 32)
 
Do
    _Limit 1
Loop
 
Sub _GL ()
    _glViewport 0, 0, _Width, _Height
    _glMatrixMode _GL_MODELVIEW
    _glTranslatef -1, 1, 0
    _glScalef 1 / (0.5 * _Width(0)), -1 / (0.5 * _Height(0)), 1
 
    _glBegin _GL_TRIANGLES 'normal qb screen coordinates
    _glVertex2f 300, 0
    _glVertex2f 600, 600
    _glVertex2f 0, 600
    _glEnd
 
    _glFlush
End Sub
 

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: TempodiBasic on August 29, 2021, 08:43:21 am

Hi
my pleasure to get the attention and the joining in thread of all you!

All the info showed by you are very important for a beginner of Opengl.

1. Yes Opengl uses own screen dimensions and Cartesian axis, own range value for _RGB system, own coordinates to map images to use as sprite or as textures.

2. (i dunno if it is different in other languages of programming) but in QB64 you can use Opengl commands only into _GL() sub

3. In running mode _GL sub runs about at 60FPS (frequency or rate for second and NOT frame for second)

4. So you can imagine that you cannot make I/O or calculations or loops or _delays in it except for those that don't break this its nature to run always fast. (so you get that without a blocking loop you can use Inkey$ or _Keyhit or _Keydown in _GL sub)

5. Ashish has already posted an alternative solution to the problem of translate the coordinates between Screen setting and Opengl metric system. Other 2 solutions are A) that used in the code that translates on fly at need the coordinates or
B) set the Screen coordinates equal to Opengl cohordinates by using WINDOW command of QB. For example

Code: QB64: [Select]

Dim S as long
S = _Newimage (800,600,32)
Screen S
Window (-1, - 1) - (1,1)
 

A bit more complex is to use a matrix (bidimensionale array) that stores value already calculated. It is evident when you try to make a Plasma code into Opengl.

5. The screen of Opengl is always void! This means that all those commands and techniques that relies their own efficacy on the information stored in graphic memory (think about point() or screen and all the others commands) are without importance here. The easy workaround is to store those informations into a matrix of 2 dimensional array) of unsigned long for a 32bit color screen.

@Ashish
your Opengl tutorial is very good, but as the general tutorial, it doesn't cover all the features of Opengl commands nor all Opengl commands nor how using Opengl to do.....
Nevertheless I find it not only for beginners because it is plenty of informations.
As I said you some time ago, if it is your interest and your will, you can make video tutorials or a more step by step tutorial on Opengl.

@bplus
Yes
1. surely the Opengl subs to draw pad can be unified.
2. Ai Vs human is more interesting I'll do an algorithm
3. Wiki is so much void about _GL commands
4. Easily the standard graphic mode can be stripped out to show the only Opengl version and the beginner must be focused to see the difference between this mode and standard mode to do graphic.

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: bplus on August 29, 2021, 10:44:10 am

Quick question on this:

Code: QB64: [Select]

B) set the Screen coordinates equal to Opengl cohordinates by using WINDOW  command of QB. For example
Code: QB64: [Select]
DIM S AS LONG
S = _NEWIMAGE (800,600,32)
SCREEN S
WINDOW (-1, - 1) - (1,1)
 
 

To avoid distortion of circles, wouldn't you want S to be square? ie 600 x 600, not 800 x 600.

Note how Ashish starts with square screen dimensions.

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: TempodiBasic on August 29, 2021, 11:22:59 am

@bplus
Here the first step
1. unifying the 2 SUB DrawPad in OpenGl
2. make a more rounded ball :-)
3. have more control in the input section

Code: QB64: [Select]

Option _Explicit
' OpenGl Pong
DefLng L ' Longs start with L
DefInt I ' Integers start with I
DefStr S ' Strings start with S
DefSng N 'Singles start with N
 
' type of data called OBJECT
Type obj
    X As Integer
    Y As Integer
    Width1 As Integer
    Height As Integer
    Color1 As _Unsigned Long
    Active As Integer
    SpeedX As Integer
    SpeedY As Integer
End Type
 
Const True = -1, False = 0, Left = 19200, Right = 19712, Escape = 27
Const Enter = 13, iPlayer1 = 1, iPlayer2 = 2
Dim lScreen
Dim Shared iKeyb(1 To 2) As Integer
Dim Shared iActiveGl, myScreen As obj, Pad(1 To 2) As obj, Ball As obj
Dim Shared Gc As Integer, Rc As Integer, Bc As Integer, Ac As Integer
Dim Shared InitGl As Integer, iBallGl As Integer
Dim Shared iPadGl1 As Integer, iPadGl2 As Integer
 
lScreen = _NewImage(800, 600, 32) ' graphic
Screen lScreen ' graphic  creating the window of the program
'  wait that window has been created
_Delay 2 'Do While Not _ScreenExists: Loop
_ScreenMove 1, 1
_Title "OpenGl Pong v.1.0: press Enter to switch between normal vs OpenGl mode"
 
 
Init
 
Do While (iKeyb(iPlayer1) <> Escape) Or (iKeyb(iPlayer2) <> Escape)
    GetInput
    ' stardard graphic mode
    If iActiveGl = False Then
        Border
        Showpad iPlayer1
        Showpad iPlayer2
        ShowBall
        Call Message(1, 1, "press Escape to quit, A/S player 1 Left/Right, cursor Left/Right player 2")
        '    Else
        '  GL() graphic mode
 
        ' Nothing to do here  go to _GL()
    End If
 
    ' calculations for new screenshot
    MovePad
    MoveBall
 
    ' this toggles between standard graphic mode and  Gl graphic mode
    If iKeyb(iPlayer1) = Enter Or iKeyb(iPlayer2) = Enter Then iActiveGl = Not iActiveGl
    Do: Loop Until _KeyHit = 0 ' waiting that user releases the key
    ' saving CPU usage
    _Limit 20
Loop
End
 
' area GL--------------------------------------------------------------
 
Sub _GL ()
    If iActiveGl = 0 Then Exit Sub
    If InitGl Then InitGlSub
    ClearScreen
 
    If iBallGl = True Then BallGl
    If iPadGl1 Then PADgL iPlayer1 'Thanks to Bplus suggestion
    If iPadGl2 Then PADgL iPlayer2 ' one SUB with a flag at the place of 2 subs
    _glFlush
End Sub
 
Sub BallGl
    Dim nGc, nBc, nRc, nAc
    Dim e As Single, gXb As Single, gYb As Single
    ComponentColor Ball.Color1
    If SetColorGL!(nGc, nBc, nRc, nAc) Then
        _glBegin _GL_TRIANGLE_FAN
        For e = 1 To (_Pi(2)) Step (2 * _Pi / 10) ' <-- increasing the number we get a more suitable ball
            gXb = Proportion!(0, _Width, -1, 1, Ball.X + (Ball.Width1 * Cos(e)))
            gYb = Proportion!(0, _Height, 1, -1, Ball.Y + (Ball.Height * Sin(e)))
            _glVertex2f gXb, gYb
        Next e
        _glEnd
    End If
End Sub
 
Sub PADgL (F As Integer)
    Dim nGc, nBc, nRc, nAc
    Dim nx1, nx2, ny1, ny2, dummy
    ComponentColor Pad(F).Color1
    If SetColorGL!(nGc, nBc, nRc, nAc) Then
        nx1 = Proportion(0, _Width, -1, 1, Pad(F).X)
        ny1 = Proportion(0, _Height, 1, -1, Pad(F).Y)
        ny2 = Proportion(0, _Height, 1, -1, Pad(F).Y + Pad(F).Height)
        nx2 = Proportion(0, _Width, -1, 1, Pad(F).X + Pad(F).Width1)
        _glBegin _GL_QUADS
        _glVertex2f nx1, ny1
        _glVertex2f nx1, ny2
        _glVertex2f nx2, ny2
        _glVertex2f nx2, ny1
        _glEnd
        ComponentColor _RGB32(0)
        dummy = SetColorGL!(nGc, nBc, nRc, nAc)
        nx1 = Proportion(0, _Width, -1, 1, Pad(F).X + 2)
        ny1 = Proportion(0, _Height, 1, -1, Pad(F).Y + 2)
        ny2 = Proportion(0, _Height, 1, -1, Pad(F).Y + Pad(F).Height - 2)
        nx2 = Proportion(0, _Width, -1, 1, Pad(F).X + Pad(F).Width1 - 2)
        _glBegin _GL_LINE_LOOP
        _glVertex2f nx1, ny1
        _glVertex2f nx1, ny2
        _glVertex2f nx2, ny2
        _glVertex2f nx2, ny1
        _glEnd
 
    End If
End Sub
 
 
Sub ClearScreen
    _glClear _GL_COLOR_BUFFER_BIT
End Sub
 
Function SetColorGL! (nGc, nRc, nBc, nAc)
    SetColorGL! = False
    nGc = Proportion(1, 255, 0, 1, Gc)
    nRc = Proportion(1, 255, 0, 1, Rc)
    nBc = Proportion(1, 255, 0, 1, Bc)
    nAc = Proportion(1, 255, 0, 1, Ac)
    _glColor3f nRc, nGc, nBc
    SetColorGL! = True
End Function
 
Sub InitGlSub
    'settings viewport for GL screen
    _glViewport myScreen.X, myScreen.Y, myScreen.Width1, myScreen.Height
    Dim nGc, nBc, nRc, nAc
    ComponentColor myScreen.Color1
    If SetColorGL!(nGc, nRc, nBc, nAc) Then
        _glClearColor nRc, nGc, nBc, nAc
    Else
        Print "Error"
    End If
    InitGl = False
End Sub
 
 
' area sub/functions*****************************************************
Function Proportion (imin1, imax1, imin2, imax2, ivalue)
    Dim iDelta1, iDelta2
    iDelta1 = (imax1 - imin1)
    iDelta2 = (imax2 - imin2)
    Proportion = ((ivalue * iDelta2) / iDelta1) + imin2
End Function
 
 
 
Sub ComponentColor (C As _Unsigned Long)
    Gc = _Green32(C)
    Rc = _Red32(C)
    Bc = _Blue32(C)
    Ac = _Alpha32(C)
End Sub
 
Sub Init
    ' window of program
    myScreen.X = 0
    myScreen.Y = 0
    myScreen.Width1 = _Width
    myScreen.Height = _Height
    myScreen.Color1 = _RGB32(200, 200, 50)
    myScreen.Active = True
 
    ' ball
    Ball.X = 400
    Ball.Y = 300
    Ball.Active = True
    Ball.Width1 = 10
    Ball.Height = 10
    Ball.SpeedX = 3
    Ball.SpeedY = 3
    Ball.Color1 = _RGB32(200, 10, 10)
 
    'PAD player1
    Pad(iPlayer1).X = 350
    Pad(iPlayer1).Y = 400
    Pad(iPlayer1).Width1 = 100
    Pad(iPlayer1).Height = 30
    Pad(iPlayer1).Color1 = _RGB32(40, 230, 200)
    Pad(iPlayer1).SpeedX = 0
    Pad(iPlayer1).SpeedY = 0
    Pad(iPlayer1).Active = True
 
 
    'PAD player2
    Pad(iPlayer2).X = 350
    Pad(iPlayer2).Y = 150
    Pad(iPlayer2).Width1 = 100
    Pad(iPlayer2).Height = 30
    Pad(iPlayer2).Color1 = _RGB32(230, 130, 220)
    Pad(iPlayer2).SpeedX = 0
    Pad(iPlayer2).SpeedY = 0
    Pad(iPlayer2).Active = True
 
    'Gl
    InitGl = True
    iBallGl = True
    iPadGl1 = True
    iPadGl2 = True
    iActiveGl = False ' at the start the graphic is normal
End Sub
 
' Graphic normal---------------
Sub Showpad (P As Integer)
    If Pad(P).Active Then
        Line (Pad(P).X, Pad(P).Y)-Step(Pad(P).Width1, Pad(P).Height), Pad(P).Color1, BF
        Line (Pad(P).X, Pad(P).Y)-Step(Pad(P).Width1, Pad(P).Height), _RGB32(0), B
    End If
End Sub
 
Sub ShowBall
    Circle (Ball.X, Ball.Y), Ball.Width1, Ball.Color1
    Paint Step(0, 0), Ball.Color1, Ball.Color1
End Sub
 
Sub Border
    Line (myScreen.X + 1, myScreen.Y + 1)-(myScreen.X + myScreen.Width1 - 1, myScreen.Y + myScreen.Height - 1), myScreen.Color1, BF
End Sub
 
' movement and I/O area-----------------------------
Sub Message (iWhereX As Integer, iWhereY As Integer, sMessage As String)
    Locate iWhereY, iWhereX
    Print sMessage;
End Sub
 
Sub MovePad
    Dim i
    For i = iPlayer1 To iPlayer2 Step 1
        If iKeyb(i) = Right Then Pad(i).X = Pad(i).X + 10
        If Pad(i).X > myScreen.Width1 - Pad(i).Width1 Then Pad(i).X = myScreen.Width1 - Pad(i).Width1
        If iKeyb(i) = Left Then Pad(i).X = Pad(i).X - 10
        If Pad(i).X < myScreen.X Then Pad(i).X = myScreen.X
    Next
End Sub
 
Sub MoveBall
    Ball.X = Ball.X + Ball.SpeedX
    Ball.Y = Ball.Y + Ball.SpeedY
    ' bouncing control
    'vs walls
    If Ball.X < 0 Then Ball.X = Int(Ball.Width1 / 2) + 1: Ball.SpeedX = -Ball.SpeedX
    If Ball.X > myScreen.Width1 - Int(Ball.Width1 / 2) + 1 Then Ball.X = myScreen.Width1 - Int(Ball.Width1 / 2) + 1: Ball.SpeedX = -Ball.SpeedX
    If Ball.Y < 0 Then Ball.Y = Int(Ball.Height / 2) + 1: Ball.SpeedY = -Ball.SpeedY
    If Ball.Y > myScreen.Height - Int(Ball.Height / 2) + 1 Then Ball.Y = myScreen.Height - Int(Ball.Height / 2) + 1: Ball.SpeedY = -Ball.SpeedY
    ' vs player1
    If Abs(Pad(iPlayer1).Y + Int(Pad(iPlayer1).Height / 2) - (Ball.Y + Int(Ball.Height / 2))) < Int((Pad(iPlayer1).Height + Ball.Height) / 2) Then
        If Abs((Pad(iPlayer1).X + Int(Pad(iPlayer1).Width1 / 2)) - (Ball.X + Int(Ball.Width1 / 2))) < Int((Pad(iPlayer1).Width1 + Ball.Width1) / 2) Then
            Ball.SpeedY = -Ball.SpeedY
        End If
    End If
    ' vs player2
    If Abs(Pad(iPlayer2).Y + Int(Pad(iPlayer2).Height / 2) - (Ball.Y + Int(Ball.Height / 2))) < Int((Pad(iPlayer2).Height + Ball.Height) / 2) Then
        If Abs((Pad(iPlayer2).X + Int(Pad(iPlayer2).Width1 / 2)) - (Ball.X + Int(Ball.Width1 / 2))) < Int((Pad(iPlayer2).Width1 + Ball.Width1) / 2) Then
            Ball.SpeedY = -Ball.SpeedY
        End If
    End If
End Sub
 
Sub GetInput
    ' it resets command variables
    iKeyb(iPlayer1) = 0
    iKeyb(iPlayer2) = 0
    ' keyboard input
    iKeyb(iPlayer1) = _KeyHit
    If _KeyDown(115) Or _KeyDown(83) Then iKeyb(iPlayer2) = Right Else If iKeyb(iPlayer2) = Right Then iKeyb(iPlayer2) = False
    If _KeyDown(65) Or _KeyDown(97) Then iKeyb(iPlayer2) = Left Else If iKeyb(iPlayer2) = Left Then iKeyb(iPlayer2) = False
    If _KeyDown(27) Then iKeyb(iPlayer2) = Escape
    If _KeyDown(13) Then iKeyb(iPlayer2) = Enter
    '  Do: Loop Until _KeyHit = 0
    ' mouse input
    ' -->in developing
    'joystick input
    '-->in developing
End Sub
 
 
 

PS I'm delaying for AI because OpenGl is a graphic issue, so I'm putting it in a second order.

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: TempodiBasic on August 29, 2021, 11:48:35 am

Here the code with only OpenGl version

Code: QB64: [Select]

OPTION _EXPLICIT
' OpenGl Pong
DEFLNG L ' Longs start with L
DEFINT I ' Integers start with I
DEFSTR S ' Strings start with S
DEFSNG N 'Singles start with N
 
' type of data called OBJECT
TYPE obj
    X AS INTEGER
    Y AS INTEGER
    Width1 AS INTEGER
    Height AS INTEGER
    Color1 AS _UNSIGNED LONG
    Active AS INTEGER
    SpeedX AS INTEGER
    SpeedY AS INTEGER
END TYPE
 
CONST True = -1, False = 0, Left = 19200, Right = 19712, Escape = 27
CONST Enter = 13, iPlayer1 = 1, iPlayer2 = 2
DIM lScreen
DIM SHARED iKeyb(1 TO 2) AS INTEGER
DIM SHARED iActiveGl, myScreen AS obj, Pad(1 TO 2) AS obj, Ball AS obj
DIM SHARED Gc AS INTEGER, Rc AS INTEGER, Bc AS INTEGER, Ac AS INTEGER
DIM SHARED InitGl AS INTEGER, iBallGl AS INTEGER
DIM SHARED iPadGl1 AS INTEGER, iPadGl2 AS INTEGER
 
lScreen = _NEWIMAGE(800, 600, 32) ' graphic
SCREEN lScreen ' graphic  creating the window of the program
'  wait that window has been created
_DELAY 2 'Do While Not _ScreenExists: Loop
_SCREENMOVE 1, 1
_TITLE "OpenGl Pong v.1.0: press Enter to switch between normal vs OpenGl mode"
 
 
Init
 
DO WHILE (iKeyb(iPlayer1) <> Escape) OR (iKeyb(iPlayer2) <> Escape)
    GetInput
    ' stardard graphic mode
    IF iActiveGl = False THEN
        Border
        Showpad iPlayer1
        Showpad iPlayer2
        ShowBall
        CALL Message(1, 1, "press Escape to quit, A/S player 1 Left/Right, cursor Left/Right player 2")
        '    Else
        '  GL() graphic mode
 
        ' Nothing to do here  go to _GL()
    END IF
 
    ' calculations for new screenshot
    MovePad
    MoveBall
 
    ' this toggles between standard graphic mode and  Gl graphic mode
    IF iKeyb(iPlayer1) = Enter OR iKeyb(iPlayer2) = Enter THEN iActiveGl = NOT iActiveGl
    DO: LOOP UNTIL _KEYHIT = 0 ' waiting that user releases the key
    ' saving CPU usage
    _LIMIT 20
LOOP
END
 
' area GL--------------------------------------------------------------
 
SUB _GL ()
    IF iActiveGl = 0 THEN EXIT SUB
    IF InitGl THEN InitGlSub
    ClearScreen
 
    IF iBallGl = True THEN BallGl
    IF iPadGl1 THEN PADgL iPlayer1 'Thanks to Bplus suggestion
    IF iPadGl2 THEN PADgL iPlayer2 ' one SUB with a flag at the place of 2 subs
    _GLFLUSH
END SUB
 
SUB BallGl
    DIM nGc, nBc, nRc, nAc
    DIM e AS SINGLE, gXb AS SINGLE, gYb AS SINGLE
    ComponentColor Ball.Color1
    IF SetColorGL!(nGc, nBc, nRc, nAc) THEN
        _GLBEGIN _GL_TRIANGLE_FAN
        FOR e = 1 TO (_PI(2)) STEP (2 * _PI / 10) ' <-- increasing the number we get a more suitable ball
            gXb = Proportion!(0, _WIDTH, -1, 1, Ball.X + (Ball.Width1 * COS(e)))
            gYb = Proportion!(0, _HEIGHT, 1, -1, Ball.Y + (Ball.Height * SIN(e)))
            _GLVERTEX2F gXb, gYb
        NEXT e
        _GLEND
    END IF
END SUB
 
SUB PADgL (F AS INTEGER)
    DIM nGc, nBc, nRc, nAc
    DIM nx1, nx2, ny1, ny2, dummy
    ComponentColor Pad(F).Color1
    IF SetColorGL!(nGc, nBc, nRc, nAc) THEN
        nx1 = Proportion(0, _WIDTH, -1, 1, Pad(F).X)
        ny1 = Proportion(0, _HEIGHT, 1, -1, Pad(F).Y)
        ny2 = Proportion(0, _HEIGHT, 1, -1, Pad(F).Y + Pad(F).Height)
        nx2 = Proportion(0, _WIDTH, -1, 1, Pad(F).X + Pad(F).Width1)
        _GLBEGIN _GL_QUADS
        _GLVERTEX2F nx1, ny1
        _GLVERTEX2F nx1, ny2
        _GLVERTEX2F nx2, ny2
        _GLVERTEX2F nx2, ny1
        _GLEND
        ComponentColor _RGB32(0)
        dummy = SetColorGL!(nGc, nBc, nRc, nAc)
        nx1 = Proportion(0, _WIDTH, -1, 1, Pad(F).X + 2)
        ny1 = Proportion(0, _HEIGHT, 1, -1, Pad(F).Y + 2)
        ny2 = Proportion(0, _HEIGHT, 1, -1, Pad(F).Y + Pad(F).Height - 2)
        nx2 = Proportion(0, _WIDTH, -1, 1, Pad(F).X + Pad(F).Width1 - 2)
        _GLBEGIN _GL_LINE_LOOP
        _GLVERTEX2F nx1, ny1
        _GLVERTEX2F nx1, ny2
        _GLVERTEX2F nx2, ny2
        _GLVERTEX2F nx2, ny1
        _GLEND
 
    END IF
END SUB
 
 
SUB ClearScreen
    _GLCLEAR _GL_COLOR_BUFFER_BIT
END SUB
 
FUNCTION SetColorGL! (nGc, nRc, nBc, nAc)
    SetColorGL! = False
    nGc = Proportion(1, 255, 0, 1, Gc)
    nRc = Proportion(1, 255, 0, 1, Rc)
    nBc = Proportion(1, 255, 0, 1, Bc)
    nAc = Proportion(1, 255, 0, 1, Ac)
    _GLCOLOR3F nRc, nGc, nBc
    SetColorGL! = True
END FUNCTION
 
SUB InitGlSub
    'settings viewport for GL screen
    _GLVIEWPORT myScreen.X, myScreen.Y, myScreen.Width1, myScreen.Height
    DIM nGc, nBc, nRc, nAc
    ComponentColor myScreen.Color1
    IF SetColorGL!(nGc, nRc, nBc, nAc) THEN
        _GLCLEARCOLOR nRc, nGc, nBc, nAc
    ELSE
        PRINT "Error"
    END IF
    InitGl = False
END SUB
 
 
' area sub/functions*****************************************************
FUNCTION Proportion (imin1, imax1, imin2, imax2, ivalue)
    DIM iDelta1, iDelta2
    iDelta1 = (imax1 - imin1)
    iDelta2 = (imax2 - imin2)
    Proportion = ((ivalue * iDelta2) / iDelta1) + imin2
END FUNCTION
 
 
 
SUB ComponentColor (C AS _UNSIGNED LONG)
    Gc = _GREEN32(C)
    Rc = _RED32(C)
    Bc = _BLUE32(C)
    Ac = _ALPHA32(C)
END SUB
 
SUB Init
    ' window of program
    myScreen.X = 0
    myScreen.Y = 0
    myScreen.Width1 = _WIDTH
    myScreen.Height = _HEIGHT
    myScreen.Color1 = _RGB32(200, 200, 50)
    myScreen.Active = True
 
    ' ball
    Ball.X = 400
    Ball.Y = 300
    Ball.Active = True
    Ball.Width1 = 10
    Ball.Height = 10
    Ball.SpeedX = 3
    Ball.SpeedY = 3
    Ball.Color1 = _RGB32(200, 10, 10)
 
    'PAD player1
    Pad(iPlayer1).X = 350
    Pad(iPlayer1).Y = 400
    Pad(iPlayer1).Width1 = 100
    Pad(iPlayer1).Height = 30
    Pad(iPlayer1).Color1 = _RGB32(40, 230, 200)
    Pad(iPlayer1).SpeedX = 0
    Pad(iPlayer1).SpeedY = 0
    Pad(iPlayer1).Active = True
 
 
    'PAD player2
    Pad(iPlayer2).X = 350
    Pad(iPlayer2).Y = 150
    Pad(iPlayer2).Width1 = 100
    Pad(iPlayer2).Height = 30
    Pad(iPlayer2).Color1 = _RGB32(230, 130, 220)
    Pad(iPlayer2).SpeedX = 0
    Pad(iPlayer2).SpeedY = 0
    Pad(iPlayer2).Active = True
 
    'Gl
    InitGl = True
    iBallGl = True
    iPadGl1 = True
    iPadGl2 = True
    iActiveGl = False ' at the start the graphic is normal
END SUB
 
' Graphic normal---------------
SUB Showpad (P AS INTEGER)
    IF Pad(P).Active THEN
        LINE (Pad(P).X, Pad(P).Y)-STEP(Pad(P).Width1, Pad(P).Height), Pad(P).Color1, BF
        LINE (Pad(P).X, Pad(P).Y)-STEP(Pad(P).Width1, Pad(P).Height), _RGB32(0), B
    END IF
END SUB
 
SUB ShowBall
    CIRCLE (Ball.X, Ball.Y), Ball.Width1, Ball.Color1
    PAINT STEP(0, 0), Ball.Color1, Ball.Color1
END SUB
 
SUB Border
    LINE (myScreen.X + 1, myScreen.Y + 1)-(myScreen.X + myScreen.Width1 - 1, myScreen.Y + myScreen.Height - 1), myScreen.Color1, BF
END SUB
 
' movement and I/O area-----------------------------
SUB Message (iWhereX AS INTEGER, iWhereY AS INTEGER, sMessage AS STRING)
    LOCATE iWhereY, iWhereX
    PRINT sMessage;
END SUB
 
SUB MovePad
    DIM i
    FOR i = iPlayer1 TO iPlayer2 STEP 1
        IF iKeyb(i) = Right THEN Pad(i).X = Pad(i).X + 10
        IF Pad(i).X > myScreen.Width1 - Pad(i).Width1 THEN Pad(i).X = myScreen.Width1 - Pad(i).Width1
        IF iKeyb(i) = Left THEN Pad(i).X = Pad(i).X - 10
        IF Pad(i).X < myScreen.X THEN Pad(i).X = myScreen.X
    NEXT
END SUB
 
SUB MoveBall
    Ball.X = Ball.X + Ball.SpeedX
    Ball.Y = Ball.Y + Ball.SpeedY
    ' bouncing control
    'vs walls
    IF Ball.X < 0 THEN Ball.X = INT(Ball.Width1 / 2) + 1: Ball.SpeedX = -Ball.SpeedX
    IF Ball.X > myScreen.Width1 - INT(Ball.Width1 / 2) + 1 THEN Ball.X = myScreen.Width1 - INT(Ball.Width1 / 2) + 1: Ball.SpeedX = -Ball.SpeedX
    IF Ball.Y < 0 THEN Ball.Y = INT(Ball.Height / 2) + 1: Ball.SpeedY = -Ball.SpeedY
    IF Ball.Y > myScreen.Height - INT(Ball.Height / 2) + 1 THEN Ball.Y = myScreen.Height - INT(Ball.Height / 2) + 1: Ball.SpeedY = -Ball.SpeedY
    ' vs player1
    IF ABS(Pad(iPlayer1).Y + INT(Pad(iPlayer1).Height / 2) - (Ball.Y + INT(Ball.Height / 2))) < INT((Pad(iPlayer1).Height + Ball.Height) / 2) THEN
        IF ABS((Pad(iPlayer1).X + INT(Pad(iPlayer1).Width1 / 2)) - (Ball.X + INT(Ball.Width1 / 2))) < INT((Pad(iPlayer1).Width1 + Ball.Width1) / 2) THEN
            Ball.SpeedY = -Ball.SpeedY
        END IF
    END IF
    ' vs player2
    IF ABS(Pad(iPlayer2).Y + INT(Pad(iPlayer2).Height / 2) - (Ball.Y + INT(Ball.Height / 2))) < INT((Pad(iPlayer2).Height + Ball.Height) / 2) THEN
        IF ABS((Pad(iPlayer2).X + INT(Pad(iPlayer2).Width1 / 2)) - (Ball.X + INT(Ball.Width1 / 2))) < INT((Pad(iPlayer2).Width1 + Ball.Width1) / 2) THEN
            Ball.SpeedY = -Ball.SpeedY
        END IF
    END IF
END SUB
 
SUB GetInput
    ' it resets command variables
    iKeyb(iPlayer1) = 0
    iKeyb(iPlayer2) = 0
    ' keyboard input
    iKeyb(iPlayer1) = _KEYHIT
    IF _KEYDOWN(115) OR _KEYDOWN(83) THEN iKeyb(iPlayer2) = Right ELSE IF iKeyb(iPlayer2) = Right THEN iKeyb(iPlayer2) = False
    IF _KEYDOWN(65) OR _KEYDOWN(97) THEN iKeyb(iPlayer2) = Left ELSE IF iKeyb(iPlayer2) = Left THEN iKeyb(iPlayer2) = False
    IF _KEYDOWN(27) THEN iKeyb(iPlayer2) = Escape
    IF _KEYDOWN(13) THEN iKeyb(iPlayer2) = Enter
    '  Do: Loop Until _KeyHit = 0
    ' mouse input
    ' -->in developing
    'joystick input
    '-->in developing
END SUB
 
 
 

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: TempodiBasic on August 29, 2021, 11:58:50 am

@Ashish
I have an issue with your code!
It was flickering!

Code: QB64: [Select]

Screen _NewImage(600, 600, 32)
Randomize Timer
Do
    _Limit 1
Loop
 
Sub _GL ()
    _glViewport 0, 0, _Width, _Height
    _glMatrixMode _GL_MODELVIEW
    _glTranslatef -1, 1, 0
    _glScalef 1 / (0.5 * _Width(0)), -1 / (0.5 * _Height(0)), 1
 
    _glBegin _GL_TRIANGLES 'normal qb screen coordinates
    _glVertex2f Rnd * 300, 0
    _glVertex2f Rnd * 600, Rnd * 600
    _glVertex2f 0, Rnd * 600
    _glEnd
 
    _glFlush
End Sub
 
 

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: TempodiBasic on September 05, 2021, 11:42:22 am

@bplus
Hi
sorry for the late answer, but as you know by my nickname, I often have few time:
about your question on the distortion if it is used a rectangle screen instead of a square screen I think no because in Opengl we draw the ball that has one radius and we don't copy the image of circle from a system of cohordinates to the other system.
As soon as I'll post the WINDOW version of code.

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: bplus on September 05, 2021, 11:59:21 am

Yeah I got the ball well formed after some fiddling, I think you left too many remnants of the two different code methods and it is adding to confusion. Plus I wonder if you are making the best gl choices from all the options there are but I am biased with my regular 2D coding style with QB64. Frankly I was overwhelmed by all the different command choices of gl that do basically the same thing.

I would like to see it built from scratch with just the ball bouncing off walls in the simplest, least lines as possible form with helpfully named variables. Then add one paddle to start hitting ball.

Title: Re: OpenGl Pong: simple demonstration of OpenGl 2D graphic vs standard graphic
Post by: TempodiBasic on September 05, 2021, 07:33:18 pm

Hi Bplus
fine to meet your interest about OpenGl

about

Quote

I would like to see it built from scratch with just the ball bouncing off walls in the simplest, least lines as possible form with helpfully named variables. Then add one paddle to start hitting ball.

you're right a good tutorial must show how to build from scratch the simple demo of Pong.
So I rewrote it step by step, posting for each step a demonstration file filled by comments and consuming my hand joints by typing more and more long selfexplaining variables' names.
you can find the starting demo posted in another thread. And It maybe that if it is good enough it gains the program demo area.

Thanks for feedbacks

Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: TempodiBasic on August 26, 2021, 08:50:40 pm