Print Page - Program code ScreenShot non QB64 program fullscreen *** SOLVED = [⊞] + [PrtSc]

Active Forums => QB64 Discussion => Topic started by: Richard on November 15, 2020, 08:47:30 am

Title: Program code ScreenShot non QB64 program fullscreen *** SOLVED = [⊞] + [PrtSc]
Post by: Richard on November 15, 2020, 08:47:30 am

I am trying to in a program take a ScreenShot of a Windows Screen (the QB64 program window is not visible).

I have tried Auto Hot Key which using ^J (CHR$(10)) as the hotkey for PrintScreen and this takes a screenshot when I manually use it (i.e. Ctrl J), but when I attempt to script it for program control - the external program does not seem to accept the ^J for the screenshot via the

SHELL _DONTWAIT "START /MAX MyExternalProgram.exe filename.ext"

_CLIPBOARD$ = CHR$(10) ' Ctrl + J .ahk file ^-^-#{PrintScreen} reduce screen elements a few times THEN take a ScreenShot

PRINT _CLIPBOARD$

_SCREENPRINT CHR$(22) ' Ctrl + V paste from clipboard

_DELAY 5

Since it is not a QB64 program screen, I cannot use my program screenshot routine. Any way (program-wise) to get a ScreenShot?

Title: Re: Program code to ScreenShot non QB64 program full screen
Post by: RhoSigma on November 15, 2020, 09:06:28 am

_SCREENIMAGE maybe ?

http://www.qb64.org/wiki/SCREENIMAGE

Title: Re: Program code to ScreenShot non QB64 program full screen
Post by: SMcNeill on November 15, 2020, 09:08:05 am

_SCREENIMAGE

Title: Re: Program code to ScreenShot non QB64 program full screen
Post by: Richard on November 15, 2020, 10:02:47 am

@RhoSigma
@Steve

Thanks for your replies.

Based on the Wiki example, I inserted the following Code fragment at the beginning of the program:-

desktop& = _SCREENIMAGE
MaxScreenx& = _WIDTH(desktop&)
MaxScreeny& = _HEIGHT(desktop&)
_FREEIMAGE desktop ' free image after measuring screen (it is not displayed)
SCREEN _NEWIMAGE(MaxScreenx&, MaxScreeny&, 32) ' program window is sized to fit
_SCREENMOVE 0, 0

PRINT "..."

then had my stuff calling my externalprogram

and then used my simple .BMP format screendump

open "A:\screen32.bmp" for binary as #1

... 56 byte header

FOR y% = 1799 TO 0 STEP -1
FOR x% = 0 TO 3199

c& = POINT(x%, y%)

r$ = CHR$(_RED32(c&))
g$ = CHR$(_GREEN32(c&))
b$ = CHR$(_BLUE32(c&))
a$ = CHR$(_ALPHA32(c&)) ' PUT #1, , a$ alpha field not saved in .bmp format used so ONLY 3 bytes RGB used per pixel

PUT #1, , r$
PUT #1, , g$
PUT #1, , b$
NEXT
NEXT

CLOSE #1

Now the externalprogram is NOT FULLSCREEN and the .bmp file is all black with my "..." at top left hand corner. Its as if I cannot access anything outside of the QB64 program window.

Any further suggestions (hoping its something I omitted)?

Title: Re: Program code to ScreenShot non QB64 program full screen
Post by: RhoSigma on November 15, 2020, 11:00:54 am

1. Run external program (guess it will output something into its own window/console on the desktop)
2. Catch the current desktop contents using _SCREENIMAGE
3. Do whatever you want with the image handle obtained from step 2. (save it, print it or whatever)
4. Free the desktop image handle using _FREEIMAGE

Title: Re: Program code to ScreenShot non QB64 program full screen
Post by: Petr on November 15, 2020, 11:27:34 am

Hi. Source for image miss:

desktop& = _SCREENIMAGE
MaxScreenx& = _WIDTH(desktop&)
MaxScreeny& = _HEIGHT(desktop&)

SCREEN _NEWIMAGE(MaxScreenx&, MaxScreeny&, 32) ' program window is sized to fit
_SCREENMOVE 0, 0

PRINT "..."

then had my stuff calling my externalprogram

and then used my simple .BMP format screendump

open "A:\screen32.bmp" for binary as #1

... 56 byte header
_SOURCE desktop&
FOR y% = 1799 TO 0 STEP -1
FOR x% = 0 TO 3199

c& = POINT(x%, y%)

r$ = CHR$(_RED32(c&))
g$ = CHR$(_GREEN32(c&))
b$ = CHR$(_BLUE32(c&))
a$ = CHR$(_ALPHA32(c&)) ' PUT #1, , a$ alpha field not saved in .bmp format used so ONLY 3 bytes RGB used per pixel

PUT #1, , r$
PUT #1, , g$
PUT #1, , b$
NEXT
NEXT

_FREEIMAGE desktop& ' free image after measuring it (you do not need graphical mode SCREEN for work with images)
CLOSE #1

Title: Re: Program code to ScreenShot non QB64 program full screen
Post by: SMcNeill on November 15, 2020, 11:41:28 am

I'm not really certain what you're trying to do with your example, Richard, so I thought I'd just go the route of giving you a working example to start from:

Code: QB64: [Select]

_SCREENHIDE 'Hide our QB64 screen, so we don't grab a capture of it
DesktopImage = _SCREENIMAGE
QB64Screen = _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT, 32)
SCREEN QB64Screen 'set our screen
_SCREENSHOW 'Show our QB64 screen, so we can see what we're doing
_SCREENMOVE 0, 0 'move it to the top left of our desktop
_PUTIMAGE (_WIDTH, _HEIGHT)-(0, 0), DesktopImage 'place the screenimage onto our QB64 screen -- upside down
 
SaveBMP "UpsideDown.bmp", 0, 0, 0, _WIDTH, _HEIGHT 'Save it to the drive
 
 
 
SUB SaveBMP (filename$, image&, x1%, y1%, x2%, y2%)
    'Super special STEVE-Approved BMP Export routine for use with any QB64 graphic mode.
    IF x2% = _WIDTH(image&) THEN x2% = x2% - 1
    IF y2% = _HEIGHT(image&) THEN y2% = y2% - 1
 
    IF _PIXELSIZE(image&) = 0 THEN
        IF SaveTextAs256Color THEN
            tempimage& = TextScreenToImage256&(image&)
        ELSE
            tempimage& = TextScreenToImage32&(image&)
        END IF
        F = _FONT(image&)
        FW = _FONTWIDTH(F): FH = _FONTHEIGHT(F)
        SaveBMP filename$, tempimage&, x1% * FW, y1% * FH, x2% * FW, y2% * FH
        _FREEIMAGE tempimage&
        EXIT FUNCTION
    END IF
 
    TYPE BMPFormat
        ID AS STRING * 2
        Size AS LONG
        Blank AS LONG
        Offset AS LONG
        Hsize AS LONG
        PWidth AS LONG
        PDepth AS LONG
        Planes AS INTEGER
        BPP AS INTEGER
        Compression AS LONG
        ImageBytes AS LONG
        Xres AS LONG
        Yres AS LONG
        NumColors AS LONG
        SigColors AS LONG
    END TYPE
 
 
    DIM BMP AS BMPFormat
    DIM x AS LONG, y AS LONG
    DIM temp AS STRING, t AS STRING * 1
 
    DIM n AS _MEM, o AS _OFFSET, m AS _MEM
    m = _MEMIMAGE(image&)
 
    IF x1% > x2% THEN SWAP x1%, x2%
    IF y1% > y2% THEN SWAP y1%, y2%
    IF x2% = _WIDTH(imagehandle%) THEN x2% = _WIDTH(imagehandle%) - 1 'troubleshoot in case user does a common mistake for 0-width instead of 0 - (width-1) for fullscreen
    IF y2% = _HEIGHT(imagehandle%) THEN y2% = _HEIGHT(imagehandle%) - 1 'troubleshoot in case user does a common mistake for 0-width instead of 0 - (width-1) for fullscreen
 
    s& = _SOURCE
    _SOURCE image&
 
    BMP.PWidth = (x2% - x1%) + 1
    BMP.PDepth = (y2% - y1%) + 1
    BMP.ID = "BM"
    BMP.Blank = 0
    BMP.Hsize = 40
    BMP.Planes = 1
    BMP.Compression = 0
    BMP.Xres = 0
    BMP.Yres = 0
 
    BMP.SigColors = 0
 
    SELECT CASE _PIXELSIZE(image&)
        CASE 1
            temp = SPACE$(x2% - x1% + 1)
            OffsetBITS& = 54 + 1024 'add palette in 256 color modes
            BMP.BPP = 8
            IF BMP.PWidth MOD 4 THEN ZeroPAD$ = SPACE$(4 - (BMP.PWidth MOD 4))
            ImageSize& = (BMP.PWidth + LEN(ZeroPAD$)) * BMP.PDepth
            BMP.ImageBytes = ImageSize&
            BMP.NumColors = 256
            BMP.Size = ImageSize& + OffsetBITS&
            BMP.Offset = OffsetBITS&
        CASE 4
            temp = SPACE$(3)
            OffsetBITS& = 54 'no palette in 24/32 bit
            BMP.BPP = 24
            IF ((BMP.PWidth * 3) MOD 4) THEN ZeroPAD$ = SPACE$(4 - ((BMP.PWidth * 3) MOD 4))
            ImageSize& = (BMP.PWidth + LEN(ZeroPAD$)) * BMP.PDepth
            BMP.ImageBytes = ImageSize&
            BMP.NumColors = 0
            BMP.Size = ImageSize& * 3 + OffsetBITS&
            BMP.Offset = OffsetBITS&
    END SELECT
 
    F = FREEFILE
    n = _MEMNEW(BMP.Size)
    _MEMPUT n, n.OFFSET, BMP
    o = n.OFFSET + 54
    zp& = LEN(ZeroPAD$)
    $CHECKING:OFF
 
    IF BMP.BPP = 8 THEN 'Store the Palette for 256 color mode
        FOR c& = 0 TO 255 ' read BGR color settings from JPG image + 1 byte spacer(CHR$(0))
            cv& = _PALETTECOLOR(c&, image) ' color attribute to read.
            b$ = CHR$(_BLUE32(cv&)) + CHR$(_GREEN32(cv&)) + CHR$(_RED32(cv&)) + CHR$(0) 'spacer byte
            _MEMPUT n, o, b$
            o = o + 4
        NEXT
        y = y2% + 1
        w& = _WIDTH(image&)
        x = x2% - x1% + 1
        DO
            y = y - 1
            _MEMGET m, m.OFFSET + (w& * y + x1%), temp
            _MEMPUT n, o, temp
            o = o + x
            _MEMPUT n, o, ZeroPAD$
            o = o + zp&
        LOOP UNTIL y = y1%
    ELSE
        y = y2% + 1
        w& = _WIDTH(image&)
        DO
            y = y - 1: x = x1% - 1
            DO
                x = x + 1
                _MEMGET m, m.OFFSET + (w& * y + x) * 4, temp
                _MEMPUT n, o, temp
                o = o + 3
            LOOP UNTIL x = x2%
            _MEMPUT n, o, ZeroPAD$
            o = o + zp&
        LOOP UNTIL y = y1%
    END IF
    $CHECKING:ON
    _MEMFREE m
    OPEN filename$ FOR BINARY AS #F
    t1$ = SPACE$(BMP.Size)
    _MEMGET n, n.OFFSET, t1$
    PUT #F, , t1$
    _MEMFREE n
    CLOSE #F
    _SOURCE s&
END SUB
 
 

I hope the comments show what we're doing at each step of our code, but if you have any questions about anything, feel free to ask. With this, you should end up with an "UpsideDown.bmp" file inside your QB64 folder, which looks like your desktop turned upside down and backwards. :)

Title: Re: Program code to ScreenShot non QB64 program full screen
Post by: Richard on November 15, 2020, 02:04:58 pm

@ Steve

MANY THANKS

Your program met my requirements "to capture the whole screen as I see it (eg Windows File Explorer, etc) - effectively a Windows 10 Print Screen.

In case you are interested - just to give you an example of what I wanted to achieve:-

Call an "externalprogram" (in this case MSedge.exe) and let it do its thing with a file as listed just below AND then let the QB64 program take a complete screenshot (saved as upsidedown.bmp). SO the very minor modifications to your program is the addition as below

_DELAY 5
SHELL _DONTWAIT "START /MAX msedge.exe A:\Download_NTFS_Reader_for_DOS_-_MajorGeeks.mhtml"
_DELAY 5

Note: the computer was "off-line" when running the program

The .bmp file was converted to a .png file and is below and represents exactly ALL that I see on my display.

WARNING It has been reported by some that stuff from the above website is suspicious

Now to work out how to make it right way round before saving

Thanks again Steve!

Title: Re: Program code to ScreenShot non QB64 program full screen
Post by: SMcNeill on November 15, 2020, 02:39:13 pm

It’s my PUTIMAGE that is reversing the image for us, by putting it from bottom right to top left. Just reverse the order in that command to do it proper.

_PUTIMAGE (0, 0)-(_WIDTH, _HEIGHT), DesktopImage

Though, it sounds like all you need is to change the imagehandle in the SaveBMP command.

SaveBMP “MyFile.bmp”, DesktopImage, 0, 0, _WIDTH, _HEIGHT

Title: Re: Program code to ScreenShot non QB64 program full screen
Post by: Richard on November 15, 2020, 02:47:54 pm

@ Steve

Thanks again

I will try it out again tonite - it is sunrise now (I am going to bed)

@ Petr
@ RhoSigma

Thanks for your replies - will also check out tonite.
https://www.qb64.org/forum/index.php?topic=2276.75#lastPost

Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Richard on November 15, 2020, 08:47:30 am