Mousemove bug on fullscreen mode

[moises1953]

Bug: MOUSEMOVE on FULLSCREEN works in Desktop coordinates, but can't exceed screen coordinates.
If your Screen resolution and Desktop resolution are equal, works OK.
Else if your app runs on her window, also works OK.
But if you use [Alt][Enter] to put it in FULLSCREEN mode, you can't use de readed mouse coordinates to MOUSEMOVE, so you need to reescale.

Example: fine mouse move with keyboard arrows

Code: QB64: [Select]

1. 'fine mouse move with arrows
2. 'Bug: MOUSEMOVE on FULLSCREEN works in Desktop coordinates,
3. '     but can't exceed screen coordinates
4. 'press [Alt][Enter] to show FULLSCREEN
5. $NOPREFIX
6. DEFLNG H-P
7. PhDtp = DESKTOPWIDTH
8. PvDtp = DESKTOPHEIGHT
9.  
10. PixHor = 1366: PixVer = 768
11. 'PixHor = 1728: PixVer = 972
12.  
13. SCREEN NEWIMAGE(PixHor, PixVer, 256)
14. 'FULLSCREEN , SMOOTH
15. SCREENMOVE 0, 0
16. pxcenter = PixHor \ 2
17. pycenter = PixVer \ 2
18.  
19. PhCar = FONTWIDTH
20. PvCar = FONTHEIGHT
21. pyps = PixVer - PvCar
22.  
23. LOCATE 1, 1
24. PRINT "Desktop:"; PhDtp; PvDtp; "Screen:"; PixHor; PixVer
25. ifull = FULLSCREEN
26. LOCATE 1, 48: PRINT "FULL:"; ifull
27. PRINT "Use Keyboard arrors to fine position the mouse cursor, press any key to mark with +, [Backspace] to retrive last mark, click to draw."
28. PRINT "Test in FULLSCREEN, presing [Alt][Enter]: Now MOUSEMOVE works on Desktop coordinates"
29.  
30. mx = 0
31. my = 0
32. markx = PixHor \ 2
33. marky = PixVer \ 2
34. MOUSESHOW
35. MOUSEMOVE pxcenter, pycenter 'center mouse
36. PRINTSTRING (pxcenter - PhCar \ 2, pycenter - PvCar \ 2), "X"
37. DO
38.   nfull = FULLSCREEN
39.   IF nfull - ifull THEN
40.     LOCATE 1, 53: PRINT nfull
41.     ifull = nfull
42.   END IF
43.   DO WHILE MOUSEINPUT
44.     mx = MOUSEX
45.     my = MOUSEY
46.     mClick = MOUSEBUTTON(1)
47.     ' mouseRight = MOUSEBUTTON(2)
48.     ' mouseMiddle = MOUSEBUTTON(3)
49.     ' MOUSEWHEEL
50.     PRINTSTRING (0, pyps), STR$(mx) + STR$(my) + SPACE$(6)
51.  
52.     IF mClick THEN
53.       PSET (mx, my)
54.       PRINTSTRING (120, pyps), "Click:" + STR$(mx) + STR$(my) + SPACE$(6)
55.     END IF
56.   LOOP
57.  
58.   in$ = INKEY$
59.   IF LEN(in$) THEN
60.     '...  capture arrows & do mouse move
61.     SELECT CASE in$
62.       CASE CHR$(0) + "H" 'Up
63.         IF my THEN move = 1 ELSE move = 0
64.       CASE CHR$(0) + "K" 'Left
65.         IF mx THEN move = 2 ELSE move = 0
66.       CASE CHR$(0) + "M" 'Right
67.         IF mx + 1 < PixHor THEN move = 3 ELSE move = 0
68.       CASE CHR$(0) + "P" 'Down
69.         IF my + 1 < PixVer THEN move = 4 ELSE move = 0
70.       CASE CHR$(8) 'Backspace
71.         move = 9
72.       CASE ELSE
73.         PRINTSTRING (mx - PhCar \ 2, my - PvCar \ 2), "+"
74.         markx = mx: marky = my
75.     END SELECT
76.  
77.     IF move THEN
78.       mxi = mx: myi = my
79.       PRINTSTRING (380, pyps), "Last move:" + STR$(move)
80.       IF FULLSCREEN THEN '1:stretch, 2:squarepixels
81.         mxmovi = CINT(mx * PhDtp / PixHor) 'scale conversion for mousemove
82.         mymovi = CINT(my * PvDtp / PixVer)
83.  
84.         SELECT CASE move
85.           CASE 1: my = my - 1
86.           CASE 2: mx = mx - 1
87.           CASE 3: mx = mx + 1
88.           CASE 4: my = my + 1
89.           CASE 9
90.             mx = markx
91.             my = marky
92.           CASE ELSE
93.         END SELECT
94.         mxmov = CINT(mx * PhDtp / PixHor)
95.         mymov = CINT(my * PvDtp / PixVer)
96.         IF mxmov >= PixHor THEN move = 0
97.         IF mymov >= PixVer THEN move = 0
98.         IF move THEN
99.           PRINTSTRING (480, pyps), STR$(mxmov) + STR$(mymov) + SPACE$(6)
100.           MOUSEMOVE mxmov, mymov
101.         ELSE
102.           PRINTSTRING (480, pyps), STR$(mxmovi) + STR$(mymovi) + SPACE$(6)
103.           mx = mxi: my = myi
104.         END IF
105.       ELSE
106.         SELECT CASE move
107.           CASE 1: my = my - 1
108.           CASE 2: mx = mx - 1
109.           CASE 3: mx = mx + 1
110.           CASE 4: my = my + 1
111.           CASE 9
112.             mx = markx
113.             my = marky
114.           CASE ELSE
115.         END SELECT
116.         PRINTSTRING (480, pyps), STR$(mx) + STR$(my) + SPACE$(6)
117.         MOUSEMOVE mx, my
118.       END IF
119.       move = 0
120.     END IF
121.   END IF
122. LOOP UNTIL in$ = CHR$(27)
123. END
124.  

[Petr]

Hi, I tried too. The screen resolution in fullscreen mode remains the same (this was to be expected, otherwise you would have to recalculate the coordinates in the program for each screen mode). Wait. That's actually the answer! Well, but for level C! If the _FULLSCREEN function returns 0, it is windowed mode. If FULLSCREEN returns 1 or 2, these are different fullscreen modes. From QB64, _MOUSEMOVE does move really badly, so at the C language level, in _MOUSEMOVE somewhere, something like this has to be added:

IF FULLSCREEN then Xshift = _desktopwidth / _width * x
                               Yshift = _desktopheight / _height * y

In the current version, this conversion is obviously missing and the fullscreen is not taken into account!

The only bad way to do this from the QB64 level is to switch the screen resolution according to the value of the FULLSCREEN function, and that's stupid, you would have to recalculate the coordinates.

OR am I completely out?

Here's the program I tried. Press A to enter mouse coordinates.

Code: QB64: [Select]

1. a& = _NEWIMAGE(1366, 900, 32)
2.  
3. SCREEN a&
4. _ALLOWFULLSCREEN
5.  
6. DO UNTIL _KEYHIT = 27
7.     i$ = INKEY$
8.     IF i$ = " " THEN _FULLSCREEN
9.     IF UCASE$(i$) = "A" THEN
10.         INPUT "Insert X,Y:"; x, y
11.         IF x > _WIDTH - 1 THEN x = _WIDTH - 1
12.         IF y > _HEIGHT - 1 THEN y = _HEIGHT - 1
13.     END IF
14.     'GOTO notthis
15.  
16.  
17.  
18.     IF _FULLSCREEN > 0 THEN
19.         SCREEN 0
20.         _FREEIMAGE a&
21.         a& = _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT, 32)
22.         SCREEN a&
23.     ELSE
24.         IF a& < -1 THEN
25.             SCREEN 0
26.             _FREEIMAGE a&
27.             a& = _NEWIMAGE(1366, 900, 32)
28.             SCREEN a&
29.             IF x > _WIDTH - 1 THEN x = _WIDTH - 1
30.             IF y > _HEIGHT - 1 THEN y = _HEIGHT - 1
31.         END IF
32.     END IF
33.  
34.  
35.  
36.  
37.     notthis:
38.     CLS
39.     LOCATE 1
40.     PRINT _WIDTH, _HEIGHT; "Try press Alt + Enter -> returned resolution is still the same"
41.     PRINT _WIDTH(0), _HEIGHT(0), _FULLSCREEN
42.  
43.     _MOUSEMOVE x, y
44.     _DISPLAY
45. LOOP
46.  

[moises1953]

Tank's a lot Petr, but your solution needs rewrite screen each cycle.
The only way is ALLOWFULLSCREEN OFF, OFF.
May be, creating a new image por the desktop in fullcreen and putting the image of original screen with squarepixels.

[Petr]

Next solution is hide original mouse pointer and show own pointer. As in this program (support CUR files, in ANI support is some bug now...)

Code: QB64: [Select]

1. '$include:'cursors.bi'
2. _MOUSEHIDE
3. SCREEN _NEWIMAGE(800, 600, 32)
4. N = LOADCURSOR("aero_arrow_l.cur")
5. DO UNTIL _KEYHIT = 27
6.     WHILE _MOUSEINPUT: WEND
7.     CLS
8.     PUTCURSOR N, _MOUSEX, _MOUSEY
9.     _DISPLAY
10.     _LIMIT 30
11. LOOP
12.  
13. '$include:'cursors.bm'
14.  

Next mouse cursors you can find in windows/cursors path.

[moises1953]

Thank's a lot Petr, that's OK: It solves the problem of screenmove bug in fullscreen
This modified version allows some writing and retains the editing

Code: QB64: [Select]

1. '$include:'cursors.bi'
2. 'MousePoint-Moises1953. Modified version of Petr MousePointer test program
3. _MOUSEHIDE
4. handle& = _NEWIMAGE(800, 600, 32)
5. SCREEN handle&
6. N = LOADCURSOR("aero_arrow_l.cur")
7. DO
8.   SCREEN , , 0, 0
9.   keypress = _KEYHIT '...some writing capabilities
10.   SELECT CASE keypress
11.     CASE 27
12.       EXIT DO
13.     CASE 13
14.       PRINT
15.     CASE 32 TO 255 '...text
16.       PRINT CHR$(keypress);
17.   END SELECT
18.   WHILE _MOUSEINPUT
19.     IF _MOUSEBUTTON(1) THEN PSET (_MOUSEX, _MOUSEY) 'draw
20.   WEND
21.   SCREEN , , 1, 1 '... display cursor in another screen
22.   CLS
23.   PCOPY 0, 1 '...retrieve screen without cursor
24.   PUTCURSOR N, _MOUSEX, _MOUSEY
25.   _DISPLAY
26.   _LIMIT 30
27. LOOP
28. SCREEN , , 0, 0
29. END
30. '$include:'cursors.bm'
31.  
32.  

[Petr]

Hi, i find and repair bug in ANI support, here it is. There is next bug, placing ANI animations to correct place, but in my documentation is nothnig about correctness betwen real/animation coordinates.