Print Page - How to read the first 4 bits of the byte?

Hello. As you've surely noticed, I'm not a big friend with bit logical operators AND, XOR and OR. But because I want to get on, I need to thoroughly understand how to get the first 4 bits, or just the last bit of the byte, because the conversion to the string is too slow. Moving back from binary form makes VAL, that's no problem.

AND 15 is probably what you're looking for.

00001111 -- last 4 bits would be a total of 15 (decimal).

So let's tak a number like 34.... In binary it'd be: 00100010.

00100010
00001111 AND
-----------
00000010

Result would be 2 -- the last 4 bits of that byte.

************

First 4 would be AND &B11110000 (128 + 64 + 32 + 16.. 240). AND 240

If you're not good at converting, just us &B and type the values directly in binary. In many cases, I find, it keeps it simple and help preserves the intent of the code nicely.

Exactly it is how to take (quick) the first 4 bits of one byte and the first 4 bits of the second byte, fold a new byte, and then write this byte. I use this to store bitmap in 2/16 colors in the following code, but it is ugly slow:

Code: QB64: [Select]

ima = _SCREENIMAGE
 
 
imb = _NEWIMAGE(2048, 1024, 256)
_DEST imb
CLS , 14
LINE (100, 100)-(1948, 924), 1, BF
CIRCLE (1024, 512), 150, 0
_DEST 0
 
 
Save_BMP imb, "test16.bmp", 2  : REM 0 = 32 bit, 1 = 8 bit, 2 = 4 bit, 3 = 1 bit
 
 
 
 
 
 
 
 
SUB Save_BMP (src AS LONG, file AS STRING, typ AS _UNSIGNED _BYTE) 'typ: 0 = 32 bit, 1 = 256 colors, 2 = 16 colors, 3 = 2 colors   PRO KONVERZI NEJPRVE DITHERINGEM UDELEJ 256 clr zdroj a ten uloz. NELZE ulozit primo 32 bit do 8 bit!
    'moje save formule
 
    TYPE BMP_H
        ID AS STRING * 2 'BM                                  a
        Size AS LONG 'celkova velikost souboru
        Reserved0 AS INTEGER '0                               a
        Reserved1 AS INTEGER '0                               a
        Data_Start AS LONG ' startovni oblast dat obrazu. U 32 bitu to je hned po hlave, u ostatnich az po 54 + oblast palety - protoze tahle hlava ma 14, nasleduje druha hlava, ktera ma 40 bytu
    END TYPE
 
    TYPE BMP_I
        Hlava_velikost AS LONG '40                            a
        width AS LONG
        height AS LONG
        planes AS INTEGER '1                                  a
        BPP AS INTEGER '1/4/8/24/32
        Compress AS LONG '0/1/2                               a
        Image_Size AS LONG ' dam nulu                         a
        Xpels AS LONG '0                                      a
        Ypels AS LONG '0                                      a
        Total_Colors AS LONG 'muze byt 0    (0, 256, 16, 2)
        Important_Colors AS LONG '0                           a
    END TYPE
 
    DIM H AS BMP_H
    DIM I AS BMP_I
 
    DIM v AS _UNSIGNED LONG, v2 AS _UNSIGNED _BYTE
 
    H.Size = (_WIDTH(src) * _HEIGHT(src) * 4) + 54: I.height = _HEIGHT(src): I.width = _WIDTH(src)
    SELECT CASE typ
 
        CASE 0: DIM IM(_WIDTH(src) * _HEIGHT(src) - 1) AS _UNSIGNED LONG
            I.BPP = 32: I.Total_Colors = 0: Depth = 4 '                        32  bit
 
 
        CASE 1: DIM IM2(_WIDTH(src) * _HEIGHT(src) - 1) AS _UNSIGNED _BYTE
            I.BPP = 8: I.Total_Colors = 0: Depth = 1 '                         256 clrs
 
 
 
        CASE 2: DIM IM3((_WIDTH(src) * _HEIGHT(src) - 1) / 2) AS _UNSIGNED _BYTE
            I.BPP = 4: I.Total_Colors = 0: Depth = 1 '                         16  clrs
 
        CASE 3: DIM IM4((_WIDTH(src) * _HEIGHT(src) - 1) / 8) AS _UNSIGNED _BYTE
            I.BPP = 1: I.Total_Colors = 0: Depth = 1 '                         2   clrs
 
 
    END SELECT
 
    H.ID = "BM": H.Reserved0 = 0: H.Reserved1 = 0: I.Hlava_velikost = 40: I.planes = 1: I.Compress = 0: I.Image_Size = 0: I.Xpels = 0: I.Ypels = 0: I.Important_Colors = 0
    DIM M AS _MEM, N AS _MEM
    M = _MEMIMAGE(src)
 
 
    N = _MEMNEW(I.width * I.height * Depth) 'oblast pameti, kde se bude otacet Y
 
    FOR y = (_HEIGHT(src)) - 1 TO 0 STEP -1
        FOR x = 0 TO (_WIDTH(src) - 1)
            SELECT CASE typ
                CASE 0
                    _MEMGET M, M.OFFSET + o, v
                    _MEMPUT N, N.OFFSET + in(x, y, src&), v
                    o = o + 4
                CASE 1
                    _MEMGET M, M.OFFSET + o, v2
                    _MEMPUT N, N.OFFSET + in(x, y, src&), v2
                    o = o + 1
                CASE 2
                    _MEMGET M, M.OFFSET + o, v2
                    uk = uk + 1
                    binar$ = binar$ + RIGHT$(DECtoBIN$(v2), 4)
                    IF uk MOD 2 = 0 THEN
                        IM3(index) = BINtoDEC(binar$)
                        binar$ = ""
                        index = index + 1
                        uk = 0
                    END IF
                    o = o + 1
 
                CASE 3
                    _MEMGET M, M.OFFSET + o, v2
                    uk = uk + 1
                    binar$ = binar$ + RIGHT$(DECtoBIN$(v2), 1)
                    IF uk MOD 8 = 0 THEN
                        IM4(index) = BINtoDEC(binar$)
                        binar$ = ""
                        index = index + 1
                        uk = 0
                    END IF
                    o = o + 1
            END SELECT
    NEXT x, y
 
 
 
 
    SELECT CASE typ
        CASE 0
            _MEMFREE M
            _MEMGET N, N.OFFSET, IM()
            _MEMFREE N
        CASE 1
            _MEMFREE M
            _MEMGET N, N.OFFSET, IM2()
            _MEMFREE N
        CASE 2, 3
            _MEMFREE M
            _MEMFREE N
    END SELECT
 
 
 
 
 
    ch = FREEFILE
    OPEN file FOR OUTPUT AS #ch: CLOSE #ch: OPEN file FOR BINARY AS #ch
    PUT #ch, , H
    PUT #ch, , I
    SELECT CASE typ
        CASE 0: PUT #ch, , IM()
        CASE 1:
            FOR Palete = 0 TO 255
                v = _PALETTECOLOR(Palete, src&)
                PUT #ch, , v
            NEXT
            PUT #ch, , IM2()
 
        CASE 2:
            FOR Palete = 0 TO 15
                v = _PALETTECOLOR(Palete, src&)
                PUT #ch, , v
            NEXT
            PUT #ch, , IM3()
 
 
        CASE 3:
            FOR Palete = 0 TO 1
                v = _PALETTECOLOR(Palete, src&)
                PUT #ch, , v
            NEXT
            PUT #ch, , IM4()
    END SELECT
END SUB
 
 
FUNCTION in& (x AS INTEGER, y AS INTEGER, src&)
    in& = _PIXELSIZE(src&) * (y * _WIDTH(src&) + x)
    ' in& = (y * _WIDTH(src&) + x)
END FUNCTION
 
FUNCTION DECtoBIN$ (vstup)
    FOR rj = 7 TO 0 STEP -1
        IF vstup AND 2 ^ rj THEN DECtoBIN$ = DECtoBIN$ + "1" ELSE DECtoBIN$ = DECtoBIN$ + "0"
    NEXT rj
END FUNCTION
 
FUNCTION BINtoDEC (b AS STRING)
    BINtoDEC = VAL("&B" + b$)
END FUNCTION
 

Color compression, I take it?

Bear with me, as I'm still waking up, and let's see if I understand the need.

To get a compressed 8-bit value back into 2 4-bit values, you'd;

LeftHalf = CompressedBit AND 240
RightHalf = CompressedBit AND 15

To put those 2 halves back together into a full 8-bit value, you'd:

CompressedBit = 16 * LeftHalf + RightHalf (LeftHalf needs to shift 4 places, while the right half stays the same.)

Yes, this is it. I was able to make a write for 16 colors using this logical operator, it's much faster. The solution was AND 15 for the first pass and the same (but without re-reading the first value) for the second pass. Now I'm banging my head and trying the same thing for a two-color record. Thank You Steve.

2 color, as in black and white?

Each bit would represent a pixel.

Take a compressed byte (CB) and just AND (2 ^ pixel) for the value.

CB AND 1 = pixel 0
CB AND 2 = pixel 1
CB AND 4 = pixel 2
CB AND 8
CB AND 16
CB AND 32
CB AND 64
CB AND 128

To go the other direction:

CB = pixel 7 * 128 + pixel 6 * 64 + pixel 5 * 32 + ...... + pixel 1 * 2 + pixel 0

Perfect. Thanks a lot. In fact, even two-color BMPs contain 2 pallet records, so they do not always have to be a black-and-white picture. Only Windows painting does not accept this (while the photo viewer will display it correctly).

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Petr on October 08, 2018, 05:32:14 am