Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: SMcNeill on October 19, 2018, 08:27:36 pm

Title: Frame Library
Post by: SMcNeill on October 19, 2018, 08:27:36 pm
Code: QB64: [Select]
  1. '$INCLUDE:'FrameLibrary.BI'
  2.  
  3. CONST FileName$ = "tt.txt"
  4.  
  5.  
  6. REDIM SHARED WordGrid(0, 0) AS STRING * 1
  7. REDIM SHARED YLines(0, 0) AS STRING
  8. REDIM SHARED XLines(0, 0) AS STRING
  9.  
  10. DIM SHARED SearchTerms(1) AS STRING
  11. SearchTerms(0) = "TRICK": SearchTerms(1) = "TREAT"
  12.  
  14.  
  15. DIM SHARED LeftFrame AS INTEGER, RightFrame AS INTEGER
  16.  
  17.  
  18. SCREEN _NEWIMAGE(1280, 720, 32) '720p HD just cause I like it as a standard
  19.  
  20.  
  21. LeftFrame = NewTextArea(0, 0, 400, _HEIGHT - 1, False)
  22. ColorTextArea LeftFrame, _RGB32(255, 255, 255), _RGB32(0, 0, 128)
  23. DrawTextArea LeftFrame
  24.  
  25. RightFrame = NewTextArea(401, 0, _WIDTH - 1, _HEIGHT - 1, False)
  26. ColorTextArea RightFrame, _RGB32(255, 255, 255), _RGB32(0, 0, 0)
  27. DrawTextArea RightFrame
  28.  
  29.  
  30.  
  31. LoadWordGrid
  32. MakeDirectional
  33. ShowGrid
  34. FindWords
  35.  
  36.  
  37.  
  38. SUB FindWords
  39.     FOR j = 0 TO UBOUND(SearchTerms)
  40.         SetPrintStyleX RightFrame, CenterJustify
  41.         SetPrintUpdate RightFrame, NewLine
  42.         SetTextForeground RightFrame, _RGB32(255, 255, 0)
  43.         PrintOut RightFrame, "SEARCHING FOR " + SearchTerms(j)
  44.         SetTextForeground RightFrame, _RGB32(255, 255, 255)
  45.         PrintOut RightFrame, ""
  46.         PrintOut RightFrame, "Finding Left to Right Matches"
  47.         SetPrintStyleX RightFrame, NoJustify
  48.         SetPrintUpdate RightFrame, NoNewLine
  49.  
  50.         FOR i = 1 TO Y
  51.             foundone = 0
  52.             DO
  53.                 foundone = INSTR(foundone + 1, YLines(1, i), SearchTerms(j))
  54.                 IF foundone THEN
  55.                     PrintOut RightFrame, "(Line" + STR$(i) + ", Position" + STR$(foundone) + "), "
  56.                     tc = tc + 1
  57.                 END IF
  58.             LOOP UNTIL NOT foundone
  59.         NEXT
  60.  
  61.         SetPrintStyleX RightFrame, CenterJustify
  62.         SetPrintUpdate RightFrame, NewLine
  63.         PrintOut RightFrame, ""
  64.         PrintOut RightFrame, ""
  65.         PrintOut RightFrame, "Finding Right to Left Matches"
  66.         SetPrintUpdate RightFrame, NoNewLine
  67.         SetPrintStyleX RightFrame, NoJustify
  68.         FOR i = 1 TO Y
  69.             foundone = 0
  70.             DO
  71.                 foundone = INSTR(foundone + 1, YLines(2, i), SearchTerms(j))
  72.                 IF foundone THEN
  73.                     PrintOut RightFrame, "(Line" + STR$(i) + ", Position" + STR$(X - foundone + 1) + "), "
  74.                     tc = tc + 1
  75.                 END IF
  76.             LOOP UNTIL NOT foundone
  77.         NEXT
  78.  
  79.         SetPrintStyleX RightFrame, CenterJustify
  80.         SetPrintUpdate RightFrame, NewLine
  81.         PrintOut RightFrame, ""
  82.         PrintOut RightFrame, ""
  83.         PrintOut RightFrame, "Finding Up to Down Matches"
  84.         SetPrintUpdate RightFrame, NoNewLine
  85.         SetPrintStyleX RightFrame, NoJustify
  86.         FOR i = 1 TO X
  87.             foundone = 0
  88.             DO
  89.                 foundone = INSTR(foundone + 1, XLines(1, i), SearchTerms(j))
  90.                 IF foundone THEN
  91.                     PrintOut RightFrame, "(Line" + STR$(foundone) + ", Position" + STR$(i) + "), "
  92.                     tc = tc + 1
  93.                 END IF
  94.             LOOP UNTIL NOT foundone
  95.         NEXT
  96.  
  97.         SetPrintStyleX RightFrame, CenterJustify
  98.         SetPrintUpdate RightFrame, NewLine
  99.         PrintOut RightFrame, ""
  100.         PrintOut RightFrame, ""
  101.         PrintOut RightFrame, "Finding Down to Up Matches"
  102.         SetPrintUpdate RightFrame, NoNewLine
  103.         SetPrintStyleX RightFrame, NoJustify
  104.         FOR i = 1 TO X
  105.             foundone = 0
  106.             DO
  107.                 foundone = INSTR(foundone + 1, XLines(2, i), SearchTerms(j))
  108.                 IF foundone THEN
  109.                     PrintOut RightFrame, "(Line" + STR$(foundone) + ", Position" + STR$(i) + "), "
  110.                     tc = tc + 1
  111.                 END IF
  112.             LOOP UNTIL NOT foundone
  113.         NEXT
  114.  
  115.  
  116.         SetPrintUpdate RightFrame, NewLine
  117.         PrintOut RightFrame, ""
  118.         PrintOut RightFrame, ""
  119.         PrintOut RightFrame, STR$(tc) + " total matches found."
  120.         PrintOut RightFrame, ""
  121.         PrintOut RightFrame, ""
  122.         tc = 0
  123.     NEXT
  125.  
  126.  
  127.  
  128. SUB ShowGrid
  129.     'Print the words in the grid
  130.     SetTextColor LeftFrame, _RGB32(255, 255, 0), 0
  131.     PrintOut LeftFrame, ""
  132.     PrintOut LeftFrame, "                     WORD GRID"
  133.     PrintOut LeftFrame, ""
  134.     SetTextColor LeftFrame, _RGB32(255, 255, 255), 0
  135.     FOR i = 1 TO Y
  136.         PrintOut LeftFrame, "  " + YLines(1, i)
  137.     NEXT
  139.  
  140.  
  141.  
  142.  
  143. SUB LoadWordGrid
  144.     OPEN FileName$ FOR BINARY AS #1
  145.     DO UNTIL EOF(1)
  146.         LINE INPUT #1, junk$
  147.         Y = Y + 1
  148.     LOOP
  149.     X = LEN(junk$): Y = Y
  150.     SEEK #1, 1
  151.  
  152.     REDIM WordGrid(1 TO X, 1 TO Y) AS STRING * 1 'Properly size our grid, with borders
  153.     REDIM YLines(2, Y) AS STRING
  154.     REDIM XLines(2, X) AS STRING
  155.  
  156.     FOR i = 1 TO Y
  157.         LINE INPUT #1, junk$
  158.         FOR j = 1 TO X
  159.             WordGrid(j, i) = MID$(junk$, j) 'Fill in the grid with the letters
  160.         NEXT
  161.     NEXT
  162.     CLOSE #1
  164.  
  165. SUB MakeDirectional
  166.     FOR i = 1 TO Y
  167.         FOR j = 1 TO X
  168.             YLines(1, i) = YLines(1, i) + WordGrid(j, i) 'Left to Right Lines
  169.     NEXT j, i
  170.     FOR i = 1 TO Y: FOR j = X TO 1 STEP -1
  171.             YLines(2, i) = YLines(2, i) + WordGrid(j, i) 'Right to Left Lines
  172.     NEXT j, i
  173.     FOR i = 1 TO Y: FOR j = 1 TO X
  174.             XLines(1, i) = XLines(1, i) + WordGrid(j, i) 'Up to Down Lines
  175.     NEXT j, i
  176.     FOR i = 1 TO Y: FOR j = X TO 1 STEP -1
  177.             XLines(2, i) = XLines(1, i) + WordGrid(j, i) 'Right to Left Lines
  178.     NEXT j, i
  180.  
  181. '$INCLUDE:'FrameLibrary.BM'
  182.  

Using Bplus's halloween challenge to do a wordsearch from a grid of letters in various directions, I came up with this little demo to highlight the flexibility and ease of use of my little TextFrame Library.

What *IS* the FrameLibrary, you ask??

It's a simple way to designate various areas of the screen to print and interact independently on.  In this case, the left side holds the grid for us, while the right side prints out the results.  If you look at the demo I posted over at the other forums, it has 4 designated frame areas which we can print to.  (HERE: http://qb64.freeforums.net/thread/46/text-frames )

Each of these frames are 100% independent of the others.  You can set them to have various justification levels (left, right, center, no justification) for the text.  You can set whether text prints to a new line when finished, or not.  You can even set if the text frame is visible, or if you want to move it somewhere else onto the screen...

In the example here, we see how easy it is to designate our framed areas:

Code: QB64: [Select]
  1. LeftFrame = NewTextArea(0, 0, 400, _HEIGHT - 1, False)
  2. ColorTextArea LeftFrame, _RGB32(255, 255, 255), _RGB32(0, 0, 128)
  3. DrawTextArea LeftFrame
  4.  
  5. RightFrame = NewTextArea(401, 0, _WIDTH - 1, _HEIGHT - 1, False)
  6. ColorTextArea RightFrame, _RGB32(255, 255, 255), _RGB32(0, 0, 0)
  7. DrawTextArea RightFrame

You can also see where we center our output text, while moving the pointer to a newline afterwards:
Code: QB64: [Select]
  1.         SetPrintStyleX RightFrame, CenterJustify
  2.         SetPrintUpdate RightFrame, NewLine)

And, where we change back to where we don't want to justify our text, or move to a new line after:
Code: QB64: [Select]
  1.         SetPrintStyleX RightFrame, NoJustify
  2.         SetPrintUpdate RightFrame, NoNewLine

Changing the color of the text is rather simple:
Code: QB64: [Select]
  1.         SetTextForeground RightFrame, _RGB32(255, 255, 0)  

And, doing the actual printing is as simple as:
Code: QB64: [Select]
  1.         PrintOut RightFrame, "SEARCHING FOR " + SearchTerms(j)

The library does automatic word-wrap.  Automatic scrolling of a frame, if we print down to the bottom of the frame, just as QB64 does when we print at the bottom lines of the screen...

*******************************
*******************************

Honestly, it's not that complicated to use, once one tries it just a bit.  Most of the commands mimic what we already have in QB64, with just the extra parameter in front for WHICH frame we're using.

PRINT whatever$  --->  PrintOut frame, whatever$
COLOR fg, bg ---> SetTextColor frame, fg, bg
LOCATE x, y ---> SetPrintPosition frame, x, y
and so...

The only exception is when we go to adding NEW, non-native QB64 capabilities:

SetPrintStyleX frame, HOW -->  frame is the same as above, HOW is: LeftJustify, RightJustify, CenterJustify, or NoJustify

In this case, LeftJustify prints our text at the left edge of the frame; RightJustify prints the text starting from the right edge of the frame, CenterJustify centers the text on the line, and NoJustify doesn't do any justification (much like a simple PRINT statement.)

**************************
**************************

Anywho... I thought I'd just share and show off the library a bit.  I don't think many people have even taken a look at this one (much less used it), but I find it to be useful in a TON of things which I do.  Being able to designate and print to multiple sections of the screen, without disturbing the rest of the screen, has always been something which I felt was too difficult to do -- thus, the birth of this.  :D
Title: Re: Frame Library
Post by: TerryRitchie on October 19, 2018, 09:26:20 pm
Awesome! Thanks for sharing :)
Title: Re: Frame Library
Post by: codeguy on October 20, 2018, 01:02:33 am
Nifty.
Title: Re: Frame Library
Post by: SMcNeill on October 20, 2018, 01:31:14 am
Another simple demo to highlight some of the power of the library:

Code: QB64: [Select]
  1. '$INCLUDE:'FrameLibrary.BI'
  2.  
  3.  
  4. SCREEN _NEWIMAGE(640, 480, 32)
  5.  
  6. CIRCLE (320, 240), 200, _RGB32(255, 0, 0)
  7. PAINT (320, 240), _RGB32(255, 0, 0)
  8. LOCATE 15, 35: PRINT "See the circle?"
  9.  
  11. PopUp = NewTextArea(200, 150, 400, 300, True)
  12. ColorTextArea PopUp, _RGB32(255, 255, 255), _RGB32(0, 0, 128)
  13. DrawTextArea PopUp
  14. PrintOut PopUp, "See how we popped up text in the box here, which has now overdrawn our circle?"
  16.  
  17. HideFrame PopUp
  18. LOCATE 2, 2: PRINT "Notice how we preserve the background when we hide/close the frame?"
  19.  
  20.  
  21. '$include:'FrameLibrary.BM'

Needs the library files above to work, so grab them before trying this.

Notice here when I make the frame, the last option is set to TRUE:

Code: QB64: [Select]
  1. PopUp = NewTextArea(200, 150, 400, 300, TRUE)

PopUp is the name which I'm calling my designated text area.  200, 150, 400,300 are the screen coordinates where the frame is created.  The last option (TRUE in this case) is a toggle asking, "Do we want to preserve the background underneath the PopUp?"

Since we said, TRUE, when we hide the PopUp, the background is restored...

** These frames can hide/appear without disturbing existing text which we already have on the screen!
Title: Re: Frame Library
Post by: SMcNeill on October 20, 2018, 01:35:53 am
And to expand with another demo, highlighting a little more flexibility:

Code: QB64: [Select]
  1. '$INCLUDE:'FrameLibrary.BI'
  2.  
  3.  
  4. SCREEN _NEWIMAGE(640, 480, 32)
  5.  
  6. CIRCLE (320, 240), 200, _RGB32(255, 0, 0)
  7. PAINT (320, 240), _RGB32(255, 0, 0)
  8. LOCATE 15, 35: PRINT "See the circle?"
  9.  
  11. PopUp = NewTextArea(200, 150, 400, 300, True)
  12. ColorTextArea PopUp, _RGB32(255, 255, 255), _RGB32(0, 0, 128)
  13. DrawTextArea PopUp
  14. PrintOut PopUp, "See how we popped up text in the box here, which has now overdrawn our circle?"
  16.  
  17. FOR x = 0 TO 100
  18.     _LIMIT 30
  19.     MoveFrame PopUp, 200 - x, 150 - x
  21. LOCATE 2, 2: PRINT "Notice how how even moving the frame doesn't harm the background?"
  22.  
  23.  
  24. '$include:'FrameLibrary.BM'
  25.  

Just like before, hit the space bar a few times and watch as we interact with our background, and pay attention to the simple fact that:

** We can MOVE the frames, and still not disturb the background as we do so!
Title: Re: Frame Library
Post by: SMcNeill on October 20, 2018, 01:43:07 am
Just a demo of the centering technique:
Code: QB64: [Select]
  1. '$INCLUDE:'FrameLibrary.BI'
  2.  
  3.  
  4. SCREEN _NEWIMAGE(640, 480, 32)
  5.  
  6. CIRCLE (320, 240), 200, _RGB32(255, 0, 0)
  7. PAINT (320, 240), _RGB32(255, 0, 0)
  8. LOCATE 15, 35: PRINT "See the circle?"
  9.  
  10.  
  11. PopUp = NewTextArea(200, 150, 400, 300, True)
  12. ColorTextArea PopUp, _RGB32(255, 255, 255), _RGB32(0, 0, 128)
  13. DrawTextArea PopUp
  14. SetPrintStyleX PopUp, CenterJustify
  15. SetTextColor PopUp, -1, 0
  16. PrintOut PopUp, "See how we popped up text in the box here, which has now overdrawn our circle?                AND...                Do you notice how with one command we can center each line automatically??"
  17.  
  19.  
  20.  
  21. '$include:'FrameLibrary.BM'
  22.  

SetPrintStyleX PopUp, CenterJustify --This one line centers all the text which pops out for us, in the frame.  Other options are LeftJustify, RightJustify, NoJustify
Title: Re: Frame Library
Post by: SMcNeill on October 20, 2018, 01:48:13 am
And to showcase another simple option:
Code: QB64: [Select]
  1. '$INCLUDE:'FrameLibrary.BI'
  2.  
  3.  
  4. SCREEN _NEWIMAGE(640, 480, 32)
  5.  
  6. CIRCLE (320, 240), 200, _RGB32(255, 0, 0)
  7. PAINT (320, 240), _RGB32(255, 0, 0)
  8. LOCATE 15, 35: PRINT "See the circle?"
  9.  
  10.  
  11. PopUp = NewTextArea(200, 150, 400, 300, True)
  12. ColorTextArea PopUp, _RGB32(255, 255, 255), _RGB32(0, 0, 128)
  13. DrawTextArea PopUp
  14. SetPrintStyleX PopUp, CenterJustify
  15. SetPrintStyleY PopUp, CenterLine
  16. SetTextColor PopUp, -1, 0
  17. PrintOut PopUp, "Perfectly centered!"
  18.  
  20.  
  21.  
  22. '$include:'FrameLibrary.BM'
  23.  

SetPrintStyleY PopUp, CenterLine  -- Notice that with the single addition of this one line of code, we're now perfectly centering our text inside the box vertically!  Other options here are OnLine, TopLine, BottomLine

OnLine says we print on the line where we left off, doing nothing special.
TopLine says we print from the top line of the frame.
BottomLine  says we print from the bottom line of the frame.

Simple enough!  ;)
Title: Re: Frame Library
Post by: SMcNeill on October 20, 2018, 02:04:51 am
And, one more option available for us:

Code: QB64: [Select]
  1. '$INCLUDE:'FrameLibrary.BI'
  2.  
  3.  
  4. SCREEN _NEWIMAGE(640, 480, 32)
  5.  
  6. CIRCLE (320, 240), 200, _RGB32(255, 0, 0)
  7. PAINT (320, 240), _RGB32(255, 0, 0)
  8. LOCATE 15, 35: PRINT "See the circle?"
  9.  
  10.  
  11. PopUp = NewTextArea(200, 150, 400, 300, True)
  12. ColorTextArea PopUp, _RGB32(255, 255, 255), _RGB32(0, 0, 128)
  13. DrawTextArea PopUp
  14. SetTextColor PopUp, -1, 0
  15.  
  16.  
  17. PrintOut PopUp, "Now, watch as we count to 10, while fiddling with a few settings.  (Press <ANY KEY> to start."
  19. SetPrintUpdate PopUp, NewLine
  20. FOR i = 1 TO 10
  21.     PrintOut PopUp, STR$(i)
  22.     _DELAY .3
  24. PrintOut PopUp, "Did you notice the frame scroll the text as we counted??  Like we'd expect, huh?  Press <ANY KEY> to continue."
  26.  
  27. ClearTextArea PopUp
  28. SetPrintUpdate PopUp, NoNewLine
  29. FOR i = 1 TO 10
  30.     PrintOut PopUp, STR$(i)
  31.     _DELAY .3
  33. PrintOut PopUp, ".....  HEY?!!  What's up??  "
  34. PrintOut PopUp, "These lines aren't automatically printing to a new line?!!"
  36. '$include:'FrameLibrary.BM'
  37.  

What we're focusing on here are two commands in particular:

SetPrintUpdate PopUp, NewLine
SetPrintUpdate PopUp, NoNewLine

Our first command (above), is how we tell the library if we want to PRINT and then move to a new line afterwards, or if we want to stay on the same line, at the same position.  Think of it as the difference between PRINT text$ and PRINT text$; (see that semi-colon?)

ClearTextArea PopUp -- and our second command, which strangely enough, Clears the Text Area we specify.  NOTE:  This doesn't change our text printing position; it simply clears the frame for us.  To change the print position we use the almost-LOCATE command:  SetPrintPosition.
Title: Re: Frame Library
Post by: johnno56 on October 20, 2018, 02:13:45 am
Brilliant demos!  Cool....

:)
Title: Re: Frame Library
Post by: Petr on October 20, 2018, 03:32:53 am
Thank you for sharing this library. Wonderful is also the ability to share text fields in this way (as PopUp in your program) . That's what I'm using in the latest program I'm doing. But I have a lot of work ahead of me.
Title: Re: Frame Library
Post by: Qwerkey on October 20, 2018, 05:55:50 am
Steve, marvellous as ever.  We expect nothing less.

Quote from: SMcNeill on October 20, 2018, 01:31:14 am

Since we said, TRUE, when we hide the PopUp, the background is restored...

** These frames can hide/appear without disturbing existing text which we already have on the screen!

How does the computer know how to restore the background image when the frame is removed?  As I understand software images (I use the word "understand" without justification!), each time that a PRINT statement (or other graphics method) is used, the computer retains that image.  So when the frame is removed, you have to 'overwrite' it with the background (in your demo, this is the red circle - the CIRCLE and PAINT statements are used only once).  One of these days, Fellippe will place a ban on demonstrably stupid members (I'm in that sub-set)!  Richard
Title: Re: Frame Library
Post by: Dav on October 20, 2018, 06:23:16 am
Cool Library!  Thanks for sharing.

- Dav
Title: Re: Frame Library
Post by: STxAxTIC on October 20, 2018, 07:42:43 am
Fun!

I'm sure the next edition will be able handle instances of CHR$(13) inside the printed text. As of now it shows up as a musical note and doesn't break the line. Specifically I tried this:

Code: QB64: [Select]
  1. PrintOut PopUp, "Perfectly center dsfadsfsdfdsfdfsdfd fdf dasf dsafdf dsf df" + CHR$(13) + "ed!"

EDIT (5 minutes later)

Ah, I see this issue can be hacked around by calling PrintOut more than once as the next demo does:
Code: QB64: [Select]
  1. FOR i = 1 TO 10
  2.     PrintOut PopUp, STR$(i)
  3.     _DELAY .3

Title: Re: Frame Library
Post by: SMcNeill on October 20, 2018, 12:43:29 pm
Quote from: STxAxTIC on October 20, 2018, 07:42:43 am
Fun!

I'm sure the next edition will be able handle instances of CHR$(13) inside the printed text. As of now it shows up as a musical note and doesn't break the line. Specifically I tried this:

Code: QB64: [Select]
  1. PrintOut PopUp, "Perfectly center dsfadsfsdfdsfdfsdfd fdf dasf dsafdf dsf df" + CHR$(13) + "ed!"

EDIT (5 minutes later)

Ah, I see this issue can be hacked around by calling PrintOut more than once as the next demo does:
Code: QB64: [Select]
  1. FOR i = 1 TO 10
  2.     PrintOut PopUp, STR$(i)
  3.     _DELAY .3

Aye.  I'd considered fixing it so CHR$(13) worked as a new line, but then decided against it.  What if you simply meant to print the little musical icon instead?  I figured this was something best handled by the user/program and not by library itself.

Easy solution though:  Write a SUB to handle the process for you, in your program.

SUB MultiPrintOut (frame, what$)
IF INSTR(what$, CHR$(13)) THEN
    PrintOut frame, LEFT$(what$, INSTR(what$, CHR$(13))
    SetPrintUpdate frame, NewLine 'Set the option to print to a new line
    PrintOut frame, "" 'Print that Linebreak
    SetPrintUpdate frame, NoNewLine 'Restore back to single line printing
    MultiPrintOut frame, MID$(what$, INSTR(what$, CHR$(13)+1)
ELSE
    PrintOut frame, what$
END IF
END SUB
Title: Re: Frame Library
Post by: SMcNeill on October 20, 2018, 01:01:19 pm
Quote from: Qwerkey on October 20, 2018, 05:55:50 am
Steve, marvellous as ever.  We expect nothing less.

Quote from: SMcNeill on October 20, 2018, 01:31:14 am

Since we said, TRUE, when we hide the PopUp, the background is restored...

** These frames can hide/appear without disturbing existing text which we already have on the screen!

How does the computer know how to restore the background image when the frame is removed?  As I understand software images (I use the word "understand" without justification!), each time that a PRINT statement (or other graphics method) is used, the computer retains that image.  So when the frame is removed, you have to 'overwrite' it with the background (in your demo, this is the red circle - the CIRCLE and PAINT statements are used only once).  One of these days, Fellippe will place a ban on demonstrably stupid members (I'm in that sub-set)!  Richard


Here's the trick, explained using strings, to make it easy to see.

Normally, if we replace the middle part of a string, we have no way to revert it back, afterwards.  For example:

a$ = "12345"
MID$(a$, 2) = "ABC"

IF we print a$, it now prints "1ABC5" -- and this is basically how drawing on the screen works.  Draw something and it just overwrites what was already there, replacing it forever, with no way to undo that.

So, how would we undo the process??

We intercept with a back up of what we're overwriting:

a$ = "12345"
temp$ = MID$(a$, 2, 3) 'store the "234"
MID$(a$, 2) = "ABC" 'do our replacement as we wanted before

.....  And, when we want to restore the original:
MID$(a$, 2) = temp$

*********************

And it's the exact same process with graphics.

Start with the old screen.
Take a screen grab of the section we want to write to with _NEWIMAGE and _PUTIMAGE.
Write to the section we want to.

....and, when done, use _Putimage to restore the image we saved! Then _FREEIMAGE that temp image.

**********************

And, this is the process the library does for us, all behind the scenes, of course.  ;)
Title: Re: Frame Library
Post by: Qwerkey on October 21, 2018, 05:00:50 am
Quote from: SMcNeill on October 20, 2018, 01:01:19 pm

Start with the old screen.
Take a screen grab of the section we want to write to with _NEWIMAGE and _PUTIMAGE.
Write to the section we want to.

....and, when done, use _Putimage to restore the image we saved! Then _FREEIMAGE that temp image.

**********************

And, this is the process the library does for us, all behind the scenes, of course.  ;)

That's what I imagined that you were doing (how else could it be done?), but I couldn't find a _SCREENIMAGE statement anywhere - and then take the relevant part of that image.  You must be doing it another way.
Title: Re: Frame Library
Post by: Petr on October 21, 2018, 05:28:10 am
Hi Qwerkey.

_SCREENIMAGE is of course not used. It uses NEWIMAGE by the area it wants to store, and then restores this backed area again via PUTIMAGE. It's the same way as when you copy only one area of  photo to a different screen. I think this is done by lines 81, 82, 83 and 84 in FrameLibrary.bm
Title: Re: Frame Library
Post by: Qwerkey on October 21, 2018, 06:47:55 am
Petr, I also found those lines in the Library.  When looking to see if the background was copied, I had first looked for _SCREENIMAGE, assuming that the background was already on screen.  But Steve uses the background image direct - wooly thinking on my part!
Title: Re: Frame Library
Post by: Petr on October 21, 2018, 07:05:40 am
Sorry. I look in it again, so Image is saved to array in line 348, 349  and copyed back before next print in line 371 is background restore from this array to screen.
Title: Re: Frame Library
Post by: SMcNeill on October 21, 2018, 12:07:45 pm
Library files updated to offer us one more option which we didn't have before:  FONTS.  (As long as they're monospaced fonts.  The word-wrap routine would need some work to play nice with non-monospaced fonts, and that's a chore for another day, as I found bigger fish to fry ATM.  :P

A demo of setting different monospaced fonts is below:

Code: QB64: [Select]
  1. '$INCLUDE:'FrameLibrary.BI'
  2.  
  3. Cyberbit = _LOADFONT("cyberbit.ttf", 24, "MONOSPACE")
  4.  
  5. SCREEN _NEWIMAGE(640, 480, 32)
  6.  
  7. CIRCLE (320, 240), 200, _RGB32(255, 0, 0)
  8. PAINT (320, 240), _RGB32(255, 0, 0)
  9. LOCATE 15, 35: PRINT "See the circle?"
  10.  
  12.  
  13. PopUp = NewTextArea(200, 150, 400, 300, True)
  14. ColorTextArea PopUp, _RGB32(255, 255, 255), _RGB32(0, 0, 128)
  15. DrawTextArea PopUp
  16. SetFont PopUp, 8
  17. PrintOut PopUp, "See how we popped up text in the box here, which has now overdrawn our circle?"
  18.  
  19.  
  20. BottomFrame = NewTextArea(0, 400, 639, 479, True)
  21. ColorTextArea BottomFrame, _RGB32(255, 255, 255), _RGB32(0, 0, 128)
  22. DrawTextArea BottomFrame
  23. SetFont BottomFrame, Cyberbit
  24. PrintOut BottomFrame, "Testing a different font."
  25.  
  26.  
  28.  
  29. HideFrame PopUp
  30. LOCATE 2, 2: PRINT "Notice how we preserve the background when we hide/close the frame?"
  31.  
  32.  
  33. '$INCLUDE:'FrameLibrary.BM'

(New Library files replaced the old ones at the bottom of the first post so that folks who grab the files there will always have the newest version available.)
Title: Re: Frame Library
Post by: TempodiBasic on October 21, 2018, 04:10:49 pm
Hi Steve
great tool this frame library !!!
Please adjourn the files that you have appended!
Using these files I got different error, while getting those from this link (HERE: http://qb64.freeforums.net/thread/46/text-frames ) (http://(HERE: http://qb64.freeforums.net/thread/46/text-frames )) they run fine. 
With the files that you have posted at the beginning of the thread I have got some trouble that I want to share with screenshots.

Thanks to read
Title: Re: Frame Library
Post by: SMcNeill on October 21, 2018, 08:55:47 pm
Aye.  It's as you noticed; I changed the routine name a little to make it less confusing.

SetPrintPoistionX became SetPrintStyleX, while SetPrintPositionY became SetPrintStyleY. 

SetPrintPosition works as a LOCATE for us, and I felt that SetPrintPositionX/Y was just asking for folks to get confused.  We aren't actually changing the X/Y coordinates, as much as we're changing the style of how we interact with those coordinates.

I was going to fix those demos to match, but noticed that the precompiler did weird things for us (as I described here: https://www.qb64.org/forum/index.php?topic=720.0 ), and since it's my little baby that I hijacked into QB64, I thought I'd drop everything and get right on it.  Others might not use $IF or $LET very often, but I find them invaluable tools for my work, so I certainly want them to work properly.

Good news though:  The precompiler has been fixed and its capabilities have even been expanded!!

Now, we can bypass the CONST issue I was talking about earlier with libraries by:

Code: QB64: [Select]
  1. $IF TRUEFALSE = UNDEFINED THEN
  2.     CONST TRUE = -1, FALSE = 0
  3.     $LET TRUEFALSE = TRUE

Appear once in a set of code and it executes, setting the CONST values.  Appear another 50 times, and all those are excluded from operation.  It's a good way around the library issue, and simply just adds more power/flexibility for people when writing their code.

***********************

I'll fix the examples later tonight, or tomorrow, to reflect the name change in the Subs.  Honestly, I didn't think anyone would notice the difference that fast!  You've got sharp eyes and the heart of a beta-tester!  Many thanks for trying everything out so diligently, Tempodibasic!  ;D
Title: Re: Frame Library
Post by: SMcNeill on October 21, 2018, 10:47:37 pm
Demos corrected; they should all now run with the new library, which took a little tweaking to correct a bug introduced with the addition of Font ability.  (Frames didn't start with a default font, so unless you manually set one, they crapped out -- that's been fixed now.)

FrameLibrary.BM has been corrected and updated under the first post.  If you're going to use this library, grab the latest version of it and simply overwrite the old version.  FrameLibrary.BI hasn't changed since the second update, so if you've grabbed it already, you don't need to worry about replacing it.

Just a reminder:  If you don't get the latest FrameLibrary.BM, the demos aren't going to work, and you'll need to manually set a font for any frame which you want to print to, as I overlooked adding a default to the original upgrade.  :)
Text Only | Text with Attachments