QB64.org Forum

Active Forums => Programs => Topic started by: SpriggsySpriggs on June 19, 2020, 04:02:43 pm

Title: Recursive Image to MEM
Post by: SpriggsySpriggs on June 19, 2020, 04:02:43 pm

So @Dav , a while back, had made a program that allows you to store a picture as a MEM block in a program to use it as an image handle. I turned it into a GUI conversion program along with his BASIMAGE program. Now this is something a bit different here. I saw that @Ashish had a Github with a program/library called Iconizer with a folder chock full of good icons. I thought it would be cool to make a program that recursively runs the MEM conversion function for every PNG in a directory and write them to .MEM files. The only issue was that they didn't have transparent backgrounds and the way that Dav's code was set up, you couldn't affect the transparency. I changed it up to allow for that. Here is the code for that along with a zip folder of the original PNG files and the MEM files:

Code: QB64: [Select]

1. DEFINT A-Z
2. DECLARE FUNCTION E$ (B$)
3. SHELL "DIR /b " + CHR$(34) + _STARTDIR$ + "\Images\*.png" + CHR$(34) + " > imagelist.txt"
4. F = FREEFILE
5. OPEN "imagelist.txt" FOR BINARY AS F
6. IF LOF(F) = 0 THEN
7.     KILL "imagelist.txt"
8. ELSE
9.     CHDIR "Images\"
10.     PRINT _CWD$
11.     DO
12.         IF NOT EOF(F) THEN
13.             LINE INPUT #F, image$
14.             IN$ = image$
15.             OUT$ = StripDirectory(image$)
16.             OUT$ = MID$(OUT$, 1, _INSTRREV(OUT$, ".png") - 1) + ".MEM"
17.             i& = _LOADIMAGE(IN$, 32):
18.             SCREEN _NEWIMAGE(_WIDTH(i&), _HEIGHT(i&), 32)
19.             _SOURCE i&
20.             _DEST 0
21.             _SETALPHA 0, _RGB32(85, 85, 85) TO _RGB32(255, 255, 255), i&
22.             _PUTIMAGE
23.             DIM m AS _MEM: m = _MEMIMAGE(0)
24.             INDATA$ = SPACE$(m.SIZE)
25.             _MEMGET m, m.OFFSET, INDATA$
26.             INDATA$ = _DEFLATE$(INDATA$)
27.             wid = _WIDTH: hih = _HEIGHT
28.             OPEN OUT$ FOR OUTPUT AS 2
29.             Q$ = CHR$(34) 'quotation mark
30.             inFunc$ = LEFT$(IN$, LEN(IN$) - 4)
31.             FOR i = 32 TO 47
32.                 IF INSTR(inFunc$, CHR$(i)) THEN
33.                     inFunc$ = String.Remove(inFunc$, CHR$(i))
34.                 END IF
35.             NEXT
36.             FOR i = 58 TO 64
37.                 IF INSTR(inFunc$, CHR$(i)) THEN
38.                     inFunc$ = String.Remove(inFunc$, CHR$(i))
39.                 END IF
40.             NEXT
41.             FOR i = 91 TO 96
42.                 IF INSTR(inFunc$, CHR$(i)) THEN
43.                     IF i <> 92 THEN
44.                         inFunc$ = String.Remove(inFunc$, CHR$(i))
45.                     END IF
46.                 END IF
47.             NEXT
48.             PRINT #2, "$IF " + UCASE$(inFunc$) + " = UNDEFINED THEN"
49.             PRINT #2, "$LET " + UCASE$(inFunc$) + " = TRUE"
50.             PRINT #2, "FUNCTION __" + StripDirectory(inFunc$) + "&"
51.             PRINT #2, "DIM v&"
52.             PRINT #2, "DIM A$"
53.             PRINT #2, "DIM btemp$"
54.             PRINT #2, "DIM i&"
55.             PRINT #2, "DIM B$"
56.             PRINT #2, "DIM C%"
57.             PRINT #2, "DIM F$"
58.             PRINT #2, "DIM C$"
59.             PRINT #2, "DIM j"
60.             PRINT #2, "DIM t%"
61.             PRINT #2, "DIM B&"
62.             PRINT #2, "DIM X$"
63.             PRINT #2, "v&=_NEWIMAGE("; wid; ","; hih; ",32)"
64.             PRINT #2, "DIM m AS _MEM:m=_MEMIMAGE(v&)"
65.             PRINT #2, "A$ = "; Q$; Q$
66.             PRINT #2, "A$ = A$ + "; Q$;
67.             BC& = 1
68.             DO
69.                 a$ = MID$(INDATA$, BC&, 3)
70.                 BC& = BC& + 3: LL& = LL& + 4
71.                 IF LL& = 60 THEN
72.                     LL& = 0
73.                     PRINT #2, E$(a$);: PRINT #2, Q$
74.                     PRINT #2, "A$ = A$ + "; Q$;
75.                 ELSE
76.                     PRINT #2, E$(a$);
77.                 END IF
78.                 IF LEN(INDATA$) - BC& < 3 THEN
79.                     a$ = MID$(INDATA$, LEN(INDATA$) - BC&, 1): B$ = E$(a$)
80.                     SELECT CASE LEN(B$)
81.                         CASE 0: a$ = Q$
82.                         CASE 1: a$ = "%%%" + B$ + Q$
83.                         CASE 2: a$ = "%%" + B$ + Q$
84.                         CASE 3: a$ = "%" + B$ + Q$
85.                     END SELECT: PRINT #2, a$;: EXIT DO
86.                 END IF
87.             LOOP: PRINT #2, ""
88.             PRINT #2, "btemp$="; Q$; Q$
89.             PRINT #2, "FOR i&=1TO LEN(A$) STEP 4:B$=MID$(A$,i&,4)"
90.             PRINT #2, "IF INSTR(1,B$,"; Q$; "%"; Q$; ") THEN"
91.             PRINT #2, "FOR C%=1 TO LEN(B$):F$=MID$(B$,C%,1)"
92.             PRINT #2, "IF F$<>"; Q$; "%"; Q$; "THEN C$=C$+F$"
93.             PRINT #2, "NEXT:B$=C$:END IF:FOR j=1 TO LEN(B$)"
94.             PRINT #2, "IF MID$(B$,j,1)="; Q$; "#"; Q$; " THEN"
95.             PRINT #2, "MID$(B$,j)="; Q$; "@"; Q$; ":END IF:NEXT"
96.             PRINT #2, "FOR t%=LEN(B$) TO 1 STEP-1"
97.             PRINT #2, "B&=B&*64+ASC(MID$(B$,t%))-48"
98.             PRINT #2, "NEXT:X$="; Q$; Q$; ":FOR t%=1 TO LEN(B$)-1"
99.             PRINT #2, "X$=X$+CHR$(B& AND 255):B&=B&\256"
100.             PRINT #2, "NEXT:btemp$=btemp$+X$:NEXT"
101.             PRINT #2, "btemp$=_INFLATE$(btemp$)"
102.             PRINT #2, "_MEMPUT m, m.OFFSET, btemp$: _MEMFREE m"
103.             PRINT #2, "__" + inFunc$ + "& = _COPYIMAGE(v&): _FREEIMAGE v&"
104.             PRINT #2, "END FUNCTION"
105.             PRINT #2, "$END IF"
106.             CLOSE #2
107.         END IF
108.     LOOP UNTIL image$ = "" OR EOF(F)
109. END IF
110. SYSTEM
111. FUNCTION E$ (B$)
112.     FOR T% = LEN(B$) TO 1 STEP -1
113.         B& = B& * 256 + ASC(MID$(B$, T%))
114.     NEXT
115.     a$ = ""
116.     FOR T% = 1 TO LEN(B$) + 1
117.         g$ = CHR$(48 + (B& AND 63)): B& = B& \ 64
118.         IF g$ = "@" THEN g$ = "#"
119.         a$ = a$ + g$
120.     NEXT: E$ = a$
121. END FUNCTION
122. FUNCTION StripDirectory$ (OFile$)
123.     DO
124.         OFile$ = RIGHT$(OFile$, LEN(OFile$) - INSTR(OFile$, "\"))
125.     LOOP WHILE INSTR(OFile$, "\")
126.     StripDirectory$ = OFile$
127. END FUNCTION
128. FUNCTION String.Remove$ (a AS STRING, b AS STRING)
129.     DIM c AS STRING
130.     c = ""
131.     j = INSTR(a, b)
132.     IF j > 0 THEN
133.         r$ = LEFT$(a, j - 1) + c + String.Remove(RIGHT$(a, LEN(a) - j + 1 - LEN(b)), b)
134.     ELSE
135.         r$ = a
136.     END IF
137.     String.Remove = r$
138. END FUNCTION
139.  

 [ This attachment cannot be displayed inline in 'Print Page' view ]  

Title: Re: Recursive Image to MEM
Post by: Ashish on June 20, 2020, 12:34:13 am

Oh cool! Nice work.
BTW, I never thought of posting Iconizer library at the forum. I thought it will be hardly useful to anyone

Text Only | Text with Attachments