Print Page - Is There a Mouse Equivalent of

Title: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: Qwerkey on January 03, 2019, 07:24:09 am

Is There a Mouse Equivalent of _KEYCLEAR, where any stray mouse events are used up? From my reading of the Wiki, there isn't and I could code and have coded a routine to use up any _MOUSEBUTTON events. But an existing command would be easier.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: SMcNeill on January 03, 2019, 07:41:07 am

WHILE _MOUSEINPUT: WEND

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: Qwerkey on January 03, 2019, 07:53:58 am

Steve, I thought that it had to be slightly more complicated:

Code: QB64: [Select]

DO 'make sure that mouse button is released
    Dum` = _MOUSEINPUT
 LOOP UNTIL NOT _MOUSEBUTTON(ButtonNo%%)

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: SMcNeill on January 03, 2019, 08:57:20 am

Quote from: Qwerkey on January 03, 2019, 07:53:58 am

Steve, I thought that it had to be slightly more complicated:

Code: QB64: [Select]
DO 'make sure that mouse button is released
Dum` = _MOUSEINPUT
LOOP UNTIL NOT _MOUSEBUTTON(ButtonNo%%)

What you've got is a No-No code snippet, except under very controlled situations. Here it is, in an actual program:

Code: QB64: [Select]

SCREEN _NEWIMAGE(640, 480, 32)
_SCREENMOVE _MIDDLE
 
LINE (100, 100)-(200, 200), &HFFFF0000, BF
LINE (250, 100)-(350, 200), &HFF00FF00, BF
LINE (400, 100)-(500, 200), &HFF0000FF, BF
 
 
ButtonNo%% = 1 'left mouse
DO
    _LIMIT 60
    DO 'make sure that mouse button is released
        Dum` = _MOUSEINPUT
    LOOP UNTIL NOT _MOUSEBUTTON(ButtonNo%%)
    LOCATE 1, 1
    PRINT _MOUSEX, _MOUSEY
LOOP

Now, scroll your mouse around the screen a few times and watch the X/Y location print for you. STOP moving the mouse, and watch the X/Y location...

It's still updating from the mousebuffer, LOOOOOOOOOOONG after you quit moving the mouse!

Not the effect you're looking for at all, I'd imagine. :)

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: SMcNeill on January 03, 2019, 08:59:47 am

For a simple mouseclick type event, to see if an user has clicked inside a proper boundry for you, try something like this:

Code: QB64: [Select]

SCREEN _NEWIMAGE(640, 480, 32)
_SCREENMOVE _MIDDLE
 
TYPE Point
    x AS INTEGER
    y AS INTEGER
    Color AS _UNSIGNED LONG
    Click AS LONG
END TYPE
 
DIM Box(3) AS Point
FOR i = 100 TO 400 STEP 150
    count = count + 1
    Box(count).x = i
    Box(count).y = 100
NEXT
Box(1).Color = &HFFFF0000
Box(2).Color = &HFF00FF00
Box(3).Color = &HFF0000FF
 
 
 
DO
    _LIMIT 60
    CLS
    WHILE _MOUSEINPUT: WEND
    FOR i = 1 TO 3
        LINE (Box(i).x, Box(i).y)-STEP(100, 100), Box(i).Color, BF
    NEXT
 
    IF OMB = 0 THEN 'The mouse button was up on a previous pass
        IF _MOUSEBUTTON(1) THEN
            FOR i = 1 TO 3
                IF _MOUSEX >= Box(i).x AND _MOUSEX <= Box(i).x + 100 AND _MOUSEY >= Box(i).y AND _MOUSEY <= Box(i).y + 100 THEN 'we clicked a box
                    Box(i).Click = Box(i).Click + 1
                END IF
            NEXT
        END IF
    END IF
    LOCATE 1, 1
    PRINT _MOUSEX, _MOUSEY
    FOR i = 1 TO 3: PRINT "Box"; i; "Clicked:", Box(i).Click: NEXT
    OMB = _MOUSEBUTTON(1) 'Old Mouse Button
    _DISPLAY
LOOP
 

Notice how I update the mouseinput buffer?

Code: QB64: [Select]

    WHILE _MOUSEINPUT: WEND  

It's as simple as it gets. Clear the buffer, deal with what's going on with the mouse as your program makes each current loop. ;)

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: SMcNeill on January 03, 2019, 09:38:45 am

And here's a more elaborate mouse routine:

Code: QB64: [Select]

SCREEN _NEWIMAGE(640, 480, 32)
_SCREENMOVE _MIDDLE
 
TYPE Point
    x AS INTEGER
    y AS INTEGER
    Color AS _UNSIGNED LONG
    Click AS LONG
END TYPE
 
DIM Box(3) AS Point
FOR i = 100 TO 400 STEP 150
    count = count + 1
    Box(count).x = i
    Box(count).y = 100
NEXT
Box(1).Color = &HFFFF0000
Box(2).Color = &HFF00FF00
Box(3).Color = &HFF0000FF
 
 
 
DO
    _LIMIT 60
    CLS
    WHILE _MOUSEINPUT: WEND
    FOR i = 1 TO 3
        LINE (Box(i).x, Box(i).y)-STEP(100, 100), Box(i).Color, BF
    NEXT
 
    IF OMB = 0 THEN 'The mouse button was up on a previous pass
        IF _MOUSEBUTTON(1) THEN
            StartX = _MOUSEX: StartY = _MOUSEY
            t# = TIMER(0.001)
            WHILE _MOUSEBUTTON(1)
                junk = _MOUSEINPUT
                held = TIMER(0.001) - t# 'check to see if the button is held down for .2 seconds or more
                IF held > 0.2 THEN EXIT WHILE 'After .2 seconds, we declare this a "hold event"
            WEND
 
            IF held < 0.2 THEN 'if we're not held down, it's a click
                FOR i = 1 TO 3
                    IF _MOUSEX >= Box(i).x AND _MOUSEX <= Box(i).x + 100 AND _MOUSEY >= Box(i).y AND _MOUSEY <= Box(i).y + 100 THEN 'we clicked a box
                        Box(i).Click = Box(i).Click + 1
                    END IF
                NEXT
            ELSE ' If we're held down, let's store the original coordinates of the box we're held over (if any)
                BO = 0
                FOR i = 1 TO 3
                    IF StartX >= Box(i).x AND StartX <= Box(i).x + 100 AND StartY >= Box(i).y AND StartY <= Box(i).y + 100 THEN
                        BOX = Box(i).x: BOY = Box(i).y 'Box Original X and Box Original Y
                        BO = i 'Box the mouse is Over
                    END IF
                NEXT
            END IF
        END IF
    ELSE 'If the button was down on a previous pass, we'll deal with a "hold button" event, if we have one.
        IF held THEN
            IF StartX >= BOX AND StartX <= BOX + 100 AND StartY >= BOY AND StartY <= BOY + 100 THEN 'we held the mouse down over a box
                Xshift = StartX - _MOUSEX
                Yshift = StartY - _MOUSEY
                Box(BO).x = BOX - Xshift
                Box(BO).y = BOY - Yshift
            END IF
        END IF
    END IF
    LOCATE 1, 1
    PRINT _MOUSEX, _MOUSEY
    FOR i = 1 TO 3: PRINT "Box"; i; "Clicked:", Box(i).Click: NEXT
    OMB = _MOUSEBUTTON(1) 'Old Mouse Button
    IF _MOUSEBUTTON(1) = 0 THEN held = 0
    _DISPLAY
LOOP
 

For this sample, click on the boxes just as you did before, and you can see how we interact with a "click event".

Then click on a box and hold the mouse down and move it across the screen. You can see how we'd deal with a "mouse down/ drag event".

In either case, our main routine for mouse handling is:

Code: QB64: [Select]

WHILE _MOUSEINPUT: WEND 

If you notice, I *do* have a routine in this code which looks rather similar to the one you posted:

Code: QB64: [Select]

                WHILE _MOUSEBUTTON(1)
                    junk = _MOUSEINPUT
                    held = TIMER(0.001) - t# 'check to see if the button is held down for .2 seconds or more
                    IF held > 0.2 THEN EXIT WHILE
                WEND

The difference here?

The main process handles all the real mouse input work, and I only trap the input for 2/10ths of a second, so I can to see if I'm dealing with a "click event", or starting a "hold button" event. The "WHILE _MOUSEINPUT: WEND" keeps the mousebuffer clear for us, and stops the input backlog from building up like we saw in the very first little demo I showcased above.

"WHILE _MOUSEINPUT: WEND" is normally your main mouse loop, and the only thing you normally see inside it might be a counter if you're tracking the mouse scroll status. ;)

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: FellippeHeitor on January 03, 2019, 09:49:25 am

Instead of timers, I'd recommend using flags for mouse down, as in the code I posted at https://www.qb64.org/forum/index.php?topic=912.0 (and everything mouse related I post).

Look in SUB checkMouseAction.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: FellippeHeitor on January 03, 2019, 09:53:22 am

In summary:

'poll mouse buffer
WHILE _MOUSEINPUT: WEND

SUB checkMouseAction STATIC
IF _MOUSEBUTTON(1) THEN
IF mouseDown = 0 THEN
'first pressed
mouseDown = -1
ELSE
'dragging
END IF
ELSE
IF mouseDown THEN
mouseDown = 0
'release/click (if st same coordinates of initial mousedown above)
END IF
END IF
END SUB

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: SMcNeill on January 03, 2019, 09:57:32 am

Quote from: FellippeHeitor on January 03, 2019, 09:49:25 am

Instead of timers, I'd recommend using flags for mouse down, as in the code I posted at https://www.qb64.org/forum/index.php?topic=912.0 (and everything mouse related I post).

Look in SUB checkMouseAction.

That’s what OMB does for us. The 0.2 second timer is basically an “escape timer”, so a user won’t hold the button forever and pause program execution, like I’ve seen in some mouse routines. ;)

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: FellippeHeitor on January 03, 2019, 09:59:03 am

The above leaves little to no room for hanging, check it out.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: SMcNeill on January 03, 2019, 10:39:22 am

Quote from: FellippeHeitor on January 03, 2019, 09:59:03 am

The above leaves little to no room for hanging, check it out.

It also leaves no time for someone to do a mouse click with a sticky mouse button. As long as it polls down then up, it’s a “mouse click”. If your button sticks for a few milliseconds, it’s called a “drag event”.

And, correct me if I’m wrong, but doesn’t it also generate a “click event” when the “drag event” ends? Or is that accounted for in the commented out ‘dragging section?

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: FellippeHeitor on January 03, 2019, 10:48:55 am

It does, just like all modern systems. It's up to the programmer to ignore a drag if a drag is not interesting in context.

Like a double click always implies a single click.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: Qwerkey on January 04, 2019, 07:40:53 am

O Magnificent Gurus of the Great Spiritual Mouse, what then is the correct method for using up stray mouse clicks? Pray, graciously enlighten your lowly, humble and ignorant follower.

From Steve (edited):

Quote from: SMcNeill on January 03, 2019, 08:59:47 am

For a simple mouseclick type event, to see if an user has clicked inside a proper boundry for you, try something like this:

Code: QB64: [Select]
DO
_LIMIT 60
CLS
WHILE _MOUSEINPUT: WEND

IF _MOUSEBUTTON(1) THEN
FOR i = 1 TO 3
IF _MOUSEX >= Box(i).x AND _MOUSEX <= Box(i).x + 100 AND _MOUSEY >= Box(i).y AND _MOUSEY <= Box(i).y + 100 THEN 'we clicked a box
Box(i).Click = Box(i).Click + 1
END IF
NEXT
END IF
_DISPLAY
LOOP

Steve's mouse polling is inside a limited WHILE/WEND.

My code would look like:

Code: QB64: [Select]

WHILE SomeCondition`
    _LIMIT 60
    'Do Something
    WHILE _MOUSEINPUT
        IF _MOUSEBUTTON(1) THEN
            'Set some flag
        END IF
    WEND
    '_DISPLAY if display update required
WEND

The program actioning is inside a WHILE/WEND with a _LIMIT, but inside that the Mouse polling is inside an unlimited WHILE/WEND, and therfore there is no delay. My Use-Up-Mouse Routine would be before the next required mouse polling.

When I first coded a use up mouse click routine, I did the simple WHILE _MOUSEINPUT: WEND, and I thought that it didn't seem to work properly, hence my version. Maybe I just didn't look correctly. If WHILE _MOUSEINPUT:WEND is guaranteed to use up mouse clicks (it ought, I suppose), I'll use that in future.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: Qwerkey on January 04, 2019, 08:12:16 am

Ah! My Use-Up-Mouse Routine mouse polling (_MOUSEINPUT) is NOT inside an umilited WHILE:WEND (whereas all my other mouse polling is). I see Steve's concerns now. Will change to WHILE _MOUSEINPUT: WEND

What a goon!

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: SMcNeill on January 04, 2019, 10:01:27 am

Quote from: Qwerkey on January 04, 2019, 07:40:53 am

O Magnificent Gurus of the Great Spiritual Mouse, what then is the correct method for using up stray mouse clicks? Pray, graciously enlighten your lowly, humble and ignorant follower.

From Steve (edited):
Quote from: SMcNeill on January 03, 2019, 08:59:47 am
For a simple mouseclick type event, to see if an user has clicked inside a proper boundry for you, try something like this:

Code: QB64: [Select]
DO
_LIMIT 60
CLS
WHILE _MOUSEINPUT: WEND

IF _MOUSEBUTTON(1) THEN
FOR i = 1 TO 3
IF _MOUSEX >= Box(i).x AND _MOUSEX <= Box(i).x + 100 AND _MOUSEY >= Box(i).y AND _MOUSEY <= Box(i).y + 100 THEN 'we clicked a box
Box(i).Click = Box(i).Click + 1
END IF
NEXT
END IF
_DISPLAY
LOOP

Steve's mouse polling is inside a limited WHILE/WEND.

My code would look like:

Code: QB64: [Select]
WHILE SomeCondition`
_LIMIT 60
'Do Something
WHILE _MOUSEINPUT
IF _MOUSEBUTTON(1) THEN
'Set some flag
END IF
WEND
'_DISPLAY if display update required
WEND

The program actioning is inside a WHILE/WEND with a _LIMIT, but inside that the Mouse polling is inside an unlimited WHILE/WEND, and therfore there is no delay. My Use-Up-Mouse Routine would be before the next required mouse polling.

When I first coded a use up mouse click routine, I did the simple WHILE _MOUSEINPUT: WEND, and I thought that it didn't seem to work properly, hence my version. Maybe I just didn't look correctly. If WHILE _MOUSEINPUT:WEND is guaranteed to use up mouse clicks (it ought, I suppose), I'll use that in future.

If you look, my mouse polling is in an unlimited WHILE: WEND, inside the DO:LOOP...

DO
LIMIT
WHILE _MOUSEINPUT: WEND
IF _MOUSEBUTTON .....

Compared to your:

WHILE
LIMIT
WHILE _MOUSEINPUT
IF _MOUSEBUTTON.....
WEND

The mouse polls an unbelievable number of times each second. Adding IF conditions and other code inside the update/polling routine is almost guaranteed to create a backlog of information to be processed, resulting in your program always racing to try and catch up to past events and getting stuck inside that loop much longer than you’d intend/want.

The best practice is: WHILE _MOUSEINPUT: WEND. It truly is the equivalent to _KEYCLEAR, for the mouse.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: luke on January 04, 2019, 10:24:41 am

Any code with a wild WHILE _MOUSEINPUT: WEND will miss clicks. It works as a _KEYCLEAR for the mouse, certainly, but you don't want to have it in a handling loop.

And since we're sharing mouse handling code, here's mine:

Code: QB64: [Select]

DO
  IF _MOUSEINPUT THEN
    IF _MOUSEBUTTON(1) = mouse_down THEN 'Is the button still in the same position?
      DO WHILE _MOUSEINPUT
        IF _MOUSEBUTTON(1) <> mouse_down THEN EXIT DO 'Process through the queue until the button changes state
      LOOP
    END IF
    mouse_down = _MOUSEBUTTON(1)
    'Do mouse click processing here
  END IF
  'Do other stuff
  _LIMIT 30 
LOOP

Admittedly this doesn't bother trying to detect drag events, just clicks. Also, don't ask me to explain exactly how it works; it was written a long time ago.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: Qwerkey on January 05, 2019, 05:46:19 am

From Steve:

Quote from: SMcNeill on January 04, 2019, 10:01:27 am

The best practice is: WHILE _MOUSEINPUT: WEND. It truly is the equivalent to _KEYCLEAR, for the mouse.

From Luke:

Quote from: luke on January 04, 2019, 10:24:41 am

Any code with a wild WHILE _MOUSEINPUT: WEND will miss clicks. It works as a _KEYCLEAR for the mouse, certainly, but you don't want to have it in a handling loop.

Two of our Great Masters at complete loggerheads (and Fellippe's contributions were rather over my head).

I changed my project code back to Steve's simple loop and then the program set off unwanted mouse click events again, so I agree with Luke: WHILE _MOUSEINPUT: WEND will miss clicks which seems to be the case. I have put back my original code and this prevents false mouse click events in my project. I may also add Luke's code as a double-check. I will shortly submit my project code and perhaps Steve would care to spend more of his valuable time to check it through.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: SMcNeill on January 05, 2019, 07:10:07 am

Quote from: Qwerkey on January 05, 2019, 05:46:19 am

From Steve:
Quote from: SMcNeill on January 04, 2019, 10:01:27 am
The best practice is: WHILE _MOUSEINPUT: WEND. It truly is the equivalent to _KEYCLEAR, for the mouse.

From Luke:
Quote from: luke on January 04, 2019, 10:24:41 am
Any code with a wild WHILE _MOUSEINPUT: WEND will miss clicks. It works as a _KEYCLEAR for the mouse, certainly, but you don't want to have it in a handling loop.

Two of our Great Masters at complete loggerheads (and Fellippe's contributions were rather over my head).

Not in disagreement. Luke was saying that stray WHILE _MOUSEINPUT: WEND routines will cause you to miss events, and he’s right. You only need the main mousepolling event ONCE, in your main loop. As I said, think of it as a _KEYCLEAR for your mouse:

DO
_DELAY 1
k = _KEYHIT ‘get single byte from the keyboard buffer
_KEYCLEAR ‘this keyclear will eliminate all the extra buffer events
PRINT k
LOOP

With the above, you might bang out “ASDFG” on the keyboard and only print out “A” to the screen. You put extra events into the buffer, but then used _KEYCLEAR to erase them before handling them once each second.

A stray/unneeded _KEYCLEAR causes keyboard input to be missed. Unnecessary uses of WHILE _MOUSEINPUT: WEND do the same for the mouse.

I’d guess if you’re you’re getting unwanted events, it’s from simply detecting “mouse down” events instead of “mouse click” events.

A mouse down checker is as simple as:
IF _MOUSEBUTTON(1) THEN....

A mouse click checker needs to be something a little more, like:
CONST Up = 0, Down = -1
IF OldState = Up THEN ‘if the mouse was up last pass
IF _MOUSEBUTTON(1) = Down THEN ‘and it’s down now — We went from up to down
... do click stuff
END IF
END IF
OldState = _MOUSEBUTTON(1) ‘store the state of this pass to compare next pass

******

You don’t want to just check to see that the mouse was down for your needs. After all, holding it down for 10 seconds shouldn’t generate 1000 mouse clicks... You want it to at least be counted as an, “It WAS up, but now it’s down” type event.

(And If you’re adding “hold events”, you basically need to check, “It WAS up, then down, then released back up” for a click; “Up, down, staying down” for a hold event.)

Feel free to share your actual code, and I’ll be more than happy to look over it. ;)

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: luke on January 05, 2019, 08:01:43 am

^ what Steve said.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: Qwerkey on January 05, 2019, 08:16:16 am

Thanks guys, you may find it perplexing that there are some of the very simplest things that I struggle to understand - dimwitted Qwerkey.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: Qwerkey on January 05, 2019, 08:54:57 am

Fellippe, we could do with a _MOUSECLEAR function, so that the dimwitted amongst us don't have to struggle (or even think!).

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: FellippeHeitor on January 05, 2019, 09:25:55 am

Let's see what my peers have to say on that. My view is that it's unrequired, but I'm only one.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: SMcNeill on January 05, 2019, 09:40:07 am

Quote from: FellippeHeitor on January 05, 2019, 09:25:55 am

Let's see what my peers have to say on that. My view is that it's unrequired, but I'm only one.

I think it’d be asking for trouble.

We don’t really do a _MOUSECLEAR with a WHILE _MOUSEINPUT: WEND, as much as we do a _MOUSEUPDATE to update mouse x/y/button positions. At *no* point do we ever actually return NULL (clear) values for the mouse.

_KEYCLEAR gives us a keyboard buffer of “”...

What exactly would a _MOUSECLEAR give us? MouseX/Y of 0? Mouse button of 0?

Would _MOUSEINPUT even function properly after a _MOUSECLEAR, or would you lose too many events? And would we be able to track wheel events?

Personally, I think it’d complicate things a lot more than it’d simplify them, in the long run.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: Qwerkey on January 05, 2019, 11:13:58 am

Here is the code of my project where I found it necessary to have a "Use Up Mouse Clicks" routine.

Code: QB64: [Select]

' Pelmanism (Pairs) Game version 2 by QWERKEY 2019-01-05
' Images from openclipart.org,clipartpng.com & pngimg.com
' Sounds from findsounds.com
 
CONST True = -1`, False = 0`
CONST NoObjectsLess1%% = 67
DIM SHARED ButtonNo%%
DIM BestScore%(2), GameLevel%%(2, 1), NosImg&(9, 1), Images&(NoObjectsLess1%%)
$EXEICON:'.\Balloons.ico'
_TITLE "Pelmanism Game"
RANDOMIZE (TIMER)
 
DATA 4,4
DATA 6,6
DATA 10,6
FOR N%% = 0 TO 2
    FOR M%% = 0 TO 1
        READ GameLevel%%(N%%, M%%)
    NEXT M%%
NEXT N%%
'Create Images
DATA Bananas,Cherry,Carrots,Pepper,Tomato,Cat,Egg,Beer,Acorn,Feather,Squirrel,IcedBun,LightBulb,GoldCup
DATA Parrot,LadyMouse,Mushrooms,Pineapple,Balloons,Rose,CloverLeaf,Goose,Raccoon,Raspberry,Violin,TeddyBear
DATA Clock,Shoes,Wrench,Hammer,Computer,Matches,Diamond,WineGlass,Frog,Chimp,Apricot,RollsRoyce,Knight,Bee
DATA Fish,IceCream,SnowFlake,XmasTree,Butterfly,Rainbow,Penguin,Fox,Hummingbird,Cashews,Tulips,Matryoshka
DATA Lion,Apple,Hat,Heart,Key1,Ladybird,Strawberry,TV,Dog,Dolphin,Koala,Earth,Olives,Einstein,Plane,Flag
FOR N%% = 0 TO NoObjectsLess1%%
    READ Dum$
    Images&(N%%) = _LOADIMAGE(Dum$ + ".png", 33)
NEXT N%%
IF RND > 0.5 THEN
    ObverseImg& = _LOADIMAGE("Back1.png", 33)
ELSE
    ObverseImg& = _LOADIMAGE("Back2.png", 33)
END IF
FOR N%% = 0 TO 9
    TempImg& = _NEWIMAGE(40, 40, 32)
    _DEST TempImg&
    UsedFont& = _LOADFONT("calibriz.ttf", 40)
    _FONT UsedFont&
    COLOR _RGB32(255, 0, 0), _RGB32(0, 0, 0)
    _PRINTSTRING (5, 5), LTRIM$(STR$(N%%))
    _FONT 16
    _FREEFONT UsedFont&
    NosImg&(N%%, 1) = MakeHardware&(TempImg&)
NEXT N%%
FOR N%% = 0 TO 9
    TempImg& = _NEWIMAGE(40, 40, 32)
    _DEST TempImg&
    UsedFont& = _LOADFONT("calibriz.ttf", 40)
    _FONT UsedFont&
    COLOR _RGB32(0, 255, 0), _RGB32(0, 0, 0)
    _PRINTSTRING (5, 5), LTRIM$(STR$(N%%))
    _FONT 16
    _FREEFONT UsedFont&
    NosImg&(N%%, 0) = MakeHardware&(TempImg&)
NEXT N%%
TempImg& = _NEWIMAGE(110, 74, 32)
_DEST TempImg&
UsedFont& = _LOADFONT("calibriz.ttf", 40)
_FONT UsedFont&
COLOR _RGB32(255, 0, 0), _RGB32(0, 0, 0)
_PRINTSTRING (5, 5), "Best"
_PRINTSTRING (5, 45), "Score:"
_FONT 16
_FREEFONT UsedFont&
BestImg& = MakeHardware&(TempImg&)
'Load/Set Initial Data
IF _FILEEXISTS("pelman.dat") THEN
    OPEN "pelman.dat" FOR INPUT AS #1
    INPUT #1, ButtonNo%%
    FOR N%% = 0 TO 2
        INPUT #1, BestScore%(N%%)
    NEXT N%%
    CLOSE #1
ELSE
    SCREEN _NEWIMAGE(500, 500, 32)
    _SCREENMOVE 100, 100
    _DEST 0
    CLS
    _DISPLAYORDER _SOFTWARE , _HARDWARE
    Mousey& = _LOADIMAGE("Mouse.png", 33)
    LOCATE 2, 7
    PRINT "Click on the mouse below with your normal button";
    LOCATE 3, 5
    PRINT "Click (not double-click) to make this screen disappear";
    CorrectButton` = False: ButtonNo%% = 1
    WHILE NOT CorrectButton`
        _LIMIT 60
        _PUTIMAGE (50, 100), Mousey&
        'Assumes hardware has mouse buttons, value <=5
        WHILE _MOUSEINPUT
            IF _MOUSEBUTTON(1) THEN
                CorrectButton` = True
                ButtonNo%% = 1
            ELSEIF _MOUSEBUTTON(2) THEN
                CorrectButton` = True
                ButtonNo%% = 2
            ELSEIF _MOUSEBUTTON(3) THEN
                CorrectButton` = True
                ButtonNo%% = 3
            ELSEIF _MOUSEBUTTON(4) THEN
                CorrectButton` = True
                ButtonNo%% = 4
            ELSEIF _MOUSEBUTTON(5) THEN
                CorrectButton` = True
                ButtonNo%% = 5
            END IF
        WEND
        _DISPLAY
    WEND
    _FREEIMAGE Mousey&
END IF
CALL UseUpMouse
'Perform Game
Pelmanism` = True
WHILE Pelmanism`
    'Set Game Level
    TempImg& = _NEWIMAGE(70, 90, 32)
    _DEST TempImg&
    COLOR _RGB32(100, 255, 100), _RGBA32(100, 100, 100, 0)
    CLS
    LINE (0, 0)-(69, 89), , B
    Highlight& = MakeHardware&(TempImg&)
    Img123& = _LOADIMAGE("Pelman123.png", 33)
    ImgSkills& = _LOADIMAGE("SkillLevel.png", 33)
    SCREEN _NEWIMAGE(500, 500, 32)
    _SCREENMOVE 100, 100
    _DEST 0
    _DISPLAYORDER _HARDWARE
    CLS
    Skilled` = False
    ValidMouse` = False
    DoGrid` = True
    DoMore` = True
    WHILE NOT Skilled`
        _LIMIT 30
        _PUTIMAGE (70, 50), ImgSkills&
        _PUTIMAGE (30, 300), Img123&
        WHILE _MOUSEINPUT
            XMouse% = _MOUSEX: YMouse% = _MOUSEY
            ValidMouse` = False
            IF YMouse% > 345 AND YMouse% < 405 THEN
                IF XMouse% > 343 AND XMouse% < 385 THEN
                    Level%% = 2
                    ValidMouse` = True
                ELSEIF XMouse% > 223 AND XMouse% < 265 THEN
                    Level%% = 1
                    ValidMouse` = True
                ELSEIF XMouse% > 103 AND XMouse% < 145 THEN
                    Level%% = 0
                    ValidMouse` = True
                END IF
            END IF
            IF _MOUSEBUTTON(ButtonNo%%) AND ValidMouse` THEN Skilled` = True
        WEND
        IF ValidMouse` THEN
            SELECT CASE Level%%
                CASE 2
                    _PUTIMAGE (333, 330), Highlight&
                CASE 1
                    _PUTIMAGE (213, 330), Highlight&
                CASE ELSE
                    _PUTIMAGE (93, 330), Highlight&
            END SELECT
        END IF
        _DISPLAY
        K$ = INKEY$
        IF K$ <> "" THEN
            IF VAL(K$) = 1 THEN
                Skilled` = True
                Level%% = 0
            ELSEIF VAL(K$) = 2 THEN
                Skilled` = True
                Level%% = 1
            ELSEIF VAL(K$) = 3 THEN
                Skilled` = True
                Level%% = 2
            ELSEIF ASC(K$) = 27 THEN 'Esc - Quit Program
                Skilled` = True
                Pelmanism` = False
                DoGrid` = False
                DoMore` = False
            END IF
        END IF
        K$ = ""
    WEND
    _FREEIMAGE Highlight&
    _FREEIMAGE Img123&
    _FREEIMAGE ImgSkills&
    CALL UseUpMouse
    'Do Puzzle
    IF DoGrid` THEN
        XLimit% = 57 + (GameLevel%%(Level%%, 0) - 1) * 107 + 45
        YLimit% = 57 + (GameLevel%%(Level%%, 1) - 1) * 107 + 45
        IsComplete` = False
        Score% = 0
        NoRemaining%% = GameLevel%%(Level%%, 0) * GameLevel%%(Level%%, 1)
        NoPairs%% = 0
        FirstV%% = 50
        ValidMouse` = False
        Flipping` = False
        TurningBack` = False
        FlipCount%% = 0
        Paused` = False
        PCount%% = 0
        FirstGo` = True
        REDIM Motion`(10, 6, 2), Selected%%(30), Choisi`(10, 6), Grid%%(10, 6)
        RANDOMIZE (TIMER)
        WHILE NoRemaining%% > 0
            Vacant` = False
            WHILE NOT Vacant`
                HorizPos%% = 1 + INT(GameLevel%%(Level%%, 0) * RND)
                VertPos%% = 1 + INT(GameLevel%%(Level%%, 1) * RND)
                IF Grid%%(HorizPos%%, VertPos%%) = 0 THEN Vacant` = True
            WEND
            NewPair` = False
            WHILE NOT NewPair`
                PairNo%% = 1 + INT(NoObjectsLess1%% * RND)
                PairsExists` = False
                N%% = 1
                WHILE NOT PairsExists` AND N%% <= NoPairs%%
                    IF PairNo%% = Selected%%(N%%) THEN PairsExists` = True
                    N%% = N%% + 1
                WEND
                IF NOT PairsExists` THEN NewPair` = True
            WEND
            NoPairs%% = NoPairs%% + 1
            Selected%%(NoPairs%%) = PairNo%%
            Grid%%(HorizPos%%, VertPos%%) = PairNo%%
            Vacant` = False
            WHILE NOT Vacant`
                HorizPos%% = 1 + INT(GameLevel%%(Level%%, 0) * RND): VertPos%% = 1 + INT(GameLevel%%(Level%%, 1) * RND)
                IF Grid%%(HorizPos%%, VertPos%%) = 0 THEN Vacant` = True
            WEND
            Selected%%(NoPairs%%) = PairNo%%
            Grid%%(HorizPos%%, VertPos%%) = PairNo%%
            NoRemaining%% = NoRemaining%% - 2
        WEND
        NoRemaining%% = GameLevel%%(Level%%, 0) * GameLevel%%(Level%%, 1)
        TempImg& = _NEWIMAGE(205 + XLimit%, YLimit% + 12, 32)
        _DEST TempImg&
        COLOR _RGB32(255, 255, 255), _RGBA32(100, 100, 100, 0)
        CLS
        FOR N%% = 0 TO GameLevel%%(Level%%, 0) - 1
            FOR M%% = 0 TO GameLevel%%(Level%%, 1) - 1
                LINE (3 + N%% * 107, 3 + M%% * 107)-(3 + (N%% + 1) * 107, 3 + (M%% + 1) * 107), , B
            NEXT M%%
        NEXT N%%
        UsedFont& = _LOADFONT("calibriz.ttf", 60)
        _FONT UsedFont&
        COLOR _RGB32(0, 0, 255)
        _PRINTSTRING (XLimit% + 35, 355), "QUIT"
        _FONT 16
        _FREEFONT UsedFont&
        UsedFont& = _LOADFONT("calibriz.ttf", 40)
        _FONT UsedFont&
        COLOR _RGB32(0, 255, 0)
        _PRINTSTRING (XLimit% + 35, 190), "Score:"
        _FONT 16
        _FREEFONT UsedFont&
        Background& = MakeHardware&(TempImg&)
        TempImg& = _NEWIMAGE(104, 104, 32)
        _DEST TempImg&
        COLOR _RGB32(0, 176, 0), _RGBA32(100, 100, 100, 0)
        CLS
        LINE (0, 0)-(103, 103), , B
        LINE (1, 1)-(102, 102), , B
        Highlight& = MakeHardware&(TempImg&)
        TempImg& = _NEWIMAGE(144, 52, 32)
        _DEST TempImg&
        COLOR _RGB32(0, 176, 0), _RGBA32(100, 100, 100, 0)
        CLS
        LINE (0, 0)-(143, 51), , B
        Quitlight& = MakeHardware&(TempImg&)
        SCREEN _NEWIMAGE(205 + XLimit%, YLimit% + 12, 32)
        _SCREENMOVE 20, 20
        _DEST 0
        _DISPLAYORDER _HARDWARE
        WHILE DoGrid`
            IF TurningBack` THEN
                _LIMIT 65
            ELSE
                _LIMIT 40
            END IF
            _PUTIMAGE (0, 0), Background&
            IF BestScore%(Level%%) <> 0 THEN
                _PUTIMAGE (XLimit% + 30, 20), BestImg&
                IF BestScore%(Level%%) <= 9 THEN
                    _PUTIMAGE (XLimit% + 140, 60), NosImg&(BestScore%(Level%%), 1)
                ELSE
                    _PUTIMAGE (XLimit% + 140, 60), NosImg&(BestScore%(Level%%) \ 10, 1)
                    _PUTIMAGE (XLimit% + 160, 60), NosImg&(BestScore%(Level%%) MOD 10, 1)
                END IF
            END IF
            IF Score% <= 9 THEN
                _PUTIMAGE (XLimit% + 140, 185), NosImg&(Score%, 0)
            ELSE
                _PUTIMAGE (XLimit% + 140, 185), NosImg&(Score% \ 10, 0)
                _PUTIMAGE (XLimit% + 160, 185), NosImg&(Score% MOD 10, 0)
            END IF
            MouseClick` = False
            WHILE _MOUSEINPUT
                ValidMouse` = False
                QuitMouse` = False
                XMouse% = _MOUSEX: YMouse% = _MOUSEY
                IF XMouse% > 7 AND XMouse% < (GameLevel%%(Level%%, 0)) * 107 AND YMouse% > 7 AND YMouse% < (GameLevel%%(Level%%, 1)) * 107 THEN
                    ValidMouse` = True
                    XX%% = (XMouse% - 7) \ 107
                    YY%% = (YMouse% - 7) \ 107
                    XHighLight% = 5 + 107 * XX%%
                    YHighLight% = 5 + 107 * YY%%
                ELSEIF XMouse% > XLimit% + 35 AND XMouse% < XLimit% + 169 AND YMouse% > 355 AND YMouse% < 397 THEN
                    QuitMouse` = True
                    XHighLight% = XLimit% + 30
                    YHighLight% = 350
                END IF
                IF _MOUSEBUTTON(ButtonNo%%) THEN
                    IF XMouse% > XLimit% + 35 AND XMouse% < XLimit% + 169 AND YMouse% > 355 AND YMouse% < 397 THEN DoGrid` = False
                    IF ValidMouse` THEN MouseClick` = True
                END IF
            WEND
            IF DoGrid` THEN
                IF ValidMouse` THEN
                    _PUTIMAGE (XHighLight%, YHighLight%), Highlight&
                ELSEIF QuitMouse` THEN
                    _PUTIMAGE (XHighLight%, YHighLight%), Quitlight&
                END IF
                FOR HorizPos%% = 1 TO GameLevel%%(Level%%, 0)
                    FOR VertPos%% = 1 TO GameLevel%%(Level%%, 1)
                        IF Motion`(HorizPos%%, VertPos%%, 2) THEN
                            'Turn back
                            IF Paused` THEN
                                _PUTIMAGE (107 * (HorizPos%% - 1) + 7, 107 * (VertPos%% - 1) + 7), Images&(Grid%%(HorizPos%%, VertPos%%)) 'Fronts
                                PCount%% = PCount%% + 1
                                IF PCount%% = 40 THEN
                                    Paused` = False
                                    PCount%% = 0
                                END IF
                            ELSE
                                IF FlipCount%% = 0 THEN
                                    XPos% = 107 * (HorizPos%% - 1) + 7
                                    YPos% = 107 * (VertPos%% - 1) + 7
                                END IF
                                IF FlipCount%% < 50 THEN
                                    _PUTIMAGE (FlipCount%% + XPos%, YPos%)-(XPos% + 100 - FlipCount%%, YPos% + 100), Images&(Grid%%(HorizPos%%, VertPos%%))
                                ELSE
                                    _PUTIMAGE (XPos% + FlipCount%%, YPos%)-(XPos% + 100 - FlipCount%%, YPos% + 100), ObverseImg&
                                END IF
                                FlipCount%% = FlipCount%% + 1
                                IF FlipCount%% = 100 THEN
                                    FlipCount%% = 0
                                    IF HorizPos%% = FirstH%% AND VertPos%% = FirstV%% THEN
                                        Motion`(HorizPos%%, VertPos%%, 2) = False
                                        Motion`(HorizPos%%, VertPos%%, 0) = False
                                        Flipping` = False
                                        TurningBack` = False
                                        FirstV%% = 50
                                        CALL UseUpMouse
                                    ELSE
                                        Motion`(HorizPos%%, VertPos%%, 2) = False
                                        Motion`(HorizPos%%, VertPos%%, 0) = False
                                        Motion`(FirstH%%, FirstV%%, 2) = True
                                    END IF
                                END IF
                            END IF
                        ELSEIF Motion`(HorizPos%%, VertPos%%, 1) THEN
                            'Turn forward
                            IF FlipCount%% = 0 THEN
                                XPos% = 107 * (HorizPos%% - 1) + 7
                                YPos% = 107 * (VertPos%% - 1) + 7
                            END IF
                            IF FlipCount%% < 50 THEN
                                _PUTIMAGE (XPos% + 100 - FlipCount%%, YPos%)-(XPos% + FlipCount%%, YPos% + 100), ObverseImg&
                            ELSE
                                _PUTIMAGE (100 - FlipCount%% + XPos%, YPos%)-(XPos% + FlipCount%%, YPos% + 100), Images&(Grid%%(HorizPos%%, VertPos%%))
                            END IF
                            FlipCount%% = FlipCount%% + 1
                            IF FlipCount%% = 100 THEN
                                FlipCount%% = 0
                                Flipping` = False
                                Motion`(HorizPos%%, VertPos%%, 1) = False
                                Motion`(HorizPos%%, VertPos%%, 0) = True
                                IF FirstGo` THEN
                                    FirstGo` = False
                                ELSE
                                    FirstGo` = True
                                    IF Grid%%(HorizPos%%, VertPos%%) = Grid%%(FirstH%%, FirstV%%) THEN 'Matched pair
                                        Choisi`(HorizPos%%, VertPos%%) = True 'Registers that that grid position cannot be clicked any more
                                        Choisi`(FirstH%%, FirstV%%) = True
                                        NoRemaining%% = NoRemaining%% - 2
                                        IF NoRemaining%% = 0 THEN
                                            'Tah-dah sound (completed)
                                            _SNDPLAYFILE ("fanfare.mp3")
                                        ELSE
                                            'Ching sound (match)
                                            _SNDPLAYFILE ("match3.mp3")
                                        END IF
                                    ELSE
                                        'Initiate sequential turn back
                                        Motion`(HorizPos%%, VertPos%%, 2) = True
                                        Flipping` = True
                                        TurningBack` = True
                                        Paused` = True
                                        PCount%% = 0
                                        _SNDPLAYFILE ("nomatch1.mp3"), , 0.2
                                    END IF
                                    IF Score% < 99 THEN Score% = Score% + 1
                                    IF NoRemaining%% = 0 THEN
                                        'Pairings Completed
                                        IF Score% < BestScore%(Level%%) OR BestScore%(Level%%) = 0 THEN BestScore%(Level%%) = Score%
                                    END IF
                                END IF
                                CALL UseUpMouse
                            END IF
                        ELSEIF Motion`(HorizPos%%, VertPos%%, 0) THEN
                            _PUTIMAGE (107 * (HorizPos%% - 1) + 7, 107 * (VertPos%% - 1) + 7), Images&(Grid%%(HorizPos%%, VertPos%%)) 'Fronts
                        ELSE
                            _PUTIMAGE (107 * (HorizPos%% - 1) + 7, 107 * (VertPos%% - 1) + 7), ObverseImg& 'Backs
                        END IF
                    NEXT VertPos%%
                NEXT HorizPos%%
                _DISPLAY
                K$ = INKEY$
                IF K$ <> "" THEN
                    IF ASC(K$) = 27 THEN 'Esc - Quit Program
                        Pelmanism` = False
                        DoGrid` = False
                        DoMore` = False
                    ELSEIF UCASE$(K$) = "Q" THEN
                        DoGrid` = False
                    END IF
                END IF
                K$ = ""
                IF MouseClick` AND DoGrid` AND NOT Flipping` THEN
                    HorizPos%% = XX%% + 1
                    VertPos%% = YY%% + 1
                    IF Choisi`(HorizPos%%, VertPos%%) OR (FirstH%% = HorizPos%% AND FirstV%% = VertPos%%) THEN
                        'Do nothing
                    ELSE
                        Motion`(HorizPos%%, VertPos%%, 1) = True 'Set this cell turning
                        Flipping` = True
                        IF FirstGo` THEN
                            FirstH%% = HorizPos%%
                            FirstV%% = VertPos%%
                        END IF
                    END IF
                END IF
            END IF
        WEND
        _FREEIMAGE Background&
        _FREEIMAGE Highlight&
        _FREEIMAGE Quitlight&
        CALL UseUpMouse
    END IF
    'Try Again?
    IF DoMore` THEN
        ImgYes& = _LOADIMAGE("PelmanYes.png", 33)
        ImgNo& = _LOADIMAGE("PelmanNo.png", 33)
        ImgAgain& = _LOADIMAGE("PlayAgain.png", 33)
        TempImg& = _NEWIMAGE(110, 70, 32)
        ValidMouse` = False
        _DEST TempImg&
        COLOR _RGB32(100, 255, 100), _RGBA32(100, 100, 100, 0)
        CLS
        LINE (0, 0)-(109, 69), , B
        Highlight& = MakeHardware&(TempImg&)
        SCREEN _NEWIMAGE(500, 500, 32)
        _SCREENMOVE 100, 100
        _DEST 0
        CLS
        _DISPLAYORDER _HARDWARE
        WHILE DoMore`
            _LIMIT 30
            _PUTIMAGE (150, 50), ImgAgain&
            _PUTIMAGE (200, 250), ImgYes&
            _PUTIMAGE (195, 350), ImgNo&
            WHILE _MOUSEINPUT
                XMouse% = _MOUSEX: YMouse% = _MOUSEY
                ValidMouse` = False
                IF XMouse% > 195 AND XMouse% < 295 AND YMouse% > 275 AND YMouse% < 335 THEN
                    ValidMouse` = True
                    XHighLight% = 190
                    YHighLight% = 270
                ELSEIF XMouse% > 195 AND XMouse% < 295 AND YMouse% > 370 AND YMouse% < 430 THEN
                    ValidMouse` = True
                    XHighLight% = 190
                    YHighLight% = 365
                END IF
                IF _MOUSEBUTTON(ButtonNo%%) THEN
                    IF XMouse% > 195 AND XMouse% < 295 AND YMouse% > 275 AND YMouse% < 335 THEN 'Another Game
                        DoMore` = False
                    ELSEIF XMouse% > 195 AND XMouse% < 295 AND YMouse% > 370 AND YMouse% < 430 THEN 'Quit
                        DoMore` = False
                        Pelmanism` = False
                    END IF
                END IF
            WEND
            IF ValidMouse` THEN _PUTIMAGE (XHighLight%, YHighLight%), Highlight&
            K$ = INKEY$
            IF K$ <> "" THEN
                IF ASC(K$) = 27 OR UCASE$(K$) = "N" THEN
                    DoMore` = False
                    Pelmanism` = False
                ELSEIF UCASE$(K$) = "Y" THEN
                    DoMore` = False
                END IF
            END IF
            K$ = ""
            _DISPLAY
        WEND
        _FREEIMAGE ImgYes&
        _FREEIMAGE ImgNo&
        _FREEIMAGE ImgAgain&
        _FREEIMAGE Highlight&
    END IF
WEND
 
'Freeimages
_FREEIMAGE ObverseImg&
FOR N%% = 0 TO 9
    _FREEIMAGE NosImg&(N%%, 1)
    _FREEIMAGE NosImg&(N%%, 0)
NEXT N%%
_FREEIMAGE BestImg&
FOR N%% = 0 TO NoObjectsLess1%%
    _FREEIMAGE Images&(N%%)
NEXT N%%
 
OPEN "pelman.dat" FOR OUTPUT AS #1
PRINT #1, ButtonNo%%
FOR N%% = 0 TO 2
    PRINT #1, BestScore%(N%%)
NEXT N%%
CLOSE #1
CLS
 
SYSTEM
 
FUNCTION MakeHardware& (Img&)
    MakeHardware& = _COPYIMAGE(Img&, 33)
    _FREEIMAGE Img&
END FUNCTION
 
SUB UseUpMouse
    _KEYCLEAR
    DO 'make sure that mouse button is released
        Dum` = _MOUSEINPUT
    LOOP UNTIL NOT _MOUSEBUTTON(ButtonNo%%)
    WHILE _MOUSEINPUT
        IF _MOUSEBUTTON(ButtonNo%%) = mouse_down THEN 'Is the button still in the same position?
            DO WHILE _MOUSEINPUT
                IF _MOUSEBUTTON(ButtonNo%%) <> mouse_down THEN EXIT DO 'Process through the queue until the button changes state
            LOOP
        END IF
        mouse_down = _MOUSEBUTTON(ButtonNo%%)
    WEND
END SUB
 
 

This code is used with my Pelmanism Game Program (qv).

What I found is that spurious triggering of the main program (turning a picture over) can happen if Line 114 or Line 191 is omitted. I think that my mouse button bounces a little and may cause more than 1 mouse down events when clicked. So when you're selecting a game level, excess mouse clicks are carried over into the picture select part of the program, and a picture turns over without actually selecting it - you will probably need to use the actual program to undersatnd what I'm saying. Thanks, Steve, in advance.

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: SMcNeill on January 05, 2019, 01:20:22 pm

See if this doesn't clear up the issue a bit better for you:

Code: QB64: [Select]

' Pelmanism (Pairs) Game version 2 by QWERKEY 2019-01-05
' Images from openclipart.org,clipartpng.com & pngimg.com
' Sounds from findsounds.com
 
CONST True = -1`, False = 0`
CONST NoObjectsLess1%% = 67
DIM SHARED ButtonNo%%
DIM BestScore%(2), GameLevel%%(2, 1), NosImg&(9, 1), Images&(NoObjectsLess1%%)
$EXEICON:'.\Balloons.ico'
_TITLE "Pelmanism Game"
RANDOMIZE (TIMER)
 
DATA 4,4
DATA 6,6
DATA 10,6
FOR N%% = 0 TO 2
    FOR M%% = 0 TO 1
        READ GameLevel%%(N%%, M%%)
    NEXT M%%
NEXT N%%
'Create Images
DATA Bananas,Cherry,Carrots,Pepper,Tomato,Cat,Egg,Beer,Acorn,Feather,Squirrel,IcedBun,LightBulb,GoldCup
DATA Parrot,LadyMouse,Mushrooms,Pineapple,Balloons,Rose,CloverLeaf,Goose,Raccoon,Raspberry,Violin,TeddyBear
DATA Clock,Shoes,Wrench,Hammer,Computer,Matches,Diamond,WineGlass,Frog,Chimp,Apricot,RollsRoyce,Knight,Bee
DATA Fish,IceCream,SnowFlake,XmasTree,Butterfly,Rainbow,Penguin,Fox,Hummingbird,Cashews,Tulips,Matryoshka
DATA Lion,Apple,Hat,Heart,Key1,Ladybird,Strawberry,TV,Dog,Dolphin,Koala,Earth,Olives,Einstein,Plane,Flag
FOR N%% = 0 TO NoObjectsLess1%%
    READ Dum$
    Images&(N%%) = _LOADIMAGE(Dum$ + ".png", 33)
NEXT N%%
IF RND > 0.5 THEN
    ObverseImg& = _LOADIMAGE("Back1.png", 33)
ELSE
    ObverseImg& = _LOADIMAGE("Back2.png", 33)
END IF
FOR N%% = 0 TO 9
    TempImg& = _NEWIMAGE(40, 40, 32)
    _DEST TempImg&
    UsedFont& = _LOADFONT("calibriz.ttf", 40)
    _FONT UsedFont&
    COLOR _RGB32(255, 0, 0), _RGB32(0, 0, 0)
    _PRINTSTRING (5, 5), LTRIM$(STR$(N%%))
    _FONT 16
    _FREEFONT UsedFont&
    NosImg&(N%%, 1) = MakeHardware&(TempImg&)
NEXT N%%
FOR N%% = 0 TO 9
    TempImg& = _NEWIMAGE(40, 40, 32)
    _DEST TempImg&
    UsedFont& = _LOADFONT("calibriz.ttf", 40)
    _FONT UsedFont&
    COLOR _RGB32(0, 255, 0), _RGB32(0, 0, 0)
    _PRINTSTRING (5, 5), LTRIM$(STR$(N%%))
    _FONT 16
    _FREEFONT UsedFont&
    NosImg&(N%%, 0) = MakeHardware&(TempImg&)
NEXT N%%
TempImg& = _NEWIMAGE(110, 74, 32)
_DEST TempImg&
UsedFont& = _LOADFONT("calibriz.ttf", 40)
_FONT UsedFont&
COLOR _RGB32(255, 0, 0), _RGB32(0, 0, 0)
_PRINTSTRING (5, 5), "Best"
_PRINTSTRING (5, 45), "Score:"
_FONT 16
_FREEFONT UsedFont&
BestImg& = MakeHardware&(TempImg&)
'Load/Set Initial Data
IF _FILEEXISTS("pelman.dat") THEN
    OPEN "pelman.dat" FOR INPUT AS #1
    INPUT #1, ButtonNo%%
    FOR N%% = 0 TO 2
        INPUT #1, BestScore%(N%%)
    NEXT N%%
    CLOSE #1
ELSE
    SelectButton
END IF
'CALL UseUpMouse
'Perform Game
Pelmanism` = True
WHILE Pelmanism`
    GetSkillLevel
    OldButton = _MOUSEBUTTON(ButtonNo%%) 'Get the current mouse state to make certain the user lifted it up after selecting the skill level
    'Do Puzzle
    IF DoGrid` THEN
        XLimit% = 57 + (GameLevel%%(Level%%, 0) - 1) * 107 + 45
        YLimit% = 57 + (GameLevel%%(Level%%, 1) - 1) * 107 + 45
        IsComplete` = False
        Score% = 0
        NoRemaining%% = GameLevel%%(Level%%, 0) * GameLevel%%(Level%%, 1)
        NoPairs%% = 0
        FirstV%% = 50
        ValidMouse` = False
        Flipping` = False
        TurningBack` = False
        FlipCount%% = 0
        Paused` = False
        PCount%% = 0
        FirstGo` = True
        REDIM Motion`(10, 6, 2), Selected%%(30), Choisi`(10, 6), Grid%%(10, 6)
        RANDOMIZE (TIMER)
        WHILE NoRemaining%% > 0
            Vacant` = False
            WHILE NOT Vacant`
                HorizPos%% = 1 + INT(GameLevel%%(Level%%, 0) * RND)
                VertPos%% = 1 + INT(GameLevel%%(Level%%, 1) * RND)
                IF Grid%%(HorizPos%%, VertPos%%) = 0 THEN Vacant` = True
            WEND
            NewPair` = False
            WHILE NOT NewPair`
                PairNo%% = 1 + INT(NoObjectsLess1%% * RND)
                PairsExists` = False
                N%% = 1
                WHILE NOT PairsExists` AND N%% <= NoPairs%%
                    IF PairNo%% = Selected%%(N%%) THEN PairsExists` = True
                    N%% = N%% + 1
                WEND
                IF NOT PairsExists` THEN NewPair` = True
            WEND
            NoPairs%% = NoPairs%% + 1
            Selected%%(NoPairs%%) = PairNo%%
            Grid%%(HorizPos%%, VertPos%%) = PairNo%%
            Vacant` = False
            WHILE NOT Vacant`
                HorizPos%% = 1 + INT(GameLevel%%(Level%%, 0) * RND): VertPos%% = 1 + INT(GameLevel%%(Level%%, 1) * RND)
                IF Grid%%(HorizPos%%, VertPos%%) = 0 THEN Vacant` = True
            WEND
            Selected%%(NoPairs%%) = PairNo%%
            Grid%%(HorizPos%%, VertPos%%) = PairNo%%
            NoRemaining%% = NoRemaining%% - 2
        WEND
        NoRemaining%% = GameLevel%%(Level%%, 0) * GameLevel%%(Level%%, 1)
        TempImg& = _NEWIMAGE(205 + XLimit%, YLimit% + 12, 32)
        _DEST TempImg&
        COLOR _RGB32(255, 255, 255), _RGBA32(100, 100, 100, 0)
        CLS
        FOR N%% = 0 TO GameLevel%%(Level%%, 0) - 1
            FOR M%% = 0 TO GameLevel%%(Level%%, 1) - 1
                LINE (3 + N%% * 107, 3 + M%% * 107)-(3 + (N%% + 1) * 107, 3 + (M%% + 1) * 107), , B
            NEXT M%%
        NEXT N%%
        UsedFont& = _LOADFONT("calibriz.ttf", 60)
        _FONT UsedFont&
        COLOR _RGB32(0, 0, 255)
        _PRINTSTRING (XLimit% + 35, 355), "QUIT"
        _FONT 16
        _FREEFONT UsedFont&
        UsedFont& = _LOADFONT("calibriz.ttf", 40)
        _FONT UsedFont&
        COLOR _RGB32(0, 255, 0)
        _PRINTSTRING (XLimit% + 35, 190), "Score:"
        _FONT 16
        _FREEFONT UsedFont&
        Background& = MakeHardware&(TempImg&)
        TempImg& = _NEWIMAGE(104, 104, 32)
        _DEST TempImg&
        COLOR _RGB32(0, 176, 0), _RGBA32(100, 100, 100, 0)
        CLS
        LINE (0, 0)-(103, 103), , B
        LINE (1, 1)-(102, 102), , B
        Highlight& = MakeHardware&(TempImg&)
        TempImg& = _NEWIMAGE(144, 52, 32)
        _DEST TempImg&
        COLOR _RGB32(0, 176, 0), _RGBA32(100, 100, 100, 0)
        CLS
        LINE (0, 0)-(143, 51), , B
        Quitlight& = MakeHardware&(TempImg&)
        SCREEN _NEWIMAGE(205 + XLimit%, YLimit% + 12, 32)
        _SCREENMOVE 20, 20
        _DEST 0
        _DISPLAYORDER _HARDWARE
        WHILE DoGrid`
            IF TurningBack` THEN
                _LIMIT 65
            ELSE
                _LIMIT 40
            END IF
            _PUTIMAGE (0, 0), Background&
            IF BestScore%(Level%%) <> 0 THEN
                _PUTIMAGE (XLimit% + 30, 20), BestImg&
                IF BestScore%(Level%%) <= 9 THEN
                    _PUTIMAGE (XLimit% + 140, 60), NosImg&(BestScore%(Level%%), 1)
                ELSE
                    _PUTIMAGE (XLimit% + 140, 60), NosImg&(BestScore%(Level%%) \ 10, 1)
                    _PUTIMAGE (XLimit% + 160, 60), NosImg&(BestScore%(Level%%) MOD 10, 1)
                END IF
            END IF
            IF Score% <= 9 THEN
                _PUTIMAGE (XLimit% + 140, 185), NosImg&(Score%, 0)
            ELSE
                _PUTIMAGE (XLimit% + 140, 185), NosImg&(Score% \ 10, 0)
                _PUTIMAGE (XLimit% + 160, 185), NosImg&(Score% MOD 10, 0)
            END IF
            MouseClick` = False
            WHILE _MOUSEINPUT: WEND
            ValidMouse` = False
            QuitMouse` = False
            XMouse% = _MOUSEX: YMouse% = _MOUSEY
            IF XMouse% > 7 AND XMouse% < (GameLevel%%(Level%%, 0)) * 107 AND YMouse% > 7 AND YMouse% < (GameLevel%%(Level%%, 1)) * 107 THEN
                ValidMouse` = True
                XX%% = (XMouse% - 7) \ 107
                YY%% = (YMouse% - 7) \ 107
                XHighLight% = 5 + 107 * XX%%
                YHighLight% = 5 + 107 * YY%%
            ELSEIF XMouse% > XLimit% + 35 AND XMouse% < XLimit% + 169 AND YMouse% > 355 AND YMouse% < 397 THEN
                QuitMouse` = True
                XHighLight% = XLimit% + 30
                YHighLight% = 350
            END IF
            IF _MOUSEBUTTON(ButtonNo%%) AND NOT OldButton THEN 'check to make certain the mouse is UP, before we count a down event
                IF XMouse% > XLimit% + 35 AND XMouse% < XLimit% + 169 AND YMouse% > 355 AND YMouse% < 397 THEN DoGrid` = False
                IF ValidMouse` THEN MouseClick` = True
            END IF
            OldButton = _MOUSEBUTTON(ButtonNo%%) 'store whether mouse was up or down last
 
            IF DoGrid` THEN
                IF ValidMouse` THEN
                    _PUTIMAGE (XHighLight%, YHighLight%), Highlight&
                ELSEIF QuitMouse` THEN
                    _PUTIMAGE (XHighLight%, YHighLight%), Quitlight&
                END IF
                FOR HorizPos%% = 1 TO GameLevel%%(Level%%, 0)
                    FOR VertPos%% = 1 TO GameLevel%%(Level%%, 1)
                        IF Motion`(HorizPos%%, VertPos%%, 2) THEN
                            'Turn back
                            IF Paused` THEN
                                _PUTIMAGE (107 * (HorizPos%% - 1) + 7, 107 * (VertPos%% - 1) + 7), Images&(Grid%%(HorizPos%%, VertPos%%)) 'Fronts
                                PCount%% = PCount%% + 1
                                IF PCount%% = 40 THEN
                                    Paused` = False
                                    PCount%% = 0
                                END IF
                            ELSE
                                IF FlipCount%% = 0 THEN
                                    XPos% = 107 * (HorizPos%% - 1) + 7
                                    YPos% = 107 * (VertPos%% - 1) + 7
                                END IF
                                IF FlipCount%% < 50 THEN
                                    _PUTIMAGE (FlipCount%% + XPos%, YPos%)-(XPos% + 100 - FlipCount%%, YPos% + 100), Images&(Grid%%(HorizPos%%, VertPos%%))
                                ELSE
                                    _PUTIMAGE (XPos% + FlipCount%%, YPos%)-(XPos% + 100 - FlipCount%%, YPos% + 100), ObverseImg&
                                END IF
                                FlipCount%% = FlipCount%% + 1
                                IF FlipCount%% = 100 THEN
                                    FlipCount%% = 0
                                    IF HorizPos%% = FirstH%% AND VertPos%% = FirstV%% THEN
                                        Motion`(HorizPos%%, VertPos%%, 2) = False
                                        Motion`(HorizPos%%, VertPos%%, 0) = False
                                        Flipping` = False
                                        TurningBack` = False
                                        FirstV%% = 50
                                        'CALL UseUpMouse
                                    ELSE
                                        Motion`(HorizPos%%, VertPos%%, 2) = False
                                        Motion`(HorizPos%%, VertPos%%, 0) = False
                                        Motion`(FirstH%%, FirstV%%, 2) = True
                                    END IF
                                END IF
                            END IF
                        ELSEIF Motion`(HorizPos%%, VertPos%%, 1) THEN
                            'Turn forward
                            IF FlipCount%% = 0 THEN
                                XPos% = 107 * (HorizPos%% - 1) + 7
                                YPos% = 107 * (VertPos%% - 1) + 7
                            END IF
                            IF FlipCount%% < 50 THEN
                                _PUTIMAGE (XPos% + 100 - FlipCount%%, YPos%)-(XPos% + FlipCount%%, YPos% + 100), ObverseImg&
                            ELSE
                                _PUTIMAGE (100 - FlipCount%% + XPos%, YPos%)-(XPos% + FlipCount%%, YPos% + 100), Images&(Grid%%(HorizPos%%, VertPos%%))
                            END IF
                            FlipCount%% = FlipCount%% + 1
                            IF FlipCount%% = 100 THEN
                                FlipCount%% = 0
                                Flipping` = False
                                Motion`(HorizPos%%, VertPos%%, 1) = False
                                Motion`(HorizPos%%, VertPos%%, 0) = True
                                IF FirstGo` THEN
                                    FirstGo` = False
                                ELSE
                                    FirstGo` = True
                                    IF Grid%%(HorizPos%%, VertPos%%) = Grid%%(FirstH%%, FirstV%%) THEN 'Matched pair
                                        Choisi`(HorizPos%%, VertPos%%) = True 'Registers that that grid position cannot be clicked any more
                                        Choisi`(FirstH%%, FirstV%%) = True
                                        NoRemaining%% = NoRemaining%% - 2
                                        IF NoRemaining%% = 0 THEN
                                            'Tah-dah sound (completed)
                                            _SNDPLAYFILE ("fanfare.mp3")
                                        ELSE
                                            'Ching sound (match)
                                            _SNDPLAYFILE ("match3.mp3")
                                        END IF
                                    ELSE
                                        'Initiate sequential turn back
                                        Motion`(HorizPos%%, VertPos%%, 2) = True
                                        Flipping` = True
                                        TurningBack` = True
                                        Paused` = True
                                        PCount%% = 0
                                        _SNDPLAYFILE ("nomatch1.mp3"), , 0.2
                                    END IF
                                    IF Score% < 99 THEN Score% = Score% + 1
                                    IF NoRemaining%% = 0 THEN
                                        'Pairings Completed
                                        IF Score% < BestScore%(Level%%) OR BestScore%(Level%%) = 0 THEN BestScore%(Level%%) = Score%
                                    END IF
                                END IF
                                'CALL UseUpMouse
                            END IF
                        ELSEIF Motion`(HorizPos%%, VertPos%%, 0) THEN
                            _PUTIMAGE (107 * (HorizPos%% - 1) + 7, 107 * (VertPos%% - 1) + 7), Images&(Grid%%(HorizPos%%, VertPos%%)) 'Fronts
                        ELSE
                            _PUTIMAGE (107 * (HorizPos%% - 1) + 7, 107 * (VertPos%% - 1) + 7), ObverseImg& 'Backs
                        END IF
                    NEXT VertPos%%
                NEXT HorizPos%%
                _DISPLAY
                K$ = INKEY$
                IF K$ <> "" THEN
                    IF ASC(K$) = 27 THEN 'Esc - Quit Program
                        Pelmanism` = False
                        DoGrid` = False
                        DoMore` = False
                    ELSEIF UCASE$(K$) = "Q" THEN
                        DoGrid` = False
                    END IF
                END IF
                K$ = ""
                IF MouseClick` AND DoGrid` AND NOT Flipping` THEN
                    HorizPos%% = XX%% + 1
                    VertPos%% = YY%% + 1
                    IF Choisi`(HorizPos%%, VertPos%%) OR (FirstH%% = HorizPos%% AND FirstV%% = VertPos%%) THEN
                        'Do nothing
                    ELSE
                        Motion`(HorizPos%%, VertPos%%, 1) = True 'Set this cell turning
                        Flipping` = True
                        IF FirstGo` THEN
                            FirstH%% = HorizPos%%
                            FirstV%% = VertPos%%
                        END IF
                    END IF
                END IF
            END IF
        WEND
        _FREEIMAGE Background&
        _FREEIMAGE Highlight&
        _FREEIMAGE Quitlight&
        'CALL UseUpMouse
    END IF
    'Try Again?
    IF DoMore` THEN
        ImgYes& = _LOADIMAGE("PelmanYes.png", 33)
        ImgNo& = _LOADIMAGE("PelmanNo.png", 33)
        ImgAgain& = _LOADIMAGE("PlayAgain.png", 33)
        TempImg& = _NEWIMAGE(110, 70, 32)
        ValidMouse` = False
        _DEST TempImg&
        COLOR _RGB32(100, 255, 100), _RGBA32(100, 100, 100, 0)
        CLS
        LINE (0, 0)-(109, 69), , B
        Highlight& = MakeHardware&(TempImg&)
        SCREEN _NEWIMAGE(500, 500, 32)
        _SCREENMOVE 100, 100
        _DEST 0
        CLS
        _DISPLAYORDER _HARDWARE
        WHILE DoMore`
            _LIMIT 30
            _PUTIMAGE (150, 50), ImgAgain&
            _PUTIMAGE (200, 250), ImgYes&
            _PUTIMAGE (195, 350), ImgNo&
            WHILE _MOUSEINPUT: WEND
            XMouse% = _MOUSEX: YMouse% = _MOUSEY
            ValidMouse` = False
            IF XMouse% > 195 AND XMouse% < 295 AND YMouse% > 275 AND YMouse% < 335 THEN
                ValidMouse` = True
                XHighLight% = 190
                YHighLight% = 270
            ELSEIF XMouse% > 195 AND XMouse% < 295 AND YMouse% > 370 AND YMouse% < 430 THEN
                ValidMouse` = True
                XHighLight% = 190
                YHighLight% = 365
            END IF
            IF _MOUSEBUTTON(ButtonNo%%) AND NOT OldButton THEN
                IF XMouse% > 195 AND XMouse% < 295 AND YMouse% > 275 AND YMouse% < 335 THEN 'Another Game
                    DoMore` = False
                ELSEIF XMouse% > 195 AND XMouse% < 295 AND YMouse% > 370 AND YMouse% < 430 THEN 'Quit
                    DoMore` = False
                    Pelmanism` = False
                END IF
            END IF
            OldButton = _MOUSEBUTTON(ButtonNo%%)
 
            IF ValidMouse` THEN _PUTIMAGE (XHighLight%, YHighLight%), Highlight&
            K$ = INKEY$
            IF K$ <> "" THEN
                IF ASC(K$) = 27 OR UCASE$(K$) = "N" THEN
                    DoMore` = False
                    Pelmanism` = False
                ELSEIF UCASE$(K$) = "Y" THEN
                    DoMore` = False
                END IF
            END IF
            K$ = ""
            _DISPLAY
        WEND
        _FREEIMAGE ImgYes&
        _FREEIMAGE ImgNo&
        _FREEIMAGE ImgAgain&
        _FREEIMAGE Highlight&
    END IF
WEND
 
'Freeimages
_FREEIMAGE ObverseImg&
FOR N%% = 0 TO 9
    _FREEIMAGE NosImg&(N%%, 1)
    _FREEIMAGE NosImg&(N%%, 0)
NEXT N%%
_FREEIMAGE BestImg&
FOR N%% = 0 TO NoObjectsLess1%%
    _FREEIMAGE Images&(N%%)
NEXT N%%
 
OPEN "pelman.dat" FOR OUTPUT AS #1
PRINT #1, ButtonNo%%
FOR N%% = 0 TO 2
    PRINT #1, BestScore%(N%%)
NEXT N%%
CLOSE #1
CLS
 
SYSTEM
 
FUNCTION MakeHardware& (Img&)
    MakeHardware& = _COPYIMAGE(Img&, 33)
    _FREEIMAGE Img&
END FUNCTION
 
SUB SelectButton
    SHARED ButtonNo%%
    SCREEN _NEWIMAGE(500, 500, 32)
    _SCREENMOVE 100, 100
    _DEST 0
    CLS
    _DISPLAYORDER _SOFTWARE , _HARDWARE
    Mousey& = _LOADIMAGE("Mouse.png", 33)
    LOCATE 2, 7
    PRINT "Click on the mouse below with your normal button";
    LOCATE 3, 5
    PRINT "Click (not double-click) to make this screen disappear";
    CorrectButton` = False: ButtonNo%% = 1
    WHILE NOT CorrectButton`
        _LIMIT 60
        _PUTIMAGE (50, 100), Mousey&
        'Assumes hardware has mouse buttons, value <=5
        WHILE _MOUSEINPUT: WEND
        IF _MOUSEBUTTON(1) THEN
            CorrectButton` = True
            ButtonNo%% = 1
        ELSEIF _MOUSEBUTTON(2) THEN
            CorrectButton` = True
            ButtonNo%% = 2
        ELSEIF _MOUSEBUTTON(3) THEN
            CorrectButton` = True
            ButtonNo%% = 3
        ELSEIF _MOUSEBUTTON(4) THEN
            CorrectButton` = True
            ButtonNo%% = 4
        ELSEIF _MOUSEBUTTON(5) THEN
            CorrectButton` = True
            ButtonNo%% = 5
        END IF
        _DISPLAY
    WEND
    _FREEIMAGE Mousey&
END SUB
 
 
SUB GetSkillLevel
    SHARED ButtonNo%%, Skilled`, Pelmanism`, DoGrid`, DoMore`, Level%%
 
    'Set Game Level
    TempImg& = _NEWIMAGE(70, 90, 32)
    _DEST TempImg&
    COLOR _RGB32(100, 255, 100), _RGBA32(100, 100, 100, 0)
    CLS
    LINE (0, 0)-(69, 89), , B
    Highlight& = MakeHardware&(TempImg&)
    Img123& = _LOADIMAGE("Pelman123.png", 33)
    ImgSkills& = _LOADIMAGE("SkillLevel.png", 33)
    SCREEN _NEWIMAGE(500, 500, 32)
    _SCREENMOVE 100, 100
    _DEST 0
    _DISPLAYORDER _HARDWARE
    CLS
    Skilled` = False
    ValidMouse` = False
    DoGrid` = True
    DoMore` = True
    WHILE NOT Skilled`
        _LIMIT 30
        _PUTIMAGE (70, 50), ImgSkills&
        _PUTIMAGE (30, 300), Img123&
        WHILE _MOUSEINPUT: WEND
        XMouse% = _MOUSEX: YMouse% = _MOUSEY
        ValidMouse` = False
        IF YMouse% > 345 AND YMouse% < 405 THEN
            IF XMouse% > 343 AND XMouse% < 385 THEN
                Level%% = 2
                ValidMouse` = True
            ELSEIF XMouse% > 223 AND XMouse% < 265 THEN
                Level%% = 1
                ValidMouse` = True
            ELSEIF XMouse% > 103 AND XMouse% < 145 THEN
                Level%% = 0
                ValidMouse` = True
            END IF
        END IF
        IF _MOUSEBUTTON(ButtonNo%%) AND ValidMouse` THEN Skilled` = True
 
        IF ValidMouse` THEN
            SELECT CASE Level%%
                CASE 2
                    _PUTIMAGE (333, 330), Highlight&
                CASE 1
                    _PUTIMAGE (213, 330), Highlight&
                CASE ELSE
                    _PUTIMAGE (93, 330), Highlight&
            END SELECT
        END IF
        _DISPLAY
        K$ = INKEY$
        IF K$ <> "" THEN
            IF VAL(K$) = 1 THEN
                Skilled` = True
                Level%% = 0
            ELSEIF VAL(K$) = 2 THEN
                Skilled` = True
                Level%% = 1
            ELSEIF VAL(K$) = 3 THEN
                Skilled` = True
                Level%% = 2
            ELSEIF ASC(K$) = 27 THEN 'Esc - Quit Program
                Skilled` = True
                Pelmanism` = False
                DoGrid` = False
                DoMore` = False
            END IF
        END IF
        K$ = ""
    WEND
    _FREEIMAGE Highlight&
    _FREEIMAGE Img123&
    _FREEIMAGE ImgSkills&
    'CALL UseUpMouse
END SUB
 
 

Since you had 3 different areas which did the general mouse handling for you, I separated them into their own little independent modules so I could sort them out a bit easier with the program. Feel free to move them back together, if that suits your needs better -- this was just to help me sort out how many mouse routines I was actually dealing with. ;)

If you notice, in each section, I only use WHILE _MOUSEINPUT: WEND to update the mouse information for the program. There's *no* calls to an UseUpMouse routine, as it's no longer needed at all. (In fact, that little routine has been removed completely from this, for us.)

All you basically needed was a little flag which tracked whether or not the mouse was UP or DOWN prior in the program. You don't want to count any old DOWN event as a click; you want the mouse to be UP first and then pressed DOWN to be a click.

Code: QB64: [Select]

            IF _MOUSEBUTTON(ButtonNo%%) AND NOT OldButton THEN 'check to make certain the mouse is UP, before we count a down event
                IF XMouse% > XLimit% + 35 AND XMouse% < XLimit% + 169 AND YMouse% > 355 AND YMouse% < 397 THEN DoGrid` = False
                IF ValidMouse` THEN MouseClick` = True
            END IF
            OldButton = _MOUSEBUTTON(ButtonNo%%) 'store whether mouse was up or down last
 

No need for a clean up routine as you were using it, and no worries about your program lagging trying to process code inside the WHILE-WEND mouse update.

Try it out, and if you have any questions, feel free to ask. It's how we learn, after all. ;D

Title: Re: Is There a Mouse Equivalent of _KEYCLEAR?
Post by: Qwerkey on January 06, 2019, 05:08:12 am

Steve, thanks very much. That seems to work fine. From my reading of the Wiki, I completely misunderstood the WHILE _MOUSEINPUT: WEND requirements. I thought that all subsequent Mouse data (eg _MOUSEX & _MOUSEBUTTON()) had to be inside that loop, but following it later works as well. So, yes, I've have learnt a little. I'll study your code further to fully understand how to do Mouse event processing properly.

Elsewhere from Steve:

Quote

And people wonder why I quit farming! /sigh

All those hours you used to spend farming, now taken up spoon-feeding other dumb animals!!

Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Qwerkey on January 03, 2019, 07:24:09 am