Print Page - QB64 Wiki Keyword Generator

Active Forums => Programs => Topic started by: SMcNeill on November 03, 2018, 06:36:54 am

Title: QB64 Wiki Keyword Generator
Post by: SMcNeill on November 03, 2018, 06:36:54 am

This is a little tool of mine which Dav might like for his IDE (or, for other folks who want to keep a list of keywords in our wiki, for whatever reason.)

Code: QB64: [Select]

CONST SleepSet = 0 'to sleep between each keyword so we can see them and read them
CONST SaveTo = "wiki.txt" '"SCRN:" to display to the screen, or insert a filename to save the list to disk
 
SCREEN _NEWIMAGE(1024, 720, 256)
PRINT "DOWNLOAD STARTING"
file$ = "QB64WikiList.txt"
'Increase the 2-second time limit here if you need to.
DownloadRSS "http://qb64.org/wiki/Keyword_Reference_-_Alphabetical", file$, 2
PRINT "DOWNLOAD FINISHED"
PRINT
 
 
OPEN file$ FOR BINARY AS #1
temp$ = SPACE$(LOF(1))
GET #1, , temp$
CLOSE #1
l = 0
finish$ = "<div id=" + CHR$(34) + "symbols" + CHR$(34) + "></div>"
finish = INSTR(temp$, finish$) 'No need to parse anything after we get down to the symbol section of the wiki page
 
OPEN SaveTo FOR OUTPUT AS #1
 
 
DO
    l = INSTR(l, temp$, "<li>")
    IF l >= finish THEN EXIT DO
    IF l THEN
        l2 = INSTR(l + 5, temp$, "</li>"): IF l2 = 0 THEN l2 = LEN(temp$)
        work$ = MID$(temp$, l + 4, l2 - l - 5)
        li1 = INSTR(work$, CHR$(34)): li2 = INSTR(li1 + 1, work$, CHR$(34))
        link$ = MID$(work$, li1 + 1, li2 - li1 - 1)
        IF INSTR(link$, "&amp") THEN link$ = "Page does not exist yet."
        link$ = StripCRLF(link$)
        k1 = INSTR(li2 + 1, work$, ">"): k2 = INSTR(k1 + 1, work$, "<")
        keyword$ = MID$(work$, k1 + 1, k2 - k1 - 1)
        keyword$ = StripCRLF(keyword$)
        d = INSTR(k2 + 1, work$, "<span"): d1 = INSTR(d + 1, work$, ">"): d2 = INSTR(d1 + 1, work$, "</span")
        desc$ = MID$(work$, d1 + 1, d2 - d1 - 1)
        desc$ = StripCRLF(desc$)
        PRINT #1, keyword$
        PRINT #1, "         http://qb64.org"; link$
        PRINT #1, "         "; desc$
        IF SleepSet THEN SLEEP
        l = l2 + 1
    END IF
LOOP UNTIL l = 0
CLOSE
 
SLEEP
SYSTEM
 
 
SUB DownloadRSS (url$, file$, timelimit)
    link$ = url$
    DIM l AS _INTEGER64, lod AS _INTEGER64
 
    url2$ = RTRIM$(LTRIM$(link$))
    url4$ = RTRIM$(LTRIM$(link$))
    IF LEFT$(UCASE$(url2$), 7) = "HTTP://" THEN url4$ = MID$(url2$, 8)
    x = INSTR(url4$, "/")
    IF x THEN url2$ = LEFT$(url4$, x - 1)
    NewsClient = _OPENCLIENT("TCP/IP:80:" + url2$)
    IF NewsClient = 0 THEN EXIT FUNCTION
    e$ = CHR$(13) + CHR$(10) ' end of line characters
    url3$ = RIGHT$(url4$, LEN(url4$) - x + 1)
    x$ = "GET " + url3$ + " HTTP/1.1" + e$
    x$ = x$ + "Host: " + url2$ + e$ + e$
    PUT #NewsClient, , x$
 
    OPEN file$ FOR OUTPUT AS #1: CLOSE #1
    OPEN file$ FOR BINARY AS #1
 
    t! = TIMER ' start time
    head$ = ""
    cont_type$ = ""
    DO
        _LIMIT 20
        GET #NewsClient, , a$
        IF LTRIM$(a$) > "" THEN PUT #1, , a$
    LOOP UNTIL TIMER > t! + timelimit AND timelimit > 0 ' (in seconds)
    CLOSE #NewsClient
    CLOSE #1
END SUB
 
FUNCTION StripCRLF$ (text$)
    'The wiki seems to contain stray CRLF characters at the dangest spots.
    'Why it has them, I don't know, but we need to filter them out so our information will load and display properly.
    li1 = 0
    DO
        li1 = INSTR(li1 + 1, text$, CHR$(13) + CHR$(10))
        IF li1 THEN
            l$ = LEFT$(text$, li1 - 1)
            r$ = MID$(text$, li1 + 2)
            text$ = l$ + r$
        END IF
    LOOP UNTIL li1 = 0
 
    'Also some of the descriptions and such contain links to different keywords.
    'We want to just strip those links and use a normal word replacement for ease of display, since we're not going to be displaying in
    'an html editor/viewer.
 
    li1 = 0
    DO
        li1 = INSTR(li1 + 1, text$, "<a href")
        IF li1 THEN
            li2 = INSTR(li1 + 1, text$, "</a>")
            li3 = INSTR(li1 + 1, text$, ">")
            l$ = LEFT$(text$, li1 - 1)
            m$ = MID$(text$, li3 + 1, li2 - li3 - 1)
            r$ = MID$(text$, li2 + 4)
            text$ = l$ + m$ + r$
        END IF
    LOOP UNTIL li1 = 0
 
    StripCRLF$ = text$
END FUNCTION
 

Change SleepSet to 0 if you don't want to be bothered with the need to press a key between keywords.
Change SaveTo to a filename (like "wiki.txt") if you want to save the list to an external file on your hard drive.

This gives us 3 pieces of information for each entry in the wiki:

Keyword name.
Link to the wiki page where we can go to get detailed information about that keyword.
And a brief summery of what the keyword does.

Title: Re: QB64 Wiki Keyword Generator
Post by: FellippeHeitor on November 03, 2018, 06:45:24 am

Does it work with no changes with the new wiki? I've had to do some reworking with the IDE's parsing routines for the wiki because we use a newer version of MediaWiki than Galleon had installed and some new formatting/tagging got in the way.

Title: Re: QB64 Wiki Keyword Generator
Post by: SMcNeill on November 03, 2018, 06:56:21 am

Here's a small sample of how it outputs information for us -- as far as I can tell, it processes everything fine, without glitching out anywhere.

Quote

_ACOS
http://qb64.org/wiki/ACOS
arccosine function returns the angle in radians based on an input COSine value range from -1 to 1.
_ACOSH
http://qb64.org/wiki/ACOSH
Returns the nonnegative arc hyperbolic cosine of x, expressed in radians.
_ALPHA
http://qb64.org/wiki/ALPHA
returns the alpha channel transparency level of a color value used on a screen page or image.
_ALPHA32
http://qb64.org/wiki/ALPHA32
returns the alpha channel transparency level of a color value used on a 32 bit screen page or image.
_ARCCOT
http://qb64.org/wiki/Mathematical_Operations
is the inverse function of the cotangent. . <a rel="nofollow" class="external free" href="http://mathworld.wolfram.com/InverseCosecant.html">http://mathworld.wolfram.com/InverseCosecant.html[/url]
_ARCCSC
http://qb64.org/wiki/Mathematical_Operations
is the inverse function of the cosecant. <a rel="nofollow" class="external free" href="http://mathworld.wolfram.com/InverseCosecant.html">http://mathworld.wolfram.com/InverseCosecant.html[/url]
_ARCSEC
http://qb64.org/wiki/Mathematical_Operations
is the inverse function of the secant. <a rel="nofollow" class="external free" href="http://mathworld.wolfram.com/InverseSecant.html">http://mathworld.wolfram.com/InverseSecant.html[/url]
_ASIN
http://qb64.org/wiki/ASIN
Returns the principal value of the arc sine of x, expressed in radians.
_ASINH
http://qb64.org/wiki/ASINH
Returns the arc hyperbolic sine of x, expressed in radians.
_ATAN2
http://qb64.org/wiki/ATAN2
Returns the principal value of the arc tangent of y/x, expressed in radians.
_ATANH
http://qb64.org/wiki/ATANH
Returns the arc hyperbolic tangent of x, expressed in radians.
_AUTODISPLAY
http://qb64.org/wiki/AUTODISPLAY
enables the automatic display of the screen image changes previously disabled by _DISPLAY.
_AUTODISPLAY (function)
http://qb64.org/wiki/AUTODISPLAY_(function)
returns the current display mode as true (-1) if automatic or false (0) if per request using _DISPLAY.
_AXIS
http://qb64.org/wiki/AXIS
returns a SINGLE value between -1 and 1 indicating the maximum distance from the device axis center, 0.

Edit: You were right; it required some changing to the links to each keyword. They're no longer in the "Keyword_Reference_-_Alphabetical" subfolder, as each now falls directly into "http://qb64.org/wiki/".

Changed and links should now be valid again.

Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: SMcNeill on November 03, 2018, 06:36:54 am