QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Pete on May 23, 2019, 10:18:02 pm

Title: Anyone know how to make letters with a transparent background?
Post by: Pete on May 23, 2019, 10:18:02 pm

This should not be possible in SCREEN 0, so I was hoping for a graphics solution...

Can the foreground of a character be set to white, and its background be set to transparent? If so, a window with a black background on the top half, and a red background on the bottom half, might be able to have the white letters with a transparent background appear as white on black in the top half of the window, and white on red in the bottom half. I know, we are dealing with two actual layers here, one for the window background itself, and one for the characters, foreground and a transparent background, so I have no idea if this is possible in QB64, but hey, I'm no graphics guru, that's for sure but just to be clear, I know I could set the background of the letters to red or black, but that's not what I'm getting at. I'm thinking more of having a pattern of colors for the window, so it would be fast and easy if the background of the characters were transparent but slow and clumsy if I have to screen read the window color and adjust each character, printing them one at a time.

Thanks,

Pete

Title: Re: Anyone know how to make letters with a transparent background?
Post by: bplus on May 23, 2019, 11:46:12 pm

Easy set background of  COLOR to transparent color:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(512, 512, 32)
2. _TITLE "XOR Magic"
3. COLOR &HFFFFFFFF, &H0 ' white foreground, transparent background
4. i = 16
5. DO
6.     FOR y = 0 TO 512
7.         FOR x = 0 TO 512
8.             PSET (x, y), _RGB(x MOD 256, (x MOD 512 XOR y) MOD 256, y MOD 256)
9.         NEXT
10.     NEXT
11.     _PRINTSTRING (150, i), "Hi Pete!"
12.     _DISPLAY
13.     _LIMIT 60
14.     i = i + 1
15.     IF i > 496 THEN i = 16
16. LOOP
17.  
18.  

Title: Re: Anyone know how to make letters with a transparent background?
Post by: bplus on May 23, 2019, 11:56:19 pm

Print in transparent!

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(512, 512, 32)
2. _TITLE "XOR Magic"
3. COLOR &H0, &HFFFF0000 ' transparent foreground
4. i = 16
5. DO
6.     FOR y = 0 TO 512
7.         FOR x = 0 TO 512
8.             PSET (x, y), _RGB(x MOD 256, (x MOD 512 XOR y) MOD 256, y MOD 256)
9.         NEXT
10.     NEXT
11.     _PRINTSTRING (150, i), "  Hi Pete!  "
12.     _DISPLAY
13.     _LIMIT 60
14.     i = i + 1
15.     IF i > 496 THEN i = 16
16. LOOP
17.  
18.  

Title: Re: Anyone know how to make letters with a transparent background?
Post by: Petr on May 24, 2019, 01:14:53 am

Code: QB64: [Select]

1.  
2. SCREEN _NEWIMAGE(640, 480, 32)
3.  
4. stp = 255 / 639
5. FOR l = 0 TO 639
6.     LINE (l, 0)-(l, 479), _RGB32(clr, clr, 255 - stp)
7.     clr = clr + stp
8. NEXT
9.  
10. _PRINTMODE _KEEPBACKGROUND
11. COLOR _RGB32(0, 0, 0)
12. _PRINTSTRING (180, 240), "Is _PRINTMODE, what Pete search?"
13.  
14.  

Title: Re: Anyone know how to make letters with a transparent background?
Post by: SMcNeill on May 24, 2019, 01:33:35 am

And you can also play around with custom routines like a few of my old print utilities: http://qb64.freeforums.net/thread/37/custom-routines-supports-textures-shading

Not only can you print transparent backgrounds, you can do oh so much more...

Title: Re: Anyone know how to make letters with a transparent background?
Post by: Pete on May 24, 2019, 02:17:06 am

Wow lots of responses. I'm only working on the first one so far, but I'll show you what I have so far...

Code: QB64: [Select]

1. CONST HWND_TOPMOST%& = -1
2. CONST SWP_NOSIZE%& = &H1
3. CONST SWP_NOMOVE%& = &H2
4. CONST SWP_SHOWWINDOW%& = &H40
5.  
6. DECLARE DYNAMIC LIBRARY "User32"
7.     FUNCTION GetWindowLongA& (BYVAL hwnd AS LONG, BYVAL nIndex AS LONG)
8.     FUNCTION SetWindowPos& (BYVAL hWnd AS LONG, BYVAL hWndInsertAfter AS _OFFSET, BYVAL X AS INTEGER, BYVAL Y AS INTEGER, BYVAL cx AS INTEGER, BYVAL cy AS INTEGER, BYVAL uFlags AS _OFFSET)
9.     FUNCTION SetWindowLongA& (BYVAL hwnd AS LONG, BYVAL nIndex AS LONG, BYVAL dwNewLong AS LONG)
10.     FUNCTION GetForegroundWindow&
11.     FUNCTION SetLayeredWindowAttributes& (BYVAL hwnd AS LONG, BYVAL crKey AS LONG, BYVAL bAlpha AS _UNSIGNED _BYTE, BYVAL dwFlags AS LONG)
12. END DECLARE
13. SCREEN _NEWIMAGE(600, 480, 32)
14. GWL_STYLE = -16
15. ws_border = &H800000
16. WS_VISIBLE = &H10000000
17. _TITLE "Borderless Window"
18. DIM hwnd AS LONG
19. hwnd = _WINDOWHANDLE
20. _DELAY .1
21. Level = 175
22. SetWindowOpacity hwnd, Level
23.  
24. winstyle2& = GetWindowLongA&(hwnd, GWL_STYLE)
25. winstyle& = -12582913
26. a& = SetWindowLongA&(hwnd, GWL_STYLE, winstyle& AND WS_VISIBLE) ' AND NOT WS_VSCROLL) ' AND NOT ws_border)
27. a& = SetWindowPos&(hwnd, 0, 0, 0, 0, 0, 39)
28. msg$ = "Welcome to Translucent Windows Without Borders!"
29. i = 16
30. COLOR &HFFFFFFFF, &H0 ' white foreground, transparent background
31. DO
32.     _LIMIT 60
33.     FGwin& = GetForegroundWindow&
34.     IF hwnd <> FGwin& THEN ' QB64 no longer in focus.
35.         WHILE _MOUSEINPUT: WEND
36.         a& = SetWindowPos&(hwnd, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOMOVE + SWP_NOSIZE + SWP_SHOWWINDOW)
37.         DO: _LIMIT 30: LOOP UNTIL hwnd = GetForegroundWindow&
38.     END IF
39.     IF INKEY$ = CHR$(27) THEN EXIT DO
40.     FOR y = 480 TO 0 STEP -1
41.         FOR x = 640 TO 0 STEP -1
42.             PSET (x, 480 - y), _RGB(y / 2 MOD 256, 100, 200) ' (x MOD 512 XOR y) MOD 256, y MOD 256)
43.         NEXT
44.     NEXT
45.     _PRINTSTRING (92, 1), msg$
46.     _PRINTSTRING (1, 464), "Press Esc to quit."
47.     _PRINTSTRING (250, i), "Hi Chez-Pete!"
48.     _DISPLAY
49.     i = i + 1
50.     IF i > 464 THEN i = 16
51. LOOP
52. SYSTEM
53.  
54. SUB SetWindowOpacity (hwnd AS LONG, Level)
55. DIM Msg AS LONG
56. CONST G = -20
57. CONST LWA_ALPHA = &H2
58. CONST WS_EX_LAYERED = &H80000
59. Msg = GetWindowLongA&(hwnd, G)
60. Msg = Msg OR WS_EX_LAYERED
61. action = SetWindowLongA&(hwnd, G, Msg)
62. action = SetLayeredWindowAttributes(hwnd, 0, Level, LWA_ALPHA)
63. END SUB
64.  

I'm going to try to get some sleep now. I've been up too many days with a sick cat. My Son is taking finals this week, so I'm going to tough it out until he has his college stuff wrapped up. Thanks to all three of you for the interest in this topic. I'll look into Mark and Steve's post tomorrow. Also, if I stick with the color gradient, I would imagine that could be done faster with a _PRINTSTRING statement, to print across the width of the screen, instead of pixel by pixel.

Pete

Title: Re: Anyone know how to make letters with a transparent background?
Post by: johnno56 on May 24, 2019, 10:14:01 am

Oh nuts.  I get a 'DYNAMIC LIBRARY not found on line 6"

Would I be correct in assuming that this might be a reaction to a 64 bit Linux OS?

I changed nothing. Just copy / paste... Maybe it's the way I hold the Mouse?  lol

Title: Re: Anyone know how to make letters with a transparent background?
Post by: Pete on May 24, 2019, 11:00:38 am

Right. The code uses Windows Libraries. Sorry, I should have put that in the post. I have no idea if there would be a way to do this in Linux.

Pete

Title: Re: Anyone know how to make letters with a transparent background?
Post by: Pete on May 24, 2019, 11:52:16 am

@Mark: Ah, thanks for showing reverse transparency. That will come in handy for highlighting!

@ Steve: I'm following the link you posted now...

@Petr: Yes! _PRINTMODE is more what I was hoping for, thank you! Also _KEEPBACKGROUND. I modified the code to how I would use it, below...

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2.  
3. stp = 255 / 479
4. clr = 255
5. FOR l = 0 TO 479
6.     LINE (639, l)-(0, l), _RGB32(clr, clr, 255)
7.     clr = clr - stp
8. NEXT
9.  
10. _PRINTMODE _KEEPBACKGROUND
11. COLOR _RGB32(0, 0, 0)
12. _PRINTSTRING (180, 240), "_PRINTMODE, is what Pete was searching for!"
13.  
14. SLEEP
15.  

Now I need to go learn colors. Eventually, I want to get a white to yellow to orange blend.

Pete

Title: Re: Anyone know how to make letters with a transparent background?
Post by: SMcNeill on May 24, 2019, 12:41:24 pm

You can also easily use 0 alpha colors...

SCREEN _NEWIMAGE(640,480,32)
CLS &HFFAA0000 ‘red background
COLOR ,0 ‘notice the comma
PRINT “Hello World, transparent background”


It’s that simple.

Title: Re: Anyone know how to make letters with a transparent background?
Post by: bplus on May 24, 2019, 01:22:22 pm

Quote

Eventually, I want to get a white to yellow to orange blend.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2.  
3. FOR l = 0 TO 213
4.     midInk 255, 255, 255, 255, 255, 0, l / 214
5.     LINE (639, l)-(0, l)
6.  
7.     midInk 255, 255, 0, 255, 100, 0, l / 214
8.     LINE (639, l + 214)-(0, l + 214)
9.  
10.     midInk 255, 100, 0, 60, 25, 0, l / 214
11.     LINE (639, l + 428)-(0, l + 428)
12.  
13. NEXT
14.  
15. _PRINTMODE _KEEPBACKGROUND
16. COLOR _RGB32(0, 0, 0)
17. s$ = "_PRINTMODE, is what Pete was searching for!"
18. _PRINTSTRING ((_WIDTH - LEN(s$) * 8) / 2, 232), s$
19.  
20. SLEEP
21.  
22. SUB midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
23.     COLOR _RGB32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
24. END SUB
25.  
26.  

Title: Re: Anyone know how to make letters with a transparent background?
Post by: Pete on May 24, 2019, 01:54:28 pm

You guys are too fast for me. Remember what Qwerkey said, I'm old and I'm grumpy!

OK, I'll post this first, and then I'll take a look at Steve's alpha example and BP's blend. I was able to figure out the colors for yellow and orange. It was a single operation to blend near white to yellow, so I went with that in the example below. I'm pretty happy with the results!

Code: QB64: [Select]

1. wdt = 640: hgt = 480
2.  
3. SCREEN _NEWIMAGE(wdt, hgt, 32)
4.  
5. stp = 255 / (hgt - 1)
6. clr = 255
7. FOR l = 0 TO (hgt - 1)
8.     LINE ((wdt - 1), l)-(0, l), _RGB32(clr, clr, 204 - xlr)
9.     xlr = xlr + stp / 2
10. NEXT
11. _PRINTMODE _KEEPBACKGROUND
12. COLOR _RGB32(0, 0, 0)
13.  
14. LOCATE 1, 1
15. FOR i = 1 TO wdt / 8 * (hgt - 16) / 16
16.     DO
17.         x = INT(RND * 30) + 1
18.         IF x > 26 THEN
19.             x = -64: IF flag = 0 THEN flag = -1: EXIT DO
20.         ELSE
21.             flag = 0: EXIT DO
22.         END IF
23.     LOOP
24.     a$ = CHR$(96 + x)
25.     x$ = x$ + a$
26. NEXT
27.  
28. REDIM q$(hgt \ 16)
29. m = 1
30. DO
31.     q$ = MID$(x$, m, wdt \ 8)
32.     i = _INSTRREV(q$, " ")
33.     IF i = 0 THEN m = m + wdt \ 8 ELSE m = m + i
34.     q$ = MID$(q$, 1, i)
35.     j = 0: xq$ = q$
36.     DO
37.         j = j + 1
38.         z$ = MID$(x$, m, j)
39.         IF z$ <> " " THEN EXIT DO
40.         xq$ = xq$ + z$
41.         m = m + 1
42.     LOOP
43.     cnt = cnt + 1
44.     q$(cnt) = xq$
45.     PRINT MID$(q$(cnt), 1, wdt \ 8);
46.     IF cnt = hgt \ 16 - 1 THEN EXIT DO
47. LOOP
48. SLEEP
49.  

@BPlus: OK, Mark, that's pretty impressive. A bit above my pay grade for now, but I'll get the hang of it in time. Thanks!!!

@Steve: I had to tweak your code a bit to get it to work to...

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. COLOR , &HFFAA0000 'red background
3. CLS
4. COLOR , 0 'notice the comma
5. PRINT "Hello World, transparent background!"
6. SLEEP

I was expecting to see black text on red, but it turned out to be bright white. I don't see foreground defined anywhere in the code, so huh???

Pete

Title: Re: Anyone know how to make letters with a transparent background?
Post by: Petr on May 24, 2019, 02:31:49 pm

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. COLOR , &HFFAA0000 'red background
3. CLS
4. COLOR &HFF000000, 0 'notice the comma
5. PRINT "Hello World, transparent background!"
6. SLEEP
7.  

Black text and transparent background

If you write COLOR &HFF000000 is the same as COLOR _RGBA32(0,0,0,255), with "&H" is it in this order: ALPHA, RED, GREEN, BLUE.

Title: Re: Anyone know how to make letters with a transparent background?
Post by: SMcNeill on May 24, 2019, 02:44:02 pm

Quote from: Pete on May 24, 2019, 01:54:28 pm

@Steve: I had to tweak your code a bit to get it to work to...

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. COLOR , &HFFAA0000 'red background
3. CLS
4. COLOR , 0 'notice the comma
5. PRINT "Hello World, transparent background!"
6. SLEEP

I was expecting to see black text on red, but it turned out to be bright white. I don't see foreground defined anywhere in the code, so huh???

Pete

If you don’t change the foreground color any, it defaults to white.  Think of the normal screen — white text on black background.

All we used the COLOR statement for, was to change the background:

COLOR , 0

No foreground change was made, so it stayed white.  The background became color 0 — which is 0 red, 0 Green, 0 Blue, 0 alpha, in 32-bit color values.  0 alpha is full transparency, so it’s just default white with no background, which we printed.

Title: Re: Anyone know how to make letters with a transparent background?
Post by: Jack002 on May 24, 2019, 03:51:45 pm

COLOR 0,0 can really cut down on typos.

My tip of the day

Title: Re: Anyone know how to make letters with a transparent background?
Post by: Petr on May 24, 2019, 05:01:16 pm

Quote

COLOR 0,0 can really cut down on typos.

This is Braill mode  :-D

Title: Re: Anyone know how to make letters with a transparent background?
Post by: Pete on May 24, 2019, 05:14:59 pm

Code: QB64: [Select]

1.    

Title: Re: Anyone know how to make letters with a transparent background?
Post by: Pete on May 24, 2019, 07:16:04 pm

Well, that's the last time I take a "Tip of the Day" from Jack. Anyway, Here's Marks white-yellow-orange blend in a scallable version, meaning you can change the screen width and height variables, wdt and hgt, as desired.

Code: QB64: [Select]

1. wdt = 340
2. hgt = 580
3. SCREEN _NEWIMAGE(wdt, hgt, 32)
4. _SCREENMOVE 500, 100
5. FOR l = 0 TO hgt * .45
6.     midInk 255, 255, 255, 255, 255, 0, l / (hgt * .45)
7.     LINE (wdt - 1, l)-(0, l)
8.  
9.     midInk 255, 255, 0, 255, 100, 0, l / (hgt * .45)
10.     LINE (wdt - 1, l + hgt * .45 + 0)-(0, l + hgt * .45 + 0)
11.  
12.     midInk 255, 100, 0, 60, 25, 0, l / (hgt * .45)
13.     LINE (wdt - 1, l + (hgt * .45 + 0) * 2)-(0, l + (hgt * .45 + 0) * 2)
14. NEXT
15.  
16. _PRINTMODE _KEEPBACKGROUND
17.  
18. CALL getparagraph(wdt, hgt, x$)
19. COLOR _RGB32(0, 0, 0)
20. ' Center with: _PRINTSTRING ((_WIDTH - LEN(s$) * 8) / 2, 232), s$
21. LOCATE 1, 1
22. REDIM q$(hgt \ 16)
23. m = 1
24. DO
25.     q$ = MID$(x$, m, wdt \ 8)
26.     i = _INSTRREV(q$, " ")
27.     IF i = 0 THEN m = m + wdt \ 8 ELSE m = m + i
28.     q$ = MID$(q$, 1, i)
29.     j = 0: xq$ = q$
30.     DO
31.         j = j + 1
32.         z$ = MID$(x$, m, j)
33.         IF z$ <> " " THEN EXIT DO
34.         xq$ = xq$ + z$
35.         m = m + 1
36.     LOOP
37.     cnt = cnt + 1
38.     q$(cnt) = xq$
39.     PRINT MID$(q$(cnt), 1, wdt \ 8);
40.     IF cnt = hgt \ 16 - 1 THEN EXIT DO
41. LOOP
42. SLEEP
43. SYSTEM
44.  
45. SUB midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
46. COLOR _RGB32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
47. END SUB
48.  
49. SUB getparagraph (wdt, hgt, x$)
50. FOR i = 1 TO wdt / 8 * (hgt - 16) / 16
51.     DO
52.         x = INT(RND * 30) + 1
53.         IF x > 26 THEN
54.             x = -64: IF flag = 0 THEN flag = -1: EXIT DO
55.         ELSE
56.             flag = 0: EXIT DO
57.         END IF
58.     LOOP
59.     a$ = CHR$(96 + x)
60.     x$ = x$ + a$
61. NEXT
62. END SUB
63.  

Pete

Title: Re: Anyone know how to make letters with a transparent background?
Post by: bplus on May 24, 2019, 10:11:49 pm

Make things more interesting, change width and height with p (plus) m (minus) keypress, PLUS some Braille:

Code: QB64: [Select]

1. _TITLE "Try keypress m or p..."
2. wdt = 800
3. hgt = 600
4. SCREEN _NEWIMAGE(wdt, hgt, 32)
5. _SCREENMOVE 500, 100
6. p = 4
7. DO
8.     k$ = INKEY$
9.     IF k$ = "p" THEN
10.         IF p < 64 THEN p = p * 2 ELSE p = 2
11.         wdt = wdt + 5: hgt = hgt + 5
12.     ELSEIF k$ = "m" THEN
13.         IF p > 2 THEN p = p / 2 ELSE p = 64
14.         wdt = wdt - 5: hgt = hgt - 5
15.     END IF
16.     SCREEN _NEWIMAGE(wdt, hgt, 32)
17.     COLOR 15, 0
18.     CLS
19.  
20.     FOR l = 0 TO hgt * .3333
21.         midInk 255, 255, 255, 255, 255, 0, l / (hgt * .3333)
22.         LINE (wdt - 1, l)-(0, l), , BF
23.  
24.         midInk 255, 255, 0, 255, 100, 0, l / (hgt * .3333)
25.         LINE (wdt - 1, l + hgt * .3333 + 0)-(0, l + hgt * .3333 + 0), , BF
26.  
27.         midInk 255, 100, 0, 60, 25, 0, l / (hgt * .3333)
28.         LINE (wdt - 1, l + (hgt * .3333 + 0) * 2)-(0, l + (hgt * .3333 + 0) * 2), , BF
29.     NEXT
30.     COLOR &HFFFFFF00
31.     FOR y = 0 TO hgt STEP p
32.         FOR x = 0 TO wdt STEP p
33.             IF y MOD 2 * p = 0 THEN
34.                 IF x MOD 2 * p = 0 THEN
35.                     CIRCLE (x, y), 1
36.                     PSET (x, y)
37.                 END IF
38.             ELSEIF y MOD 2 * p = p THEN
39.                 IF x MOD 2 * p = p THEN
40.                     CIRCLE (x, y), 1
41.                     PSET (x, y)
42.                 END IF
43.             END IF
44.         NEXT
45.     NEXT
46.  
47.  
48.     _PRINTMODE _KEEPBACKGROUND
49.  
50.     CALL getparagraph(wdt, hgt, x$)
51.     COLOR _RGB32(0, 0, 0)
52.     ' Center with: _PRINTSTRING ((_WIDTH - LEN(s$) * 8) / 2, 232), s$
53.     LOCATE 1, 1
54.     REDIM q$(hgt \ 16)
55.     m = 1: cnt = 0
56.     DO
57.         q$ = MID$(x$, m, wdt \ 8)
58.         i = _INSTRREV(q$, " ")
59.         IF i = 0 THEN m = m + wdt \ 8 ELSE m = m + i
60.         q$ = MID$(q$, 1, i)
61.         j = 0: xq$ = q$
62.         DO
63.             j = j + 1
64.             z$ = MID$(x$, m, j)
65.             IF z$ <> " " THEN EXIT DO
66.             xq$ = xq$ + z$
67.             m = m + 1
68.         LOOP
69.         cnt = cnt + 1
70.         q$(cnt) = xq$
71.         PRINT MID$(q$(cnt), 1, wdt \ 8);
72.         IF cnt = hgt \ 16 - 1 THEN EXIT DO
73.     LOOP
74.     _DISPLAY
75.     _LIMIT 60
76.  
77. LOOP
78. SLEEP
79. SYSTEM
80.  
81. SUB midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
82.     COLOR _RGB32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
83. END SUB
84.  
85. SUB getparagraph (wdt, hgt, x$)
86.     FOR i = 1 TO wdt / 8 * (hgt - 16) / 16
87.         DO
88.             x = INT(RND * 30) + 1
89.             IF x > 26 THEN
90.                 x = -64: IF flag = 0 THEN flag = -1: EXIT DO
91.             ELSE
92.                 flag = 0: EXIT DO
93.             END IF
94.         LOOP
95.         a$ = CHR$(96 + x)
96.         x$ = x$ + a$
97.     NEXT
98. END SUB
99.  
100.  

EDIT: fix Pete's midInk Math

Text Only | Text with Attachments