QB64.org Forum

Samples Gallery & Reference => Samples => 2D/3D Graphics => Topic started by: Qwerkey on March 26, 2020, 05:52:12 am

Title: MAPTRIANGLE in 3D by Petr
Post by: Qwerkey on March 26, 2020, 05:52:12 am

MAPTRIANGLE in 3D - ROTATION

Author: @Petr
Source: qb64.org Forum
URL: https://www.qb64.org/forum/index.php?topic=300.msg101478#msg101478 (https://www.qb64.org/forum/index.php?topic=300.msg101478#msg101478)
Version: 3D Rotation
Tags: [3D], [Graphics]

Description:
A demo to show rotation in 3D using MAPTRIANGLE 3D, without direct OpenGL statements.

Librarian's Note:  The sample given here is just one of a number of _MAPTRIANGLE(3D) examples which appear in Petr's post.  That post is a good learning resource for anyone wanting to learn 3D graphics using _MAPTRIANGLE(3D).

Source Code:

Code: QB64: [Select]

1. 'Program details:
2.  
3. 'ad 1:  SUB init - read text "Petr", which is writed to virtual screen and write every pixel position to array T.
4. '       array T contains pixels positions data, recalculated to 3D in the same way as OpenGL (X = minus values to left, plus values to right, zero is middle,
5. '       Y = minus values down, plus values up, zero in middle, Z values - visible from -1 to lower values)
6. '
7. ' I see such a small reproach to myself in the definition of the T array. Next time I would write also new function, that would return a number
8. ' indicating the real number used pixels, because is an unnecessary waste of memory and performance to write  DIM T (16*8) for one character, if this
9. ' character use just 20 pixels.
10.  
11. 'ad 2: (row 73 in source code): Program read array T. If in T is some record ( T().x >0 ) then is called SUB kostka. SUB kostka create cube in
12. '      coordinates X, Y, Z and use OpenGL coordinate system.
13.  
14.  
15.  
16.  
17. _TITLE "Next MAPTRIANGLE 3D demo"
18.  
19. k = _PI(2) / 4 'k is angle 360 / 4 in radians, for 4 cube corners (cube is double quad)
20.  
21. TYPE b
22.     x AS INTEGER
23.     y AS INTEGER
24. END TYPE
25.  
26. '------------
27. DIM SHARED texture AS LONG, rot
28. DIM i AS LONG
29.  
30. TYPE T
31.     x AS SINGLE
32.     y AS SINGLE
33.     z AS SINGLE
34. END TYPE
35.  
36. DIM SHARED T(14 * 110) AS T
37.  
38. init '                          SEE ad 1
39. '---------------------
40.  
41.  
42.  
43. SCREEN _NEWIMAGE(800, 600, 32)
44. CLS , _RGB32(127, 127, 188)
45.  
46.  
47. DIM B(3) AS b
48.  
49.  
50. B(0).x = -1: B(0).y = -1
51. B(1).x = 1: B(1).y = -1
52. B(2).x = -1: B(2).y = -1
53. B(3).x = 1: B(3).y = -1 '            B() are starting coordinates for cube in middle screen
54.  
55. w = _WIDTH(i)
56. h = _HEIGHT(i)
57.  
58. DO
59.     IF i THEN _FREEIMAGE i '         if exists hardware image (which contains clock), then free it from memory
60.     j = _NEWIMAGE(150, 100, 32) '    create software image (handle j)
61.     _DEST j
62.     CLS , _RGBA32(0, 50, 127, 100)
63.     clock 0, 0 '                    draw new clock image, which contains current system time to software image (handle j)
64.     _DEST 0
65.     '                               copy software image j as hardware image i and then delete software image j
66.     i = _COPYIMAGE(j, 33)
67.     _FREEIMAGE j
68.  
69.     clock 0, 0 '                    as you see, here you are in DEST 0. Clocks is now paint to screen to left corner (coordinates 0,0)
70.  
71.     texture& = i '                  set i handle as texture& handle
72.     '--------------------
73.  
74.     FOR Ys = 0 TO 17 '                            SEE ad 2
75.         zz2 = zz2 + .01
76.         FOR Xs = 0 TO 50
77.             IF T(i4).x > 0 THEN
78.                 X = T(i4).x + 70
79.                 Y = T(i4).y
80.                 z = T(i4).z - 70
81.                 kostka X - zz2, Y, z - 15 + zz2
82.             END IF
83.             i4 = i4 + 1
84.     NEXT Xs, Ys
85.     i4 = 0
86.     IF zz2 > 140 THEN zz2 = -50
87.     '-----------------------------
88.  
89.     Sx = 0
90.     Sz = -2.5
91.     Sy = -1
92.  
93.  
94.     Rx = 1
95.     Ry = -1
96.     Rz = 1
97.     ' info for rotation. To rotate the bodies, you must have all the points that are rotating in the same center. For this demo, it is easy to specify the radius of rotation,
98.     ' because all the points are just as far from the center as the cube is a symmetrical body. But if you want to write a 3D game, then if you want to write with MAPTRIANGLE,
99.     ' you need to map the floor using 4 triangles and calculate the radius for the points on the edges using the Pythagoras theorem:
100.     '
101.     '       A--------------------------B     x is your position, as you see, all points use different radius
102.     '       I\\\                   Y / I     Y is your triangle side 1, next is floor height - Y
103.     '       I   \\\\\\             Y/  I     X is your triangle side 2, next is floor width - X
104.     '       I          \\\\\\\\/// xXXXI     third sides calculate using Pythagoras.
105.     '       I       ////////////    \  I
106.     '       I //////                 \ I
107.     '       C--------------------------D
108.     '
109.     x1 = Sx + SIN(rot) * Rx: z1 = Sz + COS(rot) * Rz: y1R = Sy + SIN(rot) * Ry
110.     x2 = Sx + SIN(rot + k) * Rx: z2 = Sz + COS(rot + k) * Rz: y2R = Sy + SIN(rot + k) * Ry
111.  
112.     x4 = Sx + SIN((2 * k) + rot) * Rx: z4 = Sz + COS((2 * k) + rot) * Rz: y3R = Sy + SIN((3 * k) + rot) * Ry
113.     x3 = Sx + SIN((3 * k) + rot) * Rx: z3 = Sz + COS((3 * k) + rot) * Rz: y4R = Sy + SIN((4 * k) + rot) * Ry
114.  
115.     y1 = B(0).y
116.     y2 = B(1).y
117.     y4 = B(2).y
118.     y3 = B(3).y
119.  
120.  
121.  
122.  
123.     y5 = y1 + 1.5
124.     y6 = y2 + 1.5
125.     y7 = y3 + 1.5
126.     y8 = y4 + 1.5
127.  
128.  
129.     _MAPTRIANGLE (0, h)-(w, h)-(0, 0), i TO(x1, y1, z1)-(x2, y2, z2)-(x3, y3, z3) 'podlaha                 floor
130.     _MAPTRIANGLE (w, h)-(0, 0)-(w, 0), i TO(x2, y2, z2)-(x3, y3, z3)-(x4, y4, z4) 'podlaha
131.  
132.  
133.     _MAPTRIANGLE (0, h)-(w, h)-(0, 0), i TO(x1, y5, z1)-(x2, y6, z2)-(x3, y7, z3) 'strop                   roof
134.     _MAPTRIANGLE (w, h)-(0, 0)-(w, 0), i TO(x2, y6, z2)-(x3, y7, z3)-(x4, y8, z4) 'strop
135.  
136.     _MAPTRIANGLE (0, h)-(w, h)-(0, 0), i TO(x1, y1, z1)-(x2, y2, z2)-(x1, y5, z1) 'prava stena             right wall
137.     _MAPTRIANGLE (w, h)-(0, 0)-(w, 0), i TO(x2, y2, z2)-(x1, y5, z1)-(x2, y6, z2) 'prava stena
138.  
139.  
140.     _MAPTRIANGLE (w, h)-(0, h)-(w, 0), i TO(x3, y3, z3)-(x4, y4, z4)-(x3, y7, z3) 'leva stena              left wall
141.     _MAPTRIANGLE (0, h)-(w, 0)-(0, 0), i TO(x4, y4, z4)-(x3, y7, z3)-(x4, y8, z4) 'leva stena
142.  
143.  
144.     _MAPTRIANGLE (w, h)-(0, h)-(w, 0), i TO(x1, y1, z1)-(x3, y3, z3)-(x1, y5, z1) 'zadni stena             back wall
145.     _MAPTRIANGLE (0, h)-(w, 0)-(0, 0), i TO(x3, y3, z3)-(x1, y5, z1)-(x3, y7, z3) 'zadni stena
146.  
147.  
148.     _MAPTRIANGLE (0, h)-(w, h)-(0, 0), i TO(x2, y2, z2)-(x4, y4, z4)-(x2, y6, z2) 'predni stena            front wall
149.     _MAPTRIANGLE (w, h)-(0, 0)-(w, 0), i TO(x4, y4, z4)-(x2, y6, z2)-(x4, y8, z4) 'zadni stena
150.  
151.  
152.     _DISPLAY
153.     _LIMIT 50
154.  
155.     rot = rot + .01
156. LOOP
157.  
158. SUB kostka (x, y, z) 'zadavas levy horni predni roh ,udela kostku v zadane x,y,z                         x y z are coordinates for left upper corner, do cube on this place
159.  
160.  
161.     W = _WIDTH(texture&)
162.     H = _HEIGHT(texture&)
163.  
164.     '                g                       h                                e                  f
165.     MAPQUAD x + -1.5, y + 1.5, z + -1.5, x + .5, y + 1.5, z + -1.5, x + -1.5, y + -.5, z + -1.5, x + .5, y + -.5, z - 1.5, texture&
166.     MAPQUAD x + -1, y + 1, z + -1, x + 1, y + 1, z + -1, x + -1.5, y + 1.5, z + -1.5, x + .5, y + 1.5, z + -1.5, texture&
167.     MAPQUAD x + -1.5, y + -.5, z + -1.5, x + .5, y + -.5, z - 1.5, x + -1, y + -1, z + -1, x + 1, y - 1, z - 1, texture& '
168.     MAPQUAD x + -1, y + 1, z + -1, x + -1.5, y + 1.5, z + -1.5, x + -1, y + -1, z + -1, x + -1.5, y + -.5, z + -1.5, texture&
169.     MAPQUAD x + .5, y + 1.5, z + -1.5, x + .5, y + -.5, z - 1.5, x + 1, y - 1, z - 1, x + 1, y + 1, z + -1, texture&
170.     '                a                     b                    c                       d
171.     MAPQUAD x + -1, y + 1, z + -1, x + 1, y + 1, z + -1, x + -1, y + -1, z + -1, x + 1, y - 1, z - 1, texture&
172.  
173. END SUB
174.  
175.  
176.  
177.  
178. SUB MAPQUAD (x1, y1, z1, x2, y2, z2, x3, y3, z3, x4, y4, z4, texture AS LONG)
179.     W = _WIDTH(texture&)
180.     H = _HEIGHT(texture&)
181.  
182.     _MAPTRIANGLE (0, 0)-(W, 0)-(0, H), texture& TO(x1, y1, z1)-(x2, y2, z2)-(x3, y3, z3)
183.     _MAPTRIANGLE (W, 0)-(0, H)-(W, H), texture& TO(x2, y2, z2)-(x3, y3, z3)-(x4, y4, z4)
184. END SUB
185.  
186. SUB init
187.     text$ = " Petr" 'width = 32 pixels (records)
188.  
189.     virtual& = _NEWIMAGE(100, 100, 256)
190.     _DEST virtual&
191.     PRINT text$
192.     _SOURCE virtual&
193.     i = 0
194.     FOR Y = 17 TO 0 STEP -1
195.         FOR X = 0 TO 50
196.             IF POINT(X, Y) <> 0 THEN
197.                 T(i).x = (-8.5 + X)
198.                 T(i).y = -18 + (16 - Y) * 2
199.                 T(i).z = -5 - X '                      this shift cubes in space consecutively. One pixel = One cube.
200.             END IF
201.             i = i + 1
202.     NEXT X, Y
203.     _DEST 0: _SOURCE 0: _FREEIMAGE virtual&
204.     i = 0
205. END SUB
206.  
207.  
208. SUB clock (x, y) '                                     This sub draw software image contains clock
209.     de = _DEST
210.     clocka& = _NEWIMAGE(100, 100, 32)
211.     _DEST clocka&
212.     vterina = VAL(RIGHT$(TIME$, 2))
213.     hodina = VAL(LEFT$(TIME$, 2))
214.     minuta = VAL(MID$(TIME$, 4, 2))
215.  
216.     IF hodina > 12 THEN hodina = hodina - 12
217.     hodina = hodina + (1 / 59) * minuta
218.  
219.  
220.     vt = vterina + 45
221.     ho = hodina + 45
222.     mi = minuta + 45
223.  
224.     pozicevterina = _PI(2) / 60 * vt
225.     poziceminuta = _PI(2) / 60 * ho * 5
226.     pozicehodina = _PI(2) / 60 * mi
227.  
228.     xs = 50 + COS(pozicevterina) * 30
229.     ys = 50 + SIN(pozicevterina) * 30
230.  
231.     xm = 50 + COS(poziceminuta) * 35
232.     ym = 50 + SIN(poziceminuta) * 35
233.  
234.     xh = 50 + COS(pozicehodina) * 40
235.     yh = 50 + SIN(pozicehodina) * 40
236.  
237.     FOR n = 1 TO 100
238.         LINE (n, 0)-(n, 99), _RGB32(127 - n, n, 27 + n), BF
239.     NEXT n
240.     LINE (0, 0)-(99, 99), _RGB32(255, 255, 255), B
241.  
242.     COLOR _RGBA32(127, 127, 127, 150)
243.     _PRINTMODE _KEEPBACKGROUND
244.     _PRINTSTRING (35, 45), "QB64"
245.     COLOR _RGB32(255, 255, 255)
246.  
247.  
248.     LINE (50, 50)-(xh, yh), _RGB32(255, 255, 0)
249.     LINE (50, 50)-(xm, ym), _RGB32(255, 255, 0)
250.     LINE (50, 50)-(xs, ys), _RGB32(0, 255, 255)
251.     m = 0
252.     FOR kruh = 0 TO _PI(2) STEP _PI(2) / 60
253.         PSET (50 + COS(kruh) * 47, 50 + SIN(kruh) * 47)
254.         IF m MOD 5 = 0 THEN LINE (50 + COS(kruh) * 47, 50 + SIN(kruh) * 47)-(50 + COS(kruh) * 44, 50 + SIN(kruh) * 44), , BF
255.         m = m + 1
256.     NEXT kruh
257.     _DEST de
258.     _SETALPHA 100, , clocka&
259.     _PUTIMAGE (x, y), clocka&, de
260.     _FREEIMAGE clocka&
261. END SUB
262.  

 

 

Text Only | Text with Attachments