Angle Pong

[_vince]

Move the mouse left right up down to change position and angle, self explanatory

Code: [Select]

deflng a-z
const sw = 640
const sh = 480
dim shared pi as double
pi = 4*atn(1)

declare sub circlef(x, y, r, c)

dim a as double
dim b as double, d as double
dim p as double, q as double
dim cx as double, cy as double
dim vx as double, vy as double
dim vxx as double, vyy as double
cx = sw/2
cy = sh/4
vx = 0
vy = 1
r = 15

rebound = -1
ball = 0

screen 12
do

        if cx < r then
                vx = -vx
                rebound = -1
        end if
        if cx > sw - r then
                vx = -vx
                rebound = -1
        end if
        if cy < r then
                vy = -vy
                rebound = -1
        end if
        if cy > sh - r then
                cx = sw/2
                cy = sh/4
                vx = 0
                vy = 1
                rebound = -1
                ball = ball + 1
        end if

        cx = cx + vx
        cy = cy + vy

        do
                mx = _mousex
                my = _mousey
        loop while _mouseinput

        line (0,0)-(sw,sh),0,bf

        x = mx
        y = 395
        if mx < 80 then x = 80
        if mx > sw - 80 then x = sw - 80
        a = (my - sh/2)/(1.1*sh/2)*(pi/2)
        line (x, y)-step(80*cos(a), 80*sin(a))
        line (x, y)-step(-80*cos(a), -80*sin(a))

        if rebound then
        'if a >= 0 and vx <=0 or a < 0 and vx >= 0 then
                q = sin(a)*cos(a + pi/2) - cos(a)*sin(a + pi/2)
                if q <> 0 then
                        p = cy*cos(a) - cx*sin(a) - y*cos(a) + x*sin(a)
                        d = p/q
                        b = (cx + d*cos(a + pi/2) - x)/cos(a)
                        if abs(b) < 80 then
                                'line (cx, cy)- step(d*cos(a + pi/2), d*sin(a + pi/2)), 12
                                if d < r then
                                        vxx = vx*cos(2*a) + vy*sin(2*a)
                                        vyy = vx*sin(2*a) - vy*cos(2*a)
                                        vx = vxx
                                        vy = vyy
                                        rebound = 0
                                end if
                        end if
                end if
        'end if
        end if

        circlef cx, cy, r, 15

        locate 1,1: ? ball
        'locate 1,1: ? a*180/pi
        _display
        _limit 200
loop until _keyhit = 27
sleep
system

sub circlef(x, y, r, c)
        x0 = r
        y0 = 0
        e = -r

        do while y0 < x0
                if e <=0 then
                        y0 = y0 + 1
                        line (x - x0, y + y0)-(x + x0, y + y0), c, bf
                        line (x - x0, y - y0)-(x + x0, y - y0), c, bf
                        e = e + 2*y0
                else
                        line (x - y0, y - x0)-(x + y0, y - x0), c, bf
                        line (x - y0, y + x0)-(x + y0, y + x0), c, bf
                        x0 = x0 - 1
                        e = e - 2*x0
                end if
        loop
        line (x - r, y)-(x + r, y), c, bf
end sub


[johnno56]

Just a few things:

1. What, no aliens? lol
2. Cool concept.
3. If the "bat" is perfectly horizontal the "ball" passes through it.... I know, it's early days...

[bplus]

It doesn't have to be perfectly horizontal for pass through, nor perfectly in middle of paddle what I thought next. I doubt this is random there is something amiss but it is nice to have control of ball return which is why I like a circular paddle in Air Hockey and an oblong bread like bun (ellipse) in my version of Breakout.

Is this a bug or a feature? ;-))

[_vince]

I've noticed it too, occasionally, but it seemed playable, proof of concept at least, oh well.

There's two ways for the paddle to be come 'invisible', either it detects a backwards paddle which otherwise messes with the geometry calculations, or it has already bounced the ball and will be invisible until the ball hits a wall again.  I've commented out the former in original post, might be more reliable, just dont turn the paddle backwards. Either those things are buggy or something else is fundamentally wrong, not sure if I will bother to look into it.

[bplus]

Maybe if paddle swung its angle from mouse wheel instead of whatever you are doing with position.

[johnno56]

Oh dear... Taking it too seriously... I knew it was a P.O.C demo... Just 'poking a stick at the sleeping bear' to get a reaction.... lol

(just in case: I am not implying that anyone is a 'sleeping bear'... just coining a phrase... lol)

I would be interested to see if this demo will develop into anything of note... Looks cool. Perhaps a circular ping pong. Ball would move slightly quicker with each 'bounce' off the 'bat'... First thing I thought of... lol

[bplus]

Ball versus ball collision piece of cake, ball versus angled rectangle kind tricky as we have seen here.

Try Circle Intersect Line or Ellipse Intersect Line

[_vince]

If you uncomment line 74, the red LINE, you can see how the calculation works, should be robust, so i wonder if it's the 'backwards paddle' detection hack. You can see the mess of trig around it, i've derived it with pure trig and it wasn't the most trivial derivation. Given all the sines and cosines of arctans, there should definitely be a pythagorean theorem variant path for the equivalent or perhaps more robust geometry.

[bplus]

I don't like wading deep into other's code system which is why I don't attempt to fix _vince version.

Circle intersect line, my version had to be reworked into useful function, I did that here:

Code: QB64: [Select]

1. _TITLE "Line Intersect Circle Function" ' b+ 2020-03-09 develop
2.  
3. CONST xmax = 800, ymax = 600
4. SCREEN _NEWIMAGE(xmax, ymax, 32)
5. _DELAY .25
6. _SCREENMOVE _MIDDLE
7.  
8. DO
9.     CLS
10.     IF testTangent = 0 THEN 'test plug in set of border conditions not easy to click
11.         PRINT "First set here is a plug in test set for vertical lines."
12.         mx(1) = 200: my(1) = 100: mx(2) = 200: my(2) = 400 'line  x = 200
13.         mx(3) = 400: my(3) = 300: mx(4) = 150: my(4) = 300 ' circle origin (center 400, 300) then radius test 200 tangent, 150 more than tangent, 250 short
14.         FOR i = 1 TO 4
15.             CIRCLE (mx(i), my(i)), 2
16.         NEXT
17.         IF mx(1) <> mx(2) THEN
18.             slopeYintersect mx(1), my(1), mx(2), my(2), m, Y0 ' Y0 otherwise know as y Intersect
19.             LINE (0, Y0)-(xmax, m * xmax + Y0), &HFF0000FF
20.             LINE (mx(1), my(1))-(mx(2), my(2))
21.         ELSE
22.             LINE (mx(1), 0)-(mx(1), ymax), &HFF0000FF
23.             LINE (mx(1), my(1))-(mx(2), my(2))
24.         END IF
25.         testTangent = 1
26.     ELSE
27.         PRINT "First 2 clicks will form a line, 3rd the circle origin and 4th the circle radius:"
28.         WHILE pi < 4 'get 4 mouse clicks
29.             _PRINTSTRING (20, 20), SPACE$(20)
30.             _PRINTSTRING (20, 20), "Need 4 clicks, have" + STR$(pi)
31.             WHILE _MOUSEINPUT: WEND
32.             IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN 'new mouse down
33.                 pi = pi + 1
34.                 mx(pi) = _MOUSEX: my(pi) = _MOUSEY
35.                 CIRCLE (mx(pi), my(pi)), 2
36.                 IF pi = 2 THEN 'draw first line segment then line
37.                     IF mx(1) <> mx(2) THEN
38.                         slopeYintersect mx(1), my(1), mx(2), my(2), m, Y0 ' Y0 otherwise know as y Intersect
39.                         LINE (0, Y0)-(xmax, m * xmax + Y0), &HFF0000FF
40.                         LINE (mx(1), my(1))-(mx(2), my(2))
41.                     ELSE
42.                         LINE (mx(1), 0)-(mx(1), ymax), &HFF0000FF
43.                         LINE (mx(1), my(1))-(mx(2), my(2))
44.                     END IF
45.                 END IF
46.             END IF
47.             oldMouse = _MOUSEBUTTON(1)
48.             _DISPLAY
49.             _LIMIT 60
50.         WEND
51.     END IF
52.  
53.     p = mx(3): q = my(3) 'draw circle
54.     r = SQR((mx(3) - mx(4)) ^ 2 + (my(3) - my(4)) ^ 2)
55.     CIRCLE (p, q), r, &HFFFF0000
56.  
57.     intersect = lineIntersectCircle%(mx(1), my(1), mx(2), my(2), mx(3), my(3), r, ix1, iy1, ix2, iy2)
58.     IF intersect = 0 THEN
59.         PRINT "No intersect"
60.     ELSEIF intersect = 1 THEN
61.         PRINT "Intersect at tangent point ("; TS$(ix1); ", "; TS$(iy1); ")"
62.         CIRCLE (ix1, iy1), 2, &HFFFFFF00
63.     ELSEIF intersect = 2 THEN
64.         PRINT "2 point intersect ("; TS$(ix1); ", "; TS$(iy1); ") and ("; TS$(ix2); ", "; TS$(iy2); ")"
65.         CIRCLE (ix1, iy1), 2, &HFFFFFF00
66.         CIRCLE (ix2, iy2), 2, &HFFFFFF00
67.     END IF
68.  
69.     'IF mx(1) = mx(2) THEN 'line is vertical so if r =
70.     '    IF r = ABS(mx(1) - mx(3)) THEN ' one point tangent intersect
71.     '        PRINT "Tangent point is "; TS$(mx(1)); ", "; TS$(my(3))
72.     '        CIRCLE (mx(1), my(3)), 2, &HFFFFFF00
73.     '        CIRCLE (mx(1), my(3)), 4, &HFFFFFF00
74.     '    ELSEIF r < ABS(mx(1) - mx(3)) THEN 'no intersect
75.     '        PRINT "No intersect, radius too small."
76.     '    ELSE '2 point intersect
77.     '        ydist = SQR(r ^ 2 - (mx(1) - mx(3)) ^ 2)
78.     '        y1 = my(3) + ydist
79.     '        y2 = my(3) - ydist
80.     '        PRINT "2 Point intersect (x1, y1) = "; TS$(mx(1)); ", "; TS$(y1); "  (x2, y2) = "; TS$(mx(1)); ", "; TS$(y2)
81.     '        CIRCLE (mx(1), y1), 2, &HFFFFFF00 'marking intersect points yellow
82.     '        CIRCLE (mx(1), y2), 2, &HFFFFFF00
83.     '        CIRCLE (mx(1), y1), 4, &HFFFFFF00 'marking intersect points yellow
84.     '        CIRCLE (mx(1), y2), 4, &HFFFFFF00
85.  
86.     '    END IF
87.     'ELSE
88.     '    'OK the calculations!
89.     '    'from inserting eq ofline into eq of circle where line intersects circle see reference
90.     '    ' https://math.stackexchange.com/questions/228841/how-do-i-calculate-the-intersections-of-a-straight-line-and-a-circle
91.     '    A = m ^ 2 + 1
92.     '    B = 2 * (m * Y0 - m * q - p)
93.     '    C = q ^ 2 - r ^ 2 + p ^ 2 - 2 * Y0 * q + Y0 ^ 2
94.     '    D = B ^ 2 - 4 * A * C 'telling part of Quadratic formula = 0 then circle is tangent  or > 0 then 2 intersect points
95.     '    IF D < 0 THEN ' no intersection
96.     '        PRINT "m, y0 "; TS$(m); ", "; TS$(Y0)
97.     '        PRINT "(p, q) "; TS$(p); ", "; TS$(q)
98.     '        PRINT "A: "; TS$(A)
99.     '        PRINT "B: "; TS$(B)
100.     '        PRINT "C: "; TS$(C)
101.     '        PRINT "D: "; TS$(D); " negative so no intersect."
102.     '    ELSEIF D = 0 THEN ' one point tangent
103.     '        x1 = (-B + SQR(D)) / (2 * A)
104.     '        y1 = m * x1 + Y0
105.     '        PRINT "Tangent Point Intersect (x1, y1) = "; TS$(x1); ", "; TS$(y1)
106.     '        CIRCLE (x1, y1), 2, &HFFFFFF00 'yellow circle should be on line perprendicular to 3rd click point
107.     '        CIRCLE (x1, y1), 4, &HFFFFFF00 'yellow circle should be on line perprendicular to 3rd click point
108.     '    ELSE
109.     '        '2 points
110.     '        x1 = (-B + SQR(D)) / (2 * A): y1 = m * x1 + Y0
111.     '        x2 = (-B - SQR(D)) / (2 * A): y2 = m * x2 + Y0
112.     '        PRINT "2 Point intersect (x1, y1) = "; TS$(x1); ", "; TS$(y1); "  (x2, y2) = "; TS$(x2); ", "; TS$(y2)
113.     '        CIRCLE (x1, y1), 2, &HFFFFFF00 'marking intersect points yellow
114.     '        CIRCLE (x2, y2), 2, &HFFFFFF00
115.     '        CIRCLE (x1, y1), 4, &HFFFFFF00 'marking intersect points yellow
116.     '        CIRCLE (x2, y2), 4, &HFFFFFF00
117.     '    END IF
118.     'END IF
119.     _DISPLAY
120.     INPUT "press enter to continue, any + enter to quit "; q$
121.     IF LEN(q$) THEN SYSTEM
122.     pi = 0 'point index
123. LOOP UNTIL _KEYDOWN(27)
124.  
125. ' return 0 no Intersect, 1 = tangent 1 point touch, 2 = 2 point intersect
126. FUNCTION lineIntersectCircle% (lx1, ly1, lx2, ly2, cx, cy, r, ix1, iy1, ix2, iy2)
127.     IF lx1 <> lx2 THEN
128.         slopeYintersect lx1, ly1, lx2, ly2, m, Y0 ' Y0 otherwise know as y Intersect
129.  
130.         ' https://math.stackexchange.com/questions/228841/how-do-i-calculate-the-intersections-of-a-straight-line-and-a-circle
131.         A = m ^ 2 + 1
132.         B = 2 * (m * Y0 - m * cy - cx)
133.         C = cy ^ 2 - r ^ 2 + cx ^ 2 - 2 * Y0 * cy + Y0 ^ 2
134.         D = B ^ 2 - 4 * A * C 'telling part of Quadratic formula = 0 then circle is tangent  or > 0 then 2 intersect points
135.         IF D < 0 THEN ' no intersection
136.             ix1 = -999: iy1 = -999: ix2 = -999: iy2 = -999: lineIntersectCircle% = 0
137.         ELSEIF D = 0 THEN ' one point tangent
138.             x1 = (-B + SQR(D)) / (2 * A)
139.             y1 = m * x1 + Y0
140.             ix1 = x1: iy1 = y1: ix2 = -999: iy2 = -999: lineIntersectCircle% = 1
141.         ELSE '2 points
142.             x1 = (-B + SQR(D)) / (2 * A): y1 = m * x1 + Y0
143.             x2 = (-B - SQR(D)) / (2 * A): y2 = m * x2 + Y0
144.             ix1 = x1: iy1 = y1: ix2 = x2: iy2 = y2: lineIntersectCircle% = 2
145.         END IF
146.     ELSE 'vertical line
147.         IF r = ABS(lx1 - cx) THEN ' tangent
148.             ix1 = lx1: iy1 = cy: ix2 = -999: iy2 = -999: lineIntersectCircle% = 1
149.         ELSEIF r < ABS(lx1 - cx) THEN 'no intersect
150.             ix1 = -999: iy1 = -999: ix2 = -999: iy2 = -999: lineIntersectCircle% = 0
151.         ELSE '2 point intersect
152.             ydist = SQR(r ^ 2 - (lx1 - cx) ^ 2)
153.             ix1 = lx1: iy1 = cy + ydist: ix2 = lx1: iy2 = cy - ydist: lineIntersectCircle% = 2
154.         END IF
155.     END IF
156. END FUNCTION
157.  
158. SUB slopeYintersect (X1, Y1, X2, Y2, slope, Yintercept) ' fix for when x1 = x2
159.     slope = (Y2 - Y1) / (X2 - X1)
160.     Yintercept = slope * (0 - X1) + Y1
161. END SUB
162.  
163. FUNCTION TS$ (n)
164.     TS$ = _TRIM$(STR$(n \ 1))
165. END FUNCTION
166.  
167.  

I looked at STxAxTIC's Ellipse Intersect Line and that look like complex translation job too, so I fixed up Circle Intersect line because I wanted a useful Function anyway.

Given two points that make a like, the circle's center and radius the above function will tell you if there is an intersection by returning 0, 1 or 2 the number of points:
0 no intersect
1 one intersect at Tangent and the point location
2 ywo point intersect and their locations.

Next to test with paddle = line and ball = circle intersect?

[_vince]

One thing I've learned from the superficial method is that with random angles and precision errors, there's going to be instances where you will not get a single point, but it will instantly go from no points to two points. I guess you could look at the distances between the two points and if it's short enough, do the bounce, and that's a fair and acceptable solution. What if one point is on paddle and the other is off? IDK, but should be doable. Then your axis of reflection for the ball is the line crossing between the two points and normal to the paddle. Easier? IDK, but it's all yours if you want to show me up. I went with finding the incident vector from ball to paddle and seeing if it's within the paddle bounds and whether it's shorter than ball radius.

[bplus]

What if one point is on paddle and the other is off?

What if both points are? good question!!!

[bplus]

Hey I made some progress, I can tell when contact is made and which side of the paddle the ball is on. I can draw the paddle handle on the opposite side of the ball, woohoo!

Ball rebound absolutely stinks but I know it can be worked out now that I have a handle on things, ha, ha!

Code: QB64: [Select]

1. _TITLE "Angle Paddle Test, mouse wheel down is clockwise" 'b+ started 2020-03-08  from _vince idea
2. CONST xmax = 800, ymax = 600, xc = 400, yc = 300
3. DIM SHARED P, P2, Pd2
4. P = _PI: P2 = 2 * P: Pd2 = P / 2
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _DELAY .2 'need time for screen to load before attempting to move it.
7. _SCREENMOVE _MIDDLE
8. RANDOMIZE TIMER
9.  
10. bx = xc: by = yc: bdx = -1: bdy = 3: br = 20
11. mr = 50: ma = 0
12. WHILE _KEYDOWN(27) = 0
13.     CLS
14.     ba = _ATAN2(bdy, bdx)
15.     IF ba < 0 THEN ba = ba + P2
16.     PRINT "ma"; _R2D(ma) \ 1; "  ba"; _R2D(ba) \ 1
17.  
18.     bx = bx + bdx
19.     IF bx < br THEN bx = br: bdx = -bdx
20.     IF bx > xmax - br THEN bx = xmax - br: bdx = -bdx
21.  
22.     by = by + bdy
23.     IF by < br THEN by = br: bdy = -bdy
24.     IF by > ymax - br THEN by = ymax - br: bdy = -bdy
25.  
26.     WHILE _MOUSEINPUT '                                            paddle
27.         ma = ma + _MOUSEWHEEL * P2 / 72 '5 degrees change
28.     WEND
29.     mx = _MOUSEX: my = _MOUSEY
30.     mx1 = mx + mr * COS(ma)
31.     my1 = my + mr * SIN(ma)
32.     mx2 = mx + mr * COS(ma + P)
33.     my2 = my + mr * SIN(ma + P)
34.     LINE (mx1, my1)-(mx2, my2), &HFFFF8800
35.     'draw a handle to track the side the ball is on
36.     hx1 = mx + br * COS(ma + Pd2): hy1 = my + br * SIN(ma + Pd2)
37.     hx2 = mx + br * COS(ma - Pd2): hy2 = my + br * SIN(ma - Pd2)
38.     d1 = _HYPOT(hx1 - bx, hy1 - by): d2 = _HYPOT(hx2 - bx, hy2 - by)
39.     IF d1 < d2 THEN LINE (hx2, hy2)-(mx, my), &HFFFF8800 ELSE LINE (hx1, hy1)-(mx, my), &HFFFF8800
40.  
41.     tx = -99: ty = -99
42.     dist = _HYPOT(bx - mx, by - my) '                             collision?
43.     IF dist < br + mr THEN '                                     centers close enough
44.         contacts = lineIntersectCircle%(mx1, my1, mx2, my2, bx, by, br, ix1, iy1, ix2, iy2)
45.         IF contacts THEN PRINT "Contact"; contacts: _DELAY .5 'OK so far
46.         IF contacts = 1 THEN 'just touched (or passed through)
47.             IF _HYPOT(ix1 - mx, iy1 - my) < br THEN tx = ix1: ty = iy1
48.         ELSEIF contacts = 2 THEN
49.             'contact point would have been in middle of 2 points
50.             tx = (ix1 + ix2) / 2: ty = (iy1 + iy2) / 2
51.         END IF
52.         IF tx > 0 THEN ' rebound ball
53.             CIRCLE (tx, ty), 2
54.             ba = _ATAN2(bdy, bdx)
55.             bs = _HYPOT(bdx, bdy)
56.             ta = _ATAN2(ty - by, tx - bx)
57.             PRINT ba, bs, ta, ma
58.             IF ba - (ma + _PI / 2) < _PI / 2 THEN
59.                 ba = ba - (ma + _PI / 2)
60.             ELSE
61.                 ba = ba - (ma - _PI / 2)
62.             END IF
63.             bdx = bs * COS(ba) 'update the new direction of ball
64.             bdy = bs * SIN(ba)
65.         END IF
66.     END IF
67.     CIRCLE (bx, by), br 'ball
68.     _DISPLAY
69.     _LIMIT 60
70. WEND
71.  
72.  
73. ' return 0 no Intersect, 1 = tangent 1 point touch, 2 = 2 point intersect
74. FUNCTION lineIntersectCircle% (lx1, ly1, lx2, ly2, cx, cy, r, ix1, iy1, ix2, iy2)
75.  
76.     'needs    SUB slopeYintersect (X1, Y1, X2, Y2, slope, Yintercept)
77.  
78.     IF lx1 <> lx2 THEN
79.         slopeYintersect lx1, ly1, lx2, ly2, m, Y0 ' Y0 otherwise know as y Intersect
80.  
81.         ' https://math.stackexchange.com/questions/228841/how-do-i-calculate-the-intersections-of-a-straight-line-and-a-circle
82.         A = m ^ 2 + 1
83.         B = 2 * (m * Y0 - m * cy - cx)
84.         C = cy ^ 2 - r ^ 2 + cx ^ 2 - 2 * Y0 * cy + Y0 ^ 2
85.         D = B ^ 2 - 4 * A * C 'telling part of Quadratic formula = 0 then circle is tangent  or > 0 then 2 intersect points
86.         IF D < 0 THEN ' no intersection
87.             ix1 = -999: iy1 = -999: ix2 = -999: iy2 = -999: lineIntersectCircle% = 0
88.         ELSEIF D = 0 THEN ' one point tangent
89.             x1 = (-B + SQR(D)) / (2 * A)
90.             y1 = m * x1 + Y0
91.             ix1 = x1: iy1 = y1: ix2 = -999: iy2 = -999: lineIntersectCircle% = 1
92.         ELSE '2 points
93.             x1 = (-B + SQR(D)) / (2 * A): y1 = m * x1 + Y0
94.             x2 = (-B - SQR(D)) / (2 * A): y2 = m * x2 + Y0
95.             ix1 = x1: iy1 = y1: ix2 = x2: iy2 = y2: lineIntersectCircle% = 2
96.         END IF
97.     ELSE 'vertical line
98.         IF r = ABS(lx1 - cx) THEN ' tangent
99.             ix1 = lx1: iy1 = cy: ix2 = -999: iy2 = -999: lineIntersectCircle% = 1
100.         ELSEIF r < ABS(lx1 - cx) THEN 'no intersect
101.             ix1 = -999: iy1 = -999: ix2 = -999: iy2 = -999: lineIntersectCircle% = 0
102.         ELSE '2 point intersect
103.             ydist = SQR(r ^ 2 - (lx1 - cx) ^ 2)
104.             ix1 = lx1: iy1 = cy + ydist: ix2 = lx1: iy2 = cy - ydist: lineIntersectCircle% = 2
105.         END IF
106.     END IF
107. END FUNCTION
108.  
109. SUB slopeYintersect (X1, Y1, X2, Y2, slope, Yintercept) ' fix for when x1 = x2
110.     slope = (Y2 - Y1) / (X2 - X1)
111.     Yintercept = slope * (0 - X1) + Y1
112. END SUB
113.  
114.  

[STxAxTIC]

I should have posted my notes here rather than there! Ball rebound is perfectly calculated at:

https://www.qb64.org/forum/index.php?topic=2319.msg115468#msg115468

Limit the second ball at r=infinity to turn it into a line and let its mass be infinite if you dont want the paddle to rebound.

[bplus]

Well for now I will settle for treating ball meets paddle the same as ball meets wall, only the wall/paddle has infinitely many angles (theoretically). That is why I needed to know which side of the wall/paddle the ball is. Ball meets moving paddle/wall is for later.

[bplus]

I think I have it. I put a tracer on the ball and paddle to show that the the angle in = the angle out as in a reflection of light.

Code: QB64: [Select]

1. _TITLE "Angle Paddle Test, mouse wheel down is clockwise" 'b+ started 2020-03-08  from _vince idea
2. CONST xmax = 800, ymax = 600, xc = 400, yc = 300
3. DIM SHARED P, P2, Pd2
4. P = _PI: P2 = 2 * P: Pd2 = P / 2
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _DELAY .2 'need time for screen to load before attempting to move it.
7. _SCREENMOVE _MIDDLE
8. RANDOMIZE TIMER
9.  
10. bx = xc: by = yc: br = 20: bs = 5: ba = _D2R(60)
11. mr = 50: ma = 0
12. WHILE _KEYDOWN(27) = 0
13.  
14.     LINE (0, 0)-(xmax, ymax), &H10000000, BF
15.     bdx = bs * COS(ba): bdy = bs * SIN(ba)
16.     LOCATE 1, 1: PRINT "ma"; _R2D(ma) \ 1; "  ba"; _R2D(ba) \ 1
17.  
18.     bx = bx + bdx
19.     IF bx < br THEN bx = br: bdx = -bdx
20.     IF bx > xmax - br THEN bx = xmax - br: bdx = -bdx
21.  
22.     by = by + bdy
23.     IF by < br THEN by = br: bdy = -bdy
24.     IF by > ymax - br THEN by = ymax - br: bdy = -bdy
25.  
26.     ba = _ATAN2(bdy, bdx)
27.  
28.     WHILE _MOUSEINPUT '                                            paddle
29.         ma = ma + _MOUSEWHEEL * P2 / 72 '5 degrees change
30.     WEND
31.     mx = _MOUSEX: my = _MOUSEY
32.     mx1 = mx + mr * COS(ma)
33.     my1 = my + mr * SIN(ma)
34.     mx2 = mx + mr * COS(ma + P)
35.     my2 = my + mr * SIN(ma + P)
36.     LINE (mx1, my1)-(mx2, my2), &HFFFF8800
37.     'draw a handle to track the side the ball is on
38.     hx1 = mx + br * COS(ma + Pd2): hy1 = my + br * SIN(ma + Pd2)
39.     hx2 = mx + br * COS(ma - Pd2): hy2 = my + br * SIN(ma - Pd2)
40.     d1 = _HYPOT(hx1 - bx, hy1 - by): d2 = _HYPOT(hx2 - bx, hy2 - by)
41.  
42.     IF d1 < d2 THEN
43.         LINE (hx2, hy2)-(mx, my), &HFFFF8800
44.         paddleNormal = _ATAN2(my - hy2, mx - hx2)
45.     ELSE
46.         LINE (hx1, hy1)-(mx, my), &HFFFF8800
47.         paddleNormal = _ATAN2(my - hy1, mx - hx1)
48.     END IF
49.  
50.     tx = -99: ty = -99
51.     dist = _HYPOT(bx - mx, by - my) '                             collision?
52.     IF dist < br + mr THEN '                                     centers close enough
53.         contacts = lineIntersectCircle%(mx1, my1, mx2, my2, bx, by, br, ix1, iy1, ix2, iy2)
54.         IF contacts THEN PRINT "Contact"; contacts ': _DELAY .5 'OK so far
55.         IF contacts = 1 THEN 'just touched (or passed through)
56.             IF _HYPOT(ix1 - mx, iy1 - my) < br THEN tx = ix1: ty = iy1
57.         ELSEIF contacts = 2 THEN
58.             'contact point would have been in middle of 2 points
59.             tx = (ix1 + ix2) / 2: ty = (iy1 + iy2) / 2
60.         END IF
61.         IF tx > 0 THEN ' rebound ball
62.             CIRCLE (tx, ty), 2 'show contact point
63.  
64.             'relocate bx, by
65.             bx = tx + br * COS(paddleNormal) 'this is where the ball would be at contact
66.             by = ty + br * SIN(paddleNormal)
67.  
68.             'find the angle of reflection
69.             ba = _ATAN2(bdy, bdx)
70.             aReflect = ABS(paddleNormal - ba) 'apparently I have to flip the next clac by PI
71.             IF ba < paddleNormal THEN ba = paddleNormal + aReflect + P ELSE ba = paddleNormal - aReflect + P
72.  
73.         END IF
74.     END IF
75.     CIRCLE (bx, by), br 'ball
76.     _DISPLAY
77.     _LIMIT 60
78. WEND
79.  
80.  
81. ' return 0 no Intersect, 1 = tangent 1 point touch, 2 = 2 point intersect
82. FUNCTION lineIntersectCircle% (lx1, ly1, lx2, ly2, cx, cy, r, ix1, iy1, ix2, iy2)
83.  
84.     'needs    SUB slopeYintersect (X1, Y1, X2, Y2, slope, Yintercept)
85.  
86.     IF lx1 <> lx2 THEN
87.         slopeYintersect lx1, ly1, lx2, ly2, m, Y0 ' Y0 otherwise know as y Intersect
88.  
89.         ' https://math.stackexchange.com/questions/228841/how-do-i-calculate-the-intersections-of-a-straight-line-and-a-circle
90.         A = m ^ 2 + 1
91.         B = 2 * (m * Y0 - m * cy - cx)
92.         C = cy ^ 2 - r ^ 2 + cx ^ 2 - 2 * Y0 * cy + Y0 ^ 2
93.         D = B ^ 2 - 4 * A * C 'telling part of Quadratic formula = 0 then circle is tangent  or > 0 then 2 intersect points
94.         IF D < 0 THEN ' no intersection
95.             ix1 = -999: iy1 = -999: ix2 = -999: iy2 = -999: lineIntersectCircle% = 0
96.         ELSEIF D = 0 THEN ' one point tangent
97.             x1 = (-B + SQR(D)) / (2 * A)
98.             y1 = m * x1 + Y0
99.             ix1 = x1: iy1 = y1: ix2 = -999: iy2 = -999: lineIntersectCircle% = 1
100.         ELSE '2 points
101.             x1 = (-B + SQR(D)) / (2 * A): y1 = m * x1 + Y0
102.             x2 = (-B - SQR(D)) / (2 * A): y2 = m * x2 + Y0
103.             ix1 = x1: iy1 = y1: ix2 = x2: iy2 = y2: lineIntersectCircle% = 2
104.         END IF
105.     ELSE 'vertical line
106.         IF r = ABS(lx1 - cx) THEN ' tangent
107.             ix1 = lx1: iy1 = cy: ix2 = -999: iy2 = -999: lineIntersectCircle% = 1
108.         ELSEIF r < ABS(lx1 - cx) THEN 'no intersect
109.             ix1 = -999: iy1 = -999: ix2 = -999: iy2 = -999: lineIntersectCircle% = 0
110.         ELSE '2 point intersect
111.             ydist = SQR(r ^ 2 - (lx1 - cx) ^ 2)
112.             ix1 = lx1: iy1 = cy + ydist: ix2 = lx1: iy2 = cy - ydist: lineIntersectCircle% = 2
113.         END IF
114.     END IF
115. END FUNCTION
116.  
117. SUB slopeYintersect (X1, Y1, X2, Y2, slope, Yintercept) ' fix for when x1 = x2
118.     slope = (Y2 - Y1) / (X2 - X1)
119.     Yintercept = slope * (0 - X1) + Y1
120. END SUB
121.  
122.