Print Page - FireFox Management App for Windows

REDIM SHARED tabx(1000) AS INTEGER, taby(1000) AS INTEGER
REDIM SHARED settings$(100), session$(100)
REDIM SHARED title$, findbrowsertitle$, numofspaces%, inputindex, inputcount, word$(1000), crow%, ccol%
REDIM SHARED scindent%, srindent%, fw%, fh%, cwidth%, rheight%, num%, p1%, p2%, p3%, p4%, fileextension$
REDIM SHARED maxwinheight%, mintopindent%, browsertab$, hwnd%&, ClassName, WindowName$, nVirtKey, nCmdShow
DECLARE DYNAMIC LIBRARY "user32"
FUNCTION FindWindowA%& (BYVAL ClassName AS _OFFSET, WindowName$) 'find process handle by title
FUNCTION GetKeyState% (BYVAL nVirtKey AS LONG) 'Windows virtual key presses
FUNCTION ShowWindow& (BYVAL hwnd AS _OFFSET, BYVAL nCmdShow AS LONG) 'maximize process
FUNCTION GetForegroundWindow%& 'find currently focused process handle
FUNCTION SetForegroundWindow& (BYVAL hwnd AS _OFFSET) 'set foreground window process(focus)
END DECLARE
title$ = "FireFox Session Manager" 'Title of program window
_TITLE title$ 'Set program title
findbrowsertitle$ = "Bing - mozilla firefox"
browsertab$ = "bing.com"
fileextension$ = ".ses"
numofspaces% = 60
scindent% = 10 ' To be centered to screen.
mintopindent% = 5 ' Minimum rows indented from the top needed to see clickable areas above.
maxwinheight% = _DESKTOPHEIGHT \ _FONTHEIGHT - mintopindent%
IF maxwinheight% > 42 THEN
maxwinheight% = 42
rheight% = 42 - 4 ' Last width that supports font size 16 height.
ELSE
rheight% = maxwinheight% - 4 ' -4 is to keep window bottom above taskbar.
END IF
CALL setscreen
IF _FILEEXISTS("session-manager-settings.dat") THEN
ELSE
RESTORE settingslist
REDIM settings$(100)
OPEN "session-manager-settings.dat" FOR OUTPUT AS #2
i = 0
DO
READ a$
IF LCASE$(a$) = "eof" THEN EXIT DO
i = i + 1
settings$(i) = a$ + "," + "(Undefined)"
PRINT #2, settings$(i)
LOOP
CLOSE #2
END IF
RESTORE tasklist
i = 0
crow% = 9
DO
READ a$, action$
IF LCASE$(a$) = "eof" THEN EXIT DO
a$ = LTRIM$(STR$(i)) + ") " + a$
IF w4 < LEN(a$) THEN w4 = LEN(a$)
LOOP
ccol% = cwidth% \ 2 - w4 \ 2
w3 = 0
w4 = w4 + 2 ' margin buffer for menu box.
heading$ = "FireFox Session Menu"
LOCATE crow% - 2, ccol% + (w4 - 2) \ 2 - LEN(heading$) \ 2
PRINT heading$;
LOCATE crow%, ccol%
RESTORE tasklist
DO
READ a$, action$
IF LCASE$(a$) = "eof" THEN EXIT DO
w3 = w3 + 1
a$ = LTRIM$(STR$(w3)) + ") " + a$
PRINT a$;
LOCATE crow% + w3, ccol%
LOOP
p1% = ccol%: p2% = ccol% + w4: p3% = crow%: p4% = crow% + w3 ' selection parameters
CALL box(w3, w4)
CALL selection(w3, b$)
RESTORE tasklist
FOR i = 1 TO VAL(b$)
READ a$, action$
a$ = LTRIM$(STR$(i)) + ") " + a$
NEXT
CALL highlight(a$, b$)
SELECT CASE VAL(b$)
CASE 1 ' Firefox Full Screen
CALL startbrowser
RUN
CASE 2 ' Firefox minimized
CALL startbrowser
_DELAY .1
CALL minimizewindow
RUN
CASE 3
task$ = "load previous session" ' Load Previous Session.
CALL taskactions(task$, flag)
IF flag THEN flag = 0: CALL makesettings
RUN
CASE 4
SHELL _HIDE "dir /b *." + fileextension$ + ">tmp.tmp"
OPEN "tmp.tmp" FOR INPUT AS #1
w3 = 0: REDIM session$(100)
DO UNTIL EOF(1)
LINE INPUT #1, a$
IF INSTR(a$, fileextension$) <> 0 THEN ' Strip off file extension.
a$ = RTRIM$(MID$(a$, 1, INSTR(a$, fileextension$) - 1))
END IF
w3 = w3 + 1
session$(w3) = a$
LOOP
CLOSE #1
w4 = 0
IF w3 > 1 THEN ' More than one saved session in database.
FOR j = 1 TO w3
IF LEN(session$(j)) > w4 THEN w4 = LEN(session$(j))
NEXT
crow% = 10
ccol% = cwidth% \ 2 - w4 \ 2
p1% = ccol%: p2% = ccol% + w4: p3% = crow%: p4% = crow% + w3 ' selection parameters
w4 = w4 + 2 ' margin buffer for menu box.
CLS
LOCATE crow%, ccol%
FOR j = 1 TO w3
PRINT session$(j)
LOCATE , ccol%
NEXT
heading$ = "Click to Load Session"
LOCATE crow% - 3, ccol% + (w4 - 2) \ 2 - LEN(heading$) \ 2
PRINT heading$;
heading$ = "Back | Quit"
LOCATE crow% - 2, ccol% + (w4 - 2) \ 2 - LEN(heading$) \ 2
COLOR 3, 0
PRINT heading$;
COLOR 7, 0
LOCATE crow%, ccol%
CALL box(w3, w4)
DO
CALL selection(w3, b$)
IF b$ = "run" THEN RUN
IF b$ = "esc" THEN SYSTEM
IF VAL(b$) > 0 THEN EXIT DO
LOOP
a$ = session$(VAL(b$))
CALL highlight(a$, b$)
ELSE
b$ = "1" ' Only one selection.
END IF
OPEN session$(VAL(b$)) + fileextension$ FOR INPUT AS #1
DO UNTIL EOF(1)
LINE INPUT #1, a$
SHELL _HIDE "firefox.exe " + a$
_DELAY .2
LOOP
_DELAY 2
RUN
CASE 5
task$ = "session"
CALL mapping(task$)
_DELAY 3
RUN
CASE 6
task$ = "close"
CALL taskactions(task$, flag)
IF flag THEN flag = 0: CALL makesettings
RUN
CASE 7
CALL makesettings
RUN
CASE 8
SYSTEM
END SELECT
tasklist:
DATA FireFox Full Screen,Starting FireFox...
DATA FireFox Minimized,Starting FireFox Minimized...
DATA FireFox Load Previous Session,Starting Firefox Last Session...
DATA Load a Saved Session,Loading Session Menu...
DATA Map a New Session,Map a New Session...
DATA Close Firefox,Close Firefox...
DATA Settings,Go to Settings...
DATA Quit,Quit
DATA eof,eof
programcommands:
DATA back,run
DATA quit,esc
DATA eof,eof
settingslist:
DATA Close
DATA Load Previous Session
DATA eof
SUB mouse (x%, y%, mb%, rb%)
WHILE _MOUSEINPUT: WEND
x% = _MOUSEX
y% = _MOUSEY
mb% = _MOUSEBUTTON(1)
rb% = _MOUSEBUTTON(2)
IF INKEY$ = CHR$(27) THEN SYSTEM
END SUB
SUB mapping (task$)
_DELAY .1
hwnd%& = FindWindowA(0, title$ + CHR$(0)) 'find this program's process handle
oldx% = -1: w = 0: v = 0: num% = 0
DO
IF oldx% <> x% OR oldy% <> y% THEN
IF dispon% = 0 THEN
CLS
CALL startbrowser
CALL focusapp
IF task$ = "session" THEN
LOCATE crow%, ccol%
PRINT "Open all websites you want"
LOCATE , ccol%
PRINT "saved in this session."
PRINT
LOCATE , ccol%
PRINT "Click the taskbar icon to"
LOCATE , ccol%
PRINT "record and save session..."
DO
_LIMIT 30
FGwin%& = GetForegroundWindow%&
CALL mouse(x%, y%, mb%, rb%)
IF mb% THEN EXIT DO
b$ = INKEY$
IF b$ = CHR$(27) THEN SYSTEM
IF b$ <> "" THEN EXIT DO
IF FGwin%& <> hwnd%& THEN EXIT DO ' Exit when Firefox is clicked.
LOOP
'Minimize here.
CALL minimizewindow
_DELAY 1
CLS
LOCATE crow% + 1, ccol%
PRINT "Working..."
DO
_LIMIT 30
FGwin%& = GetForegroundWindow%&
_DELAY 1
IF FGwin%& = hwnd%& THEN EXIT DO ' Exit when program window is restored from task bar.
LOOP
CALL restorewindow
END IF
CLS
_DELAY .1
z& = SetForegroundWindow&(hwnd%&) 'set focus
GOSUB putimage
LOCATE crow% + 1, ccol%
SELECT CASE task$
CASE "session"
PRINT "Left click the tabs you want saved in this session."
PRINT: LOCATE , ccol%
PRINT "Right click anywhere when finished..."
CASE "close"
PRINT "Left click the [X] Close symbol in Firefox."
CASE "load previous session"
SELECT CASE num%
CASE 0
PRINT "Click browser: " + CHR$(34) + "History" + CHR$(34)
PRINT
CASE 1
LOCATE , ccol%
PRINT "Click: " + CHR$(34) + "Restore Previous Session"
END SELECT
END SELECT
END IF
LOCATE crow% + 6, ccol%
PRINT "Row ="; y%; " "; "Column ="; x%; " ";
oldx% = x%: oldy% = y%
END IF
WHILE _MOUSEINPUT: WEND
x% = _MOUSEX
y% = _MOUSEY
mb% = _MOUSEBUTTON(1)
rb% = _MOUSEBUTTON(2)
IF mb% THEN
mb% = 0
'PRINT "Confirmed: Row ="; y%; " Column ="; x%,
num% = num% + 1
tabx(num%) = x%
taby(num%) = y%
DO: i = _MOUSEINPUT: LOOP UNTIL _MOUSEBUTTON(1) = 0
SELECT CASE task$
CASE "close"
EXIT SUB
CASE "load previous session"
CALL minimizewindow
_DELAY .1
_SCREENCLICK x%, y%
_DELAY .25
GOSUB putimage
_DELAY .25
CALL restorewindow
LOCATE 10, 75
FOR i = 1 TO 3
LOCATE , 75
PRINT SPACE$(40)
NEXT
LOCATE 11, 75
PRINT " Click " + CHR$(34) + "Restore Previous Session" + CHR$(34)
DO
CALL mouse(x%, y%, mb%, rb%)
IF mb% THEN EXIT DO
LOOP
num% = num% + 1
tabx(num%) = x%
taby(num%) = y%
CALL setscreen
EXIT SUB
END SELECT
ELSE
IF rb% AND task$ = "session" THEN
_SCREENHIDE
SCREEN 0
WIDTH cwidth%, rheight%
_SCREENMOVE scindent% * fw%, srindent% * fh%
CLS
_DELAY .25
REDIM url$(num%)
FOR i = 1 TO num%
_SCREENCLICK tabx(i), taby(i)
_DELAY .25
_SCREENCLICK 700, 80 ' Firefox URL input field.
_DELAY .1
_SCREENPRINT CHR$(1) ' Select the URL.
_DELAY .1
_SCREENPRINT CHR$(3) ' Copy the URL.
_DELAY .25
url$(i) = _CLIPBOARD$
NEXT
_SCREENSHOW
_DELAY .1
sdate$ = MID$(DATE$, 7, 4) + "-" + MID$(DATE$, 1, 2) + "-" + MID$(DATE$, 4, 2)
LOCATE 2, 2
PRINT "Name and Save this Session as: "; sdate$ + ": ";
yy% = CSRLIN: xx% = POS(0)
COLOR 0, 7
LOCATE , xx% - 1
PRINT SPACE$(60 + 2);
COLOR 7, 0
LOCATE yy%, xx%
PRINT
_DELAY .25
PRINT
FOR i = 1 TO num%
LOCATE , 2
PRINT LTRIM$(STR$(i)); ") "; MID$(url$(i), 1, cwidth% - 5)
NEXT
LOCATE yy%, xx%
z& = SetForegroundWindow&(hwnd%&) 'Set focus for key input.
CALL keyinput(word$, b$, flag)
CALL savefile(word$, sdate$, url$())
EXIT SUB
END IF
END IF
LOOP UNTIL INKEY$ = CHR$(27)
SYSTEM
putimage:
img& = _SCREENIMAGE
s& = _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT - 60, 32)
SCREEN s&
CLS
_SCREENMOVE 0, -25 ' Hides title bar above computer top screen margin.
_PUTIMAGE (0, 0), img&
_DELAY .1
_FREEIMAGE img&
dispon% = -1
RETURN
END SUB
SUB keyinput (word$, b$, flag)
startpos% = POS(1) - LEN(word$)
endpos% = startpos% + numofspaces%
DO
COLOR 7, 0
xx% = CSRLIN: yy% = POS(1)
LOCATE 1, 1
DO
ii = ii + 1
IF word$(ii) = "" THEN EXIT DO
PRINT ii; word$(ii)
LOOP
COLOR 0, 7
LOCATE xx%, yy%, 1, 7, 7
ii = 0
DO
b$ = INKEY$
IF b$ <> "" THEN EXIT DO
LOOP
xx% = CSRLIN: yy% = POS(1)
SELECT CASE b$
CASE CHR$(0) + "H"
REM DOS-KEY-LIKE REPLACE INPUT
IF inputindex > 0 THEN
IF word$ = "" THEN
inputindex = inputindex - 1: word$ = word$(inputindex)
ELSE
word$ = word$(inputindex): inputindex = inputindex - 1
END IF
flag = -1
EXIT SUB
END IF
CASE CHR$(0) + "K"
mov% = -1: GOSUB action
CASE CHR$(0) + "M"
mov% = 1: GOSUB action
CASE CHR$(0) + "S"
GOSUB wash: GOSUB delete
CASE CHR$(0) + "R"
IF ins% = 0 THEN ins% = -1 ELSE ins% = 0
IF ins% = 0 THEN LOCATE , , 1, 7, 7 ELSE LOCATE , , 1, 7, 30
CASE CHR$(0) + "O"
IF word$ <> "" THEN LOCATE xx%, startpos% + LEN(word$)
CASE CHR$(0) + "G"
LOCATE xx%, startpos%
CASE CHR$(8)
IF yy% > startpos% THEN
LOCATE , POS(1) - 1
yy% = POS(1)
GOSUB wash: GOSUB delete
END IF
CASE CHR$(13)
COLOR 7, 0
LOCATE , , 1, 7, 0
EXIT SUB
CASE CHR$(27)
COLOR 7, 0: SYSTEM
CASE CHR$(32) TO CHR$(126)
key$ = b$: GOSUB action
END SELECT
mov% = 0: key$ = ""
LOOP
action:
IF POS(1) + mov% >= startpos% AND POS(1) + mov% < endpos% THEN
DO
IF key$ <> "" THEN
SELECT CASE ins%
CASE 0
IF LEN(word$) + LEN(key$) > endpos% - startpos% THEN EXIT DO
word$ = MID$(word$, 1, POS(1) - startpos%) + key$ + MID$(word$, POS(1) - startpos% + 1)
CASE -1
word$ = MID$(word$, 1, POS(1) - startpos%) + key$ + MID$(word$, POS(1) - startpos% + 2)
END SELECT
END IF
IF POS(1) - startpos% >= LEN(word$) - LEN(key$) AND key$ <> "" OR key$ = "" OR ins% = -1 THEN
IF key$ = "" AND mov% = 1 THEN IF POS(1) - startpos% = LEN(word$) THEN EXIT DO
LOCATE , POS(1) + mov%: PRINT key$;
ELSE
LOCATE xx%, startpos%: PRINT MID$(word$, 1, yy% - startpos%); key$;: yy2% = POS(1): PRINT MID$(word$, yy% - startpos% + 2);: LOCATE xx%, yy2%
END IF
EXIT DO
LOOP
END IF
RETURN
wash:
IF POS(1) >= startpos% AND word$ <> "" AND POS(1) - startpos% < LEN(word$) THEN
LOCATE xx%, startpos% + LEN(word$) - 1
PRINT " ";
LOCATE xx%, yy%
END IF
RETURN
delete:
IF POS(1) - startpos% = 0 THEN
word$ = MID$(word$, 2)
ELSE
word$ = MID$(word$, 1, POS(1) - startpos%) + MID$(word$, POS(1) - startpos% + 2)
END IF
PRINT MID$(word$, yy% - startpos% + 1);: LOCATE xx%, yy%
RETURN
END SUB
SUB savefile (word$, sdate$, url$())
OPEN sdate$ + " " + word$ + fileextension$ FOR OUTPUT AS #2
FOR i = 1 TO num%
PRINT #2, url$(i)
NEXT
CLOSE #2
END SUB
SUB savesettings (b$)
OPEN "session-manager-settings.dat" FOR OUTPUT AS #2
i = 0
DO
i = i + 1
IF settings$(i) = "" OR i = 100 THEN EXIT DO
IF INSTR(settings$(i), ")") THEN
settings$(i) = LTRIM$(MID$(settings$(i), INSTR(settings$(i), ")") + 1)) ' Strip off any number.
END IF
PRINT #2, settings$(i)
LOOP
CLOSE #2
END SUB
SUB box (w3, w4)
LOCATE crow% - 1, ccol% - 2: PRINT CHR$(218);: PRINT STRING$(w4, 196) + CHR$(191)
FOR j = 1 TO w3
LOCATE , ccol% - 2
PRINT CHR$(179);
LOCATE , ccol% + w4 - 1: PRINT CHR$(179)
NEXT
LOCATE , ccol% - 2: PRINT CHR$(192) + STRING$(w4, 196) + CHR$(217)
END SUB
SUB selection (w3, b$)
b$ = ""
DO
_LIMIT 30
CALL mouse(x%, y%, mb%, rb%)
IF mb% THEN
IF p1% <= x% AND p2% >= x% AND p3% <= y% AND p4% >= y% THEN
b$ = CHR$(49 + y% - crow%)
END IF
IF VAL(b$) = 0 THEN ' Check for program choices above menu items.
cmd$ = CHR$(SCREEN(y%, x%))
IF LTRIM$(cmd$) = "" THEN
IF x% > 1 THEN cmd$ = CHR$(SCREEN(y%, x% - 1)) + cmd$ ' Look left
IF x% < cwidth% THEN cmd$ = cmd$ + CHR$(SCREEN(y%, x% + 1)) ' Look right
cmd$ = RTRIM$(LTRIM$(cmd$))
IF LEN(cmd$) <> 3 THEN cmd$ = "" ' Not in middle of a word."
END IF
IF cmd$ <> "" THEN
cmd$ = ""
FOR i = x% TO 1 STEP -1
cmd$ = CHR$(SCREEN(y%, i)) + cmd$
IF INSTR(cmd$, SPACE$(2)) THEN EXIT FOR ' IMPORTANT Only allows 1-space between clickable words.
NEXT
cmd$ = LTRIM$(cmd$)
IF cmd$ = "" THEN j = 0 ELSE j = 1
FOR i = x% + j TO cwidth%
cmd$ = cmd$ + CHR$(SCREEN(y%, i))
IF INSTR(cmd$, SPACE$(2)) THEN EXIT FOR
NEXT
cmd$ = LTRIM$(RTRIM$(LCASE$(cmd$)))
END IF
IF cmd$ <> "" THEN
RESTORE programcommands
b$ = ""
DO
READ a$, action$
IF LCASE$(a$) = "eof" THEN EXIT DO
IF LCASE$(a$) = cmd$ THEN b$ = action$: EXIT DO
LOOP
END IF
END IF
ELSE
b$ = INKEY$
END IF
IF b$ = CHR$(27) THEN SYSTEM
IF VAL(b$) <= w3 AND VAL(b$) <> 0 OR LEN(b$) > 1 THEN EXIT DO
LOOP
END SUB
SUB highlight (a$, b$)
LOCATE crow% + VAL(b$) - 1, ccol%
COLOR 14, 0
PRINT a$;
COLOR 7, 0
_DELAY .25
END SUB
SUB taskactions (task$, flag)
REDIM settings$(100)
IF _FILEEXISTS("session-manager-settings.dat") THEN
OPEN "session-manager-settings.dat" FOR INPUT AS #1
i = 0
DO UNTIL EOF(1)
i = i + 1
INPUT #1, a$, action$
settings$(i) = a$ + "," + action$
LOOP
CLOSE #1
flag = -1
END IF
IF flag THEN
flag = 0
FOR j = 1 TO i
IF INSTR(LCASE$(settings$(j)), LCASE$(task$)) <> 0 THEN
flag = -1
a$ = MID$(settings$(j), INSTR(settings$(j), ",") + 1)
EXIT FOR
END IF
NEXT
IF flag THEN
IF INSTR(LCASE$(a$), "(undefined)") <> 0 THEN
CLS
LOCATE crow%, ccol%
PRINT "This feature requires making a"
LOCATE , ccol%
PRINT "setting before it can be used."
PRINT
LOCATE , ccol%
PRINT "Opening the settings screen..."
_DELAY 4
CLS
EXIT SUB
END IF
flag = 0
SELECT CASE LCASE$(task$)
CASE "load previous session"
CALL startbrowser
CASE "close"
' Taskkill could be substituted here but may report an ff crash on next start up.
CALL startbrowser ' Ensures browser is running full screen before _SCREENCLICK.
REM x& = ShowWindow&(hwnd%&, 0) ' Closes Firefox but loses restore last session info.
END SELECT
DO
x% = VAL(a$)
a$ = MID$(a$, INSTR(a$, "-") + 1)
y% = VAL(a$)
_SCREENCLICK y%, x%
_DELAY 1
IF INSTR(a$, "|") = 0 THEN EXIT DO
a$ = MID$(a$, INSTR(a$, "|") + 1)
LOOP
END IF
ELSE
CLS
PRINT " ERROR: sessions-settings.dat file is missing."
PRINT
PRINT " Rerun program to re-install default data."
END
END IF
END SUB
SUB makesettings
DO
REDIM settings$(100) ' Load the settings data again.
RESTORE settingslist
IF _FILEEXISTS("session-manager-settings.dat") THEN
CLS
OPEN "session-manager-settings.dat" FOR INPUT AS #1
i = 0: w4 = 0
DO UNTIL EOF(1)
i = i + 1
INPUT #1, a$, action$
settings$(i) = LTRIM$(STR$(i)) + ") " + a$ + "," + action$
a$ = MID$(settings$(i), 1, INSTR(settings$(i), ",") - 1) ' Do not include actions in menu.
IF LEN(a$) > w4 THEN w4 = LEN(a$)
LOOP
CLOSE #1
w3 = i
w4 = w4 + 2
crow% = 10
ccol% = cwidth% \ 2 - w4 \ 2
p1% = ccol%: p2% = ccol% + w4: p3% = crow%: p4% = crow% + w3 ' selection parameters
heading$ = "Settings"
LOCATE crow% - 3, ccol% + (w4 - 2) \ 2 - LEN(heading$) \ 2
PRINT heading$;
heading$ = "Back | Quit"
LOCATE crow% - 2, ccol% + (w4 - 2) \ 2 - LEN(heading$) \ 2
COLOR 3, 0
PRINT heading$;
COLOR 7, 0
LOCATE crow%, ccol%
FOR i = 1 TO w3
LOCATE , ccol%
PRINT MID$(settings$(i), 1, INSTR(settings$(i), ",") - 1)
NEXT
CALL box(w3, w4)
CALL selection(w3, b$)
a$ = MID$(settings$(VAL(b$)), 1, INSTR(settings$(VAL(b$)), ",") - 1)
CALL highlight(a$, b$)
IF b$ = "run" THEN RUN
IF b$ = "esc" THEN SYSTEM
CLS
task$ = LCASE$(MID$(settings$(VAL(b$)), 1, INSTR(settings$(VAL(b$)), ",") - 1))
task$ = LTRIM$(MID$(task$, INSTR(task$, ")") + 1)) ' strip off number if present.
LOCATE crow% + 1, ccol%
PRINT "Working..."
CALL mapping(task$)
a$ = MID$(settings$(VAL(b$)), 1, INSTR(settings$(VAL(b$)), ","))
a$ = LTRIM$(MID$(a$, INSTR(a$, ")") + 1)) ' Strip off any number.
FOR i = 1 TO num%
a$ = a$ + LTRIM$(STR$(taby(i))) + "-" + LTRIM$(STR$(tabx(i))) + "|"
NEXT
a$ = MID$(a$, 1, LEN(a$) - 1)
settings$(VAL(b$)) = a$
CALL savesettings(b$)
CALL setscreen
ELSE
CLS
PRINT " ERROR: sessions-settings.dat file is missing."
PRINT
PRINT " Rerun program to re-install default data."
END
END IF
task$ = "": a$ = "": b$ = ""
LOOP
END SUB
SUB setscreen
SCREEN 0: CLS
srindent% = _DESKTOPHEIGHT \ _FONTHEIGHT - maxwinheight% ' To be indented from the top.
cwidth% = _DESKTOPWIDTH \ _FONTWIDTH - scindent% * 2
WIDTH cwidth%, rheight%
fw% = _FONTWIDTH: fh% = _FONTHEIGHT
' Now that WIDTH has been set, the font heigh can be used to calculate window size.
_SCREENMOVE scindent% * fw%, srindent% * fh%
END SUB
SUB startbrowser
hwnd%& = FindWindowA(0, findbrowsertitle$ + CHR$(0))
_DELAY .1
IF hwnd%& = 0 THEN
SHELL _DONTWAIT _HIDE "firefox.exe " + browsertab$
END IF
i = 0
DO ' Wait until title is registerd.
i = i + 1
hwnd%& = FindWindowA(0, findbrowsertitle$ + CHR$(0))
_DELAY .2
IF hwnd%& THEN EXIT DO
LOOP UNTIL i = 100
CALL maximizewindow
END SUB
SUB maximizewindow
x& = ShowWindow&(hwnd%&, 3) ' Maximize window from FindWindowA.
_DELAY .1
z& = SetForegroundWindow&(hwnd%&)
_DELAY .1
END SUB
SUB minimizewindow
x& = ShowWindow&(hwnd%&, 2) ' Minimize window from FindWindowA.
_DELAY .1
END SUB
SUB restorewindow
x& = ShowWindow&(hwnd%&, 1) ' Restore window from FindWindowA.
_DELAY .1
z& = SetForegroundWindow&(hwnd%&)
END SUB
SUB focusapp
hwnd%& = FindWindowA(0, title$ + CHR$(0))
_DELAY .1
z& = SetForegroundWindow&(hwnd%&)
_DELAY .1
END SUB

QB64.org Forum

Active Forums => Programs => Topic started by: Pete on December 09, 2018, 04:54:17 pm