Show Posts

This section allows you to view all posts made by this member. Note that you can only see posts made in areas you currently have access to.

Topics - Cobalt

Pages: [1] 2 3 ... 8

QB64 Discussion / Why is my END IF tabbed(spaced) wrong?

« on: February 15, 2022, 12:30:44 pm »

Everything else being spaced correctly why not this END IF? Both auto spacing and auto Indent is on. Can not recall ever seeing this before.
Pulled out just the code displaying the situation, and added the type and dims so there would be no errors stopping the auto format and it still happens. Through out the rest of the code all the other END IFs are spaced correctly, this is the only one.

Code: QB64: [Select]

TYPE Offset_data
    X AS INTEGER
    Y AS INTEGER
    Xs AS _BYTE
    Ys AS _BYTE
END TYPE
 
DIM SHARED Layer(32) AS LONG, Sprites(64) AS Offset_data
DIM SHARED DungeonMaps(9, 7, 3) AS _BYTE
Game.Scale = 1
 
SUB Draw_Mini_Map
    FOR y%% = 0 TO 3: FOR x%% = 0 TO 7
        IF DungeonMaps(Link.Dungeon, x%%, y%%) THEN
            _PUTIMAGE (16 + 8 * x%%, 16 + 8 * y%%)-STEP(Sprites(39 + DungeonMaps(Link.Dungeon, x%%, y%%)).Xs * Game.Scale, Sprites(39 + DungeonMaps(Link.Dungeon, x%%, y%%)).Ys * Game.Scale), Layer(9), Layer(1), (Sprites(39 + DungeonMaps(Link.Dungeon, x%%, y%%)).X, Sprites(39 + DungeonMaps(Link.Dungeon, x%%, y%%)).Y)-STEP(Sprites(39 + DungeonMaps(Link.Dungeon, x%%, y%%)).Xs * Game.Scale, Sprites(39 + DungeonMaps(Link.Dungeon, x%%, y%%)).Ys * Game.Scale)
            END IF
    NEXT x%%, y%%
    _PUTIMAGE (14 + Link.World_X * 4, 16 + Link.World_Y * 4)-STEP(2, 2), Layer(9), Layer(1), (618, 126)-STEP(2, 2) 'Map location beacon
END SUB
 

[ You are not allowed to view this attachment ]

QB64 Discussion / Possible issue with Select Case

« on: February 07, 2022, 04:52:48 pm »

Ran across this today, could some of you other guys test and confirm the issue?

You should get a beep, if not then there seems to be a problem with CASE # TO #

Found in current stable version, tested in latest DB(well a week old or so) same issue for me in both.

And YES the TO keyword is allowed and used in this manner. (see image)

Code: QB64: [Select]

x%% = 15
SELECT CASE x%%
 CASE 16 TO 11 'full smoke
  '    _PUTIMAGE (Objects(i%%).X, Objects(i%%).Y)-STEP(15, 15), Layer(7), Layer(10), (239 + 17 * 0, 1)-STEP(15, 15)
  BEEP
 CASE 10 TO 5 '2\3 smoke
  '    _PUTIMAGE (Objects(i%%).X, Objects(i%%).Y)-STEP(15, 15), Layer(7), Layer(10), (239 + 17 * 1, 1)-STEP(15, 15)
 CASE 4 TO 1 '1\3 smoke
  '    _PUTIMAGE (Objects(i%%).X, Objects(i%%).Y)-STEP(15, 15), Layer(7), Layer(10), (239 + 17 * 2, 1)-STEP(15, 15)
 CASE 0 'display object
  Result%% = TRUE
END SELECT
 

[ You are not allowed to view this attachment ]

QB64 Discussion / Why is an empty include file "not found"?

« on: January 27, 2022, 01:27:26 pm »

Was prepping my program to chuck some finalized SUBs into an include file and pre-made the include file and added the include line and it gave the error that the file was not found.

Whats the deal?

[ You are not allowed to view this attachment ]

QB64 Discussion / Double Check on order of operations

« on: January 22, 2022, 02:43:56 pm »

So in our order of operations, are * and /(and \) on the same level or does one take precedence over the other?
for instance if we have;

Scale%% = 3
Xloc% = 450 - 16 * 11 \ 2 * Scale%%

Would everything after the `-` evaluate from left to right or would(should) both multiplications go then the division? Since both Multiply and Divide are secondary operations(following Exponents and SQR).
I know the `-` goes last, but was curious if this would run straight or if I have to waste extra time and characters adding () around parts of it.(my testing says the latter, but wanted to make sure my testing was correct)

funny how you can spend years coding and never run across something then out of the blue...

QB64 Discussion / Small hiccup in ABS

« on: January 04, 2022, 12:57:43 pm »

Found this small hiccup in our ABS function. As ABS typically turns a negative(-) number into a positive one. however it is failing to do so with the BYTE type at a value of -128 as demonstrated by the following code.

Code: QB64: [Select]

Shift%% = 127
Shift%% = Shift%% + 1
PRINT ABS(Shift%%); Shift%%
 
PRINT
 
Shift%% = Shift%% + 1
PRINT ABS(Shift%%); Shift%%
 

output:

-128 -128

127 -127

the -128 fails to print positive with ABS but the -127(and on) works correctly.
seems to be this way from 1.1 build 82(oldest I have at the ready) clear up to 2.0.2 4d85302

Update, further testing show it does this with INTEGER(at -32768) and LONG(at -2147483648) too. However INTEGER64 works correctly.

Programs / Zelda 64(NES Zelda Clone) Demo

« on: December 19, 2021, 09:41:26 pm »

After taking a peek at Craz1000's Master Sword game (based on the NES game Zelda) reminded me of my Zelda Clone I started in March 2018! So I brought it up, deleted all the code and started from scratch!
And here is my past Weeks worth of work on it!

Temporary controls(Defaults)

Letter controls are UPPER CASE!

A - Start Button
B - Select Button (change selection(option) in game selection screen)
Space Bar - Button A (attack)
Enter - Button B(not used yet)
Arrow Keys - Map navigation, letter selection

The Title Scroll works!
The Game Selection menus all work, Pick a game to resume, Register a name, and Elimination Mode.
Once Registering and picking your character you can Explore the map.
At the moment the map is empty, no creatures to combat, No caves or dungeons to enter. You do start with the first sword so blast and slash away!

took me a few hours to get the map traversing done, took 4 DAYS to get the title screen and game selection screens working!

Really putting this up here to see what people think of the Title screen and Selection screens, and to see if anyone can break those parts.

I should warn you it is possible to get stuck, if you change map screens and the next screen bottle necks down you can wind up stuck in rock. There is no way to undo this yet, you have to quit.

As I do not have the OPTIONS screen done yet, there is one option you can manually play with if you like, the Scale option. There are 3 settings; LINE 116:G.Scale_Factor = 1
1- Small(actual game size) 256x224px
2- Normal 512x448px
3- Large 768x672px

at scale 1 a debugging map of the game is displayed at the top of the screen, the yellow square is you.

(developed in 2.0.2, but tested on 1.4,1.5,and 1.6 all work[should work with all versions back to 1.1build82])

Code: QB64: [Select]

'Zelda Clone take 2
 
TYPE ControllerKeys
 KBCon_Up AS LONG
 KBCon_Down AS LONG
 KBCon_Left AS LONG
 KBCon_Right AS LONG
 KBCon_Select AS LONG
 KBCon_Start AS LONG
 KBCon_A_Button AS LONG
 KBCon_B_Button AS LONG
END TYPE
 
TYPE Game_Data
 Impactflag AS _BYTE
 Scale_Factor AS _BYTE
 Scale_X AS _BYTE
 Scale_Y AS _BYTE
 NextScreen AS _BYTE
 Wtime AS _BYTE
 Atime AS _BYTE
 Wframe AS _BYTE
 Aframe AS _BYTE
 Projectile_Count AS _BYTE
 LoadedGame AS _BYTE 'which game is loaded?(1-3)
END TYPE
 
TYPE Projectile_Data
 Id AS _BYTE '       Kind of projectile; Sword\Arrow\Rock\Ball
 Xloc AS INTEGER '   Projectile location
 Yloc AS INTEGER '
 Direction AS _BYTE 'Direction Projectile is traveling
 Hits AS _BYTE '     Hits per projectile\(AKA:damage) in half heart increments
 Owner AS _BYTE '    Who shot the projectile
END TYPE
 
TYPE Links_Data
 '-----Position data-----
 World AS _BYTE '           Player in Overworld or Underworld
 World_X AS _BYTE '         Overworld X position
 World_Y AS _BYTE '         Overworld Y position
 Tile_X AS _UNSIGNED _BYTE 'Array X location:for Collision\entrances
 Tile_Y AS _BYTE '          Array Y location:for Collision\entrances
 Screen_X AS INTEGER '      X Position on screen
 Screen_Y AS INTEGER '      Y Position on screen
 Direction AS _BYTE '       Direction player is moving\facing
 '-----------------------
 '------Status Data------
 Hearts AS _BYTE '    Units of health: 2 units(halves) per heart
 Containers AS _BYTE 'Max number of health: total full hearts
 Hits AS _BYTE '      Used when Link has defence rings;Blue = 2 hits per 1\2 heart, Red = 4 hits per 1\2 heart
 '-----------------------
 '------Items Data-------
 Sword AS _BYTE ' which Sword does player have? Wooden-1,Silver-2,Magical-3
 Weapon AS _BYTE 'Which Weapon is in hand A? Wooden-1,Silver-2,Magical-3,Wand-4
 Ring AS _BYTE 'which does player have? 0-none, 1-blue,2-red
 '-----------------------
 '------Extra Data-------
 Action AS _BYTE '          is player; using an item, Aquiring an item\sword, or aquiring a piece of the triforce?
 Shot AS _BYTE '            player has shot sword
 Projectile_id AS _BYTE '
 Played AS _UNSIGNED _BYTE 'how many times has player played?
 Beaten AS _BYTE '          Has player beaten Game 1? Game 2?
 '-----------------------
END TYPE
 
TYPE Map_Data
 Id AS _UNSIGNED _BYTE 'Tile id
 Hidden AS _BYTE '      is there something under the tile?
 Burnable AS _BYTE '    can the tile be burnt with candle?
 Pushable AS _BYTE '    can the tile be moved by pushing?
 PushableXtra AS _BYTE 'can the tile be moved by pushing with braclet?
 Is_Shop AS _BYTE '     is there a shop here?(shop\gift\gamble)
 Walkable AS _BYTE '    can the tile be walk upon?
END TYPE
 
 
CONST TRUE = -1, FALSE = NOT TRUE, None = 0
CONST Up = 3, Right = 2, Left = 1, Down = 0, SELECT_BUTTON = 4, START_BUTTON = 5, BUTTON_B = 6, BUTTON_A = 7
CONST OverWorld = 0, UnderWorld = 1
CONST Walking = 1, Useing = 2, GetItem = 3, GetTriforce = 4, Attack = 5
CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
CONST Key_Space = 32, Key_Enter = 13
CONST Default_Key_Right = 19712, Default_Key_Left = 19200, Default_Key_Up = 18432, Default_Key_Down = 20480
CONST Default_A_Button = 32, Default_B_Button = 13, Default_Start_Button = 65, Default_Select_Button = 66
CONST Sword = 1, Arrow = 2, Rock = 3, Ball = 4, Boomerang = 5
CONST Player = 1, Monster = 2
CONST Item = 0, Slash = 1, Stairs = 2, SwordShot = 3
 
DIM SHARED Layer(16) AS LONG, Hyrule(255, 87) AS Map_Data, Link AS Links_Data, Reset_Link AS Links_Data
DIM SHARED C AS ControllerKeys, G AS Game_Data, P(16) AS Projectile_Data, Letter(44) AS STRING * 1
DIM SHARED Offset_X(3) AS INTEGER, Offset_Y(3) AS INTEGER, Cave(15, 10) AS Map_Data
DIM SHARED BGM(8) AS LONG, SFX(10) AS LONG, FFX(1) AS LONG
DIM SHARED Records(3) AS Links_Data, Nick(3) AS STRING * 8 'loading\registering\elimination
 
SCREEN _NEWIMAGE(800, 600, 32)
 
Layer(0) = _DISPLAY
Layer(1) = _NEWIMAGE(800, 600, 32) 'temp layer
Layer(2) = _NEWIMAGE(640, 480, 256) 'palettized sprite sheet for color shifting
Layer(3) = _NEWIMAGE(800, 600, 32) 'Map background prebuild layer
Layer(4) = _NEWIMAGE(800, 600, 32) 'Mob layer
Layer(5) = _NEWIMAGE(800, 600, 32) 'Sprite layer, moveable\burnable items + bomb holes + pickups
Layer(6) = _NEWIMAGE(12288, 4224, 32) 'PreBuilt Map, upto 300%, for easier map scrolling.
Layer(8) = _NEWIMAGE(800, 600, 32) 'debug map display
Layer(16) = _NEWIMAGE(800, 600, 32) 'temp
 
MFI_Loader "Zelda.MFI"
 
_CLEARCOLOR _RGB32(31), Layer(7)
_CLEARCOLOR _RGB32(116), Layer(12)
_SCREENMOVE 10, 10
 
 
'==================================
G.Scale_Factor = 1
G.Scale_X = 16 * G.Scale_Factor - 1
G.Scale_Y = 16 * G.Scale_Factor - 1
Link.Screen_X = Offset_X(G.Scale_Factor) + (16 * G.Scale_Factor * 7) + 8 * G.Scale_Factor '392
Link.Screen_Y = Offset_Y(G.Scale_Factor) + (16 * G.Scale_Factor * 5) '292
Nick(0) = "": Nick(1) = "": Nick(2) = "": Nick(3) = ""
'==================================
 
'OPEN "debug.txt" FOR OUTPUT AS #6
Build_Map_Screen 16 * Link.World_X, 11 * Link.World_Y
ClearLayer Layer(6)
Build_Map_in_Totallity 'prebuild the entire map at the current scale factor
ClearLayer Layer(1)
_FONT FFX(0), Layer(1)
_FONT FFX(0), Layer(16)
Title_Screen
Select_Screen
 
DO
 SELECT CASE Get_Input
  CASE BUTTON_A
   IF G.Aframe = 0 AND G.Atime = 0 THEN _SNDPLAY SFX(Slash): Link.Action = Attack: Press = Press + 1
   Check_Link_Sword_Shot
  CASE Up
   IF Link.Action <> Attack THEN Link.Direction = Up: Link.Action = Walking
  CASE Down
   IF Link.Action <> Attack THEN Link.Direction = Down: Link.Action = Walking
  CASE Right
   IF Link.Action <> Attack THEN Link.Direction = Right: Link.Action = Walking
  CASE Left
   IF Link.Action <> Attack THEN Link.Direction = Left: Link.Action = Walking
  CASE ELSE
   IF Link.Action = Walking THEN Link.Action = None
 END SELECT
 
 IF Link.Action = GetItem OR Link.Action = GetTriforce THEN
  IF NOT _SNDPLAYING(Temp&) THEN Link.Action = None
 END IF
 '------Graphx build------
 _PUTIMAGE , Layer(3), Layer(1)
 IF Link.Action = Walking THEN Move_Link
 IF Link.Shot THEN Move_Sword_Shot
 IF G.Impactflag THEN Impact 0, 0
 Place_Link
 ' _PRINTSTRING (0, 0), STR$(Link.Tile_X) + STR$(Link.Tile_Y) + STR$(G.Projectile_Count), Layer(1)
 IF G.Scale_Factor = 1 THEN _PUTIMAGE , Layer(8), Layer(1)
 _DEST Layer(1)
 LINE (100 + 2 * Link.Tile_X, 0 + 2 * Link.Tile_Y)-STEP(1, 1), _RGB32(255, 255, 0), BF
 _PUTIMAGE , Layer(1), Layer(0)
 ClearLayer Layer(1)
 '------------------------
 IF INKEY$ = CHR$(27) THEN ExitFlag%% = TRUE
 _LIMIT 60
LOOP UNTIL ExitFlag%%
 
 
SUB Add_Projectile (What%%, Who%%)
 SELECT CASE What%%
  CASE Sword
   P(G.Projectile_Count).Owner = Who%%
   P(G.Projectile_Count).Id = Sword
   P(G.Projectile_Count).Direction = Link.Direction
   IF Who%% = Player THEN
    P(G.Projectile_Count).Xloc = Link.Screen_X
    P(G.Projectile_Count).Yloc = Link.Screen_Y
   ELSE
   END IF
   G.Projectile_Count = G.Projectile_Count + 1
 END SELECT
END SUB
 
SUB Remove_Projectile (What%%, Who%%)
 SELECT CASE What%%
  CASE Sword
   IF Who%% = Player THEN
    G.Projectile_Count = G.Projectile_Count - 1
   END IF
 END SELECT
END SUB
 
SUB Build_Cave_Screen
 FOR Y%% = 0 TO 10
  FOR X%% = 0 TO 15
   Place_Tile_On_Screen (16 * G.Scale_Factor) * X%%, (16 * G.Scale_Factor) * Y%%, Cave(X%%, Y%%).Id, Layer(3)
  NEXT
 NEXT
END SUB
 
SUB Build_Map_Screen (Map_X~%%, Map_Y%%)
 _DEST Layer(8)
 FOR Y%% = 0 TO 10
  FOR X%% = 0 TO 15
   Place_Tile_On_Screen (16 * G.Scale_Factor) * X%%, (16 * G.Scale_Factor) * Y%%, Hyrule(Map_X~%% + X%%, Map_Y%% + Y%%).Id, Layer(3)
  NEXT
 NEXT
 FOR Y%% = 0 TO 87
  FOR x~%% = 0 TO 255
   IF Hyrule(x~%%, Y%%).Walkable = FALSE THEN LINE (100 + 2 * x~%%, 0 + 2 * Y%%)-STEP(1, 1), _RGB32(255), BF
  NEXT
 NEXT
 _DEST Layer(0)
END SUB
 
SUB Build_Map_in_Totallity
 FOR Y%% = 0 TO 87
  FOR X~%% = 0 TO 255
   tile~%% = Hyrule(X~%%, Y%%).Id
   Gy% = 17 * (tile~%% \ 20) 'get which row it comes from
   Gx% = 17 * (tile~%% MOD 20) 'which column position
   _PUTIMAGE ((16 * G.Scale_Factor) * X~%%, (16 * G.Scale_Factor) * Y%%)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(6), (1 + Gx%, 1 + Gy%)-STEP(15, 15)
  NEXT
 NEXT
END SUB
 
SUB Check_Link_Location
 Ax% = Link.World_X * 16 * (16 * G.Scale_Factor) 'gets the Left most pixel point for the current map screen
 Ay% = Link.World_Y * 11 * (16 * G.Scale_Factor) 'gets the Top most pixel point for the current map screen
 Tx~%% = (Ax% + Link.Screen_X - Offset_X(G.Scale_Factor) + (16 * G.Scale_Factor \ 2)) \ 16 * G.Scale_Factor 'now add curent x-offset+50% sprite size
 Ty%% = (Ay% + Link.Screen_Y - Offset_Y(G.Scale_Factor) - 2 + (16 * G.Scale_Factor \ 2)) \ 16 * G.Scale_Factor 'now add curent y-offset+50% sprite size
 IF Hyrule(Tx~%%, Ty%%).Is_Shop THEN Enter_Shop Hyrule(Tx~%%, Ty%%).Is_Shop
 
END SUB
 
SUB Enter_Shop (Which%%)
END SUB
 
SUB Check_Link_Sword_Shot 'Can Link shoot his sword?
 IF Link.Hearts = Link.Containers * 2 THEN 'Link has full hearts and can shoot
  IF NOT _SNDPLAYING(SFX(SwordShot)) THEN 'Link did not just shoot
   IF NOT G.Impactflag THEN 'Link's last shot has finished
    IF NOT Link.Shot THEN
     _SNDPLAY SFX(SwordShot)
     Link.Shot = TRUE
     Add_Projectile Sword, Player
    END IF
   END IF
  END IF
 END IF
END SUB
 
SUB ClearLayer (L&)
 _DEST L&
 CLS
 _DEST _DISPLAY
END SUB
 
SUB ClearLayerTrans (L&)
 _DEST L&
 CLS , 0
 _DEST _DISPLAY
END SUB
 
SUB DarkenImage (Image AS LONG, Value_From_0_To_1 AS SINGLE)
 IF Value_From_0_To_1 <= 0 OR Value_From_0_To_1 >= 1 OR _PIXELSIZE(Image) <> 4 THEN EXIT SUB
 DIM Buffer AS _MEM: Buffer = _MEMIMAGE(Image) 'Get a memory reference to our image
 DIM Frac_Value AS LONG: Frac_Value = Value_From_0_To_1 * 65536 'Used to avoid slow floating point calculations
 DIM O AS _OFFSET, O_Last AS _OFFSET
 O = Buffer.OFFSET 'We start at this offset
 O_Last = Buffer.OFFSET + _WIDTH(Image) * _HEIGHT(Image) * 4 'We stop when we get to this offset
 'use on error free code ONLY!
 $CHECKING:OFF
 DO
  _MEMPUT Buffer, O, _MEMGET(Buffer, O, _UNSIGNED _BYTE) * Frac_Value \ 65536 AS _UNSIGNED _BYTE
  _MEMPUT Buffer, O + 1, _MEMGET(Buffer, O + 1, _UNSIGNED _BYTE) * Frac_Value \ 65536 AS _UNSIGNED _BYTE
  _MEMPUT Buffer, O + 2, _MEMGET(Buffer, O + 2, _UNSIGNED _BYTE) * Frac_Value \ 65536 AS _UNSIGNED _BYTE
  O = O + 4
 LOOP UNTIL O = O_Last
 'turn checking back on when done!
 $CHECKING:ON
 _MEMFREE Buffer
END SUB
 
SUB Fade_Out (L&)
 FOR n! = 1 TO 0.5 STEP -0.05
  i2& = _COPYIMAGE(L&)
  DarkenImage i2&, n!
  _PUTIMAGE (0, 0), i2&, Layer(0)
  _FREEIMAGE i2&
  _DELAY .03
 NEXT
END SUB
 
SUB Fade_In (L&)
 FOR n! = 0.01 TO 1 STEP 0.05
  i2& = _COPYIMAGE(L&)
  DarkenImage i2&, n!
  _PUTIMAGE (0, 0), i2&, Layer(0)
  _FREEIMAGE i2&
  _DELAY .03
 NEXT
END SUB
 
FUNCTION Find_First_Available%% (Which%%, Start%%)
 Selection%% = Start%% 'always start at the first saved game slot then check
 DO 'lets find the first available selection (if there are any saved games)
  IF Selection%% < 4 THEN
   IF Which%% = 0 THEN IF RTRIM$(Nick(Selection%%)) = "" THEN Selection%% = Selection%% + 1 ELSE Good_Selection%% = TRUE
   IF Which%% = 1 THEN IF RTRIM$(Nick(Selection%%)) = "" THEN Good_Selection%% = TRUE ELSE Selection%% = Selection%% + 1
  ELSE '4 and 5 are always good selections
   Good_Selection%% = TRUE
  END IF
 LOOP UNTIL Good_Selection%%
 Find_First_Available = Selection%%
END FUNCTION
 
FUNCTION Get_Input%% ()
 Result%% = TRUE '-1 for no input
 ' SELECT CASE G.ControlType
 '  CASE TRUE 'Keyboard input
 IF _KEYDOWN(C.KBCon_Up) THEN Result%% = Up
 IF _KEYDOWN(C.KBCon_Down) THEN Result%% = Down
 IF _KEYDOWN(C.KBCon_Left) THEN Result%% = Left
 IF _KEYDOWN(C.KBCon_Right) THEN Result%% = Right
 IF _KEYDOWN(C.KBCon_Select) THEN Result%% = SELECT_BUTTON: ' DO: LOOP WHILE _KEYDOWN(C.KBCon_Select)
 IF _KEYDOWN(C.KBCon_Start) THEN Result%% = START_BUTTON: ' DO: LOOP WHILE _KEYDOWN(C.KBCon_Start)
 IF _KEYDOWN(C.KBCon_A_Button) THEN Result%% = BUTTON_A: ' DO: LOOP WHILE _KEYDOWN(C.KBCon_A_Button)
 IF _KEYDOWN(C.KBCon_B_Button) THEN Result%% = BUTTON_B: ' DO: LOOP WHILE _KEYDOWN(C.KBCon_B_Button)
 '  CASE FALSE 'joystick input
 'IF C.Control_Pad THEN
 'IF NOT G.Flag THEN DO: LOOP WHILE _DEVICEINPUT(C.Control_Pad)
 'IF NOT C.BAD_Pad THEN
 ' nul%% = AxisPower(CJR%%, CJL%%, CJU%%, CJD%%) 'read directional axis values
 ' IF CJU%% THEN Result%% = Up
 ' IF CJD%% THEN Result%% = Down
 ' IF CJL%% THEN Result%% = Left
 ' IF CJR%% THEN Result%% = Right
 'ELSE
 '   IF _BUTTON(C.Joy_Button_Up) THEN Result%% = Up ': Joy_Lock_Button (C.Joy_Button_Up)
 '   IF _BUTTON(C.Joy_Button_Down) THEN Result%% = Down ': Joy_Lock_Button (C.Joy_Button_Down)
 '   IF _BUTTON(C.Joy_Button_Left) THEN Result%% = Left ': Joy_Lock_Button (C.Joy_Button_Left)
 '   IF _BUTTON(C.Joy_Button_Right) THEN Result%% = Right ': Joy_Lock_Button (C.Joy_Button_Right)
 ' END IF
 '  IF _BUTTON(C.Joy_Select) THEN Result%% = SELECT_BUTTON: Joy_Lock_Button (C.Joy_Select)
 '  IF _BUTTON(C.Joy_Start) THEN Result%% = START_BUTTON: Joy_Lock_Button (C.Joy_Start)
 '  IF _BUTTON(C.Joy_A_Button) THEN Result%% = BUTTON_A: Joy_Lock_Button (C.Joy_A_Button)
 '  IF _BUTTON(C.Joy_B_Button) THEN Result%% = BUTTON_B: Joy_Lock_Button (C.Joy_B_Button)
 ' END IF
 ' END SELECT
 Get_Input = Result%%
END FUNCTION
 
SUB Link_Attack
 SELECT CASE Link.Direction
  CASE Up
   Ox%% = 0: Oy%% = -14 * G.Scale_Factor
  CASE Down
   Ox%% = 0: Oy%% = 14 * G.Scale_Factor
  CASE Left
   Ox%% = -14 * G.Scale_Factor + G.Aframe * (4 * G.Scale_Factor): Oy%% = 0
  CASE Right
   Ox%% = 14 * G.Scale_Factor - G.Aframe * (4 * G.Scale_Factor): Oy%% = 0
 END SELECT
 SELECT CASE G.Aframe
  CASE 0
   _PUTIMAGE (Link.Screen_X, Link.Screen_Y)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 17 * (Link.Direction + 8), 137)-STEP(15, 15)
  CASE 1
   _PUTIMAGE (Link.Screen_X, Link.Screen_Y)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 17 * (Link.Direction + 8), 137)-STEP(15, 15)
   _PUTIMAGE (Link.Screen_X + Ox%%, Link.Screen_Y + Oy%%)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 51 * Link.Weapon, 171 + 17 * Link.Direction)-STEP(15, 15)
  CASE 2
   _PUTIMAGE (Link.Screen_X, Link.Screen_Y)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 34 * Link.Direction + 17, 137)-STEP(15, 15)
   _PUTIMAGE (Link.Screen_X + Ox%%, Link.Screen_Y + Oy%%)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 51 * Link.Weapon + 17, 171 + 17 * Link.Direction)-STEP(15, 15)
  CASE 3
   _PUTIMAGE (Link.Screen_X, Link.Screen_Y)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 34 * Link.Direction + 0, 137)-STEP(15, 15)
   _PUTIMAGE (Link.Screen_X + Ox%%, Link.Screen_Y + Oy%%)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 51 * Link.Weapon + 34, 171 + 17 * Link.Direction)-STEP(15, 15)
  CASE ELSE 'attack animation finished
   G.Atime = 0: G.Aframe = 0: Link.Action = None
   _PUTIMAGE (Link.Screen_X, Link.Screen_Y)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 34 * Link.Direction + 17 * Frame%%, 137)-STEP(15, 15)
 END SELECT
 _KEYCLEAR
END SUB
 
FUNCTION Link_Collision%% (Dir%%)
 Result%% = FALSE 'start at no collision
 'get links center point x\y tile position to check for collision
 Ax% = Link.World_X * 16 * (16 * G.Scale_Factor) 'gets the Left most pixel point for the current map screen
 Ay% = Link.World_Y * 11 * (16 * G.Scale_Factor) 'gets the Top most pixel point for the current map screen
 'we now have the tile that Links center pixel is in!
 SELECT CASE Dir%%
  CASE Up
   Tx~%% = (Ax% + Link.Screen_X - Offset_X(G.Scale_Factor) + (16 * G.Scale_Factor \ 2)) \ 16 * G.Scale_Factor 'now add curent x-offset+50% sprite size
   Ty%% = (Ay% + Link.Screen_Y - Offset_Y(G.Scale_Factor) - 2 + (16 * G.Scale_Factor \ 2)) \ 16 * G.Scale_Factor 'now add curent y-offset+50% sprite size
   IF NOT Hyrule(Tx~%%, Ty%%).Walkable THEN Result%% = TRUE
  CASE Down
   Tx~%% = (Ax% + Link.Screen_X - Offset_X(G.Scale_Factor) + (16 * G.Scale_Factor \ 2)) \ 16 * G.Scale_Factor 'now add curent x-offset+50% sprite size
   Ty%% = (2 + Ay% + Link.Screen_Y - Offset_Y(G.Scale_Factor) + 2 + (16 * G.Scale_Factor \ 2)) \ 16 * G.Scale_Factor 'now add curent y-offset+50% sprite size
   IF NOT Hyrule(Tx~%%, Ty%%).Walkable THEN Result%% = TRUE
  CASE Left
   Tx~%% = (Ax% + Link.Screen_X - Offset_X(G.Scale_Factor) - 2 + (16 * G.Scale_Factor \ 2)) \ 16 * G.Scale_Factor 'now add curent x-offset+50% sprite size
   Ty%% = (Ay% + Link.Screen_Y - Offset_Y(G.Scale_Factor) + (16 * G.Scale_Factor \ 2)) \ 16 * G.Scale_Factor 'now add curent y-offset+50% sprite size
   IF NOT Hyrule(Tx~%%, Ty%%).Walkable THEN Result%% = TRUE
  CASE Right
   Tx~%% = (2 + Ax% + Link.Screen_X - Offset_X(G.Scale_Factor) + 2 + (16 * G.Scale_Factor \ 2)) \ 16 * G.Scale_Factor 'now add curent x-offset+50% sprite size
   Ty%% = (Ay% + Link.Screen_Y - Offset_Y(G.Scale_Factor) + (16 * G.Scale_Factor \ 2)) \ 16 * G.Scale_Factor 'now add curent y-offset+50% sprite size
   IF NOT Hyrule(Tx~%%, Ty%%).Walkable THEN Result%% = TRUE
 END SELECT
 Link.Tile_X = Tx~%%
 Link.Tile_Y = Ty%%
 Link_Collision = Result%%
END FUNCTION
 
SUB Move_Link
 SELECT CASE Link.Direction
  CASE Up
   IF NOT Link_Collision(Up) THEN 'nothing blocking Link
    IF Link.Screen_Y > Offset_Y(G.Scale_Factor) THEN 'Link is not at the edge of the screen
     Link.Screen_Y = Link.Screen_Y - 2 * G.Scale_Factor
    ELSE 'player is at edge of screen to shift to next one.
     G.NextScreen = Up
     Shift_New_Map_Screen
    END IF
   END IF
  CASE Down
   IF NOT Link_Collision(Down) THEN 'nothing blocking Link
    IF Link.Screen_Y < (Offset_Y(G.Scale_Factor) + (16 * G.Scale_Factor * 10)) THEN 'Link is not at the edge of the screen
     Link.Screen_Y = Link.Screen_Y + 2 * G.Scale_Factor
    ELSE 'player is at edge of screen to shift to next one.
     G.NextScreen = Down
     Shift_New_Map_Screen
    END IF
   END IF
  CASE Left
   IF NOT Link_Collision(Left) THEN 'nothing blocking Link
    IF Link.Screen_X > Offset_X(G.Scale_Factor) THEN 'Link is not at the edge of the screen
     Link.Screen_X = Link.Screen_X - 2 * G.Scale_Factor
    ELSE 'player is at edge of screen to shift to next one.
     G.NextScreen = Left
     Shift_New_Map_Screen
    END IF
   END IF
  CASE Right
   IF NOT Link_Collision(Right) THEN 'nothing blocking Link
    IF Link.Screen_X < (Offset_X(G.Scale_Factor) + (16 * G.Scale_Factor * 15)) THEN 'Link is not at the edge of the screen
     Link.Screen_X = Link.Screen_X + 2 * G.Scale_Factor
    ELSE 'player is at edge of screen to shift to next one.
     G.NextScreen = Right
     Shift_New_Map_Screen
    END IF
   END IF
 END SELECT
END SUB
 
SUB Move_Sword_Shot
 STATIC Xloc AS INTEGER, Yloc AS INTEGER, Direction AS _BYTE, Fstp AS _BYTE, Frame AS _BYTE
 IF Direction = -1 OR Xloc = 0 THEN 'if no direction assigned then assign one
  Direction = Link.Direction
  Xloc = Link.Screen_X
  Yloc = Link.Screen_Y
 END IF
 SELECT CASE Direction
  CASE Up
   Yloc = Yloc - 4 * G.Scale_Factor
  CASE Down
   Yloc = Yloc + 4 * G.Scale_Factor
  CASE Left
   Xloc = Xloc - 4 * G.Scale_Factor
  CASE Right
   Xloc = Xloc + 4 * G.Scale_Factor
 END SELECT
 _PUTIMAGE (Xloc, Yloc)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 17 * Frame + 68 * Direction, 239)-STEP(15, 15)
 SELECT CASE G.Scale_Factor
  CASE 1
   IF Xloc <= 272 OR Xloc >= 514 OR Yloc <= 212 OR Yloc >= 372 THEN Done%% = TRUE
  CASE 2
   IF Xloc <= 140 OR Xloc >= 630 OR Yloc <= 100 OR Yloc >= 430 THEN Done%% = TRUE
  CASE 3
   IF Xloc <= 16 OR Xloc >= 744 OR Yloc <= 96 OR Yloc >= 559 THEN Done%% = TRUE
 END SELECT
 IF Done%% THEN Link.Shot = FALSE: G.Impactflag = TRUE: Impact Xloc, Yloc: Direction = -1: Remove_Projectile Sword, Player
 Fstp = Fstp + 1
 IF Fstp = 2 THEN Fstp = 0: Frame = Frame + 1
 IF Frame = 4 THEN Frame = 0
END SUB
 
SUB Impact (X%, Y%)
 STATIC Frame AS _BYTE, Fstp AS _BYTE, Xloc(3) AS INTEGER, Yloc(3) AS INTEGER
 IF Frame = -1 OR Xloc(2) = 0 THEN
  Fstp = 0
  FOR i%% = 0 TO 3: Xloc(i%%) = X% + 8 * G.Scale_Factor: Yloc(i%%) = Y% + 8 * G.Scale_Factor: NEXT i%%
 END IF
 Xloc(0) = Xloc(0) - G.Scale_Factor: Yloc(0) = Yloc(0) - G.Scale_Factor
 Xloc(1) = Xloc(1) + G.Scale_Factor: Yloc(1) = Yloc(1) - G.Scale_Factor
 Xloc(2) = Xloc(2) + G.Scale_Factor: Yloc(2) = Yloc(2) + G.Scale_Factor
 Xloc(3) = Xloc(3) - G.Scale_Factor: Yloc(3) = Yloc(3) + G.Scale_Factor
 FOR i%% = 0 TO 3
  SELECT CASE i%%
   CASE 0
    _PUTIMAGE (Xloc(i%%) - 16, Yloc(i%%) - 16)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (205 + 17 * Frame, 205)-STEP(15, 15)
   CASE 1
    _PUTIMAGE (Xloc(i%%) + 16, Yloc(i%%) - 16)-STEP(-G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (205 + 17 * Frame, 205)-STEP(15, 15)
   CASE 2
    _PUTIMAGE (Xloc(i%%) + 16, Yloc(i%%) + 16)-STEP(-G.Scale_X, -G.Scale_Y), Layer(7), Layer(1), (205 + 17 * Frame, 205)-STEP(15, 15)
   CASE 3
    _PUTIMAGE (Xloc(i%%) - 16, Yloc(i%%) + 16)-STEP(G.Scale_X, -G.Scale_Y), Layer(7), Layer(1), (205 + 17 * Frame, 205)-STEP(15, 15)
  END SELECT
 NEXT i%%
 Fstp = Fstp + 1
 Frame = Frame + 1
 IF Frame = 4 THEN Frame = 0
 IF Fstp = 16 THEN Frame = -1: G.Impactflag = FALSE
END SUB
 
SUB Place_Link
 STATIC Ftime AS _BYTE, Frame AS _BYTE
 IF Link.Action = Walking THEN 'while Link is moving
  G.Wtime = G.Wtime + 1 'Increment frame time
  IF G.Wtime = 8 THEN
   IF G.Wframe THEN G.Wframe = 0 ELSE G.Wframe = 1 'change frame
   G.Wtime = 0 'reset frame time
  END IF
  _PUTIMAGE (Link.Screen_X, Link.Screen_Y)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 34 * Link.Direction + 17 * G.Wframe, 137)-STEP(15, 15)
 ELSEIF Link.Action = Useing THEN 'when Link uses an item
  Ftime = Ftime + 1 'Increment frame time
  IF Ftime = 32 THEN Link.Action = None: Ftime = 0 'action is done
  _PUTIMAGE (Link.Screen_X, Link.Screen_Y)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 17 * (Link.Direction + 8), 137)-STEP(15, 15)
 ELSEIF Link.Action = GetItem THEN 'When Link gets a sword\item or buys something
  'Held while music plays
  _PUTIMAGE (Link.Screen_X, Link.Screen_Y)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 17 * 12, 137)-STEP(15, 15)
 ELSEIF Link.Action = GetTriforce THEN 'When Link recovers a Triforce piece
  'Held while music plays
  _PUTIMAGE (Link.Screen_X, Link.Screen_Y)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 17 * 13, 137)-STEP(15, 15)
 ELSEIF Link.Action = Attack THEN
  G.Atime = G.Atime + 1 'Increment frame time
  IF G.Atime = 4 THEN G.Aframe = G.Aframe + 1: G.Atime = 0 'change frame:reset frame time
  Link_Attack
 ELSE 'Link is standing Still(Action=None)
  G.Atime = 0: G.Aframe = 0
  G.Wtime = 0: G.Wframe = 0
  _PUTIMAGE (Link.Screen_X, Link.Screen_Y)-STEP(G.Scale_X, G.Scale_Y), Layer(7), Layer(1), (1 + 34 * Link.Direction + 17 * Frame%%, 137)-STEP(15, 15)
 END IF
END SUB
 
SUB Place_Player_Record (I%%, Where%)
 SELECT CASE Where%
  CASE 0
   IF Records(I%% + 1).Beaten THEN _PUTIMAGE (260, 228 + 48 * I%%)-STEP(15, 31), Layer(12), Layer(16), (64, 247)-STEP(7, 15) 'Player 1 Sword
   _PUTIMAGE (236, 234 + 48 * I%%)-STEP(31, 31), Layer(12), Layer(16), (1 + 17 * Records(I%% + 1).Ring, 230)-STEP(15, 15) 'Player 1 Link (green)
   _PRINTSTRING (284, 232 + 48 * I%%), RTRIM$(Nick(I%% + 1)), Layer(16) 'player 1 name
   _PRINTSTRING (284, 248 + 48 * I%%), LEFT$("   ", 3 - LEN(LTRIM$(RTRIM$(STR$(Records(I%% + 1).Played))))) + LTRIM$(STR$(Records(I%% + 1).Played)), Layer(16) 'player 1 tries
   FOR j%% = 1 TO Records(I%% + 1).Containers
    IF j%% < 4 THEN 'first 3 hearts are red
     _PUTIMAGE (428 + 16 * j%%, 232 + 48 * I%%)-STEP(15, 15), Layer(12), Layer(16), (52, 230)-STEP(7, 7) 'Player 1 hearts red
    ELSE
     IF j%% < 9 THEN
      _PUTIMAGE (428 + 16 * j%%, 232 + 48 * I%%)-STEP(15, 15), Layer(12), Layer(16), (73, 267)-STEP(7, 7) 'Player 1 hearts white
     ELSE
      _PUTIMAGE (428 + 16 * (j%% - 8), 232 + 64 * I%%)-STEP(15, 15), Layer(12), Layer(16), (73, 267)-STEP(7, 7) 'Player 1 hearts white
     END IF
    END IF
   NEXT j%%
  CASE 1
   IF Records(I%% + 1).Beaten THEN _PUTIMAGE (326, 148 + 48 * (I%% - 1))-STEP(15, 31), Layer(12), Layer(16), (64, 247)-STEP(7, 15) 'Player 1 Sword
   _PUTIMAGE (300, 154 + 48 * (I%%))-STEP(31, 31), Layer(12), Layer(16), (1 + 17 * Records(I%% + 1).Ring, 230)-STEP(15, 15) 'Player 1 Link (green)
   _PRINTSTRING (364, 152 + 48 * (I%%)), RTRIM$(Nick(I%% + 1)), Layer(1)
 
 END SELECT
END SUB
 
SUB Place_Tile_On_Screen (X%, Y%, Tile~%%, L&)
 Gy% = 17 * (Tile~%% \ 20) 'get which row it comes from
 Gx% = 17 * (Tile~%% MOD 20) 'which column position
 _PUTIMAGE (Offset_X(G.Scale_Factor) + X%, Offset_Y(G.Scale_Factor) + Y%)-STEP(G.Scale_X, G.Scale_Y), Layer(7), L&, (1 + Gx%, 1 + Gy%)-STEP(15, 15)
END SUB
 
SUB Scroll_Screen_II (Dir%%)
 Cx% = Offset_X(G.Scale_Factor) 'top left corner location of map displayed
 Cy% = Offset_Y(G.Scale_Factor)
 Sfx% = 16 * 16 * G.Scale_Factor 'size of the map display
 Sfy% = 11 * 16 * G.Scale_Factor
 Lwx% = 16 * 16 * G.Scale_Factor * Link.World_X 'map area link is in
 Lwy% = 11 * 16 * G.Scale_Factor * Link.World_Y
 SELECT CASE Dir%%
  CASE Up
   FOR y% = 0 TO Sfy% STEP 2 * G.Scale_Factor
    _PUTIMAGE (Cx%, Cy%)-STEP(Sfx%, Sfy%), Layer(6), Layer(1), (Lwx%, Lwy% - y%)-STEP(Sfx%, Sfy%)
    IF y% > 16 * G.Scale_Factor THEN Link.Screen_Y = Link.Screen_Y + 2 * G.Scale_Factor
    Place_Link
    _LIMIT 60
    _PUTIMAGE , Layer(1), Layer(0)
   NEXT
   Link.World_Y = Link.World_Y - 1
  CASE Down
   FOR y% = 0 TO Sfy% STEP 2 * G.Scale_Factor
    _PUTIMAGE (Cx%, Cy%)-STEP(Sfx%, Sfy%), Layer(6), Layer(1), (Lwx%, Lwy% + y%)-STEP(Sfx%, Sfy%)
    IF y% > 16 * G.Scale_Factor THEN Link.Screen_Y = Link.Screen_Y - 2 * G.Scale_Factor
    Place_Link
    _LIMIT 60
    _PUTIMAGE , Layer(1), Layer(0)
   NEXT
   Link.World_Y = Link.World_Y + 1
  CASE Left
   FOR x% = 0 TO Sfx% STEP 2 * G.Scale_Factor
    _PUTIMAGE (Cx%, Cy%)-STEP(Sfx%, Sfy%), Layer(6), Layer(1), (Lwx% - x%, Lwy%)-STEP(Sfx%, Sfy%)
    IF x% > 16 * G.Scale_Factor THEN Link.Screen_X = Link.Screen_X + 2 * G.Scale_Factor
    Place_Link
    _LIMIT 60
    _PUTIMAGE , Layer(1), Layer(0)
   NEXT
   Link.World_X = Link.World_X - 1
  CASE Right
   FOR x% = 0 TO Sfx% STEP 2 * G.Scale_Factor
    _PUTIMAGE (Cx%, Cy%)-STEP(Sfx%, Sfy%), Layer(6), Layer(1), (Lwx% + x%, Lwy%)-STEP(Sfx%, Sfy%)
    IF x% > 16 * G.Scale_Factor THEN Link.Screen_X = Link.Screen_X - 2 * G.Scale_Factor
    Place_Link
    _LIMIT 60
    _PUTIMAGE , Layer(1), Layer(0)
   NEXT
   Link.World_X = Link.World_X + 1
 END SELECT
 Place_Link
 Lwx% = 16 * 16 * G.Scale_Factor * Link.World_X
 Lwy% = 11 * 16 * G.Scale_Factor * Link.World_Y
 _PUTIMAGE (Cx%, Cy%)-STEP(Sfx%, Sfy%), Layer(6), Layer(3), (Lwx%, Lwy%)-STEP(Sfx%, Sfy%) 'move new screen to layer(3)
END SUB
 
SUB Shift_New_Map_Screen
 SELECT CASE G.NextScreen
  CASE Up
   Scroll_Screen_II Up
  CASE Down
   Scroll_Screen_II Down
  CASE Left
   Scroll_Screen_II Left
  CASE Right
   Scroll_Screen_II Right
 END SELECT
 G.NextScreen = -1
END SUB
 
SUB Title_Screen
 _CLEARCOLOR _RGB32(21), Layer(9)
 _CLEARCOLOR _RGB32(21), Layer(10)
 _SNDVOL BGM(0), .33
 _SNDLOOP BGM(0)
 DO
  F%% = 0: F% = 0: ExitFlag%% = FALSE
  DO: _LIMIT 60: LOOP WHILE _SNDGETPOS(BGM(0)) > 10
  DO
   _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (0, 0)-STEP(255, 223)
   SELECT CASE F%%
    CASE 12 TO 18
     _PUTIMAGE (400 - 74, 300 - 128)-STEP(143, 143), Layer(9), Layer(1), (289, 0)-STEP(71, 71)
    CASE 19 TO 24
     _PUTIMAGE (400 - 74, 300 - 128)-STEP(143, 143), Layer(9), Layer(1), (289, 0 + 72)-STEP(71, 71)
    CASE 25 TO 36
     _PUTIMAGE (400 - 74, 300 - 128)-STEP(143, 143), Layer(9), Layer(1), (289, 0 + 144)-STEP(71, 71)
    CASE 37 TO 52
     _PUTIMAGE (400 - 74, 300 - 128)-STEP(143, 143), Layer(9), Layer(1), (289, 0 + 72)-STEP(71, 71)
    CASE 53 TO 59
     _PUTIMAGE (400 - 74, 300 - 128)-STEP(143, 143), Layer(9), Layer(1), (289, 0 + 0)-STEP(71, 71)
   END SELECT
   _PUTIMAGE (304, 523 - 112), Layer(10), Layer(1), (0 + 64 * wave%%, 0)-STEP(63, 111)
   _PUTIMAGE , Layer(1), Layer(0)
   _LIMIT 90
   F%% = F%% + 1
   IF F%% = 60 THEN F%% = 0
   IF F%% MOD 2 = 0 THEN wave%% = wave%% + 1
   IF wave%% = 16 THEN wave%% = 0
   IF Get_Input = START_BUTTON THEN ExitFlag%% = TRUE
  LOOP UNTIL _SNDGETPOS(BGM(0)) > 8.4 OR ExitFlag%%
 
  IF NOT ExitFlag%% THEN
   'start the title fade
   _DEST Layer(1)
   F%% = 0
   DO
    SELECT CASE F%
     CASE 0 TO 13
      LINE (144, 76)-STEP(511, 447), _RGB32(202, 241, 159), BF
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (361, 0)-STEP(255, 223)
     CASE 13 TO 24
      LINE (144, 76)-STEP(511, 447), _RGB32(182, 216, 255), BF
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (361, 0)-STEP(255, 223)
     CASE 25 TO 34
      LINE (144, 76)-STEP(511, 447), _RGB32(166, 229, 255), BF
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (361, 0)-STEP(255, 223)
     CASE 35 TO 42
      LINE (144, 76)-STEP(511, 447), _RGB32(165, 238, 223), BF
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (617, 0)-STEP(255, 223)
     CASE 43 TO 48
      LINE (144, 76)-STEP(511, 447), _RGB32(37, 190, 255), BF
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (617, 0)-STEP(255, 223)
     CASE 49 TO 52
      LINE (144, 76)-STEP(511, 447), _RGB32(0, 109, 181), BF
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (617, 0)-STEP(255, 223)
     CASE 53 TO 57
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (873, 0)-STEP(255, 223)
      Wf% = 112
     CASE 58 TO 61
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (1129, 0)-STEP(255, 223)
      Wf% = 224
     CASE 62 TO 363
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (1385, 0)-STEP(255, 223)
      Wf% = 336
     CASE 364 TO 385
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (1641, 0)-STEP(255, 223)
      Wf% = 448
     CASE 386 TO 393
      _PUTIMAGE ((800 - 512) \ 2, (600 - 448) \ 2)-STEP(511, 447), Layer(9), Layer(1), (1897, 0)-STEP(255, 223)
      Wf% = 560
    END SELECT
    _PUTIMAGE (304, 523 - 112), Layer(10), Layer(1), (0 + 64 * wave%%, 0 + Wf%)-STEP(63, 111)
    _PUTIMAGE , Layer(1), Layer(0)
    _LIMIT 90
    F% = F% + 1
    IF F% = 394 THEN ExitFlag%% = TRUE
    IF F% MOD 2 = 0 THEN wave%% = wave%% + 1
    IF wave%% = 16 THEN wave%% = 0
    IF Get_Input = START_BUTTON THEN ExitFlag%% = TRUE
   LOOP UNTIL ExitFlag%%
   ExitFlag%% = FALSE
  END IF
  ClearLayer Layer(0)
  ClearLayer Layer(1)
  IF NOT ExitFlag%% THEN
   'Title scroll
   DO: _LIMIT 60: IF Get_Input = START_BUTTON THEN ExitFlag%% = TRUE
   LOOP UNTIL _SNDGETPOS(BGM(0)) > 16 OR ExitFlag%%
   F% = 0
   IF NOT ExitFlag%% THEN
    DO
     SELECT CASE F%
      CASE 0 TO 223
       _PUTIMAGE (144, 76)-STEP(511, 447), Layer(11), Layer(1), (0, -223 + F%)-STEP(255, 223)
      CASE IS >= 354
       IF blink% THEN
        _PUTIMAGE (72, 332)-STEP(7, 15), Layer(7), Layer(11), (247, 154)-STEP(7, 15) 'heart
        _PUTIMAGE (72, 464)-STEP(7, 15), Layer(7), Layer(11), (213, 171)-STEP(7, 15) 'Ruby
        _PUTIMAGE (120, 1432)-STEP(15, 15), Layer(7), Layer(11), (239, 188)-STEP(15, 15) 'Triforce
       ELSE
        _PUTIMAGE (72, 332)-STEP(7, 15), Layer(7), Layer(11), (239, 154)-STEP(7, 15) 'heart
        _PUTIMAGE (72, 464)-STEP(7, 15), Layer(7), Layer(11), (205, 171)-STEP(7, 15) 'Ruby
        _PUTIMAGE (120, 1432)-STEP(15, 15), Layer(7), Layer(11), (222, 188)-STEP(15, 15) 'Triforce
       END IF
       IF Fblink% THEN
        _PUTIMAGE (72, 400)-STEP(7, 15), Layer(7), Layer(11), (256, 188)-STEP(7, 15) 'fairy blank
        _PUTIMAGE (72, 400)-STEP(7, 15), Layer(7), Layer(11), (281, 154)-STEP(7, 15) 'fairy
       ELSE
        _PUTIMAGE (72, 400)-STEP(7, 15), Layer(7), Layer(11), (256, 188)-STEP(7, 15) 'fairy blank
        _PUTIMAGE (72, 400)-STEP(7, 15), Layer(7), Layer(11), (273, 154)-STEP(7, 15) 'fairy
       END IF
       _PUTIMAGE (144, 76)-STEP(511, 447), Layer(11), Layer(1), (0, F% - 354)-STEP(255, 223)
     END SELECT
     _PUTIMAGE , Layer(1), Layer(0)
     _LIMIT 30
     F% = F% + 1
     IF F% = 1762 THEN F% = F% - 1 'ExitFlag%% = TRUE
     B% = B% + 1
     IF B% = 4 THEN blink% = NOT blink%: B% = 0
     IF B% MOD 2 = 0 THEN Fblink% = NOT Fblink%
     IF Get_Input = START_BUTTON THEN ExitFlag%% = TRUE
    LOOP UNTIL _SNDGETPOS(BGM(0)) >= 79.75 OR ExitFlag%%
    ExitFlag%% = FALSE
   END IF
  END IF
 
 LOOP UNTIL ExitFlag%%
 _DEST Layer(0)
 _SNDSTOP BGM(0)
 DO: LOOP UNTIL Get_Input%% = -1
 
END SUB
 
FUNCTION Projectile_Collision%%
 Result%% = FALSE
 FOR i%% = 0 TO G.Projectile_Count
 NEXT
 Projectile_Collision = Result%%
END FUNCTION
 
SUB Select_Screen
 ClearLayer Layer(16)
 IF _FILEEXISTS("Zelda.MSF") THEN 'load saved data
  OPEN "Zelda.MSF" FOR BINARY AS #1
  FOR I%% = 1 TO 3 'load all 3 records
   GET #1, , Nick(I%%)
   GET #1, , Records(I%%)
   IF Selection%% = 0 THEN IF RTRIM$(Nick(I%%)) <> "" THEN Selection%% = I%%
  NEXT I%%
  CLOSE #1
 ELSE 'file doesn't exist so make it.
  Reset_Record 1
  Reset_Record 2
  Reset_Record 3
  Save_Records
 END IF
 _PUTIMAGE (140, 72)-STEP(511, 447), Layer(12), Layer(16), (1, 1)-STEP(255, 223) 'background
 FOR I%% = 1 TO 3
  IF RTRIM$(Nick(I%%)) <> "" THEN Place_Player_Record I%% - 1, 0
 NEXT I%%
 IF Record_Count%% = 0 THEN Selection%% = 4 ELSE Selection%% = 1
 Selection%% = Find_First_Available(0, 1)
 DO
  _PUTIMAGE , Layer(16), Layer(1)
  SELECT CASE Get_Input%%
   CASE START_BUTTON
    SELECT CASE Selection%%
     CASE 1 TO 3
      Link = Records(Selection%%)
      Exitflag%% = TRUE
     CASE 4
      DO: LOOP UNTIL Get_Input%% = -1
      nul%% = Register(nul%%)
      OPEN "Zelda.MSF" FOR BINARY AS #1 'update records
      FOR I%% = 1 TO 3
       PUT #1, , Nick(I%%)
       PUT #1, , Link
       IF RTRIM$(Nick(I%%)) <> "" THEN Place_Player_Record I%% - 1, 0
      NEXT I%%
      CLOSE #1
     CASE 5
      DO: LOOP UNTIL Get_Input%% = -1
      Elimination_Mode
      nul%% = Register(nul%%) 'go straight to register mode after elimination
    END SELECT
   CASE SELECT_BUTTON
    Selection%% = Selection%% + 1
    IF Selection%% = 6 THEN Selection%% = 1
    Selection%% = Find_First_Available(0, Selection%%)
    DO: LOOP UNTIL Get_Input%% = -1
   CASE ELSE
    _PRINTSTRING (0, 20), STR$(SELECT_BUTTON), Layer(1)
  END SELECT
 
  SELECT CASE Selection%%
   CASE 1
    _PUTIMAGE (220, 242)-STEP(15, 15), Layer(12), Layer(1), (73, 247)-STEP(7, 7) 'Player 1
   CASE 2
    _PUTIMAGE (220, 290)-STEP(15, 15), Layer(12), Layer(1), (73, 247)-STEP(7, 7) 'Player 2
   CASE 3
    _PUTIMAGE (220, 338)-STEP(15, 15), Layer(12), Layer(1), (73, 247)-STEP(7, 7) 'Player 3
   CASE 4
    _PUTIMAGE (220, 394)-STEP(15, 15), Layer(12), Layer(1), (73, 247)-STEP(7, 7) 'register
   CASE 5
    _PUTIMAGE (220, 426)-STEP(15, 15), Layer(12), Layer(1), (73, 247)-STEP(7, 7) 'Elimination
  END SELECT
  _PRINTSTRING (0, 0), STR$(Selection%%), Layer(1)
  _PUTIMAGE , Layer(1), Layer(0)
  _LIMIT 60
  IF INKEY$ = CHR$(27) THEN Exitflag%% = TRUE
 LOOP UNTIL Exitflag%%
END SUB
 
FUNCTION Register%% (Records%%)
 DIM Names(2, 8) AS STRING * 1
 Result%% = Records%%
 Tmp& = _COPYIMAGE(Layer(16))
 ClearLayer Layer(16)
 ClearLayer Layer(1)
 _PUTIMAGE (140, 72)-STEP(511, 447), Layer(12), Layer(16), (258, 1)-STEP(255, 223) 'background
 FOR i%% = 1 TO 3
  IF RTRIM$(Nick(i%%)) <> "" THEN Place_Player_Record i%% - 1, 1
 NEXT i%%
 IF i%% > 0 THEN Selection%% = i%% ELSE Selection%% = 1
 FOR i%% = 1 TO 3
  IF RTRIM$(Nick(i%%)) = "" THEN _PUTIMAGE (300, 154 + 48 * (i%% - 1))-STEP(31, 31), Layer(12), Layer(16), (1, 230)-STEP(15, 15) 'Player 1 Link (green)
 NEXT i%%
 _CLEARCOLOR _RGB32(0), Layer(16)
 _PUTIMAGE , Layer(16), Layer(1)
 _DEST Layer(1)
 _PRINTMODE _KEEPBACKGROUND , Layer(1)
 Current_Letter%% = 1
 Selection%% = Find_First_Available(1, 1)
 DO
 
  SELECT CASE Get_Input%%
   CASE Up
    _PUTIMAGE (236 + 32 * Lx%, 328 + 32 * Ly%)-STEP(15, 15), Layer(12), Layer(1), (86, 240)-STEP(7, 7) 'Current selected Letter
    Ly% = Ly% - 1
    IF Ly% = -1 THEN Ly% = 3
    Current_Letter%% = Current_Letter%% - 11
    IF Current_Letter%% < 0 THEN Current_Letter%% = 44 - ABS(Current_Letter%%)
   CASE Down
    _PUTIMAGE (236 + 32 * Lx%, 328 + 32 * Ly%)-STEP(15, 15), Layer(12), Layer(1), (86, 240)-STEP(7, 7) 'Current selected Letter
    Ly% = Ly% + 1
    IF Ly% = 4 THEN Ly% = 0
    Current_Letter%% = Current_Letter%% + 11
    IF Current_Letter%% > 44 THEN Current_Letter%% = Current_Letter%% - 44
   CASE Left
    _PUTIMAGE (236 + 32 * Lx%, 328 + 32 * Ly%)-STEP(15, 15), Layer(12), Layer(1), (86, 240)-STEP(7, 7) 'Current selected Letter
    Lx% = Lx% - 1
    IF Lx% = -1 THEN Lx% = 10: Ly% = Ly% - 1: IF Ly% = -1 THEN Ly% = 3
    Current_Letter%% = Current_Letter%% - 1
    IF Current_Letter%% = 0 THEN Current_Letter%% = 44
   CASE Right
    _PUTIMAGE (236 + 32 * Lx%, 328 + 32 * Ly%)-STEP(15, 15), Layer(12), Layer(1), (86, 240)-STEP(7, 7) 'Current selected Letter
    Lx% = Lx% + 1
    IF Lx% = 11 THEN Lx% = 0: Ly% = Ly% + 1: IF Ly% = 4 THEN Ly% = 0
    Current_Letter%% = Current_Letter%% + 1
    IF Current_Letter%% = 45 THEN Current_Letter%% = 1
   CASE BUTTON_A OR BUTTON_B
    IF Selection%% <> 4 THEN 'only allow buttons if valid name entry selection
     _PUTIMAGE (364 + 16 * Length%%, 152 + 48 * (Selection%% - 1))-STEP(15, 15), Layer(12), Layer(1), (86, 240)-STEP(7, 7) 'Current Nick Letter
     Names(Selection%% - 1, Length%%) = Letter(Current_Letter%%)
     Length%% = Length%% + 1
     IF Length%% = 8 THEN Length%% = 0
    END IF
   CASE START_BUTTON
    SELECT CASE Selection%%
     CASE 4 'end
      FOR j%% = 0 TO 2
       a$ = ""
       IF RTRIM$(Nick(j%% + 1)) = "" THEN
        FOR i%% = 0 TO 7
         IF ASC(Names(j%%, i%%)) > 31 THEN a$ = a$ + Names(j%%, i%%)
        NEXT
        Nick(j%% + 1) = a$
       END IF
      NEXT
      ExitFlag%% = TRUE
    END SELECT
   CASE SELECT_BUTTON 'Change to different name or end registration
    _PUTIMAGE (364 + 16 * Length%%, 152 + 48 * (Selection%% - 1))-STEP(15, 15), Layer(12), Layer(1), (86, 240)-STEP(7, 7) 'Current Nick Letter
    _PUTIMAGE (274, 152 + 48 * (Selection%% - 1))-STEP(15, 15), Layer(12), Layer(1), (86, 240)-STEP(7, 7) 'heart selection
    Selection%% = Selection%% + 1: Length%% = 0 'reset the name position when changing.
    IF Selection%% = 5 THEN Selection%% = 1
    _PRINTSTRING (0, 0), STR$(Selection%%), Layer(1)
    Selection%% = Find_First_Available(1, Selection%%)
   CASE ELSE
    LINE (0, 0)-STEP(160, 40), _RGB32(0), BF
    _PRINTSTRING (0, 20), STR$(Selection%%), Layer(1)
  END SELECT
  DO: LOOP UNTIL Get_Input%% = -1
 
  _PUTIMAGE (274, 152 + 48 * (Selection%% - 1))-STEP(15, 15), Layer(12), Layer(1), (73, 247)-STEP(7, 7) 'heart selection
  IF Selection%% <> 4 THEN
   FOR j%% = 0 TO 8
    IF Names(Selection%% - 1, j%%) > CHR$(31) THEN _PRINTSTRING (364 + 16 * j%%, 152 + 48 * (Selection%% - 1)), Names(Selection%% - 1, j%%), Layer(1)
   NEXT j%%
  END IF
  _PUTIMAGE , Layer(1), Layer(0)
  IF blink%% AND Selection%% <> 4 THEN
   _PUTIMAGE (364 + 16 * Length%%, 152 + 48 * (Selection%% - 1))-STEP(15, 15), Layer(12), Layer(1), (61, 230)-STEP(7, 7) 'Current Nick Letter
   _PUTIMAGE (236 + 32 * Lx%, 328 + 32 * Ly%)-STEP(15, 15), Layer(12), Layer(1), (61, 230)-STEP(7, 7) 'Current selected Letter
  ELSE
   _PUTIMAGE (364 + 16 * Length%%, 152 + 48 * (Selection%% - 1))-STEP(15, 15), Layer(12), Layer(1), (86, 240)-STEP(7, 7) 'Current Nick Letter
   _PUTIMAGE (236 + 32 * Lx%, 328 + 32 * Ly%)-STEP(15, 15), Layer(12), Layer(1), (86, 240)-STEP(7, 7) 'Current selected Letter
  END IF
  _PUTIMAGE , Layer(16), Layer(1)
  b%% = b%% + 1
  IF b%% = 8 THEN blink%% = NOT blink%%: b%% = 0
  _LIMIT 60
  IF INKEY$ = CHR$(27) THEN ExitFlag%% = TRUE
 LOOP UNTIL ExitFlag%%
 ClearLayer Layer(16)
 _PUTIMAGE , Tmp&, Layer(16)
 _FREEIMAGE Tmp&
 Save_Records
 FOR i%% = 1 TO 3
  IF RTRIM$(Nick(i%%)) <> "" THEN Place_Player_Record i%% - 1, 0
 NEXT i%%
 Register = Result%%
END FUNCTION
 
SUB Elimination_Mode
 Tmp& = _COPYIMAGE(Layer(16))
 ClearLayer Layer(16)
 ClearLayer Layer(1)
 _PUTIMAGE (140, 72)-STEP(511, 447), Layer(12), Layer(16), (515, 1)-STEP(255, 223) 'background
 FOR i%% = 1 TO 3
  IF RTRIM$(Nick(i%%)) <> "" THEN Place_Player_Record i%% - 1, 1
 NEXT i%%
 _PUTIMAGE , Layer(16), Layer(0)
 IF i%% > 0 THEN Selection%% = i%% ELSE Selection%% = 1
 FOR i%% = 1 TO 3 'remove the erased game from the background screens
  IF RTRIM$(Nick(i%%)) = "" THEN _PUTIMAGE (300, 154 + 48 * (i%% - 1))-STEP(31, 31), Layer(12), Layer(16), (1, 230)-STEP(15, 15) 'Player 1 Link (green)
 NEXT i%%
 _CLEARCOLOR _RGB32(0), Layer(16)
 _PUTIMAGE , Layer(16), Layer(1)
 _DEST Layer(1)
 _PRINTMODE _KEEPBACKGROUND , Layer(1)
 Current_Letter%% = 1
 Selection%% = 1
 DO
  _PUTIMAGE , Layer(16), Layer(1)
  SELECT CASE Get_Input%%
   CASE START_BUTTON
    SELECT CASE Selection%%
     CASE 1 TO 3
      Nick(Selection%%) = ""
      Reset_Record Selection%%
      _PUTIMAGE (364, 152 + 48 * (Selection%% - 1))-STEP(159, 31), Layer(12), Layer(16), (86, 240)-STEP(7, 7) 'black out
      _PUTIMAGE (236, 232 + 48 * (Selection%% - 1))-STEP(159, 33), Layer(12), Tmp&, (86, 240)-STEP(7, 7) 'black out name
      _PUTIMAGE (428, 232 + 48 * (Selection%% - 1))-STEP(127, 31), Layer(12), Tmp&, (86, 240)-STEP(7, 7) 'black out hearts
     CASE 4
      ExitFlag%% = TRUE
    END SELECT
   CASE SELECT_BUTTON
    _PUTIMAGE (274, 152 + 48 * (Selection%% - 1))-STEP(15, 15), Layer(12), Layer(1), (86, 240)-STEP(7, 7) 'heart selection black out
    Selection%% = Selection%% + 1
    IF Selection%% = 5 THEN Selection%% = 1
   CASE ELSE
    _PRINTSTRING (0, 20), STR$(SELECT_BUTTON), Layer(1)
  END SELECT
  DO: LOOP UNTIL Get_Input%% = -1
  _PUTIMAGE (274, 152 + 48 * (Selection%% - 1))-STEP(15, 15), Layer(12), Layer(1), (73, 267)-STEP(7, 7) 'heart selection
  _PUTIMAGE , Layer(1), Layer(0)
  _LIMIT 60
  IF INKEY$ = CHR$(27) THEN ExitFlag%% = TRUE
 LOOP UNTIL ExitFlag%%
 ClearLayer Layer(16)
 _PUTIMAGE , Tmp&, Layer(16)
 _FREEIMAGE Tmp&
END SUB
 
SUB Reset_Record (Which%%)
 Records(Which%%) = Reset_Link
END SUB
 
SUB Save_Records
 OPEN "Zelda.MSF" FOR BINARY AS #1
 FOR I%% = 1 TO 3
  PUT #1, , Nick(I%%)
  PUT #1, , Records(I%%)
 NEXT I%%
 CLOSE #1
END SUB
 
SUB MFI_Loader (FN$)
 DIM Size(128) AS LONG, FOffset(128) AS LONG
 OPEN FN$ FOR BINARY AS #1
 GET #1, , c~%% 'retrieve number of files
 FOR I~%% = 1 TO c~%%
  GET #1, , FOffset(I~%%)
  GET #1, , Size(I~%%)
  FOffset&(I~%%) = FOffset&(I~%%) + 1
 NEXT I~%%
 Layer(7) = LoadGFX(FOffset(1), Size(1)) '_LOADIMAGE("overworldtiles.bmp", 32)
 Layer(9) = LoadGFX(FOffset(2), Size(2)) '_LOADIMAGE("TitleScreen.bmp", 32)
 Layer(10) = LoadGFX(FOffset(3), Size(3)) '_LOADIMAGE("Titlefalls.bmp", 32)
 Layer(11) = LoadGFX(FOffset(4), Size(4)) '_LOADIMAGE("Titlescroll.bmp", 32)
 Layer(12) = LoadGFX(FOffset(5), Size(5)) '_LOADIMAGE("selectionscreen.bmp", 32)
 
 SFX(0) = LoadSFX(FOffset(6), Size(6))
 SFX(1) = LoadSFX(FOffset(7), Size(7))
 SFX(2) = LoadSFX(FOffset(8), Size(8))
 SFX(3) = LoadSFX(FOffset(9), Size(9))
 BGM(0) = LoadSFX(FOffset(10), Size(10))
 FFX(0) = LoadFFX(FOffset(11), Size(11), 16)
 LoadData FOffset(12), Size(12)
 
 CLOSE #1
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
END SUB
 
FUNCTION LoadGFX& (Foff&, Size&)
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
 OPEN "temp.dat" FOR BINARY AS #3
 dat$ = SPACE$(Size&)
 GET #1, Foff&, dat$
 PUT #3, , dat$
 CLOSE #3
 LoadGFX& = _LOADIMAGE("temp.dat", 32)
END FUNCTION
 
FUNCTION LoadFFX& (Foff&, Size&, Fize%%)
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
 OPEN "temp.dat" FOR BINARY AS #3
 dat$ = SPACE$(Size&)
 GET #1, Foff&, dat$
 PUT #3, , dat$
 CLOSE #3
 LoadFFX& = _LOADFONT("temp.dat", Fize%%, "monospace")
END FUNCTION
 
FUNCTION LoadSFX& (Foff&, Size&)
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
 OPEN "temp.dat" FOR BINARY AS #3
 dat$ = SPACE$(Size&)
 GET #1, Foff&, dat$
 PUT #3, , dat$
 CLOSE #3
 LoadSFX& = _SNDOPEN("temp.dat")
END FUNCTION
 
SUB LoadData (Foff&, Size&)
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
 OPEN "temp.dat" FOR BINARY AS #3
 dat$ = SPACE$(Size&)
 GET #1, Foff&, dat$
 PUT #3, , dat$
 CLOSE #3
 
 F1 = FREEFILE
 OPEN "temp.dat" FOR BINARY AS #F1
 GET #F1, , Hyrule()
 GET #F1, , Link
 GET #F1, , C
 GET #F1, , G
 GET #F1, , Offset_X()
 GET #F1, , Offset_Y()
 FOR I%% = 1 TO 44
  GET #F1, , Letter(I%%)
 NEXT I%%
 CLOSE #F1
 
END SUB
 

QB64 Discussion / Lacking QB4.5 error catch

« on: December 16, 2021, 04:48:27 pm »

so in QB4.5 if you type the following line you will get an error at run time

Code: QB64: [Select]

END of

However this is allowed in QB64(2.0.2); IDE does not flag, even the compilation does not fail.(just what happens to the 'of'?)

Found this when I accidentally hit the 'o' instead of 'i'. was supposed to be END IF not END OF but it wasn't flagged.

QB64 Discussion / IF THEN issue using AND, I think I'm losing my mind!

« on: December 10, 2021, 06:31:38 pm »

given the following:

Code: QB64: [Select]

 
 P.Mouse_over_R = 16
 P.Mouse_over_B = 15
 'The following IF THEN fails even though both values are TRUE(non 0)
 IF P.Mouse_over_R  AND P.Mouse_over_B THEN
   REM Mouse_Over_Data _MOUSEX, _MOUSEY, P.World_X + P.Mouse_over_R - 1, P.World_Y + P.Mouse_over_B - 1
  ELSE
   _PRINTSTRING (0, 0), STR$(P.Mouse_over_R) + STR$(P.Mouse_over_B), _Display
 

FAILS!

BUT given these values...

Code: QB64: [Select]

 
 P.Mouse_over_R = 9
 P.Mouse_over_B = 7
 'The following IF THEN passes 
 IF P.Mouse_over_R  AND P.Mouse_over_B THEN
   REM Mouse_Over_Data _MOUSEX, _MOUSEY, P.World_X + P.Mouse_over_R - 1, P.World_Y + P.Mouse_over_B - 1
  ELSE
   _PRINTSTRING (0, 0), STR$(P.Mouse_over_R) + STR$(P.Mouse_over_B), _Display
  END IF
 

WORKS?

So why? In both scenarios the values are non 0 but one works one doesn't?
Now if I add " > 0" to both checks it works all the time, but why is that needed?
What neuron-connections in my brain have failed and made me forget something about 'AND'?

QB64 Discussion / A question about _INFLATE$\_DEFLATE$ usage

« on: December 08, 2021, 04:23:35 pm »

I was looking into using these commands for my World Builder program to help with the saved map size issue it is facing now. Recent changes, things I just did last night and today, have ballooned the file size to several megs.

Looking at the WIKI the commands take string values. Now my map data is made up of UDTs and integer arrays. How would I go about using these commands to compress the map size when saved?

QB64 Discussion / Refresh my memory please, dealing with multiple '='

« on: December 05, 2021, 01:08:49 pm »

So why do multiple '=' on the same line act like a comparative instead of assignment?

Code: QB64: [Select]

A% = 101
B% = A% 'Assignment =
C% = A% = 99 'comparative =:  C% = 0(false)
D% = A% = B% 'comparative =: D% = -1(true)
PRINT C%
PRINT D%
 

I can't seem to remember why this is. That only the first = is treated as an assignment and all others as comparatives.

QB64 Discussion / A question about Recursion and STATIC arrays

« on: December 01, 2021, 12:52:25 pm »

If I have a Function that I want to attempt recursion with that has a STATIC array defined within it, does the data in the array remain for each recursion or is it a new static array for each time the function recurses?

In my mind I see it as being the same array each time the function is called, either in recursion or by the main loop. As STATIC variables within a sub or function are supposed to remain between calls. I'm just not sure if thats how it actually works during recursion, or if anybody has done this before.

I just don't want to waste a lot of time trying to code this out if its not how things are supposed to work in the first place and then spend countless hours trying to figure out why it doesn't work correctly then.

Of course if there is no experience out there then my option is simply to give it a go and pray for a good result I guess. It however takes less time to ask, than to blindly charge in and try to fix a mangled mess later.

QB64 Discussion / Has the issue with GET\PUT using Fixed Strings been addressed lately?

« on: November 30, 2021, 11:41:45 am »

So I can stop running into this:

In file included from qbx.cpp:2185:
..\\temp\\main.txt: In function 'void SUB_SAVE_IT(qbs*)':
..\\temp\\main.txt:3329:137: error: lvalue required as unary '&' operand
sub_put(qbr(*_SUB_SAVE_IT_SINGLE_F),NULL,byte_element((uint64)(&(qbs_new_fixed(&((uint8*)(__ARRAY_STRING255_DIALOGS[0]))[(0)*255],255,1))),(255*(__ARRAY_STRING255_DIALOGS[2]&1)*__ARRAY_STRING255_DIALOGS[5])-(255*(0)),byte_element_118),0);
compilation terminated due to -Wfatal-errors.

Programs / World Explorer BETA

« on: November 28, 2021, 02:03:25 pm »

The counter part of the World Builder program. A quick Demo of how the maps created with the World Builder program are used.

The Explore-able area is limited to roughly 16x16 for this quick demo. Still some slight hiccups with the layering effect.

Arrow Keys move the player
Space bar interacts with a few areas on screen.

I hope to include the addition of Interactive areas on the screen to be create-able within the World Builder program itself. but as for now they are hard coded in the World Explorer program and will show up even in other maps at the moment.

Sample Map included, but you can make one with the latest World Builder program, to try your own map you must simply change line 49 to the name of your map.

Code: QB64: [Select]

TYPE World_Tiles
 Id AS INTEGER 'ground
 Deco AS INTEGER 'decorations(trees\bushes\ect)
 Lay3 AS INTEGER 'a third layer of map tiles
 Walkable AS _BYTE 'can player walk on this tile?
END TYPE
 
TYPE Player_Data
 World_X AS _UNSIGNED INTEGER 'world size is 0-65535 tiles^2 (4,294,967,295 tiles total)
 World_Y AS _UNSIGNED INTEGER
 Local_X AS INTEGER
 Local_Y AS INTEGER
 Direction AS _BYTE
 Frame AS _BYTE
END TYPE
 
SCREEN _NEWIMAGE(840, 640, 32)
_TITLE "World Explorer V1.0"
_SCREENMOVE 10, 10
 
CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
CONST Key_Space = 32, Key_Enter = 13
CONST Down = 0, Left = 1, Right = 2, Up = 3, InterAct = 4
CONST TRUE = -1, FALSE = NOT TRUE
 
DIM SHARED Layer(16) AS LONG, World(255, 255) AS World_Tiles
DIM SHARED P AS Player_Data, Yo%%
 
Layer(0) = _DISPLAY
Layer(1) = _NEWIMAGE(840, 640, 32) 'composite layer
'Layer(2) = _LOADIMAGE("linear_tiles.bmp", 32) 'world tiles
Layer(3) = _NEWIMAGE(840, 640, 32)
'Layer(4) = _LOADIMAGE("Character3.bmp", 32) 'world tiles
Layer(5) = _NEWIMAGE(840, 640, 32)
 
MFI_Loader "WorldExplorer.MFI"
 
_CLEARCOLOR _RGB32(0), Layer(2)
_CLEARCOLOR _RGB32(0), Layer(3)
_CLEARCOLOR _RGB32(0), Layer(5)
_CLEARCOLOR _RGB32(43, 133, 133), Layer(4)
_PRINTMODE _KEEPBACKGROUND , Layer(3)
_PRINTMODE _KEEPBACKGROUND , Layer(1)
P.World_X = 0
P.World_Y = 0
P.Local_X = 32
P.Local_Y = 32
 
Load_it "take2"
 
Draw_World_Area
 
 
DO
 SELECT CASE Get_Input
  CASE Down
   Moving%% = TRUE
   P.Direction = Down
   IF P.Local_Y < 600 THEN P.Local_Y = P.Local_Y + 1
   IF Collision_World THEN P.Local_Y = P.Local_Y - 1
  CASE Left
   Moving%% = TRUE
   P.Direction = Left
   IF P.Local_X > 2 THEN P.Local_X = P.Local_X - 1
   IF Collision_World THEN P.Local_X = P.Local_X + 1
  CASE Right
   Moving%% = TRUE
   P.Direction = Right
   IF P.Local_X < 600 THEN P.Local_X = P.Local_X + 1
   IF Collision_World THEN P.Local_X = P.Local_X - 1
  CASE Up
   Moving%% = TRUE
   P.Direction = Up
   IF P.Local_Y > 2 THEN P.Local_Y = P.Local_Y - 1
   IF Collision_World THEN P.Local_Y = P.Local_Y + 1
  CASE InterAct
   _DELAY .1
   InterActions
  CASE ELSE
   P.Frame = 0
   Moving%% = FALSE
 END SELECT
 IF Moving%% THEN Animate_Character
 
 _PUTIMAGE , Layer(3), Layer(1)
 Draw_Character 0, 0, P.Frame
 _PUTIMAGE , Layer(5), Layer(1)
 _PUTIMAGE , Layer(1), Layer(0)
 ClearLayer Layer(1)
 _LIMIT 60
 IF INKEY$ = CHR$(27) THEN ExitFlag%% = -1
LOOP UNTIL ExitFlag%%
 
SUB Animate_Character
 STATIC Frame%%
 Frame%% = Frame%% + 1
 IF Frame%% = 15 THEN P.Frame = P.Frame + 1: Frame%% = 0
 IF P.Frame = 4 THEN P.Frame = 0
END SUB
 
SUB Draw_World_Area
 FOR Y%% = 0 TO 19
  FOR X%% = 0 TO 19
   Draw_Sprite X%%, Y%%, World(P.World_X + X%%, P.World_Y + Y%%).Id
   IF World(P.World_X + X%%, P.World_Y + Y%%).Deco THEN
    Draw_Deco_Sprite X%%, Y%%, World(P.World_X + X%%, P.World_Y + Y%%).Deco, Layer(3)
   END IF
   IF World(P.World_X + X%%, P.World_Y + Y%%).Lay3 THEN
    Draw_Deco_Sprite X%%, Y%%, World(P.World_X + X%%, P.World_Y + Y%%).Lay3, Layer(5)
   END IF
  NEXT X%%
 NEXT Y%%
END SUB
 
SUB Draw_Sprite (X%%, Y%%, id%)
 _PUTIMAGE (X%% * 32, Y%% * 32), Layer(2), Layer(3), (0 + id% * 32, 0)-STEP(31, 31)
END SUB
 
SUB Draw_Deco_Sprite (x%%, y%%, id%, L&)
 _PUTIMAGE (x%% * 32, y%% * 32), Layer(2), L&, (0 + id% * 32, 0)-STEP(31, 31)
END SUB
 
SUB Load_it (File$)
 F = FREEFILE
 IF File$ = "" THEN File$ = "Defualt"
 File$ = LTRIM$(RTRIM$(File$)) 'no spaces allowed
  IF _FILEEXISTS(File$+".MAP") = FALSE THEN PRINT File$ + ".MAP is missing.": END
 OPEN File$ + ".MAP" FOR BINARY AS #F 'Save
 GET #F, , World()
 CLOSE #F
END SUB
 
SUB Draw_Character (x%%, y%%, id%)
 _PUTIMAGE (P.Local_X + x%% * 32, P.Local_Y + y%% * 32), Layer(4), Layer(1), (0 + id% * 32, 0 + 48 * P.Direction)-STEP(30, 47)
END SUB
 
FUNCTION Get_Input%% ()
 Result%% = TRUE '-1 for no input
 ' IF _KEYDOWN(ESC_Key) THEN Result%% = ESC
 IF _KEYDOWN(Key_Up) THEN Result%% = Up
 IF _KEYDOWN(Key_Down) THEN Result%% = Down
 IF _KEYDOWN(Key_Left) THEN Result%% = Left
 IF _KEYDOWN(Key_Right) THEN Result%% = Right
 IF _KEYDOWN(Key_Space) THEN Result%% = InterAct
 Get_Input%% = Result%%
END FUNCTION
 
SUB ClearLayer (L&)
 _DEST L&
 CLS
 _DEST _DISPLAY
END SUB
 
SUB ClearLayerTrans (L&)
 _DEST L&
 CLS , 0
 _DEST _DISPLAY
END SUB
 
FUNCTION Collision_World%%
 Result%% = TRUE
 SELECT CASE P.Direction 'adjust collision detection point based on direction of travel
  CASE Down
   Yo%% = 1
  CASE Up
   Yo%% = 1
  CASE Left
   Yo%% = 1
  CASE Right
   Yo%% = 1
 END SELECT
 IF World(Tile(P.Local_X + 16), Tile(P.Local_Y + 0) + Yo%%).Walkable THEN Result%% = FALSE
 
 _PUTIMAGE (650, 100)-STEP(63, 16), Layer(1), Layer(3), (700, 500)-STEP(32, 16)
 _PRINTSTRING (650, 100), STR$(Tile(P.Local_X + 16)) + STR$(Tile(P.Local_Y) + Yo%%), Layer(3)
 Collision_World = Result%%
END FUNCTION
 
FUNCTION Tile% (value%)
 Result% = value% \ 32
 Tile = Result%
END FUNCTION
 
SUB InterActions
 SELECT CASE P.Direction
  CASE Up
   IF Tile(P.Local_X + 16) = 1 AND Tile(P.Local_Y) - 1 + Yo%% = 6 THEN 'sign post
    tmp& = _COPYIMAGE(Layer(0))
    _KEYCLEAR
    _DEST Layer(1)
    DO
     _PUTIMAGE , tmp&, Layer(1)
     LINE (P.Local_X + 32, P.Local_Y + 16)-STEP(191, 40), _RGBA32(112, 32, 192, 144), BF
     _PRINTSTRING (P.Local_X + 42, P.Local_Y + 26), "This is a sign post.", Layer(1)
     _PUTIMAGE , Layer(1), Layer(0)
     _LIMIT 60
     IF Get_Input <> TRUE THEN ExitFlag%% = TRUE
    LOOP UNTIL ExitFlag%%
    _KEYCLEAR
    _FREEIMAGE tmp&
    _DEST Layer(0)
   END IF
 
   IF Tile(P.Local_X + 16) = 1 AND Tile(P.Local_Y) - 1 + Yo%% = 13 THEN 'Grave Stone
    tmp& = _COPYIMAGE(Layer(0))
    _KEYCLEAR
    _DEST Layer(1)
    DO
     _PUTIMAGE , tmp&, Layer(1)
     LINE (P.Local_X + 32, P.Local_Y + 16)-STEP(191, 48), _RGBA32(112, 32, 192, 144), BF
     _PRINTSTRING (P.Local_X + 42, P.Local_Y + 26), "Here lies: Cobalt", Layer(1)
     _PRINTSTRING (P.Local_X + 42, P.Local_Y + 42), "33AE - 121AE", Layer(1)
     _PUTIMAGE , Layer(1), Layer(0)
     _LIMIT 60
     IF Get_Input <> TRUE THEN ExitFlag%% = TRUE
    LOOP UNTIL ExitFlag%%
    _KEYCLEAR
    _FREEIMAGE tmp&
    _DEST Layer(0)
   END IF
 
   IF Tile(P.Local_X + 16) = 7 AND Tile(P.Local_Y) - 1 + Yo%% = 11 THEN 'Front door
    tmp& = _COPYIMAGE(Layer(0))
    _KEYCLEAR
    _DEST Layer(1)
    DO
     _PUTIMAGE , tmp&, Layer(1)
     LINE (P.Local_X + 32, P.Local_Y + 16)-STEP(191, 48), _RGBA32(112, 32, 192, 144), BF
     _PRINTSTRING (P.Local_X + 42, P.Local_Y + 26), "'Knock Knock...'", Layer(1)
     _PRINTSTRING (P.Local_X + 42, P.Local_Y + 42), "There is no answer.", Layer(1)
     _PUTIMAGE , Layer(1), Layer(0)
     _LIMIT 60
     IF Get_Input <> TRUE THEN ExitFlag%% = TRUE
    LOOP UNTIL ExitFlag%%
    _KEYCLEAR
    _FREEIMAGE tmp&
    _DEST Layer(0)
   END IF
 
   IF Tile(P.Local_X + 16) = 6 AND Tile(P.Local_Y) - 1 + Yo%% = 4 THEN 'Well
    tmp& = _COPYIMAGE(Layer(0))
    _KEYCLEAR
    _DEST Layer(1)
    DO
     _PUTIMAGE , tmp&, Layer(1)
     LINE (P.Local_X + 32, P.Local_Y + 16)-STEP(191, 48), _RGBA32(112, 32, 192, 144), BF
     _PRINTSTRING (P.Local_X + 42, P.Local_Y + 26), "It is a well.", Layer(1)
     _PRINTSTRING (P.Local_X + 42, P.Local_Y + 42), "Wow it is deep!", Layer(1)
     _PUTIMAGE , Layer(1), Layer(0)
     _LIMIT 60
     IF Get_Input <> TRUE THEN ExitFlag%% = TRUE
    LOOP UNTIL ExitFlag%%
    _KEYCLEAR
    _FREEIMAGE tmp&
    _DEST Layer(0)
   END IF
 
 END SELECT
END SUB
 
SUB MFI_Loader (FN$)
 DIM Size(128) AS LONG, FOffset(128) AS LONG
  IF _FILEEXISTS(FN$) = FALSE THEN PRINT FN$ + " is missing. This file needs downloaded": END
 OPEN FN$ FOR BINARY AS #1
 GET #1, , c~%% 'retrieve number of files
 FOR I~%% = 1 TO c~%%
  GET #1, , FOffset(I~%%)
  GET #1, , Size(I~%%)
  FOffset&(I~%%) = FOffset&(I~%%) + 1
 NEXT I~%%
 
 Layer(2) = LoadGFX(FOffset(1), Size(1)) 'tiles
 Layer(4) = LoadGFX(FOffset(2), Size(2)) 'characters
 
 CLOSE #1
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
END SUB
 
FUNCTION LoadGFX& (Foff&, Size&)
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
 OPEN "temp.dat" FOR BINARY AS #3
 dat$ = SPACE$(Size&)
 GET #1, Foff&, dat$
 PUT #3, , dat$
 CLOSE #3
 LoadGFX& = _LOADIMAGE("temp.dat", 32)
END FUNCTION
 

Programs / Tile Based World Maker! (FIXED update 7)

« on: November 23, 2021, 09:06:35 pm »

So I was fiddling with making a Program to create maps for a game and thought I might share it and see if you guys would want to create some custom maps?

Plus it could use some stress testing.

The interface is mouse based. Click and release, NOT CLICK AND DRAG.(although you can add to the map by clicking and dragging with left and right buttons, but not the middle button.)

To use, you click on a tile, then click the tile either in the BASE, DECO, or AUTOMATIC areas.

Left button allows selection of a tile from the tile list area to be placed in the BASE, DECO, or AUTOMATIC area.
Right button cancels the selection

In the Map grid:
Left button adds the DECO tile to the map.
Right button clears the DECO and restores the BASE tile.
Middle button places the AUTOMATIC area on the map. ~~Now this has an issue if you click and drag, and it will cause errors.~~Fixed

The AUTOMATIC area allows you to pre-make a 3x3 area that can be used over and over. Right clicking in the AUTOMATIC area erases it.

The yellow box on the "Mini Map" shows what area you are currently working in. right now the Mini Map only shows the BASE tiles no DECO tiles. This may not change due to the Mini Map being a 256x256 render of the full map which is 8192x8192.(32:1 ratio)
(FYI: DECO is short for Decorations)

There are currently 960 tiles to choose from.
this is due to the limitations of image format sizes, BMP max out at roughly 32k px. and my imaging software maxes the PNG out at roughly 30k. (I will need to come up with a round about way to make it capable of larger sets)
Only the first 8 tiles can be used for the BASE.

Maps can be saved(and loaded!) with up to 32 character long names, leaving the name blank names it "DEFUALT" no spaces allowed. Extension is automatically set to ".MAP". Can only save to the program directory at the moment.

I think that is it, tell me what you think!
(this requires a MFI file, so be sure to download it.)

Fixed an issue where the decorations would not draw correctly when you moved on the map.(11\24\2021)
Fixed an issue where the decorations displayed outside the map grid area(11\24\2021)
Added the ability to place SINGLE tiles straight to the map area. (as recommended by Bplus)
Added a 3rd layer to the placement of tiles for more depth.
Fixed issue with erasing decorations after moving in the map.(11/27/2021)

Video Demo:(outdated)
~~https://youtu.be/0K6pmuGXY-Q~~

Programs / Gapper, Give it a try! (updated[11/19/21])

« on: November 18, 2021, 01:36:35 pm »

So I present Gapper. Surf the grid changing its color to rack up points. But beware the Seeker who is out to get you!

Being absurdly busy of late this has taken far longer than it should of, but its coming along.

There is a few things to iron out yet; Bonus squares, ~~the ability to "Gap", the 5000 point bonus life~~, and the high score list.
But based on my trial runs everything seems to be working as close to original as possible. Granted my own tests hardly find anything that might be hidden or obscure. So I could use some other players to make sure they can not find anything!

The seeker has a very subtle speed curve and wont reach full speed till closer to Level 8 now.

need to find a way to add the intro screens as data without it taking 2.4mb of space(original BMP was only 900k)

Controls: Arrow Keys
Space Bar- place a temporary gap in the line.
~~(introduced a bug, you only get an extra life if you have exact multiples of 5000! fixing this soon)~~ Fixed(again)

Code: QB64: [Select]

'Gapper(1986) Clone
'10\25\2019 Cobalt
'ÃInital Start; Layout, Gapper, Seeker, L1 Grid finished [13:55EDT]
'ÀCorreted 'Catcher' to 'Seeker' as per original game
'10\31\2021
'ÃFixed Seeker movement issue with help from Bplus and Keybone, used ABS as per Bplus
'Àadded startup screen, player initials input,game options
'11\1\2021
'ÃAdded the instructions screens
'Àenabled collision of Seeker and Gapper
'11\11\2021
'ÃFinished all 8 boards
'11\13\2021
'ÃInserted Bplus's code for detecting completed boxes.
'11\14\2021
'ÃIntegrated Bplus's code for detecting completed boxes and filling them.
'ÃAdded score amount to filled boxes
'ÃLevels now end when boxes are full
'ÀScore is now kept
'11\15\2021
'ÃFixed a few minor bugs with help from Bplus
'ÃReplaced each level creation sub with a master so now all levels created with in a single sub, saved ~210 lines
'ÀChanged Seeker speed to use reducing timer to move faster as levels progress.
'11\18\2021
'ÃAdded extra life at 5000 point intervals
'ÀAdded ability to create "Gaps" on board
 
TYPE GameData
 Player AS STRING * 4
 Score AS LONG
 Lives AS _BYTE
 Level AS _BYTE
 GX AS INTEGER 'Gapper X location
 GY AS INTEGER 'Gapper Y location
 GD AS _BYTE 'Gapper direction
 SX AS INTEGER
 SY AS INTEGER
 SS AS _BYTE 'Seeker speed
 SD AS _BYTE 'Seeker direction
 Start AS _BYTE 'is level started or not(nothing happens until started)
 FPS AS INTEGER
 Quit AS _BYTE
 Caught AS _BYTE 'has the seeker caught the gapper?
 Gapped AS _BYTE 'has the player used the gap feature?
 Gap_time AS SINGLE 'the time the gap was placed. Gaps last less time at higher levels
 'board info
 CellHeight AS _BYTE
 CellWidth AS _BYTE
 Rows AS _BYTE
 Columns AS _BYTE
 Offx AS _BYTE
 Offy AS _BYTE
 Needed AS _BYTE 'number of cells needing finished to win level
 Finished AS _BYTE 'number of cells currently boxed in
END TYPE
 
TYPE High_Scores
 Nam AS STRING * 4
 Score AS LONG
 Level AS INTEGER
END TYPE
 
CONST TRUE = -1, FALSE = NOT TRUE, Gapper = 1, Seeker = 2
CONST UP = 1, DOWN = 2, LEFT = 3, RIGHT = 4
CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
CONST Key_Space = 32, Key_Enter = 13
CONST Cyan = &HFF10E0E0~& '_RGB32(0, 170, 170)
CONST Magenta = &HFFC040C0~&
CONST OffWhite = &HFFC0C0C0~&
CONST Brown = &HFFB06000~&
CONST Yellow = &HFFFFFF00~&
CONST Black = &HFF000000~&
CONST DB_Blue = &HFF0000FF~&
 
Level_data:
DATA 104,60,3,3,4,10,9,0,14,626,374
DATA 76,44,4,4,8,12,16,8,18,616,370
DATA 60,36,5,5,10,10,25,12,14,612,374
DATA 48,24,7,6,16,16,42,24,26,600,362
DATA 36,24,7,8,16,16,44,24,26,458,362
DATA 36,24,7,8,16,16,40,168,26,458,362
DATA 36,24,7,8,16,16,44,168,26,600,362
DATA 36,24,7,8,16,16,56,24,26,600,362
 
SCREEN _NEWIMAGE(640, 440, 32)
DIM SHARED Layer(11) AS LONG, G AS GameData, Frames%
DIM SHARED Scores(10) AS High_Scores
DIM SHARED FinishedBox(72) AS _BYTE, T1 AS LONG, T2 AS LONG
 
Layer(0) = _DISPLAY
Layer(1) = _NEWIMAGE(640, 440, 32) 'mix layer
Layer(2) = _NEWIMAGE(320, 220, 32) 'Grid Layer
Layer(3) = _NEWIMAGE(640, 440, 32) 'Sprite layer
Layer(4) = _NEWIMAGE(320, 220, 32) 'Info layer
Layer(5) = _NEWIMAGE(640, 440, 32) 'Collision 'Gapper\Catcher' layer
Layer(6) = _NEWIMAGE(640, 440, 32) 'Collision 'Grid' layer
Layer(7) = _NEWIMAGE(640, 440, 32) 'debug layer
Layer(8) = _NEWIMAGE(320, 220, 32) 'Menu layer
Layer(9) = _NEWIMAGE(320, 240, 32) 'instructions layer
Layer(10) = _NEWIMAGE(320, 8, 32) 'title bar layer
Layer(11) = _NEWIMAGE(320, 220, 32) 'point test location layer
 
_FONT 8, Layer(4)
_FONT 8, Layer(8)
_FONT 8, Layer(9)
_FONT 8, Layer(10)
_FONT 8, Layer(2)
_PRINTMODE _KEEPBACKGROUND , Layer(10)
_PRINTMODE _KEEPBACKGROUND , Layer(8)
_PRINTMODE _KEEPBACKGROUND , Layer(9)
_PRINTMODE _KEEPBACKGROUND , Layer(2)
_CLEARCOLOR _RGB32(0, 0, 0), Layer(3)
_CLEARCOLOR _RGB32(0, 0, 0), Layer(7)
 
_SCREENMOVE 16, 16
_SOURCE Layer(6)
T1 = _FREETIMER
T2 = _FREETIMER
ON TIMER(T1, 1) FPS
ON TIMER(T2, .05) Move_Seeker
 
Game_INIT
Title_Startup
 
 
SUB Play_game
 DO
  IF _KEYDOWN(27) THEN ExitFlag%% = TRUE: G.Quit = TRUE
  IF _KEYDOWN(Key_Up) THEN
   G.Start = TRUE
   IF NOT Collision_Grid(Gapper, UP) THEN G.GD = UP
  END IF
  IF _KEYDOWN(Key_Down) THEN
   G.Start = TRUE
   IF NOT Collision_Grid(Gapper, DOWN) THEN G.GD = DOWN
  END IF
  IF _KEYDOWN(Key_Left) THEN
   G.Start = TRUE
   IF NOT Collision_Grid(Gapper, LEFT) THEN G.GD = LEFT
  END IF
  IF _KEYDOWN(Key_Right) THEN
   G.Start = TRUE
   IF NOT Collision_Grid(Gapper, RIGHT) THEN G.GD = RIGHT
  END IF
  IF _KEYDOWN(32) AND G.Gapped = FALSE AND G.Start THEN
   G.Gapped = TRUE
   G.Score = G.Score - 5
   Create_Gap
  END IF
  IF G.Start THEN Move_Gapper ':Move_Seeker
  IF G.Gapped THEN Time_Gap 'if there is a gap then check how long its been there
 
  FOR i%% = 1 TO G.Columns * G.Rows
   IF BoxSurrounded(i%%) THEN FinishedBox(i%%) = TRUE
   IF FinishedBox(i%%) THEN FillBox i%%
  NEXT i%%
 
  Game_Data_Update
  _PUTIMAGE (0, 0)-STEP(639, 15), Layer(10), Layer(1) 'title bar
  _PUTIMAGE , Layer(4), Layer(1) 'information bar
  _PUTIMAGE , Layer(2), Layer(1) 'game board
  Place_Gapper
  Place_Seeker
  IF G.Caught THEN 'seeker caught 'em
   ClearLayer Layer(5)
   Reset_Pos
   DrawBoard
   G.Lives = G.Lives - 1
   IF G.Lives = -1 THEN ExitFlag%% = TRUE
  END IF
  ' _PRINTSTRING (600, 0), STR$(G.FPS), Layer(7)
  _PUTIMAGE , Layer(7), Layer(1) 'debug layer
  _PUTIMAGE , Layer(1), Layer(0)
  _LIMIT 60
  ClearLayer Layer(1)
  Frames% = Frames% + 1
  IF G.Finished = G.Needed THEN _DELAY .5: Change_Level
 LOOP UNTIL ExitFlag%%
END SUB
 
SUB Place_Gapper
 old& = _DEST
 _DEST Layer(5)
 LINE (G.GX - 2, G.GY - 2)-STEP(20, 18), Black, BF
 'place gapper-----
 _PUTIMAGE (G.GX, G.GY), Layer(3), Layer(1), (318, 218)-STEP(15, 13)
 'place Gapper shadow
 _PUTIMAGE (G.GX, G.GY), Layer(3), Layer(5), (318, 218)-STEP(15, 13)
 ' _DEST old&
END SUB
 
SUB Place_Seeker
 'place Seeker----
 _PUTIMAGE (G.SX, G.SY), Layer(3), Layer(1), (341, 218)-STEP(14, 11)
 '-----------------
END SUB
 
 
SUB Game_INIT
 _DEST Layer(3)
 'Player----
 DRAW "c" + STR$(Cyan) + "drurd8l2dr3u9d2rd5ru5rd5ru5ru2d9r3ul2u8r2dlbl3c" + STR$(Magenta) + "u3ld3lu3ld3"
 DRAW "bd7d3ru3rd3ru3bu3br3r4ul4bl9l4dr4"
 '----------
 DRAW "br20bu7"
 'Seeker----
 DRAW "c" + STR$(Cyan) + "r3dl3bd10r3ul3br10r3dl3bu10r3ul3c" + STR$(Magenta) + "bd2brl3dr3bd5l3dr3bl6l3ur3"
 DRAW "bu5l3ur3d2lr5dl5dr5dl5"
 '------------
 Title_Header
 _DEST Layer(5)
 LINE (0, 0)-STEP(639, 439), Black, BF
 _DEST Layer(0)
 G.Score = 0
 G.Lives = 2
 G.Level = 1
END SUB
 
SUB Title_Header
 'Header
 _DEST Layer(10)
 LINE (84, 0)-STEP(151, 8), Magenta, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Magenta
 _PRINTSTRING (135, 1), "GAPPER"
 COLOR OffWhite
END SUB
 
SUB Game_Data_Update
 'Info area updating ---------------
 _PRINTSTRING (7, 192), "Score[      ]    Lives[ ]    Level[  ]", Layer(4)
 _PRINTSTRING (95 - ((LEN(LTRIM$(STR$(G.Score))) - 1) * 8), 192), LTRIM$(STR$(G.Score)), Layer(4)
 _PRINTSTRING (191, 192), LTRIM$(STR$(G.Lives)), Layer(4)
 _PRINTSTRING (295 - ((LEN(LTRIM$(STR$(G.Level))) - 1) * 8), 192), LTRIM$(STR$(G.Level)), Layer(4)
 '-----------------------------------
END SUB
 
SUB DrawBoard
 _DEST Layer(2)
 SELECT CASE G.Level
  CASE 1 TO 8 'draw level 1 grid
   Master_Level G.Level
  CASE ELSE 'after level 8 board is random between 5 and 8
   Master_Level INT(RND * 4) + 5
 END SELECT
 _DEST Layer(0)
 ClearLayer Layer(6)
 _PUTIMAGE , Layer(2), Layer(6) 'make a copy for the collision layer
END SUB
 
SUB ClearLayer (L&)
 _DEST L&
 CLS
 _DEST _DISPLAY
END SUB
 
SUB ClearLayerTrans (L&)
 _DEST L&
 CLS , 0
 _DEST _DISPLAY
END SUB
 
FUNCTION Collision_Seeker%%
 Result%% = FALSE
 _SOURCE Layer(5)
 IF POINT(G.SX, G.SY) <> Black THEN Result%% = TRUE
 IF POINT(G.SX + 8, G.SY) <> Black THEN Result%% = TRUE
 IF POINT(G.SX, G.SY + 8) <> Black THEN Result%% = TRUE
 IF POINT(G.SX + 8, G.SY + 8) <> Black THEN Result%% = TRUE
 Collision_Seeker = Result%%
 _SOURCE Layer(6)
END FUNCTION
 
FUNCTION Collision_Grid%% (who%%, Direction%%)
 Result%% = TRUE 'always assume collision
 SELECT CASE who%% 'who are we checking collision for?
  CASE Gapper
   SELECT CASE Direction%%
    CASE UP 'see if there is grid up from Gappers position
     Check~& = POINT(G.GX + 8, G.GY + 5)
    CASE DOWN 'see if there is Grid below Gapper
     Check~& = POINT(G.GX + 8, G.GY + 9)
    CASE LEFT 'check for grid to the left of Gapper
     Check~& = POINT(G.GX + 6, G.GY + 7)
    CASE RIGHT 'Check for grid to the Right of Gapper
     Check~& = POINT(G.GX + 10, G.GY + 7)
   END SELECT
  CASE Seeker
   SELECT CASE Direction%%
    CASE UP 'see if there is grid up from Gappers position
     Check~& = POINT(G.SX + 8, G.SY + 5)
    CASE DOWN 'see if there is Grid below Gapper
     Check~& = POINT(G.SX + 8, G.SY + 9)
    CASE LEFT 'check for grid to the left of Gapper
     Check~& = POINT(G.SX + 6, G.SY + 7)
    CASE RIGHT 'Check for grid to the Right of Gapper
     Check~& = POINT(G.SX + 10, G.SY + 7)
   END SELECT
 END SELECT
 Blue~%% = _BLUE32(Check~&) 'check for Blue, grid is Cyan in color
 IF Blue~%% THEN Result%% = FALSE 'there is grid to move onto, no collision with edge of grid
 Collision_Grid = Result%%
 '_SOURCE Layer(0)
END FUNCTION
 
SUB Move_Seeker
 IF G.Start THEN
  Seeker_Logic
  SELECT CASE G.SD
   CASE UP
    IF NOT Collision_Grid(Seeker, UP) THEN G.SY = G.SY - 2
   CASE DOWN
    IF NOT Collision_Grid(Seeker, DOWN) THEN G.SY = G.SY + 2
   CASE LEFT
    IF NOT Collision_Grid(Seeker, LEFT) THEN G.SX = G.SX - 2
   CASE RIGHT
    IF NOT Collision_Grid(Seeker, RIGHT) THEN G.SX = G.SX + 2
  END SELECT
 END IF
 IF Collision_Seeker THEN G.Caught = TRUE
END SUB
 
SUB Move_Gapper
 SELECT CASE G.GD
  CASE UP
   IF NOT Collision_Grid(Gapper, UP) THEN G.GY = G.GY - 2
  CASE DOWN
   IF NOT Collision_Grid(Gapper, DOWN) THEN G.GY = G.GY + 2
  CASE LEFT
   IF NOT Collision_Grid(Gapper, LEFT) THEN G.GX = G.GX - 2
  CASE RIGHT
   IF NOT Collision_Grid(Gapper, RIGHT) THEN G.GX = G.GX + 2
 END SELECT
 Color_Line
END SUB
 
SUB Seeker_Logic
 DistX% = (G.SX - G.GX) 'find X distance between seeker and gapper
 DistY% = (G.SY - G.GY) 'find Y distance between Seeker and Gapper
 IF ABS(DistX%) > ABS(DistY%) THEN 'if player is farther on the X then
  IF DistX% < 0 THEN
   Turn_Seeker RIGHT 'try going right to get closer
  ELSE
   Turn_Seeker LEFT 'try going left to get closer
  END IF
 ELSE 'player is farther on the Y then
  IF DistY% < 0 THEN
   Turn_Seeker DOWN 'try going down to get closer
  ELSE
   Turn_Seeker UP 'try going up to get closer
  END IF
 END IF
END SUB
 
SUB Turn_Seeker (Direction%%)
 SELECT CASE Direction%%
  CASE UP
   IF NOT Collision_Grid(Seeker, UP) THEN G.SD = UP
  CASE DOWN
   IF NOT Collision_Grid(Seeker, DOWN) THEN G.SD = DOWN
  CASE LEFT
   IF NOT Collision_Grid(Seeker, LEFT) THEN G.SD = LEFT
  CASE RIGHT
   IF NOT Collision_Grid(Seeker, RIGHT) THEN G.SD = RIGHT
 END SELECT
END SUB
 
SUB Color_Line
 _DEST Layer(2)
 LINE (4 + G.GX \ 2, 3 + G.GY \ 2)-STEP(0, 0), Magenta, BF
 _DEST Layer(0)
END SUB
 
SUB FPS
 G.FPS = Frames%
 Frames% = 0
END SUB
 
SUB Title_Startup
 Load_Scores
 _DEST Layer(8)
 LINE (84, 0)-STEP(151, 8), Brown, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Brown
 _PRINTSTRING (135, 1), "GAPPER"
 LINE (0, 140)-STEP(639, 8), Brown, BF
 COLOR Black
 _PRINTSTRING (0, 141), "Score:"
 _PRINTSTRING (220, 141), "Level:"
 _PRINTSTRING (100 - (LEN(LTRIM$(STR$(G.Score))) * 8), 141), STR$(G.Score) + "."
 _PRINTSTRING (284 - (LEN(LTRIM$(STR$(G.Level))) * 8), 141), STR$(G.Level)
 
 COLOR Yellow
 _PRINTSTRING (100, 160), "P: Play a game."
 _PRINTSTRING (100, 170), "Q: Quit"
 _PRINTSTRING (100, 180), "N: New Player"
 _PRINTSTRING (100, 190), "I: Instuctions"
 
 Get_Player
 IF Search_For_Player THEN AddPlayer 'first time this player has played!
 Display_HighScores
 Get_Menu_Selection
END SUB
 
SUB Get_Player
 Blink%% = TRUE: I$ = ""
 _DEST Layer(8)
 COLOR Magenta
 LINE (0, 210)-STEP(219, 9), Black, BF
 _PRINTSTRING (0, 210), "Enter your initials:"
 COLOR OffWhite
 DO 'Initials input Loop
  KBD& = _KEYHIT
  SELECT CASE KBD&
   CASE 8 'delete
    IF LEN(I$) THEN I$ = LEFT$(I$, LEN(I$) - 1)
    LINE (168, 210)-(248, 219), Black, BF
   CASE 32 TO 122 'characters
    IF LEN(I$) < 3 THEN I$ = I$ + CHR$(KBD&)
    LINE (168, 210)-(248, 219), Black, BF
   CASE 13 'accept input(if any)
    IF RTRIM$(I$) <> "" THEN ExitFlag%% = TRUE ELSE BEEP
   CASE 27
    ExitFlag%% = TRUE
    G.Quit = TRUE
  END SELECT
  COLOR OffWhite
  _PRINTSTRING (168, 210), I$
  IF Blink%% THEN COLOR Black ELSE COLOR OffWhite
  _PRINTSTRING (168 + LEN(I$) * 8, 210), "_"
  _PUTIMAGE , Layer(8), _DISPLAY
  _LIMIT 30
  t%% = t%% + 1
  IF t%% = 4 THEN Blink%% = NOT Blink%%: t%% = 0
 LOOP UNTIL ExitFlag%%
 G.Player = I$
END SUB
 
SUB Get_Menu_Selection
 LINE (0, 210)-STEP(200, 9), Black, BF
 _PRINTSTRING (0, 210), "Please enter selection:  "
 DO
  KBD& = _KEYHIT
  SELECT CASE KBD&
   CASE ASC("p") OR ASC("P")
    New_Game
    DrawBoard
    TIMER(T1&) ON
    TIMER(T2&) ON
    Play_game
    TIMER(T1&) OFF
    TIMER(T2&) OFF
 
    CLS
    _KEYCLEAR
   CASE ASC("q") OR ASC("Q")
    ExitFlag%% = TRUE
    G.Quit = TRUE
   CASE ASC("n") OR ASC("N")
    Get_Player
    LINE (0, 210)-STEP(200, 9), Black, BF
    _PRINTSTRING (0, 210), "Please enter selection:  "
   CASE ASC("i") OR ASC("I")
    Instructions
   CASE 27
    'ExitFlag%% = TRUE
    'G.Quit = TRUE
  END SELECT
  _PUTIMAGE , Layer(8), _DISPLAY
 LOOP UNTIL ExitFlag%%
END SUB
 
SUB Display_HighScores
 _DEST Layer(8)
 IF LTRIM$(RTRIM$(Scores(1).Nam)) <> "" THEN
  COLOR Magenta
  _PRINTSTRING (0, 24), "High scores:"
  FOR i%% = 1 TO 10
   IF G.Player = Scores(i%%).Nam THEN
    COLOR Yellow 'player shows up Yellow
   ELSEIF i%% = 1 THEN
    COLOR Magenta 'High score if not player shows magenta
   ELSE
    COLOR OffWhite 'everybody else is off white
   END IF
  NEXT i%%
 END IF
END SUB
 
SUB Instructions
 ClearLayer Layer(0)
 _DEST Layer(9)
 LINE (84, 0)-STEP(151, 8), Brown, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Brown
 _PRINTSTRING (135, 1), "GAPPER"
 COLOR OffWhite
 _PRINTSTRING (84, 10), "OBJECT"
 _PRINTSTRING (1, 20), "To color all the blue lines"
 _PRINTSTRING (1, 30), "red by moving your man GAPPER"
 _PRINTSTRING (1, 40), "with the arrow keys.  At the"
 _PRINTSTRING (1, 50), "same time, you myst avoid"
 _PRINTSTRING (1, 60), "the SEEKER."
 
 _PRINTSTRING (84, 80), "POINTS"
 _PRINTSTRING (1, 90), "Fifty points are awarded for"
 _PRINTSTRING (1, 100), "each square that you surround"
 _PRINTSTRING (1, 110), "in red.  100 points are given"
 _PRINTSTRING (1, 120), "when you encircle the extra"
 _PRINTSTRING (1, 130), "point box while it is on. Each"
 _PRINTSTRING (1, 140), "gap costs 5 points."
 
 _PRINTSTRING (84, 150), "GAPPING"
 _PRINTSTRING (1, 160), "You can create a temporary"
 _PRINTSTRING (1, 170), "gap in the lines by pressing"
 _PRINTSTRING (1, 180), "the SPACE bar or RETURN.  The"
 _PRINTSTRING (1, 190), "word ON appears as long as the"
 _PRINTSTRING (1, 200), "gap is active.  Neither you nor"
 _PRINTSTRING (1, 210), "the seeker can cross the gap."
 
 _PRINTSTRING (0, 230), "Press a key..."
 _PUTIMAGE , Layer(9), _DISPLAY
 _DELAY .5
 _KEYCLEAR
 'end of page 1
 DO: _LIMIT 24: LOOP WHILE INKEY$ = ""
 CLS
 LINE (84, 0)-STEP(151, 8), Brown, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Brown
 _PRINTSTRING (135, 1), "GAPPER"
 COLOR OffWhite
 _PRINTSTRING (84, 10), "LEVELS"
 _PRINTSTRING (1, 20), "The level increases each time"
 _PRINTSTRING (1, 30), "you complete a screen.  The"
 _PRINTSTRING (1, 40), "seeker gets faster, the gap"
 _PRINTSTRING (1, 50), "time shorter and there will"
 _PRINTSTRING (1, 60), "be more boxes."
 
 _PRINTSTRING (84, 80), "LIVES"
 _PRINTSTRING (1, 90), "You start out with 2 extra"
 _PRINTSTRING (1, 100), "men.  One more will be given"
 _PRINTSTRING (1, 110), "for each 5000 points."
 
 _PRINTSTRING (84, 130), "START"
 _PRINTSTRING (1, 140), "When the grid appears, you"
 _PRINTSTRING (1, 150), "Will be in the top left and"
 _PRINTSTRING (1, 160), "the seeker at the low right."
 _PRINTSTRING (1, 170), "Press a key to begin each new"
 _PRINTSTRING (1, 180), "screen."
 
 _PRINTSTRING (0, 230), "Press a key..."
 'end of page 2
 _PUTIMAGE , Layer(9), _DISPLAY
 _DELAY .5
 _KEYCLEAR
 DO: _LIMIT 24: LOOP WHILE INKEY$ = ""
 ClearLayer Layer(0)
END SUB
 
SUB Load_Scores
 OPEN "Gapper.HSL" FOR BINARY AS #1
 GET #1, , Count%%
 FOR i%% = 1 TO Count%%
  GET #1, , Scores(i%%).Nam
  GET #1, , Scores(i%%)
  GET #1, , Scores(i%%)
 NEXT i%%
 CLOSE #1
END SUB
 
FUNCTION Search_For_Player
 FOR i%% = 1 TO 10
  IF G.Player = Scores(i%%).Nam THEN Result%% = TRUE: i%% = 11 ELSE Result%% = FALSE
 NEXT i%%
 Search_For_Player = Result%%
END FUNCTION
 
SUB AddPlayer
 OPEN "Gapper.HSL" FOR BINARY AS #1
 GET #1, , Count%%
 IF Count%% < 10 THEN Count%% = Count%% + 1
 PUT #1, 1, Count%%
 PUT #1, 1 + 10 * Count%%, G.Player
 PUT #1, , NULL& 'filler for score
 PUT #1, , NULL% 'filler for level
 CLOSE #1
 Load_Scores 'reload score list
END SUB
 
SUB Reset_Pos
 PLAY "o1l32aacceegg"
 _DELAY .25
 G.Start = FALSE
 G.Caught = FALSE
 G.Finished = 0
 ClearLayerTrans Layer(2)
 FOR i%% = 0 TO 72
  FinishedBox(i%%) = FALSE
 NEXT i%%
END SUB
 
 
 
FUNCTION BoxSurrounded%% (boxNumber AS INTEGER) 'save already tested boxes in shared array BoxesSurrounded()
 'Bplus contributed code. 11\12\2021
 'some variables changed to use existing, `**` comments are added
 _SOURCE Layer(2)
 IF FinishedBox(boxNumber) = 0 THEN '**Is the box completed already?
  row = INT((boxNumber - 1) / G.Columns) '[cellsPerCpl)] '**which row
  col = (boxNumber - 1) MOD G.Columns + 1 '[cellsAcross + 1] '**which column
 
  Good%% = TRUE
  FOR I% = row * G.CellHeight TO (row + 1) * G.CellHeight STEP 4 '**No need to check every pixel
   IF POINT(G.Offx + (col - 1) * G.CellWidth, G.Offy + I%) <> Magenta THEN I% = 9999: Good%% = FALSE ' False Baox not surrounded
   IF POINT(G.Offx + col * G.CellWidth, G.Offy + I%) <> Magenta THEN I% = 9999: Good%% = FALSE
  NEXT I%
 
  IF Good%% THEN '**only check other lines if it hasn't failed yet
   FOR I% = (col - 1) * G.CellWidth TO col * G.CellWidth STEP 4 '**No need to check every pixel
    IF POINT(G.Offx + I%, G.Offy + row * G.CellHeight) <> Magenta THEN I% = 9999: Good%% = FALSE ' False Baox not surrounded
    IF POINT(G.Offx + I%, G.Offy + (row + 1) * G.CellHeight) <> Magenta THEN I% = 9999: Good%% = FALSE
   NEXT I%
  END IF
  IF Good%% THEN BoxSurrounded = -1: G.Finished = G.Finished + 1: G.Score = G.Score + 50: PLAY "o3l54eeggee": Check_Score 'all OK
 ELSE
  BoxSurrounded = -1
 END IF
 _SOURCE Layer(6)
END FUNCTION
 
SUB FillBox (boxNumber)
 ' _DELAY .25
 _DEST Layer(2)
 row = INT((boxNumber - 1) / G.Columns)
 col = (boxNumber - 1) MOD G.Columns + 1
 LINE (G.Offx + (col - 1) * G.CellWidth + 3, G.Offy + row * G.CellHeight + 3)-STEP(G.CellWidth - 6, G.CellHeight - 6), OffWhite, BF
 COLOR Black
 _PRINTSTRING (G.Offx + (col - 1) * G.CellWidth + 3 + (INT(G.CellWidth \ 2) - 8), G.Offy + row * G.CellHeight + 3 + (INT(G.CellHeight \ 2) - 8)), "50", Layer(2)
 COLOR OffWhite
 _DEST Layer(0)
END SUB
 
SUB Change_Level
 G.Level = G.Level + 1
 speed! = (.05 - (G.Level / 1000) * 5)
 IF speed! <= .015 THEN speed! = .015
 ON TIMER(T2, speed!) Move_Seeker
 ClearLayerTrans Layer(2)
 ClearLayer Layer(5)
 ClearLayer Layer(6)
 DrawBoard
 G.Finished = 0
 FOR i%% = 0 TO 72
  FinishedBox(i%%) = FALSE
 NEXT i%%
END SUB
 
SUB Master_Level (Level)
 G.Start = FALSE
 RESTORE Level_data
 FOR i%% = 1 TO Level 'load level data
  READ G.CellWidth, G.CellHeight, G.Rows, G.Columns, G.Offx, G.Offy, G.Needed, G.GX, G.GY, G.SX, G.SY
 NEXT i%%
 SELECT CASE Level 'create levels
  CASE 1 TO 4, 8
   FOR i%% = 0 TO G.Rows
    LINE (G.Offx, G.Offy + i%% * G.CellHeight)-STEP(G.CellWidth * G.Columns, 0), Cyan 'horizontal lines
   NEXT i%%
   FOR i%% = 0 TO G.Columns
    LINE (G.Offx + i%% * G.CellWidth, G.Offy)-STEP(0, G.CellHeight * G.Rows), Cyan 'vertical lines
   NEXT i%%
  CASE 5 ' "Â" shaped level
   FOR i%% = 0 TO 4
    LINE (16, 16 + i%% * 24)-STEP(288, 0), Cyan 'horizontal lines
    LINE (88 + i%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
   NEXT i%%
   FOR i%% = 0 TO 2
    LINE (88, 136 + i%% * 24)-STEP(144, 0), Cyan 'horizontal lines
    LINE (16 + i%% * 36, 16)-STEP(0, 96), Cyan 'vertical lines
    LINE (268 + i%% * 36, 16)-STEP(0, 96), Cyan 'vertical lines
   NEXT i%%
  CASE 6 ' "Å" shaped level
   FOR i%% = 0 TO 3
    LINE (16, 64 + i%% * 24)-STEP(288, 0), Cyan 'horizontal lines
    LINE (88 + i%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
   NEXT i%%
   LINE (88 + i%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 
   FOR i%% = 0 TO 1
    LINE (88, 16 + i%% * 24)-STEP(144, 0), Cyan 'horizontal lines
    LINE (88, 160 + i%% * 24)-STEP(144, 0), Cyan 'horizontal lines
    LINE (16 + i%% * 36, 64)-STEP(0, 72), Cyan 'vertical lines
    LINE (268 + i%% * 36, 64)-STEP(0, 72), Cyan 'vertical lines
   NEXT i%%
  CASE 7 ' "Á" shaped level
   FOR i%% = 0 TO 4
    LINE (16, 88 + i%% * 24)-STEP(288, 0), Cyan 'horizontal lines
    LINE (88 + i%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
   NEXT i%%
   FOR i%% = 0 TO 1
    LINE (88, 16 + i%% * 24)-STEP(144, 0), Cyan 'horizontal lines
    LINE (16 + i%% * 36, 88)-STEP(0, 96), Cyan 'vertical lines
    LINE (268 + i%% * 36, 88)-STEP(0, 96), Cyan 'vertical lines
   NEXT i%%
   LINE (88, 16 + i%% * 24)-STEP(144, 0), Cyan 'horizontal lines
 END SELECT
END SUB
 
SUB Check_Score
 STATIC Current_life AS _BYTE
 IF G.Score = 0 THEN Current_life = 0 'reset on new game
 IF INT(G.Score \ 5000) = Current_life + 1 THEN 'Bonus Life, only worry about the thousands place to
  '                                                            avoid issues with non-5000 exact multiples
  Current_life = Current_life + 1
  G.Lives = G.Lives + 1
  TIMER(T2) OFF
  _DELAY .05
  PLAY "o6l32GFED#"
  TIMER(T2) ON
 END IF
END SUB
 
SUB Create_Gap
 STATIC X%, Y%, D%
 IF G.Gapped THEN 'when a new gap is made get the pos. this sub is called to erase too
  X% = G.GX + 8 'Xpos of gapper center
  Y% = G.GY + 7 'Ypos of gapper center
  D% = G.GD 'direction of gap(up\down or left\right)
  G.Gap_time = TIMER
 END IF
 SELECT CASE D%
  CASE UP, DOWN
   _DEST Layer(6) 'draw the gap to the detection layer
   IF G.Gapped THEN LINE (X%, Y% - 1)-STEP(0, 2), Black ELSE LINE (X%, Y% - 1)-STEP(0, 2), Cyan 'erase or restore
   _DEST Layer(2) 'also display gap on visual layer (can only gap where you've been so restore to Magenta)
   'layer 2 is 320x220 so we must half the x,y points
   IF G.Gapped THEN LINE (.5 * X%, .5 * Y% - 3)-STEP(0, 5), Black ELSE LINE (.5 * X%, .5 * Y% - 3)-STEP(0, 5), Magenta 'erase or restore
  CASE LEFT, RIGHT
   _DEST Layer(6) 'draw the gap to the detection layer
   IF G.Gapped THEN LINE (X% - 1, Y% - 1)-STEP(2, 1), Black, BF ELSE LINE (X% - 1, Y% - 1)-STEP(2, 1), Cyan, BF 'erase or restore
   _DEST Layer(2) 'also display gap on visual layer (can only gap where you've been so restore to Magenta)
   'layer 2 is 320x220 so we must half the x,y points
   IF G.Gapped THEN LINE (.5 * X% - 3, .5 * Y% - 1)-STEP(5, 1), Black, BF ELSE LINE (.5 * X% - 3, .5 * Y% - 1)-STEP(5, 1), Magenta, BF 'erase or restore
 END SELECT
 ' _DEST Layer(0)
 ' CLS
 ' _PUTIMAGE , Layer(2), Layer(0)
 ' G.GY = G.GY + 16
 ' _PUTIMAGE (G.GX, G.GY), Layer(3), Layer(0), (318, 218)-STEP(15, 13)
 ' END
END SUB
 
SUB Time_Gap
 IF G.Level <= 20 THEN Max_Time! = 500 - (G.Level * 20) ELSE Max_Time! = 100
 Max_Time! = Max_Time! / 100 'convert to seconds (5 sec to 1 sec)
 
 IF G.Gap_time + Max_Time! <= TIMER THEN 'gap time up
  G.Gapped = FALSE
  Create_Gap 'call the SUB again to fill in gap
 END IF
END SUB
 
SUB New_Game
 G.Score = 0
 G.Lives = 2
 FOR i%% = 0 TO 72
  FinishedBox(i%%) = FALSE
 NEXT i%%
 ClearLayerTrans Layer(2)
 Check_Score 'reset extra lives counter
END SUB
 

Pages: [1] 2 3 ... 8

News:

Show Posts

Topics - Cobalt

QB64 Discussion / Why is my END IF tabbed(spaced) wrong?

QB64 Discussion / Possible issue with Select Case

QB64 Discussion / Why is an empty include file "not found"?

QB64 Discussion / Double Check on order of operations

QB64 Discussion / Small hiccup in ABS

Programs / Zelda 64(NES Zelda Clone) Demo

QB64 Discussion / Lacking QB4.5 error catch

QB64 Discussion / IF THEN issue using AND, I think I'm losing my mind!

QB64 Discussion / A question about _INFLATE$\_DEFLATE$ usage

QB64 Discussion / Refresh my memory please, dealing with multiple '='

QB64 Discussion / A question about Recursion and STATIC arrays

QB64 Discussion / Has the issue with GET\PUT using Fixed Strings been addressed lately?

Programs / World Explorer BETA

Programs / Tile Based World Maker! (FIXED update 7)

Programs / Gapper, Give it a try! (updated[11/19/21])