Increase array with spacebar? [Solved]

[40wattstudio]

Hi everyone!

I'm new to this forum but not to Qbasic. That being said, there's been something that I've been trying to figure out for a while now and haven't made much progress.

Basically, I'm trying to make a traditional top-down shooter where the spacebar is the fire key.
I can make the spacebar fire one unique shot, but what I can't for the life of me figure out is how to get it to fire X amount of *unique* shots. (By unique I mean that each shot has its own Y coordinate so it can be tracked separately for the hit detection).

The way I understand it is like this:
When the player hasn't done anything (like pressed the spacebar to fire a shot), the array used to hold the shots is empty or 0 because nothing has happened. Then when the player presses or holds down the spacebar, the array should increase by 1, generating new coordinates for each unique shot.

Is it possible to start with an empty array and increase by one? Or am I going about this the wrong way entirely?

[FellippeHeitor]

Hello 40wattstudio and welcome to the forum.

You're looking for REDIM. You can start an empty array:

Code: QB64: [Select]

1. REDIM myarray(0) AS LONG

then you can increase it as needed:

Code: QB64: [Select]

1. REDIM _PRESERVE myarray(UBOUND(myarray) + 1) AS LONG

Beware the the increase/decrease of an array is a memory consuming task, so it's better to increase it by a larger amount, when needed:

Code: QB64: [Select]

1. REDIM _PRESERVE myarray(UBOUND(myarray) + 100) AS LONG

Maybe you'd be better off with a large array at start, but with an index to track which items have been used, this way you won't have to REDIM it as often.

Click the keywords in the code boxes above to jump the the wiki article on them.

[40wattstudio]

Hi Fellippe, thanks for the quick response!

I had tried the REDIM before, but that was my very first time using it so I was probably missing something. I definitely don't remember using 2 sets of () in the redimmed array.

It sounds like REDIM can be used inside a subroutine, but can the newly dimensioned array be identified by other subs?
For example, I have  a "hitdetection" sub that needs to cycle through the array of newly generated shots created by the "fireshot" sub.

[FellippeHeitor]

You can REDIM SHARED in the main module, so the array will be visible across subs and functions.

[bplus]

Hi 40 watts,

You could limit the amount of bullets to nBullets and just track if they are active of not.
When you press spacebar the code scans for nonactive bullet and activates it.
Deactivate bullets as they hit something or leave the screen.

Do you know about TYPE's?

You can setup a Bullet Type and track all you need to know about each

Code: QB64: [Select]

1. TYPE bullet
2.     x AS INTEGER
3.     y AS INTEGER
4.     dx AS SINGLE 'change along x-axis
5.     dy AS SINGLE 'change along y axis
6.     active AS INTEGER ' 0 false, -1 or track how long active
7. END TYPE
8.  
9. Dim shared nBullets = 10  'or make constant
10.  
11. DIM SHARED Bullets(1 TO nBullets) AS bullet
12.  
13. FOR i = 1 TO nBullets
14.     'bullets(i).x, bullets(i).y  >>> bullet position  for drawing it
15.     Bullets(i).x = Bullets(i).x + Bullets(i).dx 'update position on x axis
16.  
17.     IF Bullets(i).x < 0 THEN 'bullet off screen deactivate
18.         Bullets(i).active = 0
19.     END IF
20.     'and so on...
21. NEXT i
22.  

If all bullets are active when you press spacebar, hear click sound because you just fired a blank ;-))

[Petr]

My version - in text mode, for maximal 23 bullets.

Code: QB64: [Select]

1. 'shoot demo - press spacebar for shoot.
2.  
3. TYPE fire
4.     x AS INTEGER
5.     y AS INTEGER
6. END TYPE
7.  
8. REDIM fire(1 TO 23) AS fire '23 rows
9.  
10. SCREEN 0
11. x = _WIDTH / 2
12. y = 0
13.  
14.  
15. DO
16.     CLS
17.     WHILE _KEYDOWN(32)
18.         s = 1
19.         DO UNTIL fire(s).y = 0 OR s > 22: s = s + 1: LOOP
20.         fire(s).y = 1
21.         EXIT WHILE
22.     WEND
23.  
24.     FOR s = 1 TO 23
25.         IF fire(s).y THEN
26.             fire(s).y = fire(s).y + 1
27.             IF fire(s).y > 23 THEN fire(s).y = 0
28.             IF fire(s).y THEN LOCATE fire(s).y, x: PRINT "*"
29.         END IF
30.     NEXT
31.     _LIMIT 25
32. LOOP
33.  

Press (and try hold) spacebar.

[40wattstudio]

Hi bplus and Petr,

Definitely some good suggestions there!

I've been using TYPE's like crazy after I learned how to use them in a School Freeware Qbasic tutorial series.

I'll let you know how it turns out after I get a chance to play around with the code examples.
Thanks!

[TerryRitchie]

You don't need to use REDIM to keep track of bullets. Below is a crude demo showing how you can keep track of 5 bullets on the screen. Change the CONST MAXBULLETS = line to 10 or 15 and control more bullets.

Code: QB64: [Select]

1. CONST FALSE = 0, TRUE = NOT FALSE
2.  
3. CONST MAXBULLETS = 5
4.  
5. TYPE BULLET
6.     x AS INTEGER '        X location of bullet
7.     y AS INTEGER '        Y location of bullet
8.     active AS _BYTE '     TRUE if bullet currently ascending
9. END TYPE
10.  
11. DIM ShipX AS INTEGER '    X location of ship
12. DIM shot AS INTEGER '     bullet counter
13. DIM KeyWait AS INTEGER '  time to wait between shots fired
14.  
15. DIM Bullet(MAXBULLETS - 1) AS BULLET ' bullets
16.  
17. SCREEN _NEWIMAGE(640, 480, 32) '                                        create window
18. CLS
19. ShipX = 319 '                                                           X start location of ship (center)
20.  
21. DO '                                                                    main loop
22.     _LIMIT 60 '                                                         60 frames per second
23.     CLS
24.     PRINT '                                                             print instructions
25.     PRINT " RIGHT/LEFT ARROW KEYS TO MOVE"
26.     PRINT " SPACEBAR TO FIRE"
27.     PRINT " ESC TO EXIT"
28.     shot = 0
29.     DO '                                                                cycle through all 5 bullets
30.         IF Bullet(shot).active THEN '                                   is this bullet active?
31.             Bullet(shot).y = Bullet(shot).y - 5 '                       yes, decrement Y location
32.             IF Bullet(shot).y < 0 THEN '                                leave top of screen?
33.                 Bullet(shot).active = FALSE '                           yes, this bullet no longer active
34.             ELSE '                                                      no, bullet still on screen
35.                 LINE (Bullet(shot).x - 2, Bullet(shot).y)-(Bullet(shot).x + 2, Bullet(shot).y + 4), _RGB32(0, 255, 0), BF
36.             END IF
37.         END IF
38.         shot = shot + 1
39.     LOOP UNTIL shot = MAXBULLETS
40.     IF _KEYDOWN(19200) THEN '                                           LEFT ARROW key?
41.         ShipX = ShipX - 2 '                                             yes, move ship to left
42.         IF ShipX < 20 THEN ShipX = 20 '                                 stop motion if too far
43.     END IF
44.     IF _KEYDOWN(19712) THEN '                                           RIGHT ARROW key?
45.         ShipX = ShipX + 2 '                                             yes, move ship to right
46.         IF ShipX > 620 THEN ShipX = 620 '                               stop motion if too far
47.     END IF
48.     IF _KEYDOWN(32) AND KeyWait = 0 THEN '                              SPACEBAR pressed and wait timer exhausted?
49.         shot = 0
50.         DO '                                                            yes, cycle through all 5 bullets
51.             IF NOT Bullet(shot).active THEN '                           is this bullet active?
52.                 Bullet(shot).active = TRUE '                            no, it is now
53.                 Bullet(shot).x = ShipX '                                set X location of bullet
54.                 Bullet(shot).y = 453 '                                  set Y location of bullet
55.                 KeyWait = 5 '                                           wait 5 frames until next shot allowed
56.                 EXIT DO
57.             END IF
58.             shot = shot + 1
59.         LOOP UNTIL shot = MAXBULLETS
60.     END IF
61.     IF KeyWait THEN KeyWait = KeyWait - 1 '                             decrement key wait counter
62.     LINE (ShipX - 20, 455)-(ShipX + 20, 475), _RGB32(0, 255, 0), BF '   draw ship
63.     LINE (ShipX - 2, 450)-(ShipX + 2, 454), _RGB32(0, 255, 0), BF '     draw gun stack
64.     _DISPLAY '                                                          update window with changes
65. LOOP UNTIL _KEYDOWN(27) '                                               leave when ESC pressed
66. SYSTEM

[MasterGy]

I also made a version, I want to show the importance of systematization. be a large array and have lots of indexes, you can give infinite properties to 1 actor later. it is important to say from experience that the way i made the poppy game was that it was easy to add different features per character.

A,D move, SPACE shot

Code: QB64: [Select]

1. maxballs = 999
2. DIM balls(maxballs - 1, 5): 'big array, unnecessary save memory, it is worth listing all the characteristics of 1 bullet per index
3. '0-active
4. '1-X position
5. '2-Y position
6. '3-color
7. '4-speed
8. '5-letter-character
9.  
10. sc = _NEWIMAGE(640, 480, 32): SCREEN sc
11.  
12. meX = 40: meY = 1 'my coordinates
13. shotspeed_rate = 1 'universal shotspeed rate
14. randshotspeed = 1 '0=same shot speed 1=different shot speed
15.  
16. REM ----------------------------------------------------------------------
17.  
18. DO: _LIMIT 30
19.     IF _KEYDOWN(100) THEN meX = meX + 1 'move left
20.     IF _KEYDOWN(97) THEN meX = meX - 1 'move right
21.     IF _KEYDOWN(32) THEN GOSUB createnewshot 'create new shot
22.  
23.     IF meX < 1 THEN meX = 1
24.     IF meX > 79 THEN meX = 80
25.     GOSUB shotmanager 'calculating balls coordinates
26.  
27.     CLS: LOCATE meY, meX: PRINT "X"; 'draw me
28.     FOR actualindex = 0 TO maxballs - 1 'draw balls
29.         IF balls(actualindex, 0) THEN 'draw ball ,if active
30.             LOCATE balls(actualindex, 2), balls(actualindex, 1) 'set coordinates
31.             COLOR balls(actualindex, 3) 'set color
32.             PRINT CHR$(balls(actualindex, 5)) 'draw character
33.         END IF
34.     NEXT actualindex
35.  
36. LOOP
37.  
38. createnewshot:
39. FOR freeindex = 0 TO maxballs - 1
40.     IF balls(freeindex, 0) = 0 THEN GOTO findfreeindex
41. NEXT freeindex: RETURN 'no free index, no new shot
42. findfreeindex: 'free area index is 'index'
43. balls(freeindex, 0) = 1 'index is active
44. balls(freeindex, 1) = meX 'set X position is ME position
45. balls(freeindex, 2) = 2 'set start Y position
46. balls(freeindex, 3) = _RGB32(256 * RND, 256 * RND, 256 * RND)
47. balls(freeindex, 4) = 1 + randshotspeed * RND(1)
48. balls(freeindex, 5) = 65 + INT(27 * RND(1))
49. RETURN
50.  
51. shotmanager:
52. FOR actualindex = 0 TO maxballs - 1
53.     IF balls(actualindex, 0) THEN 'move shot when activated
54.         balls(actualindex, 2) = balls(actualindex, 2) + balls(actualindex, 4) * shotspeed_rate 'move ball own speed
55.         IF balls(actualindex, 2) > 29 THEN balls(actualindex, 0) = 0 'deactived if way end
56.     END IF
57. NEXT actualindex
58. RETURN
59.  
60.  
61.  
62.  
63.  

[40wattstudio]

Finally got to try out the different sample programs this afternoon. Wow, there sure are a lot of creative ways to do the same basic effect!
Petr: I like the simplicity of yours. Looks very good for Screen 0!
TerryRitchie: Yours was closest to what I needed (having your shots relative to a player ship definitely helped!)
MasterGy: Ah ha! So that's how they make those Matrix screensavers!

Here's what I came up with after I integrated everything:

Code: QB64: [Select]

1. CONST FALSE = 0, TRUE = NOT FALSE
2. CONST maxshots = 20
3.  
4. TYPE PLAYER
5.     PIC AS LONG
6.     HEIGHT AS INTEGER
7.     WIDTH AS INTEGER
8.     MIDX AS INTEGER
9.     MIDY AS INTEGER
10.     X AS INTEGER
11.     Y AS INTEGER
12.     SPEED AS INTEGER
13. END TYPE
14.  
15. TYPE WINDOW
16.     PIC AS LONG
17.     WIDTH AS INTEGER
18.     HEIGHT AS INTEGER
19.     COLORS AS INTEGER
20.     MIDX AS INTEGER
21.     MIDY AS INTEGER
22.     TOP AS INTEGER
23.     BOTTOM AS INTEGER
24.     RIGHT AS INTEGER
25.     LEFT AS INTEGER
26. END TYPE
27.  
28. TYPE SHOT
29.     PIC AS LONG
30.     HEIGHT AS INTEGER
31.     WIDTH AS INTEGER
32.     MIDX AS INTEGER
33.     MIDY AS INTEGER
34.     X AS INTEGER
35.     Y AS INTEGER
36.     SPEED AS INTEGER
37.     ACTIVE AS _BYTE
38. END TYPE
39.  
40. DIM SHARED numshots AS INTEGER
41. DIM SHARED keydelay AS INTEGER
42. DIM SHARED shot(maxshots - 1) AS SHOT
43. DIM SHARED player AS PLAYER
44. DIM SHARED win AS WINDOW
45.  
46. '                                                            ==== START HERE ===
47. newscreen
48. DO
49.     IF _KEYDOWN(32) THEN '  - SPACEBAR
50.  
51.         basicsettings
52.         level1
53.  
54.     END IF
55. LOOP UNTIL _KEYDOWN(27)
56. SYSTEM
57.  
58. SUB basicsettings '========================================================SUB BASIC SETTINGS
59.  
60.     win.MIDX = win.WIDTH / 2
61.     win.MIDY = win.HEIGHT / 2
62.     win.TOP = 0
63.     win.BOTTOM = win.HEIGHT
64.     win.LEFT = 0
65.     win.RIGHT = win.WIDTH
66.  
67.     player.PIC = _LOADIMAGE("SCRAPSHIP\gfx\playerTEST.png") 'Add path to PNG file here. This is one is 60x60
68.     player.WIDTH = 60
69.     player.HEIGHT = 60
70.     player.MIDX = player.WIDTH / 2
71.     player.MIDY = player.HEIGHT / 2
72.     player.X = win.MIDX - player.MIDX
73.     player.Y = win.MIDY - player.MIDY
74.     player.SPEED = 2
75.  
76. END SUB
77.  
78. SUB level1 '=============================================================SUB LEVEL 1
79.  
80.     newscreen
81.     DO
82.         PCOPY _DISPLAY, 1
83.         moveplayer
84.         fireshot
85.  
86.         _DISPLAY
87.         PCOPY 1, _DISPLAY
88.     LOOP UNTIL _KEYDOWN(27)
89.     SYSTEM
90.  
91. END SUB
92.  
93. SUB fireshot '======================================================== SUB SET SHOT
94.  
95.     numshots = 0
96.     DO
97.         IF shot(numshots).ACTIVE THEN
98.             shot(numshots).PIC = _LOADIMAGE("SCRAPSHIP\gfx\shot.png") 'Add path to PNG file here. This one is 10x20
99.             shot(numshots).SPEED = 5
100.             shot(numshots).HEIGHT = 20
101.             shot(numshots).WIDTH = 10
102.             shot(numshots).MIDX = shot(numshots).WIDTH / 2
103.             shot(numshots).MIDY = shot(numshots).HEIGHT / 2
104.             shot(numshots).Y = shot(numshots).Y - 5
105.             IF shot(numshots).Y < 0 THEN
106.                 shot(numshots).ACTIVE = FALSE
107.             ELSE
108.                 _PUTIMAGE (shot(numshots).X, shot(numshots).Y), shot(numshots).PIC
109.             END IF
110.         END IF
111.         numshots = numshots + 1
112.     LOOP UNTIL numshots = maxshots
113.  
114.     IF _KEYDOWN(32) AND keydelay = 0 THEN
115.         numshots = 0
116.         DO
117.             IF NOT shot(numshots).ACTIVE THEN
118.                 shot(numshots).ACTIVE = TRUE
119.                 shot(numshots).X = player.X + player.MIDX - shot(numshots).MIDX
120.                 shot(numshots).Y = player.Y
121.                 keydelay = 10
122.                 EXIT DO
123.             END IF
124.             numshots = numshots + 1
125.         LOOP UNTIL numshots = maxshots
126.     END IF
127.     IF keydelay THEN keydelay = keydelay - 1
128.  
129. END SUB
130.  
131. SUB moveplayer '===========================================================SUB MOVE PLAYER
132.  
133.     IF _KEYDOWN(CVI(CHR$(0) + "K")) AND player.X > win.LEFT THEN '    - MOVE LEFT
134.         player.X = player.X - player.SPEED
135.     END IF
136.  
137.     IF _KEYDOWN(CVI(CHR$(0) + "M")) AND player.X + player.WIDTH < win.RIGHT THEN '  - MOVE RIGHT
138.         player.X = player.X + player.SPEED
139.     END IF
140.  
141.     IF _KEYDOWN(CVI(CHR$(0) + "H")) AND player.Y > win.TOP THEN '  - MOVE UP
142.         player.Y = player.Y - player.SPEED
143.     END IF
144.  
145.     IF _KEYDOWN(CVI(CHR$(0) + "P")) AND player.Y + player.HEIGHT < win.BOTTOM THEN '   - MOVE DOWN
146.         player.Y = player.Y + player.SPEED
147.     END IF
148.  
149.     _PUTIMAGE (player.X, player.Y), player.PIC
150.  
151. END SUB
152.  
153. SUB newscreen '==============================================================SUB NEW SCREEN
154.     CLS
155.     win.WIDTH = 1080
156.     win.HEIGHT = 1080
157.     win.COLORS = 32
158.     SCREEN _NEWIMAGE(win.WIDTH, win.HEIGHT, win.COLORS)
159. END SUB
160.