Image color swap?

[Craz1000]

So i am creating another sprite based game. And i have gotten to a point to where i can have an excessive amount of sprites loaded or do a color swap.

my question is... if i have for example
PlayerSprite& = _LOADIMAGE("Images\Player1.png")

If player 1 is blue in color and i want player 2 to be green, am I able just swap blue to green on PlayerSprite& or am i going to have to have 2 different sprites?

[Petr]

Hi, 2 different image handle, but you can do this 2 handle from one image. As show this easy example:

Code: QB64: [Select]

1. $COLOR:32
2.  
3. 'this do image (the same as load it from harddrive)
4. UniversalSprite& = _NEWIMAGE(320, 240, 32)
5. _DEST UniversalSprite&
6. CLS , Yellow
7. LINE (20, 20)-(300, 220), Blue, BF
8. _DEST 0
9.  
10. SCREEN _NEWIMAGE(800, 600, 32)
11. Sprite1 = _COPYIMAGE(UniversalSprite&, 32)
12. Sprite2 = swapcolor(UniversalSprite&, Blue, Red)
13.  
14. _PUTIMAGE (50, 100), Sprite1
15. _PUTIMAGE (430, 100), Sprite2
16.  
17. FUNCTION swapcolor (handle, oldcolor~&, newcolor~&)
18.     DIM m AS _MEM, c AS _UNSIGNED LONG
19.     swapcolor = _COPYIMAGE(handle, 32)
20.     m = _MEMIMAGE(swapcolor)
21.     DO UNTIL a& = m.SIZE - 4
22.         a& = a& + 4
23.         c~& = _MEMGET(m, m.OFFSET + a&, _UNSIGNED LONG)
24.         IF c~& = oldcolor~& THEN _MEMPUT m, m.OFFSET + a&, newcolor~&
25.     LOOP
26.     _MEMFREE m
27. END FUNCTION
28.  

you use two handle - Sprite1 and Sprite2, in this example is Sprite1 original image - the same as UniversalSprite and Sprite2 is created from UniversalSprite in red color. So, if your image is easy, you can do it in this way from one source image.

[Craz1000]

Images are very small, probably 50 pixels at most, and have very limited colors. this should do nicely... thank you

[OldMoses]

The _MEM approach that Petr shows is probably the easiest way to do that. Testing for specific values and swapping them.

It's funny to me that it is Petr that answered this, as I had the same issue with one of his routines that I used in my project. I wanted to be able the change the colors of the characters in his character image system that he shared at:

https://www.qb64.org/forum/index.php?topic=498.msg3458#msg3458

which makes a handy way to resize text in a graphics screen.

I ended up trying the following after studying Steve's _MEM tutorials (great stuff BTW):

Code: QB64: [Select]

1. SUB AscAlter2 (var AS _UNSIGNED LONG)
2.  
3.     'Changes color/alpha of Petr's character image system- call before Prnt to set desired colors
4.     'var carries color value
5.  
6.     DIM m AS _MEM
7.     c = 0
8.     DO '                                                        iterate through character set
9.         x = 0
10.         m = _MEMIMAGE(chr_img(c))
11.         DO '                                                    iterate through character image
12.             IF _MEMGET(m, m.OFFSET + x, _UNSIGNED LONG) = &H00000000 THEN 'originals must be in _PRINTMODE _KEEPBACKGROUND
13.                 'make no change
14.             ELSE '                                              change color of character pixels
15.                 _MEMPUT m, m.OFFSET + x, var
16.             END IF
17.             x = x + 4 '                                         step to next long value memory location
18.         LOOP UNTIL x >= m.SIZE - 4
19.         c = c + 1 '                                             advance to next character image
20.     LOOP UNTIL c = 256
21.     _MEMFREE m
22.  
23. END SUB 'AscAlter2
24.  

It worked quite well, but after doing a speed test, I found that redefining the set with his original routine was actually about 5 times faster on average. My assumption is that the two nested loops were creating more overhead than _MEM commands were saving. For your application, running through a single loop on a small sprite, it should be fine.

[Petr]

OldMoses wrote:

It's funny to me that it is Petr that answered this, as I had the same issue with one of his routines that I used in my project. I wanted to be able the change the colors of the characters in his character image system that he shared

I am almost sure that, due to my poor knowledge of English, I did not understand your question. Now that I understand it, I would follow so:

Code: QB64: [Select]

1. 'use  IDE 1.4
2. $COLOR:32
3.  
4. DIM SHARED chars(255) AS LONG
5. SCREEN _NEWIMAGE(800, 600, 32)
6.  
7. FOR Ascii = 0 TO 255
8.     chars(Ascii) = _NEWIMAGE(10, 20, 32)
9.     _DEST chars(Ascii)
10.     _PRINTSTRING (0, 0), CHR$(Ascii), chars(Ascii)
11. NEXT Ascii
12. _DEST 0
13.  
14. Prnt "What you think? Something this?", 1, 10, 10, 20, 15
15. SLEEP 1
16. Prnt "You have many options in QB64...", 2, 10, 500, 20, -15
17.  
18.  
19.  
20. SUB Prnt (text AS STRING, size AS INTEGER, StartX AS INTEGER, StartY AS INTEGER, Xspace AS INTEGER, Yspace AS INTEGER)
21.     x = StartX
22.     y = StartY
23.     FOR f = 1 TO LEN(text)
24.         ch = ASC(text, f)
25.         x = x + Xspace
26.         IF x MOD 5 = 0 THEN y = y + Yspace
27.         'colorize character:
28.  
29.         ColoredChar = swapcolor(chars(ch), White, _RGB32(RND * 255, RND * 255, RND * 255))
30.         _PUTIMAGE (x, y)-(x + (size * 16), y + (size * (8 * f))), ColoredChar, 0
31.         _FREEIMAGE ColoredChar
32.         _DELAY .1
33.     NEXT
34. END SUB
35.  
36. FUNCTION swapcolor (handle, oldcolor~&, newcolor~&)
37.     DIM m AS _MEM, c AS _UNSIGNED LONG
38.     swapcolor = _COPYIMAGE(handle, 32)
39.     m = _MEMIMAGE(swapcolor)
40.     DO UNTIL a& = m.SIZE - 4
41.         a& = a& + 4
42.         c~& = _MEMGET(m, m.OFFSET + a&, _UNSIGNED LONG)
43.         IF c~& = oldcolor~& THEN _MEMPUT m, m.OFFSET + a&, newcolor~&
44.     LOOP
45.     _MEMFREE m
46. END FUNCTION
47.  

This code was added here because the original thread is locked. Is used the same function as in the previous case in this thread.

[Petr]

It is likely that SwapColor, as it is, is too sharply focused on a particular color. Compressing images into JPG and PNG formats scatters colors into colors of similar value. This can then cause nasty artifacts. That's why I created a better version here that will recolor pixels with some overlap from the specified color.

I planted the program for use with motion pictures. It's just a quick version that can withstand many improvements and fixes ... but I don't have time for that right now.

Code: QB64: [Select]

1. 'use  IDE 1.4
2. $COLOR:32
3.  
4. DIM SHARED chars(255) AS LONG
5. REDIM Sprites(0) AS LONG, NSprites(0) AS LONG, N2Sprites(0) AS LONG
6. SCREEN _NEWIMAGE(900, 600, 32)
7. 'GOTO lspr
8.  
9.  
10. FOR Ascii = 0 TO 255
11.     chars(Ascii) = _NEWIMAGE(10, 20, 32)
12.     _DEST chars(Ascii)
13.     _PRINTSTRING (0, 0), CHR$(Ascii), chars(Ascii)
14. NEXT Ascii
15. _DEST 0
16.  
17. Prnt "What you think? Something this?", 1, 10, 10, 20, 15
18. SLEEP 1
19. Prnt "You have many options in QB64...", 2, 10, 500, 20, -15
20.  
21. 'lspr:
22.  
23. LOADSPRITE Sprites(), "penguin.jpg", 55, 100, 10, 0, 477
24. COPYIMAGEARRAY Sprites(), NSprites()
25. COPYIMAGEARRAY Sprites(), N2Sprites()
26. ReColor NSprites(), _RGB32(209, 70, 91), 20, 20, 20, -50, 80, -90
27. ReColor N2Sprites(), _RGB32(209, 60, 81), 30, 30, 30, -110, 110, 80
28. DO
29.     f = f + 1
30.     IF f > 10 THEN f = 1
31.  
32.     _PUTIMAGE (80 * (f - 1), 100), Sprites(f)
33.     _PRINTSTRING (80 * (f - 1), 100), STR$(f)
34.  
35.     _PUTIMAGE (100, 200), Sprites(f)
36.     _PUTIMAGE (100, 300), NSprites(f)
37.     _PUTIMAGE (100, 400), N2Sprites(f)
38.     _DISPLAY
39.     _LIMIT 20
40. LOOP
41.  
42.  
43. SUB Prnt (text AS STRING, size AS INTEGER, StartX AS INTEGER, StartY AS INTEGER, Xspace AS INTEGER, Yspace AS INTEGER)
44.     x = StartX
45.     y = StartY
46.     FOR f = 1 TO LEN(text)
47.         ch = ASC(text, f)
48.         x = x + Xspace
49.         IF x MOD 5 = 0 THEN y = y + Yspace
50.         'colorize character:
51.  
52.         ColoredChar = swapcolor(chars(ch), White, _RGB32(RND * 255, RND * 255, RND * 255))
53.         _PUTIMAGE (x, y)-(x + (size * 16), y + (size * (8 * f))), ColoredChar, 0
54.         _FREEIMAGE ColoredChar
55.         _DELAY .1
56.     NEXT
57. END SUB
58.  
59. FUNCTION swapcolor (handle, oldcolor~&, newcolor~&)
60.     DIM m AS _MEM, c AS _UNSIGNED LONG
61.     swapcolor = _COPYIMAGE(handle, 32)
62.     m = _MEMIMAGE(swapcolor)
63.     DO UNTIL a& = m.SIZE - 4
64.         a& = a& + 4
65.         c~& = _MEMGET(m, m.OFFSET + a&, _UNSIGNED LONG)
66.         IF c~& = oldcolor~& THEN _MEMPUT m, m.OFFSET + a&, newcolor~&
67.     LOOP
68.     _MEMFREE m
69. END FUNCTION
70.  
71. SUB ReColor (arr() AS LONG, oldcolor~&, zoneR AS _UNSIGNED _BYTE, zoneG AS _UNSIGNED _BYTE, zoneB AS _UNSIGNED _BYTE, AddtoR AS _UNSIGNED _BYTE, AddtoG AS _UNSIGNED _BYTE, AddtoB AS _UNSIGNED _BYTE)
72.     DIM m AS _MEM, c AS _UNSIGNED LONG, R AS _UNSIGNED _BYTE, G AS _UNSIGNED _BYTE, B AS _UNSIGNED _BYTE, A AS _UNSIGNED _BYTE
73.     Ro = _RED32(oldcolor~&): Go = _GREEN32(oldcolor~&): Bo = _BLUE32(oldcolor~&): Ao = _ALPHA32(oldcolor~&): DIM Cn AS _UNSIGNED LONG
74.  
75.     DO UNTIL complete = UBOUND(arr) - 1
76.         complete = complete + 1
77.  
78.         m = _MEMIMAGE(arr(complete))
79.         h = 0
80.         DO UNTIL h = m.SIZE - 4
81.             h = h + 4
82.             _MEMGET m, m.OFFSET + h, c~&
83.             R = _RED32(c~&)
84.             G = _GREEN32(c~&)
85.             B = _BLUE32(c~&)
86.             A = _ALPHA32(c~&)
87.  
88.             IF ABS(Ro - R) <= zoneR THEN
89.                 IF ABS(Go - G) <= zoneG THEN
90.                     IF ABS(Bo - B) <= zoneB THEN
91.                         Cn~& = _RGB32(R + AddtoR, G + AddtoG, B + AddtoB)
92.                         _MEMPUT m, m.OFFSET + h, Cn~&
93.                     END IF
94.                 END IF
95.             END IF
96.         LOOP
97.     LOOP
98. END SUB
99.  
100. SUB COPYIMAGEARRAY (sourceArr() AS LONG, newArr() AS LONG)
101.     REDIM newArr(LBOUND(sourcearr) TO UBOUND(sourcearr)) AS LONG
102.     FOR c = LBOUND(sourcearr) TO UBOUND(sourcearr)
103.         newArr(c) = _COPYIMAGE(sourceArr(c), 32)
104.     NEXT
105. END SUB
106.  
107. SUB LOADSPRITE (frames() AS LONG, sourcefile AS STRING, lenght AS INTEGER, height AS INTEGER, frames_total AS INTEGER, Xstart_offset AS INTEGER, ystartoffset AS INTEGER)
108.     IF _FILEEXISTS(sourcefile) THEN
109.         handle = _LOADIMAGE(sourcefile, 32)
110.         REDIM frames(frames_total) AS LONG
111.         FOR LoadSprte = 1 TO frames_total
112.             frames(LoadSprte) = _NEWIMAGE(lenght, height, 32)
113.             predest = _DEST
114.             _DEST frames(LoadSprte): CLS: _DEST predest
115.             _PUTIMAGE (0, 0), handle, frames(LoadSprte), (Xstart_offset + (LoadSprte * lenght), ystartoffset)-(Xstart_offset + (LoadSprte * 2 * lenght), ystartoffset + height)
116.             REM  _CLEARCOLOR White, frames(LoadSprte)
117.         NEXT
118.     END IF
119. END SUB
120.  

You need attached sprite image Penguin.jpg for this code.

[OldMoses]

Excellent! I never thought of swapping colors of just the copy of the character used at the Prnt, I was just redefining the entire set each time.

BTW, it probably has more to do with MY poor English, and it's my first language. My composition is nearly as ham handed as my coding. ;)