Hi Lo without Secret Number?

[bplus]

Steve, jack you've got it backwards the program is not trying to guess the user's number. The user is trying to narrow down what the program has made up (though the challenge is to not make up any secret number).

OK time to translate the example I worked my Hi Lo Game version from.

[bplus]

I made my version of Hi Lo Game after playing around with this:

Code: QB64: [Select]

1.  
2. 'ref tsh73 from JB forum 2020-10-08
3. 'https://justbasiccom.proboards.com/thread/567/guess-number-secret
4. 'translated to QB64 b+ 2020-10-11
5.  
6.  
7. 'guessANumber
8. '   idea
9. '   instead of making a number
10. '   we deside on each turn
11. 'of cource we should store numbers tried to say "no" again
12. 'and fix probability according to not tried numbers
13.  
14. 'logic: loop
15. '   get a number
16. '   check if number is new
17. '       if it is,
18. '       with probabilty 1/#(numbers left) say Yes and stop
19. '       (or else)  store it
20. '       else say No
21.  
22. PRINT "---- Guess a number ----"
23. PRINT "I made up a number, (1..9)"
24. PRINT "- you guess it. That's all ;)"
25. PRINT
26. PRINT "No! Not quite."
27. PRINT "Actually I do not made a number."
28. PRINT "I will deside on the go."
29. PRINT
30.  
31. tried$ = ""
32.  
33. WHILE 1
34.     INPUT "Make your guess (1..9): "; guess
35.     IF guess < 1 OR guess > 9 OR INT(guess) <> guess THEN
36.         PRINT "Guess not valid"
37.         GOTO cont
38.     END IF
39.     IF INSTR(tried$, _TRIM$(STR$(guess))) THEN
40.         PRINT "Already tried that"
41.         GOTO cont
42.     END IF
43.     numsLeft = 9 - LEN(tried$)
44.     'print "1/";numsLeft,  'and the probability is
45.     IF RND < 1 / numsLeft THEN
46.         PRINT "You did it!"
47.         EXIT WHILE
48.     END IF
49.     'else
50.     tried$ = tried$ + _TRIM$(STR$(guess))
51.     PRINT "Nope, try again"
52.     cont:
53. WEND
54. PRINT "-=* thanks for playing *=-"
55. END
56.  
57.  

BTW tsh73 is generous programming teacher in Russia, so maybe we can forgive his mistakes of English spelling and grammar.

[bplus]

As a joke, I posted this for reply to tsh73:

Code: QB64: [Select]

1. _TITLE "Guess the cruel joke." ' b+ 2020-10-08 reply to tsh73 trans to QB64
2. WHILE 1
3.     INPUT "Make your guess (1..9): "; guess
4.     IF guess < 1 OR guess > 9 OR INT(guess) <> guess THEN
5.         PRINT "Guess not valid"
6.         GOTO cont
7.     END IF
8.     IF INSTR(tried$, _TRIM$(STR$(guess))) THEN
9.         PRINT "Already tried that"
10.         GOTO cont
11.     END IF
12.     IF LEN(tried$) >= 8 THEN
13.         PRINT "You did it!"
14.         EXIT WHILE
15.     END IF
16.     'else
17.     tried$ = tried$ + _TRIM$(STR$(guess))
18.     PRINT "Nope, but you're getting closer!"
19.     cont:
20. WEND
21. PRINT "-=* thanks for playing *=-"
22. END
23.  
24.  

[STxAxTIC]

waaait, the backwards version is interesting...

[bplus]

waaait, the backwards version is interesting...

Sure check this out:
https://www.qb64.org/forum/index.php?topic=1854.msg110907#msg110907

[bplus]

Here is a distribution of "Secret Numbers" finally determined at games end in 10,000 trials:

Code: [Select]

Secret Numbers results:
Program errors = 0
1             92
2             94
3             101
4             111
5             110
6             100
7             114
8             104
9             91
10            89
11            82
12            122
13            97
14            97
15            115
16            109
17            96
18            97
19            91
20            103
21            108
22            95
23            104
24            99
25            99
26            108
27            104
28            91
29            102
30            105
31            97
32            81
33            106
34            101
35            107
36            89
37            99
38            88
39            87
40            102
41            100
42            107
43            92
44            81
45            84
46            103
47            100
48            98
49            89
50            95
51            107
52            102
53            105
54            95
55            110
56            92
57            119
58            110
59            106
60            93
61            92
62            84
63            103
64            113
65            94
66            95
67            99
68            92
69            99
70            110
71            91
72            96
73            95
74            87
75            93
76            95
77            111
78            102
79            101
80            111
81            113
82            110
83            115
84            95
85            105
86            106
87            107
88            92
89            93
90            118
91            95
92            106
93            91
94            104
95            106
96            104
97            98
98            97
99            101
100           106
Total 10000
 Lowest count 81 for i = 32
Highest count 122 for i = 12


As you can see no holes and no heavy favorites. This tells me this game plays the same as one in which a secret number is decided before the start of each game or round.

[bplus]

BTW here is my QB64 version of the backwards (the program guesses my number) Hi Lo Game from 2019:

Code: QB64: [Select]

1. '2019-09-14
2. WHILE 1
3.     Hi = 101: Lo = 0
4.     DO
5.         guess = INT((Hi - Lo) / 2) + Lo
6.         PRINT "AI guesses your number ( 1 to 100) is "; guess
7.         INPUT "Enter l for low, c for correct, h for high > "; r$
8.         IF r$ = "l" THEN Lo = guess
9.         IF r$ = "h" THEN Hi = guess
10.     LOOP UNTIL r$ = "c"
11.     PRINT "Yeah, start another..."
12. WEND
13.  

[bplus]

And just to round things out, here is my version of the Standard Hi Lo Game written in SB (Shorthand Basic) for my Interpreter built with QB64:

Code: QB64: [Select]

1. Hi lo game SB.txt b+ 2020-03-07
2. [
3.     n r int(rnd * 100) + 1
4.     n c 0
5.     [
6.         ? g Guess my number from 1 to 100, (0 quits)
7.         i  g >= 1
8.             n c c + 1
9.             i  g >  r
10.                 . Too High!
11.             e
12.                 i  g < r
13.                     . Too Low!
14.                 e
15.                     . You guessed in c guesses!
16.                     .
17.                     x
18.                 f
19.             f
20.         e
21.             . You signaled quit, goodbye!
22.             z
23.         f
24.     ]  
25. ]
26.  

[ starts a loop
] ends a loop

n sets a number variable the very next item in the line is the variable name and the next stuff is number literal or numeric expression for the variables value. (So here, r is the secret number set at the beginning of the round and c is for count as in counting the number of guesses.)

? starts an INPUT statement, next item is the variable name being set and the rest is the propmt string, notice NO double quotes!

i starts an IF branch decision, the stuff following is the expression to evaluate if evaluates to True then execute the next statement else look for an f (the end of an IF block or an e the ELSE block to execute.

. starts a PRINT statement, notice no double quotes BUT if one of the isolated letters or words is a variable name the variable's value will be substituted in for the name.

x of course is for exit loop, the only way out of [ loop code ]

For comments, just don't start a line with a command like [].nxief, but for your comfort use ' to feel safe it wont be used for anything else.

BTW the indents are optional but each executable line must start with executable command. So line 1 is just  comment.

One of these days I am going to work in strings and SUBs or FUNCTIONs.

[bplus]

BTW I found the 256 Cards Trick, program can pick your card out of 256 cards by telling it which line of 4 it's in, do this 4 X's and it will count out your favorite number of cards and your card will be last shown.

https://www.qb64.org/forum/index.php?topic=1865.msg111002#msg111002

But again, this is backwards to the challenge presented in OP.

[bplus]

Update: tsh73 says my code looks OK (for Hi Lo Game that does not start with established secret numbers) but might have found something literally funny about frequency distribution of resulting "secret" numbers from pure random guessing.

I was only checking guessing with some intelligence being applied including sliding down my guess by 1 number each time, those were fine but pure random guessing produced a frequency distribution chart that lifted up at both ends like a giant smiling at a joke!

hmm... got to check that out, it may be some artifact from the chart system he is using but like I said I never thought to check pure random guessing.

OK so here is my Hi Lo Game that plays without a secret number for QB64:

Code: QB64: [Select]

1. _TITLE "Hi Lo Game without Secret Number" 'B+ 2020-10-10 works now
2. ' trans from JB 2020-10-11 minimal changes
3. RANDOMIZE TIMER
4. restart:
5. CLS
6. Hi = 101: Lo = 0 '<<<<  make these higher and lower than what the secret number can be
7. guesses$ = ""
8. WHILE Hi - Lo > 1
9.     INPUT "Guess Number 1 to 100, Enter your guess "; PlayerGuess
10.     'if PlayerGuess = 0 then goto [restart]  ' GOOD! we split first guess of 50 both ways!
11.     IF PlayerGuess < 1 OR PlayerGuess > 100 THEN
12.         PRINT "Your guess is out of range of this game."
13.         GOTO cont
14.     END IF
15.     IF INSTR(guesses$, RIGHT$("000" + STR$(PlayerGuess), 3)) THEN
16.         PRINT "You've guessed that number already."
17.         GOTO cont
18.     END IF
19.     guesses$ = guesses$ + "," + RIGHT$("000" + STR$(PlayerGuess), 3)
20.     IF PlayerGuess > Lo AND PlayerGuess < Hi THEN
21.         r = RND: p = 1 / (Hi - Lo - 1) ' must be inside the Lo and Hi range ie not inclusive boundaries.
22.         IF r <= p THEN
23.             PRINT "You Guessed!"
24.             Guessed = 1
25.             EXIT WHILE
26.         ELSE
27.             IF PlayerGuess = Hi - 1 THEN 'guess must of been too high
28.                 'PRINT Lo, Hi, "Your guess was too high.", r, p
29.                 PRINT "Your guess was too high."
30.                 Hi = PlayerGuess
31.             ELSE
32.                 IF PlayerGuess = Lo + 1 THEN
33.                     'PRINT Lo, Hi, "Your guess was too low.", r, p
34.                     PRINT "Your guess was too low."
35.                     Lo = PlayerGuess
36.                 ELSE 'toss coin if too high or low
37.                     IF RND < .5 THEN
38.                         'PRINT Lo, Hi, "Your guess was too low.", r, p
39.                         PRINT "Your guess was too low."
40.                         Lo = PlayerGuess
41.                     ELSE
42.                         ' PRINT Lo, Hi, "Your guess was too high.", r, p
43.                         PRINT "Your guess was too high."
44.                         Hi = PlayerGuess
45.                     END IF
46.                 END IF
47.             END IF
48.         END IF
49.     ELSE
50.         IF PlayerGuess >= Hi THEN PRINT "Your guess was too high." ELSE PRINT "Your guess was too low."
51.     END IF
52.     cont:
53. WEND
54. IF Guessed <> 1 THEN PRINT "Yikes! Programming error, did not find secret number."
55. PRINT: INPUT "press Enter to go again, any other + Enter to quit "; again$
56. IF LEN(again$) THEN END ELSE GOTO restart
57.  

And here is what I was using to check frequency distributions of secret numbers discovered at the end of a game:

Code: QB64: [Select]

1. _TITLE "Hi Lo Game wo secret Test Distribution" '  B+ 2020-10-10 works now
2.  
3. DIM secrets(100) 'check distribution of answers, also checking if we fail to arrive at answer
4. 'SCREEN _NEWIMAGE(800, 600, 32)
5. restart:
6. CLS
7. Hi = 101: Lo = 0 '<<<<  make these higher and lower than what the secret number can be
8. guesses$ = ""
9. ALO = 0: AHI = 101
10. Guessed = 0
11. WHILE Hi - Lo > 1
12.     'input "Guess Number 1 to 100, Enter your guess "; PlayerGuess
13.  
14.     'use AI to guess
15.     'PlayerGuess = int((AHI - ALO)/ 2) + ALO 'OK have removed blunder!
16.  
17.     'make all the guesses way too high ie ride the AHI down 1 by 1
18.     PlayerGuess = AHI - 1 'Ah still a very nice ditribution of secrets, no holes nor mountains
19.  
20.     'PlayerGuess = int((Hi - Lo )/ 2) + Lo  'debug what the heck is going on with ALO AHI??
21.     'PRINT "Player Guesses "; PlayerGuess
22.  
23.     'if PlayerGuess = 0 then goto [restart]  ' GOOD! we split first guess of 50 both ways!
24.     IF PlayerGuess < 1 OR PlayerGuess > 100 THEN
25.         PRINT "Your guess is out of range of this game."
26.         _DELAY 2
27.         GOTO cont
28.     END IF
29.     IF INSTR(guesses$, RIGHT$("000" + STR$(PlayerGuess), 3)) THEN
30.         PRINT "You've guessed that number already."
31.         _DELAY 2
32.         GOTO cont
33.     END IF
34.     guesses$ = guesses$ + "," + RIGHT$("000" + STR$(PlayerGuess), 3)
35.     IF PlayerGuess > Lo AND PlayerGuess < Hi THEN
36.         r = RND: p = 1 / (Hi - Lo - 1) ' must be inside the Lo and Hi range ie not inclusive boundaries.
37.         IF r <= p THEN
38.             ' PRINT "You Guessed!"
39.             ' _DELAY 3
40.             Guessed = 1
41.             EXIT WHILE
42.         ELSE
43.             IF PlayerGuess = Hi - 1 THEN 'guess must of been too high
44.                 'PRINT Lo, Hi, "Your guess was too high.", r, p
45.                 Hi = PlayerGuess
46.                 AHI = PlayerGuess
47.             ELSE
48.                 IF PlayerGuess = Lo + 1 THEN
49.                     'PRINT Lo, Hi, "Your guess was too low.", r, p
50.                     Lo = PlayerGuess
51.                     ALO = PlayerGuess
52.                 ELSE 'toss coin if too high or low
53.                     IF RND < .5 THEN
54.                         'PRINT Lo, Hi, "Your guess was too low.", r, p
55.                         Lo = PlayerGuess
56.                         ALO = PlayerGuess
57.                     ELSE
58.                         'PRINT Lo, Hi, "Your guess was too high.", r, p
59.                         Hi = PlayerGuess
60.                         AHI = PlayerGuess
61.                     END IF
62.                 END IF
63.             END IF
64.         END IF
65.     ELSE 'going wrong way with guessing, not narrowing down with current guess
66.         'if PlayerGuess >= Hi then Print "Your guess was too high." else print "Your guess was too low."
67.         '_DELAY 2
68.     END IF
69.     cont:
70.     'PRINT Lo, Hi, ALO, AHI 'OK that blunder was pretty dumb!
71.     'INPUT "Press enter to continue..."; wait$
72. WEND
73. IF Guessed <> 1 THEN
74.     BEEP
75.     PRINT "Yikes! Programming error, did not find secret number."
76.     programErrors = programErrors + 1
77. ELSE
78.     secrets(PlayerGuess) = secrets(PlayerGuess) + 1
79. END IF
80. trial = trial + 1
81. IF trial < 10000 THEN GOTO restart
82.  
83. PRINT "Secret Numbers results:"
84. PRINT "Program errors = "; programErrors
85. low = 10000
86. FOR i = 1 TO 100
87.     PRINT i, secrets(i)
88.     tot = tot + secrets(i)
89.     IF secrets(i) < low THEN low = secrets(i): saveLowI = i
90.     IF secrets(i) > high THEN high = secrets(i): saveHighI = i
91.     IF i MOD 20 = 0 THEN
92.         INPUT "Press enter to continue... "; w$
93.         CLS
94.     END IF
95. NEXT
96. PRINT "Total "; tot
97. PRINT " Lowest count "; low; " for i = "; saveLowI
98. PRINT "Highest count "; high; " for i = "; saveHighI
99. END
100.  

So there it is so far for those of you into esoteric program problems :)

[bplus]

My independent test confirms tsh73 report is correct, the graph of the distribution of jump way up at the two ends:

Code: QB64: [Select]

1. ' Hi Lo Game WO Secret Number Test Random Guessing Distribution  B+ 2020-10-13
2.  
3. ' Check tsh73 report of wackiness for pure random guessing.
4. ' So we aren't here all day waiting for results of 1000 tests
5. ' let us store all the guess numbers into a deck.
6. ' Shuffle the deck before each round and use 100 numbers WITHOUT REPEAT
7. ' to get that secret number established! That should save us a ship load
8. ' of time and still produce results of pure random guesses.
9.  
10. ' 2020-10-13 trans JB code to QB64
11.  
12. DEFINT A-Z
13. RANDOMIZE TIMER
14. DIM secrets(100) ' Check distribution of answers, also checking if we fail to arrive at answer.
15. DIM rg(100) '      Get our random guesses in a row! Here is our Deck!
16. FOR i = 1 TO 100 ' Create our deck of random numbers to test, rg stands for Random Guess
17.     rg(i) = i
18. NEXT
19.  
20. restart:
21. ' reinitialize all that is necessary start by reshuffle rg()
22. FOR i = 100 TO 2 STEP -1 'forget about 0 leave it alone
23.     tmp = rg(i)
24.     r = INT(RND * i) + 1
25.     rg(i) = rg(r)
26.     rg(r) = tmp
27. NEXT
28. rIdx = 1 'reset deck index
29. Hi = 101: Lo = 0 '  reset, make these higher and lower than what the secret number can be
30. guesses$ = "" '     track what has been guessed
31. Guessed = 0 '     flag the number has been established!
32.  
33. WHILE Hi - Lo > 1 ' Begin rounds of guesses for number
34.  
35.     PlayerGuess = rg(rIdx) ' 1 of 100 pure random guesses
36.     rIdx = rIdx + 1
37.     'PRINT "Player Guesses "; PlayerGuess
38.  
39.     'if PlayerGuess = 0 then goto restart  ' GOOD! we split first guess of 50 both ways!
40.     IF PlayerGuess < 1 OR PlayerGuess > 100 THEN 'not going to happen
41.         GOTO cont
42.     END IF
43.     IF INSTR(guesses$, RIGHT$("000" + STR$(PlayerGuess), 3)) THEN 'not going to happen
44.         GOTO cont
45.     END IF
46.     guesses$ = guesses$ + "," + RIGHT$("000" + STR$(PlayerGuess), 3) 'wasting time but...
47.     IF PlayerGuess > Lo AND PlayerGuess < Hi THEN
48.         r = RND: p = 1 / (Hi - Lo - 1) ' must be inside the Lo and Hi range ie not inclusive boundaries.
49.         IF r <= p THEN
50.             'PRINT "You guessed it!"
51.             Guessed = 1
52.             EXIT WHILE
53.         ELSE
54.             IF PlayerGuess = Hi - 1 THEN 'guess must of been too high
55.                 'print Lo, Hi, "Your guess was too high.", r, p
56.                 Hi = PlayerGuess
57.             ELSE
58.                 IF PlayerGuess = Lo + 1 THEN
59.                     'print Lo, Hi, "Your guess was too low.", r, p
60.                     Lo = PlayerGuess
61.                 ELSE 'toss coin if too high or low
62.                     IF RND < .5 THEN
63.                         'print Lo, Hi, "Your guess was too low.", r, p
64.                         Lo = PlayerGuess
65.                     ELSE
66.                         'print Lo, Hi, "Your guess was too high.", r, p
67.                         Hi = PlayerGuess
68.                     END IF
69.                 END IF
70.             END IF
71.         END IF
72.     ELSE 'going wrong way with guessing, not narrowing down with current guess this will happen allot!!!
73.         IF PlayerGuess >= Hi THEN
74.             'Print "Your guess was too high."
75.         ELSE
76.             'print "Your guess was too low."
77.         END IF
78.     END IF
79.     cont:
80.     'INPUT "Press enter to continue..."; wait$
81. WEND
82. IF Guessed <> 1 THEN
83.     'PRINT "Yikes! Programming error, did not find secret number."
84.     programErrors = programErrors + 1
85. ELSE
86.     secrets(PlayerGuess) = secrets(PlayerGuess) + 1
87. END IF
88. trial = trial + 1
89. IF trial < 10000 THEN GOTO restart
90.  
91. 'report results
92. CLS
93. PRINT "Secret Numbers results:"
94. PRINT "Program errors = "; programErrors
95. low = 1000
96. FOR i = 1 TO 100
97.     PRINT i, secrets(i) 'that's right in JB you can scroll output screen to review all 100
98.     tot = tot + secrets(i)
99.     IF secrets(i) < low THEN low = secrets(i): saveLowI = i
100.     IF secrets(i) > high THEN high = secrets(i): saveHighI = i
101.     IF i MOD 20 = 0 THEN
102.         INPUT " Press enter to cont..."; w$
103.         CLS
104.     END IF
105. NEXT
106. PRINT "Total "; tot
107. PRINT " Lowest count "; low; " for i = "; saveLowI
108. PRINT "Highest count "; high; " for i = "; saveHighI
109. END
110.  

[SMcNeill]

One caveat:  I haven't tried any of the code in this topic yet, to actually see what the heck type of game we're supposed to be making.  I didn't want to be inspired (or limited) by looking over anyone else's work first.  Instead, I tried to make a little program which does a magic number, without having a magic number, like I understood from bplus's posts..

Regardless of whether or not this is quite what we were looking for, here's a Steve Magic Number (without a magic number) program for everyone to enjoy:

Code: QB64: [Select]

1. COLOR 15
2. min = 1: max = 100
3.  
4. CLS
5. PRINT "Guess my magic number.  It's between 1 and 100!"
6. PRINT "If you guess high, I'll tell you to guess lower,"
7. PRINT "and if you guess low, I'll tell you to guess higher."
8.  
9.  
10. DO
11.     NumberOfGuesses = NumberOfGuesses + 1
12.     PRINT
13.     PRINT "How many guesses will it take for you to find my number?"
14.     PRINT "Let's find out! Give me your Guess #"; NumberOfGuesses;
15.     INPUT " "; Guess
16.     result = 0
17.     IF Guess < min THEN result = 1
18.     IF Guess > max THEN result = -1
19.     IF result = 0 THEN 'it's a good guess, progressing the game.
20.         target = (min + max) \ 2
21.         IF Guess >= target THEN
22.             IF min - max = 0 THEN result = 0 ELSE min = Guess + 1: result = 1
23.         ELSE
24.             max = Guess - 1: result = -1
25.         END IF
26.     END IF
27.     COLOR 4
28.     IF result < 0 THEN
29.         PRINT "PLEASE GUESS LOWER"
30.     ELSEIF result > 0 THEN
31.         PRINT "PLEASE GUESS HIGHER"
32.     ELSE
33.         PRINT "YEP!"
34.         PRINT "My secret number was "; Guess
35.         COLOR 7
36.         END
37.     END IF
38.     COLOR 15
39. LOOP
40.  

[bplus]

I haven't tried any of the code in this topic yet, to actually see what the heck type of game we're supposed to be making.  I didn't want to be inspired (or limited) by looking over anyone else's work first.  Instead, I tried to make a little program which does a magic number, without having a magic number, like I understood from bplus's posts.

I don't like to be influenced either, try the challenge raw first, see what first impressions will bring up.

Yeah Steve, that's going the right way now but the game plays the same over and over and over (because I play same numbers over and over, I always start at 50 then 75 or 25...)  I don't think RANDOMIZE TIMER would even help.

Also I am guessing the game will always take 6 guesses, that's as cruel as my version I posted as joke. You could just count the player's guesses and give them the game after a max of 7 but could be after any guess 1 to 7 if they were all different. Man! that would meet the criteria and produce a wide range of secret numbers ultimately established at the end of the game. Wish I thought of that days ago, I just found a Hi Lo Game without Secret Number with much improved frequency distribution.

Steve thanks for hanging in there with this crazy stuff!

Oh I should try different number starts, oh boy!
  [ You are not allowed to view this attachment ]  

[SMcNeill]

Who ever said we used integers?  :P

How the heck did you get stuck between 29 and 30?  I’ll have to dig into that issue.

And it’s only 6 or 7 guesses, if you narrow it down by a binary pattern.  50, +/- 25, +/- 12, +/- 6, +/- 3, +/- 1, +/- 1.

When I came up with this little concept, the idea was basically: How can the AI stretch out the game to tease the player the longest, making them use as many guesses as possible?

BEST game should be 6-7 guesses.  Worst game, could be forever, if you don’t read the instructions ((or get stuck in and endless loop).

I’ll play around a bit tomorrow, and see what the glitch is, and I might even toss in a random target for you to shoot at with it, just so it won’t be quite as easy to tell the computer is cheating.  :)

[bplus]

You could just count the player's guesses and give them the game after a max of 7 but could be after any guess 1 to 7 if they were all different. Man! that would meet the criteria and produce a wide range of secret numbers ultimately established at the end of the game. Wish I thought of that days ago, I just found a Hi Lo Game without Secret Number with much improved frequency distribution.

On 2nd thought no that won't work. You have to pay attention to players guesses and remain consistent in what you say with go higher or go lower, so the number still has to be narrowed down and you have to be careful in the narrowing down. I am pretty sure you have to test if 1 away from Lo or Hi and if it's going to be reported as a miss then only one way to go with narrowing down, no random up or down there. Maybe the glitch with Steve's code?

I was going to post my revised and improved game but now I think I will wait :)
Teaser: it has just the frequency distribution I was hoping to see of secret numbers established at end of each game ie spread pretty level from 1 to 100.