QB64.org Forum

Active Forums => Programs => Topic started by: Kiara87 on September 09, 2020, 04:09:15 am

Title: lancio di due dadi
Post by: Kiara87 on September 09, 2020, 04:09:15 am

Hello everyone
I also want to share my projects with you
i promise i am not a programmer

so maybe you understand that my programs will not initially be perfect
place a simple program that rolls two dice

Code: QB64: [Select]

1. credito = 10
2. 1 CLS
3.  
4. LOCATE 1, 1: PRINT "É"; STRING$(78, 205); "»" 'string$ scrive 78 volte il valore in ascii del 205
5. LOCATE 2, 1: PRINT "º"; TAB(80); "º" 'tab significa fai un spazio di 80 caratteri una tabbulazione
6. LOCATE 3, 1: PRINT "È"; STRING$(78, 205); "¼" 'string$ scrive 78 volte il valore in ascii del 205
7. LOCATE 2, 30: PRINT "il tuo credito"; credito; "gettoni"
8. PRINT
9. PRINT
10. PRINT
11.  
12.  
13. inizio:
14.  
15. LOCATE 4, 1
16. PRINT "hai "; credito; " Crediti"
17.  
18.  
19. COLOR 18
20. INPUT "Quanto vuoi puntare? "; puntata
21. COLOR 7
22. CLS
23.  
24. 'tasto$ = INPUT$(1)
25.  
26.  
27.  
28. IF puntata <= 0 THEN
29.     LOCATE 6, 11
30.     PRINT "devi puntare qualcosa per giocare"
31.     SLEEP 3
32.     GOTO 1
33.  
34. ELSEIF puntata > credito THEN
35.     LOCATE 21, 11
36.     PRINT "non possiedi tutto questo credito "; "hai solamente "; credito; " crediti; "
37.     'coso = 0:coso2 =0
38.     SLEEP 3
39.     GOTO 1
40.  
41. END IF
42.  
43. RANDOMIZE TIMER
44. coso = INT(RND * 5) + 1
45. coso2 = INT(RND * 5) + 1
46.  
47. LOCATE 1, 25
48.  
49.  
50.  
51. LOCATE 22, 25
52. PRINT "Programma lancio dei dadi...."
53. LOCATE 8, 11
54. PRINT "il tuo dado e "; coso
55. LOCATE 8, 42
56. PRINT "il dado del avversario e' "; coso2
57.  
58.  
59.  
60. IF coso = 6 THEN dado: dado6
61. IF coso = 5 THEN dado: dado5
62. IF coso = 4 THEN dado: dado4
63. IF coso = 3 THEN dado: dado3
64. IF coso = 2 THEN dado: dado2
65. IF coso = 1 THEN dado: dado1
66. '----------------------------------
67. IF coso2 = 6 THEN dadocoso2: cosodado6
68. IF coso2 = 5 THEN dadocoso2: cosodado5
69. IF coso2 = 4 THEN dadocoso2: cosodado4
70. IF coso2 = 3 THEN dadocoso2: cosodado3
71. IF coso2 = 2 THEN dadocoso2: cosodado2
72. IF coso2 = 1 THEN dadocoso2: cosodado1
73.  
74. IF coso = coso2 THEN
75.     LOCATE 13, 30
76.     PRINT "Pareggio"
77. ELSEIF coso > coso2 THEN
78.     credito = credito + puntata
79.     LOCATE 13, 30
80.     COLOR 10
81.     PRINT "Hai vinto"
82.     COLOR 7
83. ELSEIF coso < coso2 THEN
84.     credito = credito - puntata
85.     COLOR 4
86.     LOCATE 13, 30
87.     PRINT "Hai perso"
88.     COLOR 7
89.     IF credito <= 0 THEN
90.         LOCATE 13, 30
91.         COLOR 4
92.         PRINT "GAME OVER"
93.         FOR i = 1 TO 20 STEP 2
94.             BEEP
95.         NEXT i
96.         END
97.     END IF
98.  
99.  
100. END IF
101. GOTO inizio
102. SUB dado
103.     LOCATE 10, 10
104.     PRINT "É"; STRING$(16, 205); "»"
105.     LOCATE 17, 10
106.     PRINT "È"; STRING$(16, 205); "¼"
107.     FOR i = 11 TO 16
108.         LOCATE i, 10
109.         PRINT "º"; TAB(27); "º"
110.     NEXT i
111. END SUB
112. SUB dado1
113.  
114.     LOCATE 13, 11
115.     PRINT "       **"
116.  
117. END SUB
118. SUB dado2
119.     LOCATE 11, 11
120.     PRINT "       **"
121.     LOCATE 16, 11
122.     PRINT "       **"
123. END SUB
124. SUB dado3
125.     LOCATE 11, 11
126.     PRINT "**"
127.     LOCATE 13, 11
128.     PRINT "       **"
129.     LOCATE 16, 11
130.     PRINT "              **"
131.  
132. END SUB
133. SUB dado4
134.     LOCATE 11, 11
135.     PRINT "**            **"
136.     LOCATE 16, 11
137.     PRINT "**            **"
138.  
139.  
140. END SUB
141. SUB dado5
142.     LOCATE 11, 11
143.     PRINT "**            **"
144.     LOCATE 13, 11
145.     PRINT "       **"
146.     LOCATE 16, 11
147.     PRINT "**            **"
148.  
149. END SUB
150. SUB dado6
151.     LOCATE 11, 11
152.     PRINT "**     **     **"
153.     LOCATE 16, 11
154.     PRINT "**     **     **"
155.  
156. END SUB
157.  
158. '===============================================================
159. SUB dadocoso2
160.     LOCATE 10, 40
161.     PRINT "É"; STRING$(16, 205); "»"
162.     LOCATE 17, 40
163.     PRINT "È"; STRING$(16, 205); "¼"
164.     FOR i = 11 TO 16
165.         LOCATE i, 40
166.         PRINT "º"; TAB(57); "º"
167.     NEXT i
168.  
169. END SUB
170. SUB cosodado1
171.  
172.     LOCATE 13, 42
173.     PRINT "       **"
174.  
175. END SUB
176. SUB cosodado2
177.     LOCATE 11, 42
178.     PRINT "       **"
179.     LOCATE 16, 42
180.     PRINT "       **"
181. END SUB
182. SUB cosodado3
183.     LOCATE 11, 42
184.     PRINT "**"
185.     LOCATE 13, 42
186.     PRINT "      **"
187.     LOCATE 16, 42
188.     PRINT "             **"
189.  
190. END SUB
191. SUB cosodado4
192.     LOCATE 11, 42
193.     PRINT "**           **"
194.     LOCATE 16, 42
195.     PRINT "**           **"
196.  
197.  
198. END SUB
199. SUB cosodado5
200.     LOCATE 11, 42
201.     PRINT "**           **"
202.     LOCATE 13, 42
203.     PRINT "       **"
204.     LOCATE 16, 42
205.     PRINT "**           **"
206.  
207. END SUB
208. SUB cosodado6
209.     LOCATE 11, 42
210.     PRINT "**     **    **"
211.     LOCATE 16, 42
212.     PRINT "**     **    **"
213.  
214. END SUB
215.  
216.  

Title: Re: lancio di due dadi
Post by: bplus on September 09, 2020, 08:41:54 am

Oh looks like fun! I will try one.  :)

Code: QB64: [Select]

1. _TITLE "Dice Game - inspired by Kiara's" ' b+ 2020-09-09
2. SCREEN _NEWIMAGE(600, 600, 12)
3. _DELAY .25
4. _SCREENMOVE _MIDDLE
5. RANDOMIZE TIMER
6. _FONT 8
7. DIM SHARED doubles
8. money = 100
9. DO
10.     _FONT 8
11.     rollDice r1, r2
12.     IF r1 = r2 THEN
13.         doubles = doubles + 1
14.         IF r1 = 1 THEN money = money - 28 ELSE money = money + 6
15.     ELSEIF r1 + r2 < 7 THEN
16.         money = money - 1
17.     ELSEIF r1 + r2 > 7 THEN
18.         money = money + 1
19.     END IF
20.     _FONT 16
21.     LP 12, 34, "money:" + STR$(money)
22.     LP 22, 37, STR$(r1 + r2)
23.     LP 32, 34, "doubles:" + STR$(doubles)
24.     _DELAY 2
25. LOOP UNTIL _KEYDOWN(27)
26.  
27. SUB rollDice (r1, r2)
28.     FOR i = 1 TO 10
29.         CLS
30.         _FONT 16
31.         LP 4, 31, "IF r1 = r2 THEN"
32.         LP 5, 10, "IF r1 = 1 THEN money = money - 28 ELSE money = money + 6"
33.         LP 7, 17, "ELSEIF r1 + r2 < 7 THEN money = money - 1"
34.         LP 9, 17, "ELSEIF r1 + r2 > 7 THEN money = money + 1"
35.         _FONT 8
36.         r1 = INT(RND * 6) + 1
37.         r2 = INT(RND * 6) + 1
38.         ansiiDice 44, 22, r1
39.         ansiiDice 44, 54, r2
40.         _LIMIT 10
41.     NEXT
42. END SUB
43.  
44. SUB ansiiDice (row, col, n)
45.     radius = 4
46.     IF n > 1 THEN
47.         angle = _PI(2 / n)
48.         IF n MOD 2 = 0 THEN offset = _PI / 4 ELSE offset = _PI / 2
49.         IF n = 6 THEN offset = 0
50.         FOR i = 1 TO n
51.             r = row + INT(radius * SIN(i * angle - offset) + .5)
52.             c = col + INT(radius * COS(i * angle - offset) + .5)
53.             LP r, c, "*"
54.             'PRINT r, c
55.         NEXT
56.     ELSE
57.         LP row, col, "*"
58.     END IF
59.     c1 = col - 9: c2 = col + 9
60.     r1 = row - 9: r2 = row + 9
61.     FOR i = c1 TO c2
62.         LP r1, i, CHR$(196)
63.         LP r2, i, CHR$(196)
64.     NEXT
65.     FOR i = r1 TO r2
66.         LP i, c1, CHR$(179)
67.         LP i, c2, CHR$(179)
68.     NEXT
69.     LP r1, c1, CHR$(218)
70.     LP r2, c1, CHR$(192)
71.     LP r1, c2, CHR$(191)
72.     LP r2, c2, CHR$(217)
73. END SUB
74.  
75. SUB LP (r, c, s$)
76.     LOCATE r, c: PRINT s$
77. END SUB
78.  

EDIT: changed payout scheme

 

Title: Re: lancio di due dadi
Post by: TempodiBasic on September 10, 2020, 06:06:41 pm

@Kiara87
buon inizio, tanta pratica vale molto più di tanta teoria nella programmazione perchè bisogna saper fare e non semplicemente sapere come si fa.
A mio giudizio hai fatto un altro passo verso la programmazione modulare, ma se vuoi progredire in questa direzione devi imparare a trasformare i GOTO e i GOSUB in blocchi di codice, come hai fatto per l'output ASCII dei dadi in questo tuo programma.

Senza trasformarlo è possibile migliorare il suo output
1. è nel lato giocatore è senza apostrofo ( per mimare l'accento ) mentre nel lato l'AI è corretto

2. la testata del gioco scompare e riappare, meglio controllare con precisione il flusso
 REMmando le linee di codice 13,14,15,16 e cambiando il GOTO Inizio con GOTO 1  e alla linea 22 elimina il CLS e usa LOCATE 5,1: PRINT SPACE$(80); per cancellare l'input dell'utente e procedere con il lancio dei dadi.

3. la domanda presenta due ? ? lo puoi risolvere o cancellando ? dal testo specificato con INPUT oppure sostituendo ; ( che pone un ? prima del cursore di input ) con , (che fa seguire direttamente l'input dell'utente)

4. per quanto io adori i colori Blink dello SCREEN 0 alla riga 19 del programma preferirei sostituire COLOR 18 con COLOR 3

confronta il programma che hai postato con questa sua variante.
/
EN
@ Kiara87
good start, a lot of practice is worth much more than a lot of theory in programming because you have to know how to do and not simply know how to do it.
In my judgment you have taken another step towards modular programming, but if you want to progress in this direction you have to learn how to turn GOTOS and GOSUBs into code blocks, as you did for the ASCII output of dice in this program of yours.

Without transforming it it is possible to improve its output
1. è  (e') on the player side is without apostrophe (to mimic the accent) while on the side of the AI it ​​is correct (e' in the place of è)

2. the game head disappears and reappears, better control the flow precisely
 By removing the lines of code 13,14,15,16 and changing the GOTO Inizio with GOTO 1 and at line 22 remove the CLS and use LOCATE 5,1: PRINT SPACE $ (80); to clear user input and proceed with the roll of the dice.

3. the question has two? ? can you fix it or delete it? from the text specified with INPUT or by replacing; (which places a? before the input cursor) with, (which directly follows user input)

4. as much as I love the Blink colors of SCREEN 0 at line 19 of the program I would prefer to replace COLOR 18 with COLOR 3

compare the program you posted with this variant.

Code: QB64: [Select]

1. credito = 10
2. 1 CLS
3.  
4. LOCATE 1, 1: PRINT "É"; STRING$(78, 205); "»" 'string$ scrive 78 volte il valore in ascii del 205
5. LOCATE 2, 1: PRINT "º"; TAB(80); "º" 'tab significa fai un spazio di 80 caratteri una tabbulazione
6. LOCATE 3, 1: PRINT "È"; STRING$(78, 205); "¼" 'string$ scrive 78 volte il valore in ascii del 205
7. LOCATE 2, 30: PRINT "il tuo credito"; credito; "gettoni"
8. PRINT
9. PRINT
10. PRINT
11.  
12.  
13. '    inizio:
14.  
15. 'LOCATE 4, 1
16. 'PRINT "hai "; credito; " Crediti"
17.  
18.  
19. COLOR 18
20. INPUT "Quanto vuoi puntare? ", puntata
21. COLOR 7
22. LOCATE 5, 1: PRINT SPACE$(80); 'CLS
23.  
24. 'tasto$ = INPUT$(1)
25.  
26.  
27.  
28. IF puntata <= 0 THEN
29.     LOCATE 6, 11
30.     PRINT "devi puntare qualcosa per giocare"
31.     SLEEP 3
32.     GOTO 1
33.  
34. ELSEIF puntata > credito THEN
35.     LOCATE 21, 11
36.     PRINT "non possiedi tutto questo credito "; "hai solamente "; credito; " crediti; "
37.     'coso = 0:coso2 =0
38.     SLEEP 3
39.     GOTO 1
40.  
41. END IF
42.  
43. RANDOMIZE TIMER
44. coso = INT(RND * 5) + 1
45. coso2 = INT(RND * 5) + 1
46.  
47. LOCATE 1, 25
48.  
49.  
50.  
51. LOCATE 22, 25
52. PRINT "Programma lancio dei dadi...."
53. LOCATE 8, 11
54. PRINT "il tuo dado e "; coso
55. LOCATE 8, 42
56. PRINT "il dado del avversario e' "; coso2
57.  
58.  
59.  
60. IF coso = 6 THEN dado: dado6
61. IF coso = 5 THEN dado: dado5
62. IF coso = 4 THEN dado: dado4
63. IF coso = 3 THEN dado: dado3
64. IF coso = 2 THEN dado: dado2
65. IF coso = 1 THEN dado: dado1
66. '----------------------------------
67. IF coso2 = 6 THEN dadocoso2: cosodado6
68. IF coso2 = 5 THEN dadocoso2: cosodado5
69. IF coso2 = 4 THEN dadocoso2: cosodado4
70. IF coso2 = 3 THEN dadocoso2: cosodado3
71. IF coso2 = 2 THEN dadocoso2: cosodado2
72. IF coso2 = 1 THEN dadocoso2: cosodado1
73.  
74. IF coso = coso2 THEN
75.     LOCATE 13, 30
76.     PRINT "Pareggio"
77. ELSEIF coso > coso2 THEN
78.     credito = credito + puntata
79.     LOCATE 13, 30
80.     COLOR 10
81.     PRINT "Hai vinto"
82.     COLOR 7
83. ELSEIF coso < coso2 THEN
84.     credito = credito - puntata
85.     COLOR 4
86.     LOCATE 13, 30
87.     PRINT "Hai perso"
88.     COLOR 7
89.     IF credito <= 0 THEN
90.         LOCATE 13, 30
91.         COLOR 4
92.         PRINT "GAME OVER"
93.         FOR i = 1 TO 20 STEP 2
94.             BEEP
95.         NEXT i
96.         END
97.     END IF
98.  
99.  
100. END IF
101. '    GOTO inizio
102. SLEEP 3
103. GOTO 1
104.  
105. SUB dado
106.     LOCATE 10, 10
107.     PRINT "É"; STRING$(16, 205); "»"
108.     LOCATE 17, 10
109.     PRINT "È"; STRING$(16, 205); "¼"
110.     FOR i = 11 TO 16
111.         LOCATE i, 10
112.         PRINT "º"; TAB(27); "º"
113.     NEXT i
114. END SUB
115. SUB dado1
116.  
117.     LOCATE 13, 11
118.     PRINT "       **"
119.  
120. END SUB
121. SUB dado2
122.     LOCATE 11, 11
123.     PRINT "       **"
124.     LOCATE 16, 11
125.     PRINT "       **"
126. END SUB
127. SUB dado3
128.     LOCATE 11, 11
129.     PRINT "**"
130.     LOCATE 13, 11
131.     PRINT "       **"
132.     LOCATE 16, 11
133.     PRINT "              **"
134.  
135. END SUB
136. SUB dado4
137.     LOCATE 11, 11
138.     PRINT "**            **"
139.     LOCATE 16, 11
140.     PRINT "**            **"
141.  
142.  
143. END SUB
144. SUB dado5
145.     LOCATE 11, 11
146.     PRINT "**            **"
147.     LOCATE 13, 11
148.     PRINT "       **"
149.     LOCATE 16, 11
150.     PRINT "**            **"
151.  
152. END SUB
153. SUB dado6
154.     LOCATE 11, 11
155.     PRINT "**     **     **"
156.     LOCATE 16, 11
157.     PRINT "**     **     **"
158.  
159. END SUB
160.  
161. '===============================================================
162. SUB dadocoso2
163.     LOCATE 10, 40
164.     PRINT "É"; STRING$(16, 205); "»"
165.     LOCATE 17, 40
166.     PRINT "È"; STRING$(16, 205); "¼"
167.     FOR i = 11 TO 16
168.         LOCATE i, 40
169.         PRINT "º"; TAB(57); "º"
170.     NEXT i
171.  
172. END SUB
173. SUB cosodado1
174.  
175.     LOCATE 13, 42
176.     PRINT "       **"
177.  
178. END SUB
179. SUB cosodado2
180.     LOCATE 11, 42
181.     PRINT "       **"
182.     LOCATE 16, 42
183.     PRINT "       **"
184. END SUB
185. SUB cosodado3
186.     LOCATE 11, 42
187.     PRINT "**"
188.     LOCATE 13, 42
189.     PRINT "      **"
190.     LOCATE 16, 42
191.     PRINT "             **"
192.  
193. END SUB
194. SUB cosodado4
195.     LOCATE 11, 42
196.     PRINT "**           **"
197.     LOCATE 16, 42
198.     PRINT "**           **"
199.  
200.  
201. END SUB
202. SUB cosodado5
203.     LOCATE 11, 42
204.     PRINT "**           **"
205.     LOCATE 13, 42
206.     PRINT "       **"
207.     LOCATE 16, 42
208.     PRINT "**           **"
209.  
210. END SUB
211. SUB cosodado6
212.     LOCATE 11, 42
213.     PRINT "**     **    **"
214.     LOCATE 16, 42
215.     PRINT "**     **    **"
216.  
217. END SUB
218.  
219.  
220.  

Good start! Go on translating those GOTO to a DO LOOP cycle for the next step towards modular programming.

Title: Re: lancio di due dadi
Post by: TempodiBasic on September 10, 2020, 06:10:18 pm

@bplus
fine the battle dice  PC vs PC!...
and I can see that you loves geometry, each face of dice has its geometric formula.

Title: Re: lancio di due dadi
Post by: Kiara87 on September 10, 2020, 06:51:28 pm

grazie @TempodiBasic per i consigli
cercherò di migliorare dando esempio dal tuo codice
e confrontarlo cosi vedro i miglioramenti del programma


@bplus  thanks to you too I see that you enjoy editing programs
and it's nice to see the changes

Title: Re: lancio di due dadi
Post by: bplus on September 10, 2020, 06:52:34 pm

Quote from: TempodiBasic on September 10, 2020, 06:10:18 pm

@bplus
fine the battle dice  PC vs PC!...
and I can see that you loves geometry, each face of dice has its geometric formula.

Yeah, I can put allot more dots on the dice face with same code!

Title: Re: lancio di due dadi
Post by: bplus on September 10, 2020, 06:57:56 pm

Quote from: Kiara87 on September 10, 2020, 06:51:28 pm

grazie @TempodiBasic per i consigli
cercherò di migliorare dando esempio dal tuo codice
e confrontarlo cosi vedro i miglioramenti del programma


@bplus  thanks to you too I see that you enjoy editing programs
and it's nice to see the changes

Yes I don't understand Italian so I made up my own program after watching yours run.

Title: Re: lancio di due dadi
Post by: Kiara87 on November 20, 2020, 06:44:41 pm

hi in the created argument which is the difference on sub and end sub

where @bplus pointed out that they are similar to each other
I wanted to modify this program with functions to see if the program worked even changing between subs to functions

I tried to change only a sub as it was going and put a function but it goes in error

perhaps functions should not be called with an if condition?

Code: QB64: [Select]

1. credito = 10
2. 1 CLS
3.  
4. LOCATE 1, 1: PRINT "É"; STRING$(78, 205); "»" 'string$ scrive 78 volte il valore in ascii del 205
5. LOCATE 2, 1: PRINT "º"; TAB(80); "º" 'tab significa fai un spazio di 80 caratteri una tabbulazione
6. LOCATE 3, 1: PRINT "È"; STRING$(78, 205); "¼" 'string$ scrive 78 volte il valore in ascii del 205
7. LOCATE 2, 30: PRINT "il tuo credito"; credito; "gettoni"
8. PRINT
9. PRINT
10. PRINT
11.  
12.  
13. inizio:
14.  
15. LOCATE 4, 1
16. PRINT "hai "; credito; " Crediti"
17.  
18.  
19. COLOR 18
20. INPUT "Quanto vuoi puntare? "; puntata
21. COLOR 7
22. CLS
23.  
24. 'tasto$ = INPUT$(1)
25.  
26.  
27.  
28. IF puntata <= 0 THEN
29.     LOCATE 6, 11
30.     PRINT "devi puntare qualcosa per giocare"
31.     SLEEP 3
32.     GOTO 1
33.  
34. ELSEIF puntata > credito THEN
35.     LOCATE 21, 11
36.     PRINT "non possiedi tutto questo credito "; "hai solamente "; credito; " crediti; "
37.     'coso = 0:coso2 =0
38.     SLEEP 3
39.     GOTO 1
40.  
41. END IF
42.  
43. RANDOMIZE TIMER
44. coso = INT(RND * 5) + 1
45. coso2 = INT(RND * 5) + 1
46.  
47. LOCATE 1, 25
48.  
49.  
50.  
51. LOCATE 22, 25
52. PRINT "Programma lancio dei dadi...."
53. LOCATE 8, 11
54. PRINT "il tuo dado e "; coso
55. LOCATE 8, 42
56. PRINT "il dado del avversario e' "; coso2
57.  
58.  
59.  
60. IF coso = 6 THEN dado: dado6
61. IF coso = 5 THEN dado: dado5
62. IF coso = 4 THEN dado: dado4
63. IF coso = 3 THEN dado: dado3
64. IF coso = 2 THEN dado:  dado2
65. IF coso = 1 THEN dado: dado1
66. '----------------------------------
67. IF coso2 = 6 THEN dadocoso2: cosodado6
68. IF coso2 = 5 THEN dadocoso2: cosodado5
69. IF coso2 = 4 THEN dadocoso2: cosodado4
70. IF coso2 = 3 THEN dadocoso2: cosodado3
71. IF coso2 = 2 THEN dadocoso2: cosodado2
72. IF coso2 = 1 THEN dadocoso2: cosodado1
73.  
74. IF coso = coso2 THEN
75.     LOCATE 13, 30
76.     PRINT "Pareggio"
77. ELSEIF coso > coso2 THEN
78.     credito = credito + puntata
79.     LOCATE 13, 30
80.     COLOR 10
81.     PRINT "Hai vinto"
82.     COLOR 7
83. ELSEIF coso < coso2 THEN
84.     credito = credito - puntata
85.     COLOR 4
86.     LOCATE 13, 30
87.     PRINT "Hai perso"
88.     COLOR 7
89.     IF credito <= 0 THEN
90.         LOCATE 13, 30
91.         COLOR 4
92.         PRINT "GAME OVER"
93.         FOR i = 1 TO 20 STEP 2
94.             BEEP
95.         NEXT i
96.         END
97.     END IF
98.  
99.  
100. END IF
101. GOTO inizio
102. SUB dado
103.     LOCATE 10, 10
104.     PRINT "É"; STRING$(16, 205); "»"
105.     LOCATE 17, 10
106.     PRINT "È"; STRING$(16, 205); "¼"
107.     FOR i = 11 TO 16
108.         LOCATE i, 10
109.         PRINT "º"; TAB(27); "º"
110.     NEXT i
111. END SUB
112. SUB dado1
113.  
114.     LOCATE 13, 11
115.     PRINT "       **"
116.  
117. END SUB
118. FUNCTION dado2
119.     LOCATE 11, 11
120.     PRINT "       **"
121.     LOCATE 16, 11
122.     PRINT "       **"
123. END FUNCTION
124. SUB dado3
125.     LOCATE 11, 11
126.     PRINT "**"
127.     LOCATE 13, 11
128.     PRINT "       **"
129.     LOCATE 16, 11
130.     PRINT "              **"
131.  
132. END SUB
133. SUB dado4
134.     LOCATE 11, 11
135.     PRINT "**            **"
136.     LOCATE 16, 11
137.     PRINT "**            **"
138.  
139.  
140. END SUB
141. SUB dado5
142.     LOCATE 11, 11
143.     PRINT "**            **"
144.     LOCATE 13, 11
145.     PRINT "       **"
146.     LOCATE 16, 11
147.     PRINT "**            **"
148.  
149. END SUB
150. SUB dado6
151.     LOCATE 11, 11
152.     PRINT "**     **     **"
153.     LOCATE 16, 11
154.     PRINT "**     **     **"
155.  
156. END SUB
157.  
158. '===============================================================
159. SUB dadocoso2
160.     LOCATE 10, 40
161.     PRINT "É"; STRING$(16, 205); "»"
162.     LOCATE 17, 40
163.     PRINT "È"; STRING$(16, 205); "¼"
164.     FOR i = 11 TO 16
165.         LOCATE i, 40
166.         PRINT "º"; TAB(57); "º"
167.     NEXT i
168.  
169. END SUB
170. SUB cosodado1
171.  
172.     LOCATE 13, 42
173.     PRINT "       **"
174.  
175. END SUB
176. SUB cosodado2
177.     LOCATE 11, 42
178.     PRINT "       **"
179.     LOCATE 16, 42
180.     PRINT "       **"
181. END SUB
182. SUB cosodado3
183.     LOCATE 11, 42
184.     PRINT "**"
185.     LOCATE 13, 42
186.     PRINT "      **"
187.     LOCATE 16, 42
188.     PRINT "             **"
189.  
190. END SUB
191. SUB cosodado4
192.     LOCATE 11, 42
193.     PRINT "**           **"
194.     LOCATE 16, 42
195.     PRINT "**           **"
196.  
197.  
198. END SUB
199. SUB cosodado5
200.     LOCATE 11, 42
201.     PRINT "**           **"
202.     LOCATE 13, 42
203.     PRINT "       **"
204.     LOCATE 16, 42
205.     PRINT "**           **"
206.  
207. END SUB
208. SUB cosodado6
209.     LOCATE 11, 42
210.     PRINT "**     **    **"
211.     LOCATE 16, 42
212.     PRINT "**     **    **"
213.  
214. END SUB
215.  
216.  
217.  
218.  

Title: Re: lancio di due dadi
Post by: bplus on November 20, 2020, 07:10:29 pm

And the main difference between a SUB and FUNCTION is that you can use a FUNCTION say MyFunction$ that returns a string say "Hello" so

You can PRINT MyFunction$ and get "Hello"
You can use MyFunction$ in an IF MyFunction$ = "Goodbye" THEN END
You can assign a variable: Greeting$ = MyFunction$
So MyFunction$ works just like any other variable.

None of these things can you do with a SUB, you can only call MySub and it will execute a SUB block of code. A SUB does not return a value you can print, or assign to a variable or compare with IF.

Title: Re: lancio di due dadi
Post by: Kiara87 on November 20, 2020, 07:37:03 pm

Quote from: bplus on November 20, 2020, 07:10:29 pm

And the main difference between a SUB and FUNCTION is that you can use a FUNCTION say MyFunction$ that returns a string say "Hello" so

You can PRINT MyFunction$ and get "Hello"
You can use MyFunction$ in an IF MyFunction$ = "Goodbye" THEN END
You can assign a variable: Greeting$ = MyFunction$
So MyFunction$ works just like any other variable.

None of these things can you do with a SUB, you can only call MySub and it will execute a SUB block of code. A SUB does not return a value you can print, or assign to a variable or compare with IF.

change sub dado for function dado and continue with everyone
so in this program i can't use as a function substituting all subs for functions would it be impossible?

Title: Re: lancio di due dadi
Post by: bplus on November 20, 2020, 07:44:37 pm

Code: QB64: [Select]

1. FOR i = 1 TO 10
2.     PRINT nStars$(i)
3. NEXT
4.  
5.  
6. FUNCTION nStars$ (n)
7.     FOR i = 1 TO n
8.         addStar$ = addStar$ + "* "
9.     NEXT
10.     nStars$ = addStar$  ' <<<<<<<<<<<<<<< this assigns the function a string value
11. END FUNCTION
12.  

Title: Re: lancio di due dadi
Post by: bplus on November 20, 2020, 07:51:37 pm

Code: QB64: [Select]

1. FOR i = 1 TO 10
2.     printNStars i '<<< can only call a sub like this, no PRINT, IF, X$ =
3. NEXT
4.  
5.  
6. SUB printNStars (n) ' <<< no values assigned to SUB name
7.     FOR i = 1 TO n
8.         PRINT "* ";
9.     NEXT
10.     PRINT
11. END SUB
12.  

Title: Re: lancio di due dadi
Post by: Kiara87 on November 20, 2020, 07:53:37 pm

Quote from: bplus on November 20, 2020, 07:44:37 pm

Code: QB64: [Select]

1. FOR i = 1 TO 10
2.     PRINT nStars$(i)
3. NEXT
4.  
5.  
6. FUNCTION nStars$ (n)
7.     FOR i = 1 TO n
8.         addStar$ = addStar$ + "* "
9.     NEXT
10.     nStars$ = addStar$  ' <<<<<<<<<<<<<<< this assigns the function a string value
11. END FUNCTION
12.  

so the subs is used to call blocks of code
instead the functions call the strings to print on the screen and you can only use it to print something on the screen
correct me if I'm wrong ?

Title: Re: lancio di due dadi
Post by: bplus on November 20, 2020, 08:03:29 pm

You can do more with a function than print them to screen, here is one for random number 1 to n:

Code: QB64: [Select]

1. coso = INT(RND * 5) + 1 ' do you want numbers 1 to 6 ?
2. coso2 = INT(RND * 5) + 1
3.  
4. PRINT "see any 6's in first column?"
5. FOR i = 1 TO 20
6.     PRINT INT(RND * 5) + 1, randomNumber1to(6)
7. NEXT
8.  
9. FUNCTION randomNumber1to (n)
10.     randomNumber1to = INT(RND * n) + 1
11. END FUNCTION
12.  
13.  
14.  

Title: Re: lancio di due dadi
Post by: bplus on November 20, 2020, 08:13:14 pm

Another use of very same function:

Code: QB64: [Select]

1. DO
2.     PRINT "Win"; win, "loose"; loose
3.     IF randomNumber1to(2) = 1 THEN  ' <<<< with (2) returns only 1 or 2
4.         PRINT "You loose": loose = loose + 1
5.     ELSE
6.         PRINT "You win!": win = win + 1
7.     END IF
8.     _LIMIT .5 ' <<<<  slow us d o w n
9. LOOP UNTIL _KEYDOWN(27) ' press escape to quit
10.  
11. FUNCTION randomNumber1to (n)
12.     randomNumber1to = INT(RND * n) + 1
13. END FUNCTION
14.  

Title: Re: lancio di due dadi
Post by: bplus on November 20, 2020, 09:46:15 pm

2 for 1 sale!

Code: QB64: [Select]

1. 'SUB dado
2. '    LOCATE 10, 10
3. '    PRINT "É"; STRING$(16, 205); "»"
4. '    LOCATE 17, 10
5. '    PRINT "È"; STRING$(16, 205); "¼"
6. '    FOR i = 11 TO 16
7. '        LOCATE i, 10
8. '        PRINT "º"; TAB(27); "º"
9. '    NEXT i
10. 'END SUB
11.  
12. 'SUB dadocoso2
13. '    LOCATE 10, 40
14. '    PRINT "É"; STRING$(16, 205); "»"
15. '    LOCATE 17, 40
16. '    PRINT "È"; STRING$(16, 205); "¼"
17. '    FOR i = 11 TO 16
18. '        LOCATE i, 40
19. '        PRINT "º"; TAB(57); "º"
20. '    NEXT i
21. 'END SUB
22.  
23. SUB rettangolo (column)
24.     LOCATE 10, column
25.     PRINT "É"; STRING$(16, 205); "»";
26.     LOCATE 17, column
27.     PRINT "È"; STRING$(16, 205); "¼";
28.     FOR i = 11 TO 16
29.         LOCATE i, column
30.         PRINT "º"; STRING$(16, 32); "º";
31.     NEXT i
32. END SUB
33.  

Add dice dots:

Code: QB64: [Select]

1. dado 10, 3
2. dado 40, 5
3.  
4. SUB dado (column, dots)
5.     LOCATE 10, column
6.     PRINT "É"; STRING$(15, 205); "»";
7.     LOCATE 16, column
8.     PRINT "È"; STRING$(15, 205); "¼";
9.     FOR i = 11 TO 15
10.         LOCATE i, column
11.         PRINT "º"; STRING$(15, 32); "º";
12.     NEXT i
13.     SELECT CASE dots
14.         CASE 1
15.             LOCATE 13, column + 8: PRINT "*"
16.         CASE 2
17.             LOCATE 13, column + 6: PRINT "*   *"
18.         CASE 3
19.             LOCATE 12, column + 6: PRINT "*"
20.             LOCATE 13, column + 8: PRINT "*"
21.             LOCATE 14, column + 10: PRINT "*"
22.         CASE 4
23.             LOCATE 12, column + 6: PRINT "*   *"
24.             LOCATE 14, column + 6: PRINT "*   *"
25.         CASE 5
26.             LOCATE 12, column + 6: PRINT "*   *"
27.             LOCATE 13, column + 8: PRINT "*"
28.             LOCATE 14, column + 6: PRINT "*   *"
29.         CASE 6
30.             LOCATE 12, column + 6: PRINT "* * *"
31.             LOCATE 14, column + 6: PRINT "* * *"
32.     END SELECT
33. END SUB
34.  
35.  
36.  

Title: Re: lancio di due dadi
Post by: bplus on November 20, 2020, 10:25:20 pm

Now add our function

Code: QB64: [Select]

1. DO
2.  
3.     dado 2, randomNumber1to(6)
4.     dado 22, randomNumber1to(6)
5.     dado 42, randomNumber1to(6)
6.     dado 62, randomNumber1to(6)
7.     _LIMIT .5 'slow down to 1 every 2 secs
8. LOOP UNTIL _KEYDOWN(27) 'escape key press to quit
9.  
10. SUB dado (column, dots)
11.     LOCATE 10, column
12.     PRINT "É"; STRING$(15, 205); "»";
13.     LOCATE 16, column
14.     PRINT "È"; STRING$(15, 205); "¼";
15.     FOR i = 11 TO 15
16.         LOCATE i, column
17.         PRINT "º"; STRING$(15, 32); "º";
18.     NEXT i
19.     SELECT CASE dots
20.         CASE 1
21.             LOCATE 13, column + 8: PRINT "*"
22.         CASE 2
23.             LOCATE 13, column + 6: PRINT "*   *"
24.         CASE 3
25.             LOCATE 12, column + 6: PRINT "*"
26.             LOCATE 13, column + 8: PRINT "*"
27.             LOCATE 14, column + 10: PRINT "*"
28.         CASE 4
29.             LOCATE 12, column + 6: PRINT "*   *"
30.             LOCATE 14, column + 6: PRINT "*   *"
31.         CASE 5
32.             LOCATE 12, column + 6: PRINT "*   *"
33.             LOCATE 13, column + 8: PRINT "*"
34.             LOCATE 14, column + 6: PRINT "*   *"
35.         CASE 6
36.             LOCATE 12, column + 6: PRINT "* * *"
37.             LOCATE 14, column + 6: PRINT "* * *"
38.     END SELECT
39. END SUB
40.  
41. FUNCTION randomNumber1to (n)
42.     randomNumber1to = INT(RND * n) + 1
43. END FUNCTION
44.  
45.  

Title: Re: lancio di due dadi
Post by: bplus on November 20, 2020, 11:01:17 pm

Add an array now to track dice numbers and add another Function to total an array of numbers, so now we roll dice until key press stops and shows dice and total, press another key and roll again, ...

Code: QB64: [Select]

1. REDIM dice(1 TO 4) 'so we can add them up
2. DO
3.     CLS
4.     WHILE LEN(INKEY$) = 0 ' roll 'em
5.         FOR d = 1 TO 4
6.             dice(d) = randomNumber1to(6)
7.         NEXT
8.         dado 2, dice(1)
9.         dado 22, dice(2)
10.         dado 42, dice(3)
11.         dado 62, dice(4)
12.         _LIMIT 20 ' CPU was getting worked up, this saves fan
13.     WEND
14.     LOCATE 20, 40: PRINT totalArray(dice())
15.     SLEEP 'pause and wait for key press
16.     _KEYCLEAR 'clear keys so start rolling again
17. LOOP UNTIL _KEYDOWN(27) 'escape key press to quit
18.  
19. SUB dado (column, dots)
20.     LOCATE 10, column
21.     PRINT "É"; STRING$(15, 205); "»";
22.     LOCATE 16, column
23.     PRINT "È"; STRING$(15, 205); "¼";
24.     FOR i = 11 TO 15
25.         LOCATE i, column
26.         PRINT "º"; STRING$(15, 32); "º";
27.     NEXT i
28.     SELECT CASE dots
29.         CASE 1
30.             LOCATE 13, column + 8: PRINT "*"
31.         CASE 2
32.             LOCATE 12, column + 6: PRINT "*"
33.             LOCATE 14, column + 10: PRINT "*"
34.         CASE 3
35.             LOCATE 12, column + 6: PRINT "*"
36.             LOCATE 13, column + 8: PRINT "*"
37.             LOCATE 14, column + 10: PRINT "*"
38.         CASE 4
39.             LOCATE 12, column + 6: PRINT "*   *"
40.             LOCATE 14, column + 6: PRINT "*   *"
41.         CASE 5
42.             LOCATE 12, column + 6: PRINT "*   *"
43.             LOCATE 13, column + 8: PRINT "*"
44.             LOCATE 14, column + 6: PRINT "*   *"
45.         CASE 6
46.             LOCATE 12, column + 6: PRINT "* * *"
47.             LOCATE 14, column + 6: PRINT "* * *"
48.     END SELECT
49. END SUB
50.  
51. FUNCTION randomNumber1to (n)
52.     randomNumber1to = INT(RND * n) + 1
53. END FUNCTION
54.  
55. FUNCTION totalArray (array())
56.     FOR i = LBOUND(array) TO UBOUND(array)
57.         totalArray = totalArray + array(i)
58.     NEXT
59. END FUNCTION
60.  

EDIT: Fix 2 dots dice face.

Title: Re: lancio di due dadi
Post by: MidnightOwl on November 21, 2020, 09:33:37 am

There is an excellent dice rolling routine in 'mboard.bas' in the samples directory in your qb64 directory. It even simulates rolling dice.

Title: Re: lancio di due dadi
Post by: bplus on November 21, 2020, 11:40:52 am

Quote from: MidnightOwl on November 21, 2020, 09:33:37 am

There is an excellent dice rolling routine in 'mboard.bas' in the samples directory in your qb64 directory. It even simulates rolling dice.

Guess I need full path to mboard.bas, I couldn't find it but no matter, here we are practicing SUBs and FUNCTIONs, I think?

I have excellent game of Pig with dice image rolling but try to find it with search here... :P

One more try with capital Pig, aha!
Boink!
https://www.qb64.org/forum/index.php?topic=712.msg6204#msg6204

Title: Re: lancio di due dadi
Post by: bplus on November 21, 2020, 05:25:30 pm

Quote from: MidnightOwl on November 21, 2020, 09:33:37 am

There is an excellent dice rolling routine in 'mboard.bas' in the samples directory in your qb64 directory. It even simulates rolling dice.

Man get my curiosity going and

Inquiring minds need to know

If anyone wants a listing of Samples here it is:

Code: QB64: [Select]

1.  

mboard.bas is for Bob's excellent Monopoly Board which is magnificent, can't say that the dice are any more impressive than here though, and they squeak! LOL!
  [ This attachment cannot be displayed inline in 'Print Page' view ]  

Title: Re: lancio di due dadi
Post by: FellippeHeitor on November 21, 2020, 05:50:02 pm

Love that ASCII board.

Title: Re: lancio di due dadi
Post by: bplus on November 21, 2020, 07:00:41 pm

Well the dado's were embarrassed by Bob's dice ;-))

Code: QB64: [Select]

1. REDIM dice(1 TO 6) 'so we can add them up
2. DO
3.     CLS
4.     WHILE LEN(INKEY$) = 0 ' roll 'em
5.         FOR d = 1 TO 6
6.             dice(d) = randomNumber1to(6)
7.         NEXT
8.         dado 3, dice(1)
9.         dado 16, dice(2)
10.         dado 29, dice(3)
11.         dado 42, dice(4)
12.         dado 55, dice(5)
13.         dado 68, dice(6)
14.         _LIMIT 20 ' CPU was getting worked up, this saves fan
15.     WEND
16.     LOCATE 20, 40: PRINT totalArray(dice())
17.     SLEEP 'pause and wait for key press
18.     _KEYCLEAR 'clear keys so start rolling again
19. LOOP UNTIL _KEYDOWN(27) 'escape key press to quit
20.  
21. SUB dado (column, dots)
22.     COLOR 15, 12
23.     LOCATE 11, column
24.  
25.     PRINT CHR$(218); STRING$(9, 196); CHR$(191);
26.     LOCATE 15, column
27.     PRINT CHR$(192); STRING$(9, 196); CHR$(217);
28.     FOR i = 12 TO 14
29.         LOCATE i, column
30.         PRINT CHR$(179); STRING$(9, 32); CHR$(179);
31.     NEXT i
32.     SELECT CASE dots
33.         CASE 1
34.             LOCATE 13, column + 5: PRINT "*"
35.         CASE 2
36.             LOCATE 12, column + 3: PRINT "*"
37.             LOCATE 14, column + 7: PRINT "*"
38.         CASE 3
39.             LOCATE 12, column + 3: PRINT "*"
40.             LOCATE 13, column + 5: PRINT "*"
41.             LOCATE 14, column + 7: PRINT "*"
42.         CASE 4
43.             LOCATE 12, column + 3: PRINT "*   *"
44.             LOCATE 14, column + 3: PRINT "*   *"
45.         CASE 5
46.             LOCATE 12, column + 3: PRINT "*   *"
47.             LOCATE 13, column + 5: PRINT "*"
48.             LOCATE 14, column + 3: PRINT "*   *"
49.         CASE 6
50.             LOCATE 12, column + 3: PRINT "* * *"
51.             LOCATE 14, column + 3: PRINT "* * *"
52.     END SELECT
53.     COLOR 15, 0
54. END SUB
55.  
56. FUNCTION randomNumber1to (n)
57.     randomNumber1to = INT(RND * n) + 1
58. END FUNCTION
59.  
60. FUNCTION totalArray (array())
61.     FOR i = LBOUND(array) TO UBOUND(array)
62.         totalArray = totalArray + array(i)
63.     NEXT
64. END FUNCTION
65.  
66.  
67.  

Title: Re: lancio di due dadi
Post by: MidnightOwl on November 21, 2020, 07:46:24 pm

The ideal in programming is to avoid reinventing the wheel ie. reusable code.  The function returns dice total and shows just how complicated a function can be.  It can also be adapted to many uses with little alteration (reused) . Which was why I brought  it up in the  first place. Isn't that why there are code libraries?

Title: Re: lancio di due dadi
Post by: bplus on November 21, 2020, 07:52:43 pm

Quote from: MidnightOwl on November 21, 2020, 07:46:24 pm

The ideal in programming is to avoid reinventing the wheel ie. reusable code.  The function returns dice total and shows just how complicated a function can be.  It can also be adapted to many uses with little alteration (reused) . Which was why I brought  it up in the  first place. Isn't that why there are code libraries?

Wait are you saying we should have used this for dice from Monopoly (which is massive! and certainly not meant to be library):

Code: QB64: [Select]

1. FUNCTION RollDICE% (RRow%, CCol%)
2.  
3.     FOR ROLL = 1 TO 24
4.         Row = RRow% + FIX(RND * 2) - 1
5.         Col = CCol% + FIX(RND * 2) - 1
6.         Number1 = FIX(RND * 6) + 1
7.         Number = Number1
8.         GOSUB ShowDIE
9.         GOSUB Sides
10.         Row = RRow% + FIX(RND * 2) - 1
11.         Col = CCol% + 7 + FIX(RND * 2) - 1
12.         Number2 = FIX(RND * 6) + 1
13.         Number = Number2
14.         GOSUB ShowDIE
15.         GOSUB Sides
16.         PLAY "MBT160L64O6b"
17.         FOR Slow = 1 TO 6
18.             WAIT &H3DA, 8
19.             WAIT &H3DA, 8, 8
20.         NEXT Slow
21.     NEXT ROLL
22.     RollDICE% = Number1 + Number2
23.     IF Number1 = Number2 THEN Doubles% = TRUE
24.  
25.     EXIT FUNCTION
26.  
27.     ShowDIE:
28.     COLOR BackCOLOR%
29.     FOR x = Col - 2 TO Col + 4
30.         FOR y = Row - 1 TO Row + 4
31.             LOCATE y, x
32.             PRINT CHR$(219)
33.         NEXT y
34.     NEXT x
35.     COLOR 15, 4
36.     SELECT CASE Number
37.         CASE 1
38.             LOCATE Row, Col: GOSUB NoDOTS
39.             LOCATE Row + 1, Col: GOSUB OneDOT
40.             LOCATE Row + 2, Col: GOSUB NoDOTS
41.             LOCATE
42.         CASE 2
43.             LOCATE Row, Col: GOSUB Dot
44.             FOR Reps = 1 TO 2: GOSUB Blank: NEXT Reps
45.             LOCATE Row + 1, Col: GOSUB NoDOTS
46.             LOCATE Row + 2, Col
47.             FOR Reps = 1 TO 2: GOSUB Blank: NEXT Reps
48.             GOSUB Dot
49.         CASE 3
50.             LOCATE Row, Col: GOSUB Dot
51.             FOR Reps = 1 TO 2: GOSUB Blank: NEXT Reps
52.             LOCATE Row + 1, Col: GOSUB OneDOT
53.             LOCATE Row + 2, Col
54.             FOR Reps = 1 TO 2: GOSUB Blank: NEXT Reps
55.             GOSUB Dot
56.         CASE 4
57.             LOCATE Row, Col: GOSUB TwoDOTS
58.             LOCATE Row + 1, Col: GOSUB NoDOTS
59.             LOCATE Row + 2, Col: GOSUB TwoDOTS
60.         CASE 5
61.             LOCATE Row, Col: GOSUB TwoDOTS
62.             LOCATE Row + 1, Col: GOSUB OneDOT
63.             LOCATE Row + 2, Col: GOSUB TwoDOTS
64.         CASE 6
65.             LOCATE Row, Col: GOSUB TwoDOTS
66.             LOCATE Row + 1, Col: GOSUB TwoDOTS
67.             LOCATE Row + 2, Col: GOSUB TwoDOTS
68.     END SELECT
69.     RETURN
70.  
71.     OneDOT:
72.     GOSUB Blank
73.     GOSUB Dot
74.     GOSUB Blank
75.     RETURN
76.  
77.     TwoDOTS:
78.     GOSUB Dot
79.     GOSUB Blank
80.     GOSUB Dot
81.     RETURN
82.  
83.     NoDOTS:
84.     FOR Reps = 1 TO 3: GOSUB Blank: NEXT Reps
85.     RETURN
86.  
87.     Blank:
88.     PRINT CHR$(32);
89.     RETURN
90.  
91.     Dot:
92.     PRINT CHR$(254);
93.     RETURN
94.  
95.     Sides:
96.     COLOR 4, BackCOLOR%
97.     LOCATE Row, Col - 1: PRINT CHR$(222)
98.     LOCATE Row + 1, Col - 1: PRINT CHR$(222)
99.     LOCATE Row + 2, Col - 1: PRINT CHR$(222)
100.     LOCATE Row, Col + 3: PRINT CHR$(221)
101.     LOCATE Row + 1, Col + 3: PRINT CHR$(221)
102.     LOCATE Row + 2, Col + 3: PRINT CHR$(221)
103.     RETURN
104.  
105. END FUNCTION
106.  

Text Only | Text with Attachments