Print Page - $VIRTUALKEYBOARD Alternative for Windows and Linux

There used to be a keyword for QB64 that would pull up the virtual keyboard for Android development. The keyword still exists in QB64 but is deprecated and not used. This is my attempt at making something similar for Windows and Linux. Enjoy. For Linux, you will need to install onboard from the command line in order to use the function.

Code: QB64: [Select]

Option _Explicit
 
Dim As String test
 
VirtualKeyboard 1
Input "Test the keyboard! ", test
Print test
 
Sleep
 
VirtualKeyboard 0
 
Sub VirtualKeyboard (toggle As _Byte)
    $If WINDOWS Then
        Type PROCESSENTRY32
            As Long dwSize, cntUsage, th32ProcessID
            $If 64BIT Then
            As Long padding
            $End If
            As _Unsigned Long th32DefaultHeapID
            $If 64BIT Then
            As Long padding2
            $End If
            As Long th32ModuleID, cntThreads, th32ParentProcessID, pcPriClassBase, dwFlags
            As String * 260 szExeFile
        End Type
        Type STARTUPINFO
            As Long cb
            $If 64BIT Then
            As Long padding
            $End If
            As _Offset lpReserved, lpDesktop, lpTitle
            As Long dwX, dwY, dwXSize, dwYSize, dwXCountChars, dwYCountChars, dwFillAttribute, dwFlags
            As Integer wShowWindow, cbReserved2
            $If 64BIT Then
            As Long padding2
            $End If
            As _Offset lpReserved2, hStdInput, hStdOutput, hStdError
        End Type
        Type PROCESS_INFORMATION
            As _Offset hProcess, hThread
            As Long dwProcessId
            $If 64BIT Then
            As Long padding
            $End If
        End Type
        Declare Dynamic Library "Kernel32"
            Function CreateToolhelp32Snapshot& (ByVal dwFlags As Long, Byval th32ProcessID As Long)
            Function Process32First%% (ByVal hSnapshot As _Offset, Byval lppe As _Offset)
            Function Process32Next%% (ByVal hSnapshot As _Offset, Byval lppe As _Offset)
            Function OpenProcess& (ByVal dwDesiredAccess As Long, Byval bInheritHandle As _Byte, Byval dwProcessId As Long)
            Function TerminateProcess%% (ByVal hProcess As _Offset, Byval uExitCode As _Unsigned Long)
            Function CloseHandle%% (ByVal hObject As _Offset)
        End Declare
        Declare CustomType Library
            Function CreateProcess%% Alias "CreateProcessA" (ByVal lpApplicationName As _Offset, Byval lpCommandLine As _Offset, Byval lpProcessAttributes As _Offset, Byval lpThreadAttributes As _Offset, Byval bInheritHandles As Integer, Byval dwCreationFlags As Long, Byval lpEnvironment As _Offset, Byval lpCurrentDirectory As _Offset, Byval lpStartupInfor As _Offset, Byval lpProcessInformation As _Offset)
            $If 32BIT Then
                Function Wow64DisableWow64FsRedirection%% (ByVal oldvalue As _Offset)
            $End If
        End Declare
        Const TH32CS_SNAPPROCESS = &H00000002
        Const PROCESS_TERMINATE = &H0001
        Const CREATE_NO_WINDOW = &H8000000
        Dim As _Byte ok
        Select Case toggle
            Case 1
                $If 32BIT Then
                    Dim As _Offset oldvalue
                    Dim As _Byte result
                    result = Wow64DisableWow64FsRedirection(oldvalue)
                $End If
                Dim As STARTUPINFO si
                si.cb = Len(si)
                si.hStdInput = 0
                Dim As PROCESS_INFORMATION pi
                Dim As _Offset lpApplicationName
                Dim As String fullcmd: fullcmd = "cmd /c osk" + Chr$(0)
                Dim As String lpCommandLine: lpCommandLine = fullcmd
                Dim As _Offset lpProcessAttributes, lpThreadAttributes
                Dim As Integer bInheritHandles: bInheritHandles = 1
                Dim As Long dwCreationFlags: dwCreationFlags = CREATE_NO_WINDOW
                Dim As _Offset lpEnvironment, lpCurrentDirectory
                ok = CreateProcess(lpApplicationName, _Offset(lpCommandLine), lpProcessAttributes, lpThreadAttributes, bInheritHandles, dwCreationFlags, lpEnvironment, lpCurrentDirectory, _Offset(si), _Offset(pi))
            Case 0
                Dim As Long snap
                snap = CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0)
                Dim As PROCESSENTRY32 pEntry
                pEntry.dwSize = Len(pEntry)
                Dim As _Byte hRes
                hRes = Process32First(snap, _Offset(pEntry))
                While hRes
                    If _StrCmp(Left$(pEntry.szExeFile, InStr(pEntry.szExeFile, ".exe" + Chr$(0)) + 3), "osk.exe") = 0 Then
                        Dim As Long hProcess
                        hProcess = OpenProcess(PROCESS_TERMINATE, 0, pEntry.th32ProcessID)
                        If hProcess <> 0 Then
                            Dim As _Byte terminate, closeh
                            terminate = TerminateProcess(hProcess, 9)
                            closeh = CloseHandle(hProcess)
                        End If
                    End If
                    hRes = Process32Next(snap, _Offset(pEntry))
                Wend
                closeh = CloseHandle(snap)
        End Select
    $ElseIf LINUX Then
        Select Case toggle
        Case 1
        Shell _Hide _DontWait "dbus-send --type=method_call --dest=org.onboard.Onboard /org/onboard/Onboard/Keyboard org.onboard.Onboard.Keyboard.Show"
        Case 0
        Shell _Hide _DontWait "dbus-send --type=method_call --dest=org.onboard.Onboard /org/onboard/Onboard/Keyboard org.onboard.Onboard.Keyboard.Hide"
        End Select
    $End If
End Sub

I've updated the original post to also work with Linux. Requires an installation of onboard

On Discord, @Ashish pointed out that it wasn't working in 32 bit Windows. This was caused by an issue that is present in several programming languages and caused by Windows redirecting to 64 bit file directories. Thankfully, easily fixed by making one function call. Now it works in 32 and 64 bit Windows.

I've got a virtual keyboard here as well, if you want to check it out sometime: https://www.qb64.org/forum/index.php?topic=3608.0

Oh, yeah that thing. I remember seeing that. Mine just brings up the OS's on-screen keyboard.

Thanks! Now it works for me

QB64.org Forum

Active Forums => Programs => Topic started by: SpriggsySpriggs on April 19, 2021, 05:15:17 pm