QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: TempodiBasic on October 13, 2018, 08:50:58 am

Title: 15 days for Halloween code challenge
Post by: TempodiBasic on October 13, 2018, 08:50:58 am

Hi
 beautyful and active QB64 community
what do you think about a 15 days challange to code something about Halloween recurrence?
each coder can choose among
 an animation,
an one level game (like tetris or google's Trex),
a story in game mode,
a point and shooting,
an educational in theme (math with monsters, potions in alchemy, dictate halloween words)

No allowed mods of another coder's program! In the while the same idea can be coded in a way very far from those already posted.

Good thinking

I wait for feedback.

Title: Re: 15 days for Halloween code challenge
Post by: Petr on October 13, 2018, 01:34:53 pm

Hi TempodiBasic,

Animation, you say? Well, I have a very primitive editor for black and white animation .... so when it's time .... but I'm such a so great graphic, that others end up with a onrush of laughter under the table ...

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 14, 2018, 04:29:59 pm

Hi Petr
Thank dor your feedback
I think that black and white can be a good point to start for Halloween animation, don't you?

Title: Re: 15 days for Halloween code challenge
Post by: Pete on October 15, 2018, 12:49:33 am

Here is my SCREEN 0 ghost animation.

Code: QB64: [Select]

1. SLEEP

I dare anyone to optimize it!

OK, Here's a bat...

Code: QB64: [Select]

1. a$ = "^^0^^"
2. b$ = "VV0VV"
3.  
4. FOR i = 25 TO 1 STEP -1
5.     LOCATE i, 38
6.     PRINT a$;
7.     _DELAY .2
8.     LOCATE , 38: PRINT b$;
9.     _DELAY .1
10.     LOCATE , 38: PRINT SPACE$(5)
11. NEXT

Pete :D

I'm not only a QB Forum owner, I'm also a client!

Title: Re: 15 days for Halloween code challenge
Post by: bplus on October 15, 2018, 11:45:00 am

Here's a few more bats, probably need Windows for sound.

Title: Re: 15 days for Halloween code challenge
Post by: johnno56 on October 15, 2018, 04:02:58 pm

Pete,

It may not be the most efficient method, but it does the same thing, and a few bytes less...

a$ = "^^0^^"
b$ = "VV0VV"

FOR i = 25 TO 1 STEP -1
    LOCATE i, 38
    PRINT a$;
    _DELAY .2
    LOCATE , 38: PRINT b$;
    _DELAY .1
   CLS
NEXT

Title: Re: 15 days for Halloween code challenge
Post by: johnno56 on October 15, 2018, 04:18:07 pm

bplus,

The flight path of those bats look oddly familiar... I cannot quite put my finger on it... Never the less, still a great effect...
I tried to convert the 'wav' to 'ogg' but still no sound... Oh well... Still 'looks' good...

J

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 15, 2018, 05:03:03 pm

Hi Guys
here the screenshot of the first two challanger

Pete

 [ This attachment cannot be displayed inline in 'Print Page' view ]  

Bplus

 [ This attachment cannot be displayed inline in 'Print Page' view ]  

Waiting other challengers I thank Pete and Bplus.

As soon as I'll post my code....
yesterday I have been in war with CONST and _RGB so I cannot finish my little idea.

Title: Re: 15 days for Halloween code challenge
Post by: Pete on October 15, 2018, 07:50:33 pm

I think we should end the contest now, while BPlus has a lock on second place!

Title: Re: 15 days for Halloween code challenge
Post by: bplus on October 16, 2018, 03:44:11 pm

OK while we are waiting for TempodiBasic and others to finish their Halloween treats here is a puzzle. Count the number of times BAT appears in this Word Search, remember 8 directions to check...

Code: QB64: [Select]

1. ABBBBBATBTAABTABTBBB
2. TTTTAATATTTBTATABTAA
3. BBAATTTBBTTAABBAAATT
4. AATBAAAABTTBATBABAAT
5. ABATTBATBTTTATTTTBTT
6. BBTBATABTAAAAATTTTBA
7. BBBATBAABTTTTBBBBABA
8. TABABTTTABAATABTATBT
9. TABBTTBBBBTATBTTTTBT
10. TBAABTBBTAABBTTTAATT
11. BAABBTTTAAABTBATBATA
12. ATBBBABAABTBABTABTBB
13. TTTTAABAAAAATTATBBBA
14. TABTBAABABBABBAABBAA
15. TBATTABABTTTATATTTBT
16. BTBTTTTTBBBATTABAABB
17. BBBTAABTBBATTAATAABT
18. TTATBATTATBATATBBABT
19. TTTBBBBBTBTATABTTBBA
20. TBABBAATATTABTBATBBA
21.  

Title: Re: 15 days for Halloween code challenge
Post by: bplus on October 16, 2018, 08:35:07 pm

Here's what I found in my Halloween bag:

Code: QB64: [Select]

1. KTIREKITRATECCCRTIAKIRTTTTRRAR
2. CTKRAAKCAIERIECITCRTTCTRKRITCT
3. TTCARTTACIKKIKTRERETIKCTCICRER
4. ERRTTATTTCTCTKIETAITTRKKCIECET
5. AIEATREAIRRIRITRTTTTAKTIEREKTR
6. ATTRATIECTREATTITARETRICKTIATI
7. TTTRERTRTIRTRICKCAEKRITITTKARR
8. TRRIRRETTTRICKTATEAITCCETARTIC
9. RIATTERTKARATTTIRTATRTCRCRTKRE
10. TETCATRTAETREATKTRICKKTREATRCI
11. KTRRTRTCTETRTEKAATCTCIECTRKTCT
12. TKKTTEIRAITTIEERERRITCCTTRRERR
13. CATATRICKKCTKTETIRRTERTKTRCRTA
14. TTTERCATTTKTITRKTAERTEERRTAERE
15. RCIAKERRATARKRRRRCCTCRTIRTETKK
16. TTRACRRCRCTEIRATCCREETRKTKTCRR
17. EEIRITKTCTCARCRTTTKTITTTIRRRCK
18. IIEETKETEARTTATRTRTRTRECTETEET
19. ITREIREETACETECAITKIRKTKTKARTR
20. CRRRTTIRITERTIRERRKATTCTRIRKAR
21.  

Use your Word Search code to see how many TRICKs and how many TREATs, I have.

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 17, 2018, 05:20:57 am

Hi boys and girls
I remember to QB64's community that it lasts 13 days to the end of posting....

Good Coding

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 21, 2018, 02:20:30 pm

Quote

Hi boys and girls
I remember to QB64's community that

it lasts ten days to the end of challenge of Halloween

Post your code!

Title: Re: 15 days for Halloween code challenge
Post by: bplus on October 21, 2018, 05:18:22 pm

Hi TempodiBasic,

How is your's coming along?

Title: Re: 15 days for Halloween code challenge
Post by: SMcNeill on October 23, 2018, 05:19:54 pm

It's been a while since I got serious and decided to play around and make a game, so I thought I'd take it upon myself to give this challenge a try. 

Here's what I have so far.  Though it's nothing but the main intro screen, I think it shows a bit of the theme that I'm shooting for, for this little game.

At this point, I'm uncertain if I want to simply make it an enhanced-SCREEN 0 game, or if I want to go ahead and find a nice couple of sprite sets and plug them in to make it more of a graphical game.  I'm thinking with only about a week let to go, I'm just going to make a little screen 0 game and not worry so much about the graphics.

What I'm thinking at this moment is to make it a cross between pac-man and rogue.   Using set mazes and monsters, let the character try to find his way to the exit of the mazes, while trying to gather armor, weapons, money, and -- of course -- not get eat by the monsters.

Mazes will start out simple and steadily increase in difficultly and puzzles as we proceed through them.

Nothing too serious; I just thought I'd have a little fun with this for a bit.  Feel free to steal some/part/all of this if it's of any use in your own projects in the future. 

Game files here (7z archive): https://www.dropbox.com/s/og5ukisj6h8vv3h/Hallowmaze.7z?dl=0

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 24, 2018, 06:18:56 pm

@Steve
I have take a look and it is very interesting and cool.
I'm waiting for development....

It lasts 6 days....

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 28, 2018, 08:14:11 am

Hi Guys
I hope that you are using the lasting time to upset your creations....
and I am doing so.

I remember that it lasts only 4 days to post your contribute...

Good Coding waiting Halloween's results

Title: Re: 15 days for Halloween code challenge
Post by: SMcNeill on October 28, 2018, 10:24:42 am

Quote from: TempodiBasic on October 28, 2018, 08:14:11 am

Hi Guys
I hope that you are using the lasting time to upset your creations....
and I am doing so.

I remember that it lasts only 4 days to post your contribute...

Good Coding waiting Halloween's results

My project got postponed a bit.  The last couple of days haven't given me any time for doing much serious coding as I've been too busy trying to devirus the wife's computer.  Let me tell ya: she's got a talent for finding them!!

At this point, I'm thinking the only sensible thing to do is boot to a fresh Linux system, via CD or USB, then dig and search for her documents and pictures which she wants to save, and copy them to a quarantined drive, before finally fdisking and blanking the whole damn drive and then reinstalling Windows for her.

I dunno how she did it, but Windows is partitioned on a separate drive from her data files (D:\ instead of C:\), and yet she's managed to get BOTH drives infected with 2418 different versions of spyware, adware, malware, viruses, trojans, and keyloggers! 

The woman has a God-given talent, I'm telling ya!!

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 28, 2018, 11:31:14 am

Hi Steve
just to give a preview of your project

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 31, 2018, 04:52:09 pm

Last day to post your ideas and results about Halloween challenge...
see later!

Good Type Type Typing Code
:-)

Title: Re: 15 days for Halloween code challenge
Post by: FellippeHeitor on October 31, 2018, 04:52:55 pm

I apologize for not taking part in the challenge, Tempodi. Too much in my hands these days.

I hope more people submit entries! There's till midnight!

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 31, 2018, 05:05:28 pm

Also I am typing because yesterday  I got into a fight with alphatrasparency image. I am not a great graphic operator (I use LodePaint or GIMP 2). Now I just fight with _limit and flickering :-)
But at the end I think to win these issues!

Title: Re: 15 days for Halloween code challenge
Post by: Pete on October 31, 2018, 05:10:35 pm

@ Fell's reply: And by too much on his hands he means diapers. Don't worry Fell, potty training solves that, it just takes 1+ years.

That bat is all I've coded in the past couple of months. I've been up to a lot of political stuff with the mid-term elections here. That's hardly a hobby. It feels more like a fight to keep a decent life for family and their future. Still, I have not regained the interest in programming I used to have. I still have some projects of interest that are more business related, which I may take up next year. Until then, I'm afraid "bats" all for now.

Pete

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 31, 2018, 05:22:28 pm

Hi Pete
I'm sorry but a virus has modified your code....

Code: QB64: [Select]

1. SCREEN 0
2. RANDOMIZE TIMER
3. 'background
4. COLOR 14
5. CLS , 1
6. RESTORE moon
7. FOR a = 1 TO 13
8.     FOR b = 1 TO 15
9.         READ c
10.         IF c = 1 THEN
11.             LOCATE 6 + a, 10 + b
12.             PRINT CHR$ (64)
13.         END IF
14.     NEXT
15. NEXT
16. COLOR 6, 6
17. LOCATE 25, 1
18. PRINT SPACE$(80);
19. PCOPY 0, 1
20.  
21. a$ = "^^0^^"
22. b$ = "VV0VV"
23.  
24. FOR i = 25 TO 1 STEP -1
25.     IF i = 2 THEN i = 25
26.     IF i = 25 THEN col = INT(RND * 75) + 1
27.     PCOPY 1, 0
28.     COLOR 15, 1
29.     LOCATE 22, i: PRINT " Ü ";
30.     LOCATE 23, i: PRINT "ÛìÛ";
31.     LOCATE 24, i: PRINT "ÛÛÛ";
32.     COLOR 7, 1
33.     LOCATE i, col
34.     PRINT a$;
35.     _DELAY .2
36.     LOCATE , col: PRINT b$;
37.     _DELAY .1
38.     COLOR 15, 1
39.     LOCATE 22, i: PRINT "   ";
40.     LOCATE 23, i: PRINT "   ";
41.     LOCATE 24, i: PRINT "   ";
42.     COLOR 7, 1
43.  
44.     LOCATE , col: PRINT SPACE$(5)
45.  
46. NEXT
47. 'matrix 15x13 for moon
48. moon:
49. DATA 0,0,0,0,1,1,1,1,1,1,1,1,1,0,0
50. DATA 0,0,0,1,1,1,1,1,1,1,1,1,1,1,0
51. DATA 0,0,1,1,1,1,1,1,1,1,0,0,1,1,0
52. DATA 0,0,1,1,1,1,1,1,1,0,0,0,1,1,1
53. DATA 0,1,1,1,1,1,1,0,0,0,0,0,0,1,1
54. DATA 1,1,1,1,1,1,1,0,0,0,0,0,0,0,0
55. DATA 1,1,1,1,1,1,0,0,0,0,0,0,0,0,0
56. DATA 0,1,1,1,1,1,0,0,0,0,0,0,0,0,0
57. DATA 0,0,1,1,1,1,1,0,0,0,0,0,0,0,0
58. DATA 0,0,1,1,1,1,1,1,0,0,0,0,0,0,0
59. DATA 0,0,0,1,1,1,1,1,1,0,0,0,0,1,1
60. DATA 0,0,0,0,1,1,1,1,1,1,1,1,1,1,0
61. DATA 0,0,0,0,0,1,1,1,1,1,1,1,1,0,0
62.  

and I got this screenshot attached

I'm sorry, it seems that AVAST do not avast  (in my local dialect avast = it is not enough) !

Title: Re: 15 days for Halloween code challenge
Post by: SMcNeill on October 31, 2018, 05:25:24 pm

I'm just a guy easily distracted by other........   LOOK!  BOOBIES!!!

... Now, wait a moment...  Where was I?  OH, right!  I was saying I was easy distrac...

DID YOU SEE THAT CAT VIDEO??  No??  Well, nevermind.  What was I talking about?  Oh yeah!  My QBDbas...

Sorry.  I had to let the dog go pee...

But, as I was saying, "Have you seen the changes to CONST?  Or the bug fixes I was wooooorrr.....

BOOBIES!!  AGAIN!!

You know, I wouldn't have these issues if my wife wouldn't walk around topless half the tiiiiiimmmmeee.....

HI honey!  You know, I just love it when you lean over my shoulder and look at what I'm typing, while you're dressed like thaaaa....

....umm.....ummm..... 

Sorry guys.  I gotta go.  The wife needs my help in the bedroom for a while..  We can talk about ....  whatever it was....

Later.

Title: Re: 15 days for Halloween code challenge
Post by: Pete on October 31, 2018, 05:40:04 pm

Quote

Sorry guys.  I gotta go.  The wife needs my help in the bedroom for a while..  We can talk about ....  whatever it was....

Later.

Yeah, she needs you to go on a battery run!

Title: Re: 15 days for Halloween code challenge
Post by: STxAxTIC on October 31, 2018, 05:44:49 pm

Hahaha, this why I love Pete... always beats me to the zing and with a better one no less...

Title: Re: 15 days for Halloween code challenge
Post by: bplus on October 31, 2018, 05:48:52 pm

Oh rats! another mod from Bplus:

Code: QB64: [Select]

1. _TITLE "Fake sphere mapping mod 2  2018-10-31 B+"
2.  
3. CONST WW = 800
4. CONST WH = 600
5. SCREEN _NEWIMAGE(WW, WH, 32)
6.  
7. map& = _NEWIMAGE(WW, WH, 32)
8. _DEST map&
9. LINE (0, 0)-(WW, WH), _RGB32(200, 100, 0), BF
10. FOR i = 0 TO WW STEP WW / 12
11.     LINE (i, 0)-(i + 1, WH), _RGB32(0, 0, 0), BF
12. NEXT
13.  
14. k~& = _RGB32(255, 255, 0)
15. ftri map&, WW / 2 - 100, WH / 3, WW / 2 - 100 - 25, WH / 3 + 50, WW / 2 - 100 + 25, WH / 3 + 50, k~&
16. ftri map&, WW / 2 + 100, WH / 3, WW / 2 + 100 - 25, WH / 3 + 50, WW / 2 + 100 + 25, WH / 3 + 50, k~&
17. ftri map&, WW / 2 - 25, WH / 3 + 100, WW / 2, WH / 3 + 150, WW / 2 + 25, WH / 3 + 100, k~&
18.  
19. ftri map&, WW / 2 - 50, WH / 3 + 125, WW / 2 - 55, WH / 3 + 130, WW / 2 - 200, WH / 3 + 80, k~&
20. ftri map&, WW / 2 + 50, WH / 3 + 125, WW / 2 + 55, WH / 3 + 130, WW / 2 + 200, WH / 3 + 80, k~&
21.  
22. ftri map&, WW / 2 - 60, WH / 3 + 140, WW / 2 - 60, WH / 3 + 145, WW / 2 - 220, WH / 3 + 140, k~&
23. ftri map&, WW / 2 + 60, WH / 3 + 140, WW / 2 + 60, WH / 3 + 145, WW / 2 + 220, WH / 3 + 140, k~&
24.  
25. ftri map&, WW / 2 - 60, WH / 3 + 160, WW / 2 - 55, WH / 3 + 165, WW / 2 - 220, WH / 3 + 210, k~&
26. ftri map&, WW / 2 + 60, WH / 3 + 160, WW / 2 + 55, WH / 3 + 165, WW / 2 + 220, WH / 3 + 210, k~&
27.  
28. _DEST 0
29. _PUTIMAGE , map&
30.  
31. r = WH / 3
32. xc = WW / 2
33. yc = WH / 2
34. xo = 0
35. COLOR , _RGB32(40, 0, 68)
36. DO
37.     CLS
38.     FOR y = -r TO r
39.         x1 = SQR(r * r - y * y)
40.         tv = (_ASIN(y / r) + 1.5) / 3
41.         FOR x = -x1 + 1 TO x1
42.             tu = (_ASIN(x / x1) + 1.5) / 6
43.             _SOURCE map&
44.             pc~& = POINT((xo + tu * WW) MOD WW, tv * WH)
45.             _DEST 0
46.             PSET (x + xc, y + yc), pc~&
47.         NEXT x
48.     NEXT y
49.     xo = xo + 1
50.     xo = xo MOD WW
51.     _DISPLAY
52.     _LIMIT 60
53. LOOP
54.  
55. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
56. SUB ftri (d&, x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
57.     a& = _NEWIMAGE(1, 1, 32)
58.     _DEST a&
59.     PSET (0, 0), K
60.     _DEST d&
61.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
62.     _FREEIMAGE a& '<<< this is important!
63. END SUB
64.  
65.  

Title: Re: 15 days for Halloween code challenge
Post by: Pete on October 31, 2018, 06:22:06 pm

Quote from: STxAxTIC on October 31, 2018, 05:44:49 pm

Hahaha, this why I love Pete... always beats me to the zing and with a better one no less...

Thanks, but jokes like these have had some people considering me to be a misogynist, which is weird, because I have spent a lot of money in my adult life on battered women. They're just better deep fried. I mean who wouldn't prefer a well-"bread" woman over a boneless one, anyway?

@BPlus - Nice basketball, but why does it have a cat's face on it?

Title: Re: 15 days for Halloween code challenge
Post by: bplus on October 31, 2018, 07:25:06 pm

Some bats ate all the pumpkins.

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 31, 2018, 08:16:15 pm

Hi Guys  here my code
be patient downloading ZIP.

Your goal is to give sweet to not get the treat (spider)

Code: QB64: [Select]

1. 'Music downloaded from  [No Copyright Music] Halloween - (Royalty Free Halloween Music)
2. ' Images taken from Images downloaded from www.freepik.com
3. '
4. OPTION _EXPLICIT
5. SCREEN _NEWIMAGE(800, 600, 32)
6. _TITLE "Halloween Challenge"
7. _SCREENMOVE 200, 20
8.  
9. DIM a AS LONG, b AS LONG, c AS LONG, d AS LONG, e(1 TO 9) AS LONG, f AS LONG, f2 AS LONG, g AS INTEGER
10. DIM RightGo AS _BYTE, LeftGo AS _BYTE, FireActive AS _BYTE, ChangeMusic AS _BYTE, OffMusic AS _BYTE
11. DIM Xpump(1 TO 9) AS INTEGER, Ypump(1 TO 9) AS INTEGER, xShip AS INTEGER, xFire AS INTEGER, yFire AS INTEGER
12. DIM Fpump(1 TO 9) AS _BYTE, Lpump(1 TO 9) AS INTEGER, FireActiveP AS _BYTE, xFireP(1 TO 9) AS INTEGER, yFireP(1 TO 9) AS INTEGER
13. DIM VelP AS INTEGER, GoDown AS _BYTE, path AS STRING, files$, cmd AS INTEGER, GameOver AS INTEGER
14. DIM j AS INTEGER, k AS INTEGER, h AS INTEGER, i AS INTEGER, l AS INTEGER, m AS LONG
15. DIM SHARED mus(1 TO 4) AS LONG, snd(1 TO 4) AS LONG, ActualMus AS LONG, IndexMus AS INTEGER
16.  
17. CONST RedBack = _RGB(210, 0, 0, 32), Color1 = _RGB(255, 255, 255, 32), Color2 = _RGB(255, 177, 0, 32), Color3 = _RGB(255, 150, 80, 32)
18. CONST Color4 = _RGB(255, 100, 0, 32), Color5 = _RGB(255, 55, 0, 32), Color6 = _RGB(100, 130, 20, 32)
19. CONST FireS = 4, FireP = 3, DeathS = 2, DeathP = 1
20. CONST False = 0, True = -1, Quit = 999, Fire = 100, FireVel = 10, Right = 150, Left = 200, yShip = 500
21. CONST CMusic = 250, OMusic = 300, widS = 100, higS = 100
22.  
23. _PRINTMODE _KEEPBACKGROUND
24. RANDOMIZE TIMER
25. ' inizialize fonts----------------------------------------------------------
26. path$ = "C:\Windows\Fonts\"
27. files$ = "Tahoma.ttf" '  "lucon.ttf"  <-- Alternative fonts of system
28. loadfont path$ + files$, f, 68
29. files$ = "seguihis.ttf"
30. loadfont path$ + files$, f2, 36
31.  
32. ' initialize music and sounds------------------------------------------------
33. loadMusic
34.  
35. ' initialize images----------------------------------------------------------
36. a = _LOADIMAGE("assets_H\moon.jpg") 'BACKGROUND
37. IF a >= -1 THEN PRINT "Image not loaded moon"
38. b = _LOADIMAGE("assets_H\ship_.png") 'USER
39. IF b >= -1 THEN PRINT "Image not loaded ship"
40. c = _LOADIMAGE("assets_H\sweet.png") 'FIRE OF USER
41. IF c >= -1 THEN PRINT "Image not loaded sweet"
42. d = _LOADIMAGE("assets_H\spider.png") ' FIRE OF PUMPKINS
43. IF d >= -1 THEN PRINT "Image not loaded spider"
44. ' PUMPKINS
45. FOR g = 1 TO 9 STEP 1
46.     e(g) = _LOADIMAGE("assets_H\pum" + LTRIM$(STR$(g)) + ".png") ' FIRE OF PUMPKINS
47.     IF e(g) >= -1 THEN PRINT "Image not loaded pum" + LTRIM$(STR$(g)) + ".png", e(g)
48.     Xpump(g) = 80 * g: Ypump(g) = 70
49.     Lpump(g) = True 'life
50.     Fpump(g) = False 'firing
51. NEXT
52. VelP = 5 ' pumpkins go towards right
53.  
54. ' setting for starting------------------------------------------------------------
55. _PUTIMAGE (1, 1)-(800, 600), a
56. Credits
57. IntroStart f, f2
58. xShip = 200
59. GoDown = False
60. GameOver = 0
61. m = _NEWIMAGE(800, 600, 32)
62. 'main loop
63. DO
64.  
65.     cmd = 0 ' clear buffer commands
66.     '---------------------------INPUT MANAGEMENT--------------------------------
67.     ' take commands
68.     IF _KEYDOWN(32) AND FireActive = 0 THEN cmd = Fire
69.     IF _KEYDOWN(27) THEN cmd = quits
70.     IF _KEYDOWN(19200) THEN cmd = Right
71.     IF _KEYDOWN(19712) THEN cmd = Left
72.     IF _KEYDOWN(77) OR _KEYDOWN(109) THEN cmd = CMusic
73.     IF _KEYDOWN(13) AND (_KEYDOWN(77) OR _KEYDOWN(109)) THEN cmd = OMusic
74.  
75.     '---------------------------COMMAND TRANSLATOR------------------------------
76.     ' command Fire
77.     IF cmd = Fire THEN
78.         FireActive = True
79.         yFire = yShip
80.     END IF
81.     ' command go right
82.     IF cmd = Right THEN RightGo = True ELSE RightGo = False
83.     ' command go left
84.     IF cmd = Left THEN LeftGo = True ELSE LeftGo = False
85.     ' command change music
86.     IF OffMusic = False AND cmd = CMusic THEN ChangeMusic = True
87.     ' command off music
88.     IF cmd = OMusic THEN OffMusic = NOT OffMusic
89.  
90.  
91.     '-------------------------EVENT MANAGEMENT-----------------------------------
92.  
93.     ' event Fire  @----------------------------------------------
94.     IF FireActive THEN
95.         IF yFire = yShip THEN _SNDPLAY snd(FireS): xFire = xShip + INT(widS / 2) - 20
96.         IF yFire - FireVel > 0 THEN
97.             yFire = yFire - FireVel
98.         ELSE
99.             yFire = 0
100.             FireActive = False
101.         END IF
102.     END IF
103.  
104.     ' event go to right  @----------------------------------------------
105.     IF RightGo THEN
106.         IF xShip - 10 < 1 THEN xShip = 1 ELSE xShip = xShip - 10
107.         RightGo = False
108.     END IF
109.  
110.     ' event go to left  @----------------------------------------------
111.     IF LeftGo THEN
112.         IF xShip + 10 + widS > 800 THEN xShip = 800 - widS ELSE xShip = xShip + 10
113.         LeftGo = False
114.     END IF
115.  
116.  
117.     ' event  change music   @----------------------------------------------
118.     IF ChangeMusic = True THEN
119.         IF IndexMus = 4 THEN IndexMus = 1 ELSE IndexMus = IndexMus + 1
120.         _SNDSTOP ActualMus
121.         ActualMus = mus(IndexMus)
122.         _SNDPLAY ActualMus
123.         ChangeMusic = False
124.     END IF
125.  
126.     ' event Off music  @----------------------------------------------
127.     IF OffMusic = True THEN _SNDSTOP ActualMus
128.  
129.     ' event end music on playing  @----------------------------------------------
130.     IF _SNDPLAYING(ActualMus) = False THEN _SNDPLAY ActualMus
131.  
132.     ' event Move Pumpkins  @----------------------------------------------
133.     IF VelP > 0 THEN ' moving to right
134.         FOR j = 9 TO 1 STEP -1
135.             IF Lpump(j) = True THEN EXIT FOR
136.         NEXT
137.         IF Xpump(j) + VelP + 60 > 800 THEN
138.             VelP = VelP * -1 ' it changes direction
139.             GoDown = True ' pumpkins go towards ship
140.         ELSE
141.             GoDown = False
142.         END IF
143.     ELSE 'moving to left
144.         FOR j = 1 TO 9 STEP 1
145.             IF Lpump(j) = True THEN EXIT FOR
146.         NEXT
147.         IF Xpump(j) + VelP < 0 THEN
148.             VelP = VelP * -1 ' it changes direction
149.             GoDown = True ' pumpkins go towards ship
150.         ELSE
151.             GoDown = False
152.         END IF
153.     END IF
154.     ' it calculates the new position for pumpkins
155.     FOR k = 1 TO 9 STEP 1
156.         IF Lpump(k) = True THEN
157.             Xpump(k) = Xpump(k) + VelP
158.             IF GoDown = True THEN Ypump(k) = Ypump(k) + 10
159.         END IF
160.     NEXT
161.  
162.     ' event Fire Pumpkins  @----------------------------------------------
163.     FOR h = 1 TO 9 STEP 1
164.         IF Lpump(h) = True THEN ' if pumpkin exists
165.             IF (INT(RND * 3) + 1) > 2 THEN
166.                 IF Fpump(h) = False THEN 'if pumpkin is not firing
167.                     Fpump(h) = True ' it starts to fire
168.                     yFireP(h) = Ypump(h)
169.                 END IF
170.             END IF
171.         END IF
172.  
173.         ' event firing pumpkins       @----------------------------------------------
174.         IF Fpump(h) = True THEN
175.             IF yFireP(h) = Ypump(h) THEN _SNDPLAY snd(FireP): xFireP(h) = Xpump(h) + INT(widS / 2) - 20
176.             IF yFireP(h) + FireVel < 600 THEN
177.                 yFireP(h) = yFireP(h) + FireVel
178.             ELSE
179.                 yFireP(h) = 540
180.                 Fpump(h) = False
181.             END IF
182.         END IF
183.         ' event destroy ship       @----------------------------------------------
184.         IF (xFireP(h) > xShip AND xFireP(h) < xShip + widS) OR (xFireP(h) + 40 > xShip AND xFireP(h) + 40 < xShip + widS) THEN
185.             IF (yFireP(h) > yShip AND yFireP(h) < yShip + higS) OR (yFireP(h) + 20 > yShip AND yFireP(h) + 20 < yShip + higS) THEN
186.                 _SNDPLAY snd(2)
187.                 cmd = Quit
188.             END IF
189.         END IF
190.         ' event destroy fireship   @----------------------------------------------
191.         IF (xFireP(h) >= xFire AND xFireP(h) <= xFire + 40) OR (xFireP(h) + 40 >= xFire AND xFireP(h) + 40 <= xFire + 40) THEN
192.             IF (yFireP(h) >= yFire AND yFireP(h) <= yFire + 20) OR (yFireP(h) + 20 >= yFire AND yFireP(h) + 20 <= yFire + 20) THEN
193.                 _SNDPLAY snd(1)
194.                 Fpump(h) = False
195.                 FireActive = False
196.             END IF
197.         END IF
198.  
199.     NEXT
200.  
201.     ' event destroy pumpkin @----------------------------------------------
202.     IF FireActive THEN
203.         FOR l = 1 TO 9 STEP 1
204.             IF Lpump(l) = True THEN ' pumpkins is alive
205.                 IF (xFire > Xpump(l)) AND (Xpump(l) + 60 > xFire) OR (xFire + 40 > Xpump(l)) AND (Xpump(l) + 60 > xFire + 40) THEN
206.                     IF (yFire < Ypump(l) + 60) AND (yFire > Ypump(l)) OR (yFire + 20 < Ypump(l) + 60) AND (yFire + 20 > Ypump(l)) THEN
207.                         Lpump(l) = False
208.                         FireActive = False
209.                         GameOver = GameOver + 1
210.                         _SNDPLAY snd(1)
211.                     END IF
212.                 END IF
213.             END IF
214.         NEXT
215.     END IF
216.  
217.  
218.     '-----------------------------------------OUTPUT --------------------
219.     ' all graphic operations go onto hidden panel m
220.     _PUTIMAGE (1, 1)-(800, 600), a, m 'background layer
221.     _PUTIMAGE (xShip, yShip)-(xShip + widS, yShip + higS), b, m ' astroship layer
222.     IF FireActive THEN _PUTIMAGE (xFire, yFire)-(xFire + 40, yFire + 20), c, m ' FireShip
223.     FOR i = 1 TO 9 STEP 1
224.         IF Lpump(i) THEN _PUTIMAGE (Xpump(i), Ypump(i))-(Xpump(i) + 60, Ypump(i) + 60), e(i), m
225.         IF Fpump(i) THEN _PUTIMAGE (xFireP(i), yFireP(i))-(xFireP(i) + 40, yFireP(i) + 20), d, m
226.     NEXT
227.     _PUTIMAGE , m, 0 'copy panel m to screen
228.     _LIMIT 10
229.  
230.     'debug
231.  
232.  
233. LOOP UNTIL GameOver = 9 OR cmd = Quit ' events GameOver and Quit
234. IF GameOver = 9 THEN
235.     _SNDPLAY snd(1)
236.     CLS
237.     PRINT "YOU WIN"
238.     PRINT "GAME OVER"
239.     SLEEP 5
240. END IF
241. IF cmd = Quit THEN
242.     _SNDPLAY snd(2)
243.     CLS
244.     PRINT "YOU LOOSE"
245.     PRINT "GAME OVER"
246.     SLEEP 5
247. END IF
248.  
249. SYSTEM
250.  
251. SUB IntroStart (fn1&, fn2&)
252.     DIM cont%
253.     FOR cont% = 1 TO 2 STEP 1
254.         IF cont% = 1 THEN
255.             CLS
256.             IF fn2& > 0 THEN _FONT fn2& ELSE PRINT "No file font loaded" + " seguihis.ttf"
257.             COLOR Color6
258.             _PRINTSTRING (260, 200), "Press a key to start"
259.         ELSE
260.             CLS , RedBack
261.             _FONT fn1&
262.             COLOR Color1
263.             _PRINTSTRING (30, 120), "INSTRUCTIONS:"
264.             _PRINTSTRING (30, 200), "space = fire"
265.             _PRINTSTRING (30, 250), "arrows left/right = move"
266.             _PRINTSTRING (30, 300), "M = change music"
267.             _PRINTSTRING (30, 350), "Enter+M =Off/On music"
268.             _PRINTSTRING (30, 410), "ESC to quit"
269.         END IF
270.         IF fn1& > 0 THEN _FONT fn1& ELSE PRINT "No file font loaded" + " Tahoma.ttf"
271.         COLOR Color1
272.         _PRINTSTRING (2, 20), "HALLOWEEN CHALLENGE", 0
273.         COLOR Color2
274.         _PRINTSTRING (6, 28), "HALLOWEEN CHALLENGE", 0
275.         COLOR Color3
276.         _PRINTSTRING (10, 36), "HALLOWEEN CHALLENGE", 0
277.         COLOR Color4
278.         _PRINTSTRING (14, 40), "HALLOWEEN CHALLENGE", 0
279.         COLOR Color5
280.         _PRINTSTRING (18, 44), "HALLOWEEN CHALLENGE", 0
281.         IF cont% = 1 THEN SLEEP ELSE SLEEP 4
282.     NEXT cont%
283. END SUB
284.  
285. SUB loadfont (pat$, h&, size)
286.     IF _FILEEXISTS(pat$) THEN
287.         h& = _LOADFONT(pat$, size, "BOLD")
288.     ELSE
289.         PRINT "File font not found"
290.     END IF
291. END SUB
292.  
293. SUB Credits
294.     DIM cp AS STRING
295.     COLOR Color4
296.     _FONT 16
297.     PRINT "CREDITS:"
298.     cp = " MUSIC: downloaded from  [No Copyright Music] Halloween - (Royalty Free Halloween Music)" + CHR$(13) + "  on www.youtube.com"
299.     LOCATE 2, 2
300.     PRINT cp
301.     cp = " IMAGES: downloaded from freepik.com created: Pumpkin and Starship by Freepik, Moon by Kjpargeter,  Sweet and spider by Titusurya"
302.     PRINT cp
303.     LOCATE 12, 2
304.     PRINT "PRESS A KEY TO CONTINE..."
305.     SLEEP
306.     CLS
307. END SUB
308.  
309. SUB loadMusic
310.     SHARED OffMusic AS _BYTE
311.     DIM a AS INTEGER
312.     CLS
313.     LOCATE 2, 2
314.     PRINT "LOADING MUSIC....."
315.     mus(1) = _SNDOPEN("assets_H\UnknownFear.mp3")
316.     mus(2) = _SNDOPEN("assets_H\Halloween.mp3")
317.     mus(3) = _SNDOPEN("assets_H\WonderAndMagic.mp3")
318.     mus(4) = _SNDOPEN("assets_H\Spook.mp3")
319.     FOR a = 1 TO 4 STEP 1
320.         IF mus(a) = 0 THEN PRINT "No music " + STR$(a) + " found!"
321.     NEXT
322.     _SNDPLAY mus(a - 1) ' it plays the last music loaded
323.     ActualMus = mus(a - 1)
324.     OffMusic = False
325.     PRINT
326.     PRINT "LOADING SOUND....."
327.     snd(1) = _SNDOPEN("assets_H\DeathPump.mp3")
328.     snd(2) = _SNDOPEN("assets_H\DeathShip.mp3")
329.     snd(3) = _SNDOPEN("assets_H\FirePump.mp3")
330.     snd(4) = _SNDOPEN("assets_H\FireShip.mp3")
331.     FOR a = 1 TO 4 STEP 1
332.         IF snd(a) = 0 THEN PRINT "No music " + STR$(a) + " found!"
333.     NEXT
334.     SLEEP 2
335.     CLS
336. END SUB
337.  
338. FUNCTION quits
339.     DIM a$
340.     COLOR , 0
341.     _PRINTSTRING (200, 200), "Do you Quit?"
342.     _PRINTSTRING (300, 260), "Y/N"
343.     DO
344.         a$ = LCASE$(INPUT$(1))
345.     LOOP UNTIL a$ = "y" OR a$ = "n"
346.     IF a$ = "y" THEN quits = Quit ELSE quits = False
347. END FUNCTION

Thanks to try

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 31, 2018, 08:21:35 pm

If you find too huge .ZIP here 2 screenshots


About midnight... someoneelse can post somethingelse before his/her midnight... it can be...

Title: Re: 15 days for Halloween code challenge
Post by: TempodiBasic on October 31, 2018, 08:56:34 pm

@Bplus

Fine your rotating sphere  :-)

Title: Re: 15 days for Halloween code challenge
Post by: Pete on October 31, 2018, 09:04:03 pm

ROFL. It went from a basketball to a sphere... anything but a pumpkin!

Pete

Text Only | Text with Attachments