Print Page - Pipecom Browser for Filename$

Title: Pipecom Browser for Filename$
Post by: bplus on February 07, 2021, 08:04:56 pm

Here is application to viewing BMP24 files that NOVARSEG started:

Code: QB64: [Select]

Option _Explicit
_Title "Pipecom Browser for BMP24 File Display" 'b+ testing one array system with pipecom
' Thanks to Spriggsy, Zak, for convincing me pipecom is better!
' Using Steve's fixed BMP24 loader
' Also thanks to Dav for 1 window for file and folder selection idea
' Also thanks to NOVARSEG who got me going on this for a better filename$ retriever
 
Declare Library "pipecom"
    Function pipecom$ (cmd As String)
End Declare
 
Screen _NewImage(1280, 740, 32)
_Delay .25
_ScreenMove 65, 0 ' your screen might need different
 
ReDim myFile$, image&
ReDim As Long col, row, charW, charH
Color , &HFF000033
Cls
Do 'test our new function
    ScnState 0
    col = 16: row = 3: charW = 128: charH = 40
    myFile$ = GetFileName$(row, col, charW, charH)
    ScnState -1 ' <<<<<<<<<<<<<<<<<<<<<<<<<<< this is supposed to restore back color
    image& = loadBMP24&(myFile$)
    Color , &HFF000033
    Cls
    If image& <> 0 Then
        _Title myFile$ + " press any to get another BMP24 file image, esc to quit"
        _PutImage ((_Width - _Width(image&)) / 2, (_Height - _Height(image&)) / 2)-Step(_Width(image&), _Height(image&)), image&, 0
        Sleep
        _FreeImage image&
    End If
Loop Until _KeyDown(27)
 
Function loadBMP24& (Filename$) ' Steve's revised version without the extra handle and memory leak
    Dim As _Unsigned Long of, l, w, r, c
    Dim i As _Unsigned Integer
    Dim a As _MEM
    Dim As Long handle, h ' <<< edit as per NOVARSEG
    Dim tt As String * 4
    Dim t As String * 3
    Dim padding$
 
    If Right$(UCase$(Filename$), 4) <> ".BMP" Then Exit Function
    Print Filename$
    Open Filename$ For Binary As #1
    Get #1, 11, of
    Get #1, 15, l
    Get #1, , w
    Get #1, , h
    Get #1, , i
    Get #1, , i 'get I twice ???
    If i <> 24 Then Exit Function
    handle = _NewImage(w, h, 32)
    a = _MemImage(handle)
    If ((w * 3) Mod 4) <> 0 Then padding$ = Space$((4 - ((w * 3) Mod 4))) '’need padding pixels
    Seek #1, of + 1 'go to the offset where the data starts
    For r = h - 1 To 0 Step -1 'from the bottom to top
        For c = 0 To w - 1 'left to right
            Get #1, , t 'get the data sequentially
            tt = t + Chr$(255)
            _MemPut a, a.OFFSET + (w * r + c) * 4, tt
        Next c
        Get #1, , padding$ 'Get the padding at the end of the line
    Next r
    Close
    loadBMP24& = handle
    _MemFree a
End Function
 
Function GetFileName$ (LocateR, LocateC, CharWide, CharHigh) ' < careful Locate Row, Col NOT x, y
    'This Funtion needs:
    ' pipecom.h in same folder as QB64.exe
    ' This in main code section near top:
    ' Declare Library "pipecom"
    '    Function pipecom$ (cmd As String)
    ' End Declare
    ' sub  Split source$, delimiter$, arr$()
    ' function GetArrayItem$(x, y, w, h, arr$())
 
    ReDim As String d, s, dr
    ReDim As _Unsigned Long fc, bc
    fc = _DefaultColor: bc = _BackgroundColor ' save colors
    Getfolder:
    Color fc, bc: Cls
    d = pipecom("dir /n /o:gend") '/n files on right (40) /o = order g for group dirs first, e extension, name, date
    d = Left$(d, Len(d) - 1) ' always ends with delimiter
    ReDim dir(1 To 1) As String
    Split d, Chr$(10), dir()
    s = GetArrayItem$(LocateR, LocateC, CharWide, CharHigh, dir())
    If InStr(s, "<DIR>") Then 'isolate name
        dr = _Trim$(Mid$(s, InStr(s, "<DIR>") + 6))
        ChDir dr
        GoTo Getfolder
    ElseIf InStr(s, "AM") Or InStr(s, "PM") Then
        GetFileName$ = _Trim$(Mid$(s, 40))
        Color fc, bc: Cls
    ElseIf s = "" Then 'cancel, escape, bad line
        Color fc, bc: Cls ' will return empty string
    End If
End Function
 
Sub Split (SplitMeString As String, delim As String, loadMeArray() As String)
    Dim curpos As Long, arrpos As Long, LD As Long, dpos As Long 'fix use the Lbound the array already has
    curpos = 1: arrpos = LBound(loadMeArray): LD = Len(delim)
    dpos = InStr(curpos, SplitMeString, delim)
    Do Until dpos = 0
        loadMeArray(arrpos) = Mid$(SplitMeString, curpos, dpos - curpos)
        arrpos = arrpos + 1
        If arrpos > UBound(loadMeArray) Then ReDim _Preserve loadMeArray(LBound(loadMeArray) To UBound(loadMeArray) + 1000) As String
        curpos = dpos + LD
        dpos = InStr(curpos, SplitMeString, delim)
    Loop
    loadMeArray(arrpos) = Mid$(SplitMeString, curpos)
    ReDim _Preserve loadMeArray(LBound(loadMeArray) To arrpos) As String 'get the ubound correct
End Sub
 
 
' Help: all this I hope is intuitive so Help window is provided
' "Mouse, mouse wheel, and arrow keys should work as expected for item selection."
' "Press spacebar to select a highlighted item or just click it."
' "Use number(s) + enter to select an array item by it's index number,"
' "backspace will remove last number pressed, delete will clear a number started.
' "Numbers started are shown in bottom right PgDn bar."
' "Enter will also select the highlighted item, if no number has been started."
' "Home starts you at lowest array index, End highlights then highest index."
' "Use PgUp and PgDn keys to flip through pages of array items."
'
' Escape to Cancel Return "" else Return the selected string from the array
Function GetArrayItem$ (LocateRoww, LocateColumn, BoxWidth, BoxHeight, Arr() As String)
    'Notes: locateRow, locateColumn for top right corner of selection box on screen in characters for LOCATE.
    'boxWidth and boxHeight are in character units, again for locate and print at correct places.
    'All displaying is restricted to inside the box, which has PgUP and PgDn as top and bottom lines in the display.
 
    ReDim As Long maxWidth, maxHeight, page, hlite, mx, my, locateRow, lastMX, lastMY, row, mb
    ReDim As Long lba, uba, choice, kh, index
    Dim clrStr As String, b As String
 
    'ScnState 0 ' use out side this function before and after
    locateRow = LocateRoww + 1 'fix a miscalc in coding
    maxWidth = BoxWidth '       number of characters in box
    maxHeight = BoxHeight - 2 ' number of lines displayed of array at one time = 1 page
    lba = LBound(arr)
    uba = UBound(arr)
    page = 0
    hlite = 0 '                 line in display ready for selection by spacebar or if no number is started, enter
    clrStr$ = Space$(maxWidth) 'clearing a display line
 
    GoSub update '              show the beginning of the array items for selection
    choice = -1719
    Do 'until get a selection or demand exit
 
        'handle the key stuff
        kh& = _KeyHit
        If kh& Then
            If kh& > 0 And kh& < 255 Then
                If InStr("0123456789", Chr$(kh&)) > 0 Then
                    b$ = b$ + Chr$(kh&): GoSub update
                ElseIf kh& = 13 Then 'enter pressed check if number is being entered?
                    If Len(b$) Then
                        If Val(b$) >= lba And Val(b$) <= uba Then 'we have number started
                            choice = Val(b$): Exit Do
                        Else 'clear b$ to show some response to enter
                            b$ = "": GoSub update 'clear the value that doesn't work
                        End If
                    Else
                        choice = hlite + page * maxHeight + lba 'must mean to select the highlighted item
                    End If
                ElseIf kh& = 27 Then
                    Exit Do 'escape clause offered to Cancel selection process
                ElseIf kh& = 32 Then
                    choice = hlite + page * maxHeight + lba 'best way to choose highlighted selection
                ElseIf kh& = 8 Then 'backspace to edit number
                    If Len(b$) Then b$ = Left$(b$, Len(b$) - 1): GoSub update
                End If
            Else
                Select Case kh& 'choosing sections of array to display and highlighted item
                    Case 21248 ' delete so clear b$
                        b$ = "": GoSub update
                    Case 20736 ' pg dn
                        If (page + 1) * maxHeight + lba <= uba Then page = page + 1: GoSub update
                    Case 18688 ' pg up
                        If (page - 1) * maxHeight + lba >= lba Then page = page - 1: GoSub update
                    Case 18432 ' up
                        If hlite - 1 < 0 Then
                            If page > 0 Then
                                page = page - 1: hlite = maxHeight - 1: GoSub update
                            End If
                        Else
                            hlite = hlite - 1: GoSub update
                        End If
                    Case 20480 'down
                        If (hlite + 1) + page * maxHeight + lba <= uba Then 'ok to move up
                            If hlite + 1 > maxHeight - 1 Then
                                page = page + 1: hlite = 0: GoSub update
                            Else
                                hlite = hlite + 1: GoSub update
                            End If
                        End If
                    Case 18176 'home
                        page = 0: hlite = 0: GoSub update
                    Case 20224 ' end
                        page = Int((uba - lba) / maxHeight): hlite = maxHeight - 1: GoSub update
                End Select
            End If
        End If
 
        'handle the mouse stuff
        While _MouseInput
            If _MouseWheel = -1 Then 'up?
                If hlite - 1 < 0 Then
                    If page > 0 Then
                        page = page - 1: hlite = maxHeight - 1: GoSub update
                    End If
                Else
                    hlite = hlite - 1: GoSub update
                End If
            ElseIf _MouseWheel = 1 Then 'down?
                If (hlite + 1) + page * maxHeight + lba <= uba Then 'ok to move up
                    If hlite + 1 > maxHeight - 1 Then
                        page = page + 1: hlite = 0: GoSub update
                    Else
                        hlite = hlite + 1: GoSub update
                    End If
                End If
            End If
        Wend
        mx = Int((_MouseX - LocateColumn * 8) / 8) + 2: my = Int((_MouseY - locateRow * 16) / 16) + 2
        If _MouseButton(1) Then 'click contols or select array item
            'clear mouse clicks
            mb = _MouseButton(1)
            If mb Then 'clear it
                While mb 'OK!
                    If _MouseInput Then mb = _MouseButton(1)
                    _Limit 100
                Wend
            End If
 
            If mx >= 1 And mx <= maxWidth And my >= 1 And my <= maxHeight Then
                choice = my + page * maxHeight + lba - 1 'select item clicked
            ElseIf mx >= 1 And mx <= maxWidth And my = 0 Then 'page up or exit
                If my = 0 And (mx <= maxWidth And mx >= maxWidth - 2) Then 'exit sign
                    Exit Do 'escape plan for mouse click top right corner of display box
                Else 'PgUp bar clicked
                    If (page - 1) * maxHeight + lba >= lba Then page = page - 1: GoSub update
                End If
            ElseIf mx >= 1 And mx <= maxWidth And my = maxHeight + 1 Then 'page down bar clicked
                If (page + 1) * maxHeight + lba <= uba Then page = page + 1: GoSub update
            End If
        Else '   mouse over highlighting, only if mouse has moved!
            If mx >= 1 And mx <= maxWidth And my >= 1 And my <= maxHeight Then
                If mx <> lastMX Or my <> lastMY Then
                    If my - 1 <> hlite And (my - 1 + page * maxHeight + lba <= uba) Then
                        hlite = my - 1
                        lastMX = mx: lastMY = my
                        GoSub update
                    End If
                End If
            End If
        End If
        _Limit 200
    Loop Until choice >= lba And choice <= uba
    If choice <> -1719 Then GetArrayItem$ = Arr(choice) 'set function and restore screen
    'ScnState -1 'restore
    Exit Function
 
    'display of array sections and controls on screen  ====================================================
    update:
 
    'fix hlite if it has dropped below last array item
    While hlite + page * maxHeight + lba > uba
        hlite = hlite - 1
    Wend
 
    'main display of array items at page * maxHeight (lines high)
    For row = 0 To maxHeight - 1
        If hlite = row Then Color _RGB(200, 200, 255), _RGB32(0, 0, 88) Else Color _RGB32(0, 0, 88), _RGB(200, 200, 255)
        Locate locateRow + row, LocateColumn: Print clrStr$;
        index = row + page * maxHeight + lba
        If index >= lba And index <= uba Then
            Locate locateRow + row, LocateColumn
            Print Left$(LTrim$(Str$(index)) + ") " + Arr(index), maxWidth);
        End If
    Next
 
    'make page up and down bars to click, print PgUp / PgDn if available
    Color _RGB32(200, 200, 255), _RGB32(0, 100, 50)
    Locate locateRow - 1, LocateColumn: Print Space$(maxWidth);
    If page <> 0 Then Locate locateRow - 1, LocateColumn: Print Left$(" Pg Up" + Space$(maxWidth), maxWidth);
    Locate locateRow + maxHeight, LocateColumn: Print Space$(maxWidth);
    If page <> Int(uba / maxHeight) Then
        Locate locateRow + maxHeight, LocateColumn: Print Left$(" Pg Dn" + Space$(maxWidth), maxWidth);
    End If
    'make exit sign for mouse click
    Color _RGB32(255, 255, 255), _RGB32(200, 100, 0)
    Locate locateRow - 1, LocateColumn + maxWidth - 3
    Print " X ";
 
    'if a number selection has been started show it's build = b$
    If Len(b$) Then
        Color _RGB(255, 255, 0), _RGB32(0, 0, 0)
        Locate locateRow + maxHeight, LocateColumn + maxWidth - Len(b$) - 1
        Print b$;
    End If
    _Display
    _Limit 100
    Return
End Function
 
Sub ScnState (restoreTF As Long) 'Thanks Steve McNeill  should we get a snap shot of screen?
    Static As _Unsigned Long defaultColor, backGroundColor
    Static As Long font, dest, source, row, col, autodisplay, mb, snap
    If restoreTF Then
        _Font font
        Color defaultColor, backGroundColor
        _Dest dest
        _Source source
 
        _KeyClear
        While _MouseInput: Wend 'clear mouse clicks
        mb = _MouseButton(1)
        If mb Then 'need this if line ?
            Do
                While _MouseInput: Wend
                mb = _MouseButton(1)
                _Limit 100
            Loop Until mb = 0
        End If
        _PutImage , snap, dest
        _FreeImage snap
        _Display
        If autodisplay Then _AutoDisplay Else _Display
        Locate row, col
    Else
        snap = _NewImage(_Width, _Height, 32)
        _PutImage , 0, snap
        font = _Font: defaultColor = _DefaultColor: backGroundColor = _BackgroundColor
        dest = _Dest: source = _Source
        row = CsrLin: col = Pos(0): autodisplay = _AutoDisplay
        While _MouseInput: Wend 'clear mouse clicks
        mb = _MouseButton(1)
        If mb Then 'need this if line ?
            Do
                While _MouseInput: Wend
                mb = _MouseButton(1)
                _Limit 100
            Loop Until mb = 0
        End If
        _KeyClear
    End If
End Sub
 
 
 
 
 

You will need this in your QB64.exe Folder and a QB64 version dev 1.5 version.

EDIT: made h Long in LoadBMP24 Sub as per NOVARSEG

Title: Re: Pipecom Browser for Filename$
Post by: SpriggsySpriggs on February 07, 2021, 08:06:18 pm

@bplus It's cool that you were able to use my pipecom library to make something neat

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 07, 2021, 08:08:47 pm

Tell me you tried it already! ;-))

I just got done editing a thankyou to you. :)

Title: Re: Pipecom Browser for Filename$
Post by: SpriggsySpriggs on February 07, 2021, 09:32:33 pm

@bplus It works great! Super fast on my system. Good job on the UI

Title: Re: Pipecom Browser for Filename$
Post by: STxAxTIC on February 07, 2021, 10:25:49 pm

well this is nice!

Title: Re: Pipecom Browser for Filename$
Post by: NOVARSEG on February 08, 2021, 02:53:57 am

@bplus
got to get latest version.

Yes it is true Steve did fix the padding issue. Evidently some BMPs have a negative height value so you gotta change the

h in
Dim As _Unsigned Long of, l, w, h, r, c

to a LONG

I've never come across a negative height BMP though.. See my latest BMP viewer code that handles negative height BMPs

https://www.qb64.org/forum/index.php?topic=3602.30#lastPost

Title: Re: Pipecom Browser for Filename$
Post by: Dav on February 08, 2021, 07:39:53 am

Works great here! Fast too. I like it.

- Dav

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 08, 2021, 12:16:12 pm

Thanks for your feedback!

If someone could provide a Linux command that produces a Directory Listing that distinguishes Files from Folders and provides a Sample Output Directory, I could adapt this for Linux.

@johnno56 can you help with this?

Here simple Pipecom code to test commands to OS and Sample Output from Windows that I see all Files and Folders and can distingush Folders have <DIR> in label.

Code: [Select]

_Title "Quick Pipecom Demo" 'b+ 2021-02-08
Declare Library "pipecom"
    Function pipecom$ (cmd As String)
End Declare

Dim F As String 'tests with command line dir calls
' NOTE: these slants work \    these do not /
'F = pipecom("dir " + Chr$(34) + "C:\users\marka\desktop\QB64 work\000 work QB64" + Chr$(34) + " /b /A:D") ' Linux needs other switches
'F = pipecom("dir /b *.BAS") 'if you need just the filenames and not the rest of the output
'F = pipecom("dir /b /A:D") ' /b = bare list /A:D directories only

F = pipecom("dir ??? ") ' <<<<<<<<<<< Linux command goes between quotes here
Print F
_Clipboard$ = F


' Paste from ClipBoard
' Volume in drive C is Windows
' Volume Serial Number is 0EDF-FD28

' Directory of C:\Users\marka\Desktop\QB64 work\000 work QB64\000 Test\DIR$() replacement Spriggsy

'02/08/2021  12:14 PM    <DIR>          .
'02/08/2021  12:14 PM    <DIR>          ..
'10/26/2020  10:14 AM    <DIR>          pipecom.h bak
'02/07/2021  08:43 PM            14,491 Pipecom Browser mod 2 Better Array Select.bas
'02/06/2021  12:56 AM             1,015 Pipecom demo to replace Dir$() by Spriggsy.bas
'02/07/2021  08:54 PM             4,160 Pipecome Browser 1 Crude Keypress Select.bas
'02/08/2021  12:12 PM                 2 Quick Pipecom demo.bas
'01/19/2021  10:45 AM             2,548 Really simple pipe to clip by doppler.bas
'02/07/2021  12:00 PM             2,180 Shell dir to clipboard doppler.bas
'02/07/2021  08:35 PM         2,110,464 Pipecom Browser mod 2 Better Array Select.exe
'02/07/2021  08:53 PM         2,094,592 Pipecome Browser 1 Crude Keypress Select.exe
'02/08/2021  12:14 PM         2,080,256 Quick Pipecom demo.exe
'02/07/2021  11:59 AM         2,085,888 Really simple pipe to clip by doppler.exe
'02/07/2021  12:00 PM         2,087,424 Shell dir to clipboard doppler.exe
'              11 File(s)     10,483,020 bytes
'               3 Dir(s)  907,052,933,120 bytes free

Again put this into the same Folder as your QB64.exe

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 08, 2021, 12:34:40 pm

Quote from: NOVARSEG on February 08, 2021, 02:53:57 am

@bplus
got to get latest version.

Yes it is true Steve did fix the padding issue. Evidently some BMPs have a negative height value so you gotta change the

h in
Dim As _Unsigned Long of, l, w, h, r, c

to a LONG

I've never come across a negative height BMP though.. See my latest BMP viewer code that handles negative height BMPs

https://www.qb64.org/forum/index.php?topic=3602.30#lastPost

OK edited the original post, thanks

Title: Re: Pipecom Browser for Filename$
Post by: NOVARSEG on February 08, 2021, 06:01:08 pm

@bplus
Did you actually try it with -h?

If it works, a normal BMP image (with positive h) will be upside down.

Dim padding$
h = 0 - h ' *** add this line ***
If Right$(UCase$(Filename$), 4) <> ".BMP" Then Exit Function

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 08, 2021, 06:52:38 pm

Quote from: NOVARSEG on February 08, 2021, 06:01:08 pm

@bplus
Did you actually try it with -h?

If it works, a normal BMP image (with positive h) will be upside down.

Dim padding$
h = 0 - h ' *** add this line ***
If Right$(UCase$(Filename$), 4) <> ".BMP" Then Exit Function

I changed the type of h to Long and tested the pictures I had and ran fine.

Now if h is a negative number it will work, I assume. I need an BMP24 file with h <0 pic to test that situation..

Title: Re: Pipecom Browser for Filename$
Post by: NOVARSEG on February 08, 2021, 07:05:50 pm

Quote

Now if h is a negative number it will work, I assume. I need an BMP24 file with h <0 pic to test that situation.

.

Don't need an actual -h BMP to test

Dim padding$
h = 0 - h ' *** add this line. For testing only ***
If Right$(UCase$(Filename$), 4) <> ".BMP" Then Exit Function

If the code works then a BMP with +h will display upside down

with commented
' h = 0 - h

A BMP with actual -h will now display properly

****
for one thing

handle = _NewImage(w, h, 32)

can't have a negative h

https://www.qb64.org/forum/index.php?topic=3602.30#lastPost

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 08, 2021, 09:40:24 pm

Quote from: NOVARSEG on February 08, 2021, 07:05:50 pm

.

Don't need an actual -h BMP to test

Dim padding$
h = 0 - h ' *** add this line. For testing only ***
If Right$(UCase$(Filename$), 4) <> ".BMP" Then Exit Function

If the code works then a BMP with +h will display upside down

with commented
' h = 0 - h

A BMP with actual -h will now display properly

****
for one thing

handle = _NewImage(w, h, 32)

can't have a negative h

https://www.qb64.org/forum/index.php?topic=3602.30#lastPost

I'm not messing around with all that if it is enough to make h long. The point of this thread is to test Pipecom and filename retriever code, I just happened to use BMP24 files because it was recent and you @NOVARSEG asked about mouse input app for you code.

I will be glad to test a -h BMP24 file if one were provided with this app as it is. :)

Title: Re: Pipecom Browser for Filename$
Post by: SMcNeill on February 08, 2021, 09:47:04 pm

If you do get a -h file, just read it as usual and then _PUTIMAGE it from bottom to top to your screen.

Title: Re: Pipecom Browser for Filename$
Post by: NOVARSEG on February 08, 2021, 10:35:44 pm

@bplus

That will be a fair test of the code

I will make a -h BMP convertor. It will take a +h BMP and then convert it into a -h BMP

https://www.mozilla.org/en-US/security/advisories/mfsa2012-61/

here is an interesting one. MS paint evidently crashes with -h BMPs
https://groups.google.com/g/microsoft.public.win32.programmer.gdi/c/8CnUgn-gzD0/m/FS8rzRXq9DgJ

OK i tried engine3.bmp in MSPAINT and it worked .

Title: Re: Pipecom Browser for Filename$
Post by: NOVARSEG on February 09, 2021, 12:06:06 am

Ok here is a negative h BMP

W = 1024
H = -831

It says 831 at the bottom of the image, but that is an ABS value

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 09, 2021, 02:51:28 pm

@NOVARSEG

Thanks I am convinced just changing H to Long Type is not enough. But we knew that, I guess, I did after I went and reread everything again. Steve never updated his fixed Sub with another?

I checked back to last version you posted, it may work but it isn't in a handy, portable and convenient Sub like I have here. So get to work man! ;-))

Sorry, the Interpreter muse has struck me again (won't Aurel be thrilled?) or I'd be fixing myself.

This pipecom code and array displayer are some new features planned for making editable code as well as retrieving files.
I have found my way to a "No double quotes for strings" theory, just bare naked text.

PS might need a Line Editor, not a full fledged WP.

Title: Re: Pipecom Browser for Filename$
Post by: NOVARSEG on February 09, 2021, 08:12:27 pm

Been awhile since I wrote a SUB

Do I have to put my DIMS inside the sub? I like my DIMS at the start of a program.

Title: Re: Pipecom Browser for Filename$
Post by: SMcNeill on February 09, 2021, 08:30:33 pm

Quote from: NOVARSEG on February 09, 2021, 08:12:27 pm

Been awhile since I wrote a SUB

Do I have to put my DIMS inside the sub? I like my DIMS at the start of a program.

Are the global, or local variables?

DIM inside a sub keeps the values local to the sub, whereas DIM SHARED in the main module makethem global.

Title: Re: Pipecom Browser for Filename$
Post by: NOVARSEG on February 09, 2021, 09:37:24 pm

OK the sub would have to be something like

SUB loadBMP24 (Filename as string$, W AS LONG, H AS LONG, HANDLE AS LONG)
retunrs W width of BMP
returns H height of BMP
returns handle generated from " HANDLE = _NEWIMAGE(W, ABS(H), 32) "
input Filename
****

Gettimg a "memory not initialized" these lines of code are inside the sub

SCREEN _NEWIMAGE(W, (ABS(H)), 32)
_PUTIMAGE (0, 0), HANDLE
_MEMFREE a

the _MEMFREE a is throwing the error

*******
later DIM SHARED a AS _MEM

fixed that error

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 09, 2021, 09:46:24 pm

@NOVARSEG

Once you get image loaded under handle you should be able to just pass handle back to main code through a Function that has type Long & on end of it's name.

I've got you started in BMP thread.

Title: Re: Pipecom Browser for Filename$
Post by: NOVARSEG on February 09, 2021, 10:06:30 pm

I have a SUB working

SUB loadBMP24 (FILENAME AS STRING, W AS LONG, H AS LONG, HANDLE AS LONG)

returns W width of BMP
returns H height of BMP
returns handle generated from " HANDLE = _NEWIMAGE(W, ABS(H), 32) "
input Filename

the SUB does not display any image. That has to be done outside the SUB

Over to the other thread

Title: Re: Pipecom Browser for Filename$
Post by: SMcNeill on February 09, 2021, 10:12:16 pm

Since you guys are almost done reinventing the wheel (24-bit BMP loader in this case), I’d like to also refer you to the wiki: https://www.qb64.org/wiki/Bitmaps

With it as a reference, you can expand and load 1, 4, 8 bit BMP files too, next. :)

Title: Re: Pipecom Browser for Filename$
Post by: NOVARSEG on February 09, 2021, 11:51:00 pm

Gonna try LOADIMAGE one day :)

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 10, 2021, 12:43:12 am

Quote from: NOVARSEG on February 09, 2021, 11:51:00 pm

Gonna try LOADIMAGE one day :)

Pipecom Browser 3 All da Images! Kicks Butt with BMP24 files, gets them right, in fact this is faster than Windows.
But my fan is running?

Code: QB64: [Select]

Option _Explicit
_Title "Pipecom Browser for BMP24 File Display" 'b+ testing one array system with pipecom
' Thanks to Spriggsy, Zak, for convincing me pipecom is better!
' Using Steve's fixed BMP24 loader
' Also thanks to Dav for 1 window for file and folder selection idea
' Also thanks to NOVARSEG who got me going on this for a better filename$ retriever
' 2021-02-10 Browser 2 update with LoadBMP24 Sub
' 2021-02-10 Browser 3, just _Loadimage
 
Declare Library "pipecom"
    Function pipecom$ (cmd As String)
End Declare
 
Screen _NewImage(1280, 740, 32)
_Delay .25
_ScreenMove 65, 0 ' your screen might need different
 
ReDim myFile$
ReDim As Long col, row, charW, charH, W, H, image
Color , &HFF000033
Cls
Do 'test our new function
    ScnState 0
    col = 16: row = 3: charW = 128: charH = 40
    myFile$ = GetFileName$(row, col, charW, charH)
    ScnState -1 ' <<<<<<<<<<<<<<<<<<<<<<<<<<< this is supposed to restore back color
    'image& = loadBMP24&(myFile$)
    image = _LoadImage(myFile$)
    'loadBMP24 myFile$, W, H, image
    Color , &HFF000033
    Cls
    If image <> 0 Then
        _Title myFile$ + " press any to get another BMP24 file image, esc to quit"
        _PutImage ((_Width - _Width(image&)) / 2, (_Height - _Height(image&)) / 2)-Step(_Width(image&), _Height(image&)), image&, 0
        Sleep
        _FreeImage image&
    End If
Loop Until _KeyDown(27)
 
Function GetFileName$ (LocateR, LocateC, CharWide, CharHigh) ' < careful Locate Row, Col NOT x, y
    'This Funtion needs:
    ' pipecom.h in same folder as QB64.exe
    ' This in main code section near top:
    ' Declare Library "pipecom"
    '    Function pipecom$ (cmd As String)
    ' End Declare
    ' sub  Split source$, delimiter$, arr$()
    ' function GetArrayItem$(x, y, w, h, arr$())
 
    ReDim As String d, s, dr
    ReDim As _Unsigned Long fc, bc
    fc = _DefaultColor: bc = _BackgroundColor ' save colors
    Getfolder:
    Color fc, bc: Cls
    d = pipecom("dir /n /o:gend") '/n files on right (40) /o = order g for group dirs first, e extension, name, date
    d = Left$(d, Len(d) - 1) ' always ends with delimiter
    ReDim dir(1 To 1) As String
    Split d, Chr$(10), dir()
    s = GetArrayItem$(LocateR, LocateC, CharWide, CharHigh, dir())
    If InStr(s, "<DIR>") Then 'isolate name
        dr = _Trim$(Mid$(s, InStr(s, "<DIR>") + 6))
        ChDir dr
        GoTo Getfolder
    ElseIf InStr(s, "AM") Or InStr(s, "PM") Then
        GetFileName$ = _Trim$(Mid$(s, 40))
        Color fc, bc: Cls
    ElseIf s = "" Then 'cancel, escape, bad line
        Color fc, bc: Cls ' will return empty string
    End If
End Function
 
Sub Split (SplitMeString As String, delim As String, loadMeArray() As String)
    Dim curpos As Long, arrpos As Long, LD As Long, dpos As Long 'fix use the Lbound the array already has
    curpos = 1: arrpos = LBound(loadMeArray): LD = Len(delim)
    dpos = InStr(curpos, SplitMeString, delim)
    Do Until dpos = 0
        loadMeArray(arrpos) = Mid$(SplitMeString, curpos, dpos - curpos)
        arrpos = arrpos + 1
        If arrpos > UBound(loadMeArray) Then ReDim _Preserve loadMeArray(LBound(loadMeArray) To UBound(loadMeArray) + 1000) As String
        curpos = dpos + LD
        dpos = InStr(curpos, SplitMeString, delim)
    Loop
    loadMeArray(arrpos) = Mid$(SplitMeString, curpos)
    ReDim _Preserve loadMeArray(LBound(loadMeArray) To arrpos) As String 'get the ubound correct
End Sub
 
 
' Help: all this I hope is intuitive so Help window is provided
' "Mouse, mouse wheel, and arrow keys should work as expected for item selection."
' "Press spacebar to select a highlighted item or just click it."
' "Use number(s) + enter to select an array item by it's index number,"
' "backspace will remove last number pressed, delete will clear a number started.
' "Numbers started are shown in bottom right PgDn bar."
' "Enter will also select the highlighted item, if no number has been started."
' "Home starts you at lowest array index, End highlights then highest index."
' "Use PgUp and PgDn keys to flip through pages of array items."
'
' Escape to Cancel Return "" else Return the selected string from the array
Function GetArrayItem$ (LocateRoww, LocateColumn, BoxWidth, BoxHeight, Arr() As String)
    'Notes: locateRow, locateColumn for top right corner of selection box on screen in characters for LOCATE.
    'boxWidth and boxHeight are in character units, again for locate and print at correct places.
    'All displaying is restricted to inside the box, which has PgUP and PgDn as top and bottom lines in the display.
 
    ReDim As Long maxWidth, maxHeight, page, hlite, mx, my, locateRow, lastMX, lastMY, row, mb
    ReDim As Long lba, uba, choice, kh, index
    Dim clrStr As String, b As String
 
    'ScnState 0 ' use out side this function before and after
    locateRow = LocateRoww + 1 'fix a miscalc in coding
    maxWidth = BoxWidth '       number of characters in box
    maxHeight = BoxHeight - 2 ' number of lines displayed of array at one time = 1 page
    lba = LBound(arr)
    uba = UBound(arr)
    page = 0
    hlite = 0 '                 line in display ready for selection by spacebar or if no number is started, enter
    clrStr$ = Space$(maxWidth) 'clearing a display line
 
    GoSub update '              show the beginning of the array items for selection
    choice = -1719
    Do 'until get a selection or demand exit
 
        'handle the key stuff
        kh& = _KeyHit
        If kh& Then
            If kh& > 0 And kh& < 255 Then
                If InStr("0123456789", Chr$(kh&)) > 0 Then
                    b$ = b$ + Chr$(kh&): GoSub update
                ElseIf kh& = 13 Then 'enter pressed check if number is being entered?
                    If Len(b$) Then
                        If Val(b$) >= lba And Val(b$) <= uba Then 'we have number started
                            choice = Val(b$): Exit Do
                        Else 'clear b$ to show some response to enter
                            b$ = "": GoSub update 'clear the value that doesn't work
                        End If
                    Else
                        choice = hlite + page * maxHeight + lba 'must mean to select the highlighted item
                    End If
                ElseIf kh& = 27 Then
                    Exit Do 'escape clause offered to Cancel selection process
                ElseIf kh& = 32 Then
                    choice = hlite + page * maxHeight + lba 'best way to choose highlighted selection
                ElseIf kh& = 8 Then 'backspace to edit number
                    If Len(b$) Then b$ = Left$(b$, Len(b$) - 1): GoSub update
                End If
            Else
                Select Case kh& 'choosing sections of array to display and highlighted item
                    Case 21248 ' delete so clear b$
                        b$ = "": GoSub update
                    Case 20736 ' pg dn
                        If (page + 1) * maxHeight + lba <= uba Then page = page + 1: GoSub update
                    Case 18688 ' pg up
                        If (page - 1) * maxHeight + lba >= lba Then page = page - 1: GoSub update
                    Case 18432 ' up
                        If hlite - 1 < 0 Then
                            If page > 0 Then
                                page = page - 1: hlite = maxHeight - 1: GoSub update
                            End If
                        Else
                            hlite = hlite - 1: GoSub update
                        End If
                    Case 20480 'down
                        If (hlite + 1) + page * maxHeight + lba <= uba Then 'ok to move up
                            If hlite + 1 > maxHeight - 1 Then
                                page = page + 1: hlite = 0: GoSub update
                            Else
                                hlite = hlite + 1: GoSub update
                            End If
                        End If
                    Case 18176 'home
                        page = 0: hlite = 0: GoSub update
                    Case 20224 ' end
                        page = Int((uba - lba) / maxHeight): hlite = maxHeight - 1: GoSub update
                End Select
            End If
        End If
 
        'handle the mouse stuff
        While _MouseInput
            If _MouseWheel = -1 Then 'up?
                If hlite - 1 < 0 Then
                    If page > 0 Then
                        page = page - 1: hlite = maxHeight - 1: GoSub update
                    End If
                Else
                    hlite = hlite - 1: GoSub update
                End If
            ElseIf _MouseWheel = 1 Then 'down?
                If (hlite + 1) + page * maxHeight + lba <= uba Then 'ok to move up
                    If hlite + 1 > maxHeight - 1 Then
                        page = page + 1: hlite = 0: GoSub update
                    Else
                        hlite = hlite + 1: GoSub update
                    End If
                End If
            End If
        Wend
        mx = Int((_MouseX - LocateColumn * 8) / 8) + 2: my = Int((_MouseY - locateRow * 16) / 16) + 2
        If _MouseButton(1) Then 'click contols or select array item
            'clear mouse clicks
            mb = _MouseButton(1)
            If mb Then 'clear it
                While mb 'OK!
                    If _MouseInput Then mb = _MouseButton(1)
                    _Limit 100
                Wend
            End If
 
            If mx >= 1 And mx <= maxWidth And my >= 1 And my <= maxHeight Then
                choice = my + page * maxHeight + lba - 1 'select item clicked
            ElseIf mx >= 1 And mx <= maxWidth And my = 0 Then 'page up or exit
                If my = 0 And (mx <= maxWidth And mx >= maxWidth - 2) Then 'exit sign
                    Exit Do 'escape plan for mouse click top right corner of display box
                Else 'PgUp bar clicked
                    If (page - 1) * maxHeight + lba >= lba Then page = page - 1: GoSub update
                End If
            ElseIf mx >= 1 And mx <= maxWidth And my = maxHeight + 1 Then 'page down bar clicked
                If (page + 1) * maxHeight + lba <= uba Then page = page + 1: GoSub update
            End If
        Else '   mouse over highlighting, only if mouse has moved!
            If mx >= 1 And mx <= maxWidth And my >= 1 And my <= maxHeight Then
                If mx <> lastMX Or my <> lastMY Then
                    If my - 1 <> hlite And (my - 1 + page * maxHeight + lba <= uba) Then
                        hlite = my - 1
                        lastMX = mx: lastMY = my
                        GoSub update
                    End If
                End If
            End If
        End If
        _Limit 200
    Loop Until choice >= lba And choice <= uba
    If choice <> -1719 Then GetArrayItem$ = Arr(choice) 'set function and restore screen
    'ScnState -1 'restore
    Exit Function
 
    'display of array sections and controls on screen  ====================================================
    update:
 
    'fix hlite if it has dropped below last array item
    While hlite + page * maxHeight + lba > uba
        hlite = hlite - 1
    Wend
 
    'main display of array items at page * maxHeight (lines high)
    For row = 0 To maxHeight - 1
        If hlite = row Then Color _RGB(200, 200, 255), _RGB32(0, 0, 88) Else Color _RGB32(0, 0, 88), _RGB(200, 200, 255)
        Locate locateRow + row, LocateColumn: Print clrStr$;
        index = row + page * maxHeight + lba
        If index >= lba And index <= uba Then
            Locate locateRow + row, LocateColumn
            Print Left$(LTrim$(Str$(index)) + ") " + Arr(index), maxWidth);
        End If
    Next
 
    'make page up and down bars to click, print PgUp / PgDn if available
    Color _RGB32(200, 200, 255), _RGB32(0, 100, 50)
    Locate locateRow - 1, LocateColumn: Print Space$(maxWidth);
    If page <> 0 Then Locate locateRow - 1, LocateColumn: Print Left$(" Pg Up" + Space$(maxWidth), maxWidth);
    Locate locateRow + maxHeight, LocateColumn: Print Space$(maxWidth);
    If page <> Int(uba / maxHeight) Then
        Locate locateRow + maxHeight, LocateColumn: Print Left$(" Pg Dn" + Space$(maxWidth), maxWidth);
    End If
    'make exit sign for mouse click
    Color _RGB32(255, 255, 255), _RGB32(200, 100, 0)
    Locate locateRow - 1, LocateColumn + maxWidth - 3
    Print " X ";
 
    'if a number selection has been started show it's build = b$
    If Len(b$) Then
        Color _RGB(255, 255, 0), _RGB32(0, 0, 0)
        Locate locateRow + maxHeight, LocateColumn + maxWidth - Len(b$) - 1
        Print b$;
    End If
    _Display
    _Limit 100
    Return
End Function
 
Sub ScnState (restoreTF As Long) 'Thanks Steve McNeill  should we get a snap shot of screen?
    Static As _Unsigned Long defaultColor, backGroundColor
    Static As Long font, dest, source, row, col, autodisplay, mb, snap
    If restoreTF Then
        _Font font
        Color defaultColor, backGroundColor
        _Dest dest
        _Source source
 
        _KeyClear
        While _MouseInput: Wend 'clear mouse clicks
        mb = _MouseButton(1)
        If mb Then 'need this if line ?
            Do
                While _MouseInput: Wend
                mb = _MouseButton(1)
                _Limit 100
            Loop Until mb = 0
        End If
        _PutImage , snap, dest
        _FreeImage snap
        _Display
        If autodisplay Then _AutoDisplay Else _Display
        Locate row, col
    Else
        snap = _NewImage(_Width, _Height, 32)
        _PutImage , 0, snap
        font = _Font: defaultColor = _DefaultColor: backGroundColor = _BackgroundColor
        dest = _Dest: source = _Source
        row = CsrLin: col = Pos(0): autodisplay = _AutoDisplay
        While _MouseInput: Wend 'clear mouse clicks
        mb = _MouseButton(1)
        If mb Then 'need this if line ?
            Do
                While _MouseInput: Wend
                mb = _MouseButton(1)
                _Limit 100
            Loop Until mb = 0
        End If
        _KeyClear
    End If
End Sub
 
 

You will need this in your QB64.exe file:

Title: Re: Pipecom Browser for Filename$
Post by: NOVARSEG on February 10, 2021, 02:15:49 am

fast viewer. Gonna do another ver of BMP 24 viewer for speed.

Title: Re: Pipecom Browser for Filename$
Post by: Aurel on February 10, 2021, 03:21:41 am

(won't Aurel be thrilled?)

Youhooooo Mark....
very nice ......

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 10, 2021, 04:23:30 pm

If someone could provide a Linux command that produces a Directory Listing that distinguishes Files from Folders and provides a Sample Output Directory, I could adapt this for Linux.

@johnno56 can you help with this?

Title: Re: Pipecom Browser for Filename$
Post by: STxAxTIC on February 10, 2021, 04:24:07 pm

Quote from: johnno56 on February 10, 2021, 04:23:30 pm

If someone could provide a Linux command that produces a Directory Listing that distinguishes Files from Folders and provides a Sample Output Directory, I could adapt this for Linux.

@johnno56 can you help with this?

idk, can you?

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 10, 2021, 04:47:42 pm

Ho Ho. It is to laugh... lol

I was replying and hit ENTER before I had finished... Doh!

BPlus,

The commands 'ls' and 'dir' will display current directory contents. Main difference... the 'ls' command will display directories, executables and files in different colours. 'dir' is only white. Adding '-l' to the command will give a detailed list. To easily distinguish folders, commands and files, 'ls' or ls -l' would be the best.

There is probably a better way to do this but these are the commands that "I" use....

[ This attachment cannot be displayed inline in 'Print Page' view ]

[ This attachment cannot be displayed inline in 'Print Page' view ]

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 10, 2021, 04:53:25 pm

Quote from: johnno56 on February 10, 2021, 04:23:30 pm

If someone could provide a Linux command that produces a Directory Listing that distinguishes Files from Folders and provides a Sample Output Directory, I could adapt this for Linux.

@johnno56 can you help with this?

I think it's "dir -F" I looked it up a couple days ago.

Code: QB64: [Select]

'make sure pipecom.h is in same folder as QB64.exe
Declare Library "pipecom"
    Function pipecom$ (cmd As String)
End Declare
F$ = pipecom("dir -F")
print F$ 'see it
_clipboard = F$ 'copy to clipboard
 

If that works, get a copy of output to _clipboard, paste _clipboard into text file. Then paste a copy of txt file here.
I need to know if uses tabs or spaces in output and amount of spacing.

Then I can see how to parse output.

@johnno56 OK you posted but can't read colors from text string, try above instructions.

I know I can read Folders from a dir command because they end in a slash.

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 10, 2021, 05:03:25 pm

@johnno56 I updated instructions in above post.

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 10, 2021, 05:05:27 pm

I figured you might have issues with the colours.The colours would change with the overall theme of the desktop...
Anyway, I tried the 'dir -F' and all the directories ended in a slash.

I also tried running the the program , as is, and received a "illegal string-number conversion on line 1"

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 10, 2021, 05:11:04 pm

Quote from: johnno56 on February 10, 2021, 05:05:27 pm

I figured you might have issues with the colours.The colours would change with the overall theme of the desktop...
Anyway, I tried the 'dir -F' and all the directories ended in a slash.

I also tried running the the program , as is, and received a "illegal string-number conversion on line 1"

That's the line to the Declare Library? can't be the comment!

Well the ball is now in @SpriggsySpriggs 's court!

@johnno56 to be sure our bases are covered, you do have pipecom.h file copy in your QB64.exe Folder?

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 10, 2021, 05:11:46 pm

You were updating your listing as I was forming my last post.

Updated my listing. Ran it. "Invalid name on line 7"

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 10, 2021, 05:13:14 pm

Try $ on the end of _Clipboard$ <====

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 10, 2021, 05:14:48 pm

No. The pipecom.h is on my Desktop but the listing path was modified.

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 10, 2021, 05:15:30 pm

Adding the $ did it... nicely done...

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 10, 2021, 05:16:18 pm

Quote from: johnno56 on February 10, 2021, 05:14:48 pm

No. The pipecom.h is on my Desktop but the listing path was modified.

Well that won't work has to be where QB64.exe can get it.

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 10, 2021, 05:17:36 pm

Quote from: johnno56 on February 10, 2021, 05:15:30 pm

Adding the $ did it... nicely done...

Oh, can I get a txt copy, please? Or do you want to try a parsing yourself?

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 10, 2021, 05:27:26 pm

Ok. Normally I put 'test' programs on my desktop and transfer them if and when they work.

Both '.bas' and .h' files are now in the QB64 directory. Used 'F$ = pipecom("dir -F > pipecom.txt")' to produce a text file. See attached.

Parsed? Not sure what you mean. I'm only familiar with that term in regards to text adventures... lol

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 10, 2021, 05:43:17 pm

OK, got it. Thanks @johnno56

That's one folder?

And appears to be 2 columns but the 2nd column is a little 'all over' ;-))

I bet some kind of tabs are in there.

Parse - is just breaking down a string into more usable units of data using different string functions.
This depends on the strings having some sort of dependable or predictable structure or pattern.

Title: Re: Pipecom Browser for Filename$
Post by: SpriggsySpriggs on February 10, 2021, 11:07:40 pm

This doesn't sound like an error on pipecom's side

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 10, 2021, 11:40:37 pm

Quote from: SpriggsySpriggs on February 10, 2021, 11:07:40 pm

This doesn't sound like an error on pipecom's side

No, just going to be a challenge to make a list and preferably get all the directories at the top of the list.

I am kind of busy trying to figure out how to get ElseIf blocks into my Interpreter this time around.
(and yet I keep checking in here ;-))

OK piece of cake, it's just tabbing out to some 2nd column, displayed in Notepad++ it looked like hell.

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 11, 2021, 12:07:26 am

@johnno56

Does the command 'dir -F" always make a 2 column list, or does it pick the longest name and make the column widths as narrow as possible to fit the maximum number of names in a minimum number of lines?

OK I am assuming a width of 80 chars for lines, could be 90 so 2nd column at 45 divides in 2 the screen.

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 11, 2021, 12:28:00 am

To tell you the truth, I've never taken much notice of the display format... The standard Terminal screen size is 80 cards x 24 lines.

This is dir -F and dir -F -l. I have only expanded the height to demonstrate both commands.

[ This attachment cannot be displayed inline in 'Print Page' view ]

Widening the Terminal, prior to the dir -F, seems to create consistent columns.

[ This attachment cannot be displayed inline in 'Print Page' view ]

I hope this helps.

J

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 11, 2021, 12:42:26 am

Man I was all set to assume 2nd column always 45 but doubt that very much! After seeing last shots.

I think number of columns depends on longest filename.

dir -F -l looks interesting it's a nice one column list but I wonder if the column of interest, the last which is all we want, might be different for different people ie if "john john" were longer for another person.

BTW If I told Linux to

Code: QB64: [Select]

ChDir Android/

in Basic Code would it? Or does slash have to be removed.

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 11, 2021, 12:54:29 am

@johnno56

Any commands that gets just a plain 1 column list of just filenames or folders?

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 11, 2021, 05:38:39 pm

I have only needed dir or ls when dealing with directories. There are probably a whole swag of commands but I have not had the need to use them or to learn what they are... I know this is not very helpful... In the early days of my Linux experience, using the command line, was more widely used. The advent of better GUI's meant less use of the command line....

Title: Re: Pipecom Browser for Filename$
Post by: bplus on February 11, 2021, 07:39:43 pm

Quote from: johnno56 on February 11, 2021, 05:38:39 pm

I have only needed dir or ls when dealing with directories. There are probably a whole swag of commands but I have not had the need to use them or to learn what they are... I know this is not very helpful... In the early days of my Linux experience, using the command line, was more widely used. The advent of better GUI's meant less use of the command line....

@johnno56 I probably think of you first when I want cross platform for at least Linux. I thank you again for all your assistance and feedback from that other OS.

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 11, 2021, 11:05:47 pm

"Other" OS? Do you not mean, "The" OS? lol

Title: Re: Pipecom Browser for Filename$
Post by: SpriggsySpriggs on February 11, 2021, 11:12:56 pm

@johnno56

So you're a Linux guy? Any sort of thing (C++/POSIX-wise) you have on a wishlist for functions in Linux QB64? Linux is fun to mess with

Title: Re: Pipecom Browser for Filename$
Post by: johnno56 on February 12, 2021, 04:20:46 pm

100% Linux since 2005.... and no, nothing really to add to QB64. Quite happy with the way it functions.

A wish-list. Interesting.

I usually work with a series of "steps". Create concept. Is it feasible with the tools at hand. If so develop and produce. Otherwise move on to the next concept. "Wishing" for something, in my opinion, does not make it real or happen. But that is just me... lol

With that being said... Most 'Basics' are designed for 2D. Having a Physics engine (like Box2D) and a Particle System, 'built in', would be beneficial for 'any' Basic...

Yep. Happy with QB64.

Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: bplus on February 07, 2021, 08:04:56 pm