QB64.org Forum

Active Forums => Programs => Topic started by: Zeppelin on December 02, 2018, 08:58:33 pm

Title: Simple Chat Bot
Post by: Zeppelin on December 02, 2018, 08:58:33 pm

Hey,
I got bored (as you do) and decided to make a very simple chat bot. Yes I know its not very effiecent, but it works ok.
By the way you can teach it to respond to anything you like :)

Code: QB64: [Select]

1. DIM line$(1000000)
2. OPEN "AIDatabase.txt" FOR INPUT AS #1
3. WHILE NOT EOF(1)
4.     lines = lines + 1
5.     INPUT #1, line$(lines)
6. WEND
7. CLOSE #1
8.  
9. PRINT "LOADED " + STR$(lines) + " ASSETS"
10.  
11. DO
12.     tmpNull = 0
13.     INPUT ">> ", in$
14.     in$ = LCASE$(in$)
15.  
16.     FOR n = 1 TO lines STEP 2
17.         IF in$ = line$(n) THEN
18.             PRINT line$(n + 1)
19.         ELSE
20.             tmpNull = tmpNull + 2
21.         END IF
22.     NEXT n
23.  
24.     IF tmpNull = lines THEN
25.         PRINT "How should I respond to that?"
26.         INPUT ">> ", res$
27.         OPEN "AIDatabase.txt" FOR APPEND AS #1
28.         WRITE #1, in$
29.         WRITE #1, res$
30.         CLOSE #1
31.  
32.         FOR n = 1 TO lines
33.             line$(n) = ""
34.         NEXT n
35.  
36.         OPEN "AIDatabase.txt" FOR INPUT AS #1
37.         WHILE NOT EOF(1)
38.             lines = lines + 1
39.             INPUT #1, line$(lines)
40.         WEND
41.         CLOSE #1
42.     END IF
43. LOOP

Zep.

Title: Re: Simple Chat Bot
Post by: bplus on December 03, 2018, 03:40:02 pm

Hey nice start, I got bored and added some more powers to the bot.

Code: QB64: [Select]

1. _TITLE "AI Chat Bot Z" ' started by Zeppelin 2018-12-03
2. '2018-12-03 B+ mods fix no file started error,  more efficient coding of new lines
3. ' changed topNull to found to continue to use lines to track last loaded item in line$()
4. ' created function to remove punctuation and lower case all letters, like Eliza
5. ' setup global variables: line$(), lines, the file as CONST
6. ' created sub to show the data file to check wording call either as in$ or res$, for debugging
7. ' create function to read commands from user input in$ or user input res$, for Interpreter stuff like Bill's bot
8. ' so started a commands list and parameters list.
9.  
10. 'global variables start with cap, constants are all cap
11. CONST DATFILE = "AI Chat Data.txt"
12. DIM SHARED Line$(1 TO 1000000) 'need base 1
13. DIM SHARED Lines AS LONG
14.  
15. 'load line$
16. OPEN DATFILE FOR APPEND AS #1 '<<<<<<<<<<<<<<<<<< in case a file is not started yet
17. CLOSE #1
18. OPEN DATFILE FOR INPUT AS #1
19. WHILE NOT EOF(1)
20.     Lines = Lines + 1 ' <<<<<<<<<<<<<<<<<<<<< let lines track last entry in array
21.     INPUT #1, Line$(Lines) ' <<<<<<<<<<<<<<<< here you have lines tracking top line number
22. WEND
23. CLOSE #1
24. PRINT "LOADED " + STR$(Lines) + " ASSETS"
25.  
26. 'load commands
27. DIM SHARED Commands(1 TO 6) AS STRING 'Show is a command, just adjust this as add commands
28. Commands(1) = "show "
29.  
30. 'no paramter
31. Commands(2) = "bye"
32. Commands(3) = "good bye"
33. Commands(4) = "goodbye"
34. Commands(5) = "shutup"
35. Commands(6) = "shut up"
36.  
37. 'load parameters
38. DIM SHARED Parameters(1 TO 5) AS STRING 'Data or Time are Parameters eg Show Time, Show Data...
39. Parameters(1) = " data"
40. Parameters(2) = " time"
41. Parameters(3) = " date"
42. Parameters(4) = " today"
43. Parameters(5) = " commands"
44.  
45. DO
46.     found = 0 'topNull ????
47.     LINE INPUT "Input >> ", in$ '<<<<<<<<<<<<<<<<<<<<<<<<<<< line input allows commas
48.     modIN$ = RemovePunctuation$(in$)
49.     testInterpret = Interpret(modIN$)
50.     IF testInterpret = 0 THEN 'no commands found
51.         'in$ = LCASE$(in$)    '<<<< removePunctuation$ will do this and more
52.  
53.         FOR n = 1 TO Lines STEP 2 'need base 1 array
54.             IF modIN$ = RemovePunctuation$(Line$(n)) THEN
55.                 found = n
56.                 EXIT FOR
57.             END IF
58.         NEXT
59.  
60.         IF found THEN
61.             PRINT Line$(found + 1)
62.         ELSE
63.             'try searching the in$ string for keywords like show or tell
64.  
65.  
66.             'no key words or phrases found  THEN do this
67.             PRINT "How should I respond to that? (Just enter will skip recording a response.)"
68.             LINE INPUT "respond >> ", res$ '<<<<<<<<<<<<<<<<<<<<<<<<<<< line input allows commas
69.             IF res$ <> "" THEN 'sometimes you just don't know a good response
70.                 modRes$ = RemovePunctuation$(res$)
71.                 test = Interpret(modRes$)
72.                 IF test = 0 THEN
73.                     OPEN DATFILE FOR APPEND AS #1
74.                     WRITE #1, in$
75.                     WRITE #1, res$
76.                     CLOSE #1
77.                     ' instead of this VVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVV
78.                     'FOR n = 1 TO lines
79.                     '    line$(n) = ""
80.                     'NEXT n
81.  
82.                     'OPEN "AIDatabase.txt" FOR INPUT AS #1
83.                     'WHILE NOT EOF(1)
84.                     '    lines = lines + 1
85.                     '    INPUT #1, line$(lines)
86.                     'WEND
87.                     'CLOSE #1
88.                     '^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
89.                     'this VVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVVV
90.                     Line$(Lines + 1) = in$
91.                     Line$(Lines + 2) = res$
92.                     Lines = Lines + 2
93.                     '^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
94.                 ELSE 'res$ = ""
95.                     'could offer a menu of options when res$ is blank,   like r for random slection
96.  
97.                 END IF 'res$ <> ""
98.             END IF 'test = 0
99.         END IF 'found a response in line$()
100.     END IF 'testInterpret = 0
101. LOOP
102.  
103. FUNCTION RemovePunctuation$ (s$) 'and return lower case for copmaring Data string with Input string
104.     FOR i = 1 TO LEN(s$)
105.         IF INSTR(".,?!;:", MID$(s$, i, 1)) <= 0 THEN
106.             b$ = b$ + LCASE$(MID$(s$, i, 1))
107.         END IF
108.     NEXT
109.     RemovePunctuation$ = b$
110. END FUNCTION
111.  
112. SUB ShowData 'this is first thing I want to see when debugging the Chat Bot
113.     FOR i = 1 TO Lines STEP 2
114.         PRINT i, Line$(i)
115.         PRINT i + 1, Line$(i + 1)
116.         PRINT
117.         IF i MOD 10 = 0 THEN
118.             PRINT
119.             INPUT "Press enter to continue data display... any other to quit display."; cont$
120.             IF LEN(cont$) THEN EXIT FOR
121.         END IF
122.     NEXT
123.     INPUT "End of Data, Press enter to continue... any other to quit."; cont$
124.     IF LEN(cont$) THEN END
125. END SUB
126.  
127. 'assume removePunctuation has been used on string
128. FUNCTION Interpret% (s$) 'return 1 if found something to do (and did it) else 0 so main code can process it as normal chat
129.     ' commands
130.     Interpret = 1
131.     IF s$ = "bye" OR s$ = "good bye" OR s$ = "goodbye" OR s$ = "shutup" OR s$ = "shut up" THEN
132.         INPUT "Do you wish to end this session? y for yes ", cont$
133.         IF LEFT$(LCASE$(cont$), 1) = "y" THEN END ELSE EXIT FUNCTION
134.     END IF
135.     FOR i = LBOUND(Commands) TO UBOUND(Commands)
136.         IF INSTR(s$, Commands(i)) > 0 THEN
137.             FOR j = LBOUND(Parameters) TO UBOUND(Parameters)
138.                 IF INSTR(s$, Parameters(j)) > 0 THEN
139.                     SELECT CASE Commands(i) + Parameters(j)
140.                         CASE "show  data": ShowData: EXIT FUNCTION
141.                         CASE "show  time", "show  date", "show  today": PRINT DATE$ + " " + TIME$: EXIT FUNCTION
142.                         CASE "show  commands"
143.                             CLS
144.                             FOR k = LBOUND(commands) TO UBOUND(commands)
145.                                 PRINT "Command"; k, Commands(k)
146.                                 lineCount = lineCount + 1
147.                                 IF lineCount MOD 25 = 24 THEN
148.                                     INPUT "Press enter to continue, any other to quit ", cont$
149.                                     IF LEN(cont$) THEN EXIT FUNCTION
150.                                     CLS: lineCount = 0
151.                                 END IF
152.                             NEXT
153.                             FOR k = LBOUND(parameters) TO UBOUND(parameters)
154.                                 PRINT "Parameter"; k, Parameters(k)
155.                                 IF lineCount MOD 25 = 24 THEN
156.                                     INPUT "Press enter to continue, any other to quit ", cont$
157.                                     IF LEN(cont$) THEN EXIT FUNCTION
158.                                     CLS: lineCount = 0
159.                                 END IF
160.                             NEXT
161.                             EXIT FUNCTION
162.                     END SELECT
163.                 END IF
164.             NEXT
165.         END IF
166.     NEXT
167.     Interpret = 0
168. END FUNCTION
169.  
170.  

So now the bot can do things while you are chatting with it.

"How should I respond to that?", might be handy in conversations. ;-))

Title: Re: Simple Chat Bot
Post by: Pete on December 03, 2018, 04:13:25 pm

Well Mark, it's no BotaBing, but it ain't botabad. You know I tried making a chat bot of the wife once, but I kept getting trapped in an endless loop. Sometimes I wonder why I bot-her. Anyway, Nice job! You remind me of the days I put to much energy into the BBQ and had to squirt down the grill with a spay bottle. I imagine you doing that to your keyboard!

Hey I can't get the "show" command to do anything. I thought it would show the asset list. I know it is listed as "show " with a space, but I can't get it to work that way, either.

Pete

Title: Re: Simple Chat Bot
Post by: bplus on December 03, 2018, 05:00:16 pm

You do have to record your own responses to get the data file to have anything to show, and then the command is:
show data

show commands - gives the current list of commands with parameters

show time or date or today will print date and time

bye or goodbye or good bye or shutup or shut up don't use any parameters so all of them are for show.

This is just proof of concept stage, can always add more commands later. I wanted to start with ones to help debug the bot code.

 

Title: Re: Simple Chat Bot
Post by: Pete on December 03, 2018, 05:04:58 pm

Got it now. I was just using "show" bu itself. Ouch! I just typed "Show me yours..." and the damn thing slapped me!

Pete

Title: Re: Simple Chat Bot
Post by: Zeppelin on December 03, 2018, 07:06:22 pm

Very nice addiction B+. Removing punctuation really smart, (don't know why I didn't think to do that). But there is always a recurring problem with every chat bot, it never starts the conversation or talks before you do. Bit of a difficult problem, but if anyone is able to type even a simple prototype I'd love to read it.
:)

Zep

Title: Re: Simple Chat Bot
Post by: bplus on December 03, 2018, 07:10:13 pm

ELIZA would always start:
"Hi, I'm ELIZA. What's your problem?"

(This is where "shut up" to quit a session comes from, not my standard MO.)

;D

Text Only | Text with Attachments