QB64.org Forum

Active Forums => Programs => Topic started by: qbguy on October 06, 2018, 09:18:20 pm

Title: Reversi / Othello Game (play against computer AI)
Post by: qbguy on October 06, 2018, 09:18:20 pm

Mouse code is for QBASIC and uses CALL ABSOLUTE to call interrupt 33 and put the results in global variables named AX, BX, CX, DX.  Should still work in QB64; otherwise alter it to use CALL ITERRUPT or QB64 mouse codes.  When this was on the [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] forum there was a bug in QB64 that caused it not to compile the constants.  I think I had already put alternative mouse routines for QB64 or FreeBASIC.

Code: QB64: [Select]

1. DECLARE FUNCTION AlphaBeta% (player%, board%(), achievable%, cutoff%, ply%)
2. DECLARE FUNCTION FinalValue% (player%, board%())
3. DECLARE FUNCTION WeightedSquares% (player%, board%())
4. DECLARE FUNCTION MaximizeDifference% (player%, board%())
5. DECLARE FUNCTION CountDifference% (player%, board%())
6. DECLARE SUB MakeMove (move%, player%, board%())
7. DECLARE SUB InitBoard ()
8. DECLARE FUNCTION LegalP% (move%, player%, board%())
9. DECLARE FUNCTION WouldFlip% (move%, player%, board%(), dir%)
10. DECLARE FUNCTION FindBracketingPiece% (square%, player%, board%(), dir%)
11. DECLARE FUNCTION NextToPlay% (board%(), PreviousPlayer%)
12. DECLARE FUNCTION AnyLegalMove% (player%, board%())
13. DECLARE FUNCTION Opponent% (player%)
14. DECLARE SUB MakeFlips (move%, player%, board%(), dir%)
15. DEFINT A-Z
16. DECLARE SUB Mouse (ax AS INTEGER)
17. DECLARE FUNCTION GetMove% ()
18. DECLARE FUNCTION Colour (i)
19. DECLARE SUB ShowBd ()
20. DIM SHARED board(100) AS INTEGER
21. DIM SHARED AllDirections(8) AS INTEGER
22. DIM SHARED weights(100) AS INTEGER
23. CLEAR , , 9999
24. FOR i = 1 TO 8
25.   READ AllDirections(i)
26. NEXT
27. DATA -11, -10, -9, -1, 1, 9, 10, 11
28.  
29. FOR i = 0 TO 99
30.   READ weights(i)
31. NEXT
32. DATA 0,0,0,0,0,0,0,0,0,0
33. DATA 0,120,-20,20,5,5,20,-20,120,0
34. DATA 0,-20,-0,-5,-5,-5,-5,-40,-20,0
35. DATA 0,20,-5,15,3,3,15,-5,20,0
36. DATA 0,5,-5,3,3,3,3,-5,5,0
37. DATA 0,5,-5,3,3,3,3,-5,5,0
38. DATA 0,20,-5,15,3,3,15,-5,20,0
39. DATA 0,-20,-0,-5,-5,-5,-5,-40,-20,0
40. DATA 0,120,-20,20,5,5,20,-20,120,0
41. DATA 0,0,0,0,0,0,0,0,0,0
42.  
43. CONST ScreenWidth = 640
44. CONST ScreenHeight = 480
45. CONST SquareWidth = ScreenHeight / 8
46. CONST tlx = (ScreenWidth - ScreenHeight) / 2
47. CONST tly = 0
48. CONST brx = ScreenWidth - (ScreenWidth - ScreenHeight) / 2
49. CONST bry = ScreenHeight
50. CONST PieceRadius = SquareWidth / 2 - 5
51. CONST EMPTY = 0
52. CONST BLACK = 1
53. CONST WHITE = 2
54. CONST OUTER = 3
55. CONST WinningValue = 32767
56. CONST LosingValue = -32767
57. CONST nply = 5
58.  
59. DIM SHARED bestm(nply) AS INTEGER
60. DIM SHARED ax AS INTEGER
61. ax = 0
62. DIM SHARED bx AS INTEGER
63. bx = 0
64. DIM SHARED cx AS INTEGER
65. cx = 0
66. DIM SHARED dx AS INTEGER
67. dx = 0
68.  
69.  
70.  
71. SCREEN 12
72. CALL InitBoard
73. CALL Mouse(0)
74. CALL Mouse(1)
75. player = BLACK
76. human = BLACK
77. computer = Opponent(human)
78. DO
79.   CALL ShowBd
80.   IF player = human THEN
81.     n = GetMove
82.     IF LegalP(n, player, board()) THEN
83.       CALL MakeMove(n, player, board())
84.       player = NextToPlay(board(), player)
85.     END IF
86.   END IF
87.   CALL ShowBd
88.   IF player = computer THEN
89.     n = AlphaBeta(player, board(), LosingValue, WinningValue, nply)
90.     move = bestm(nply)
91.     CALL MakeMove(move, player, board())
92.     player = NextToPlay(board(), player)
93.   END IF
94. LOOP UNTIL player = 0
95.  
96. FUNCTION AlphaBeta (player, board(), achievable, cutoff, ply)
97.   DIM board2(100)
98.   FOR i = 0 TO 99
99.     board2(i) = board(i)
100.   NEXT
101.   IF ply = 0 THEN
102.     AlphaBeta = WeightedSquares(player, board())
103.     EXIT FUNCTION
104.   END IF
105.   nlegal = 0
106.   FOR move = 0 TO 99
107.     IF LegalP(move, player, board()) THEN
108.       nlegal = nlegal + 1
109.       CALL MakeMove(move, player, board2())
110.       value = -AlphaBeta(Opponent(player), board2(), -cutoff, -achievable, ply - 1)
111.       IF value > achievable THEN
112.         achievable = value
113.         bestmove = move
114.       END IF
115.     END IF
116.   NEXT
117.   IF nlegal = 0 THEN
118.     IF AnyLegalMove(Opponent(player), board()) THEN
119.       AlphaBeta = -AlphaBeta(Opponent(player), board(), -cutoff, -achievable, ply - 1)
120.     ELSE
121.       AlphaBeta = FinalValue(player, board())
122.     END IF
123.   END IF
124.   bestm(ply) = bestmove
125. END FUNCTION
126.  
127. FUNCTION AnyLegalMove (player, board())
128.   FOR i = 0 TO 99
129.     IF LegalP(i, player, board()) THEN AnyLegalMove = -1: EXIT FUNCTION
130.   NEXT
131. END FUNCTION
132.  
133. FUNCTION Colour (i)
134.   IF i = BLACK THEN
135.     Colour = 0
136.   ELSE
137.     Colour = 15
138.   END IF
139. END FUNCTION
140.  
141. FUNCTION CountDifference (player, board())
142.   c = 0
143.   FOR y = 1 TO 8
144.     FOR x = 1 TO 8
145.       IF board(10 * y + x) = player THEN c = c + 1
146.       IF board(10 * y + x) = Opponent(player) THEN c = c - 1
147.     NEXT
148.   NEXT
149.   CountDifference = c
150. END FUNCTION
151.  
152. FUNCTION FinalValue (player, board())
153.   SELECT CASE SGN(CountDifference(player, board()))
154.     CASE -1
155.       FinalValue = LosingValue
156.     CASE 0
157.       FinalValue = 0
158.     CASE 1
159.       FinalValue = WinningValue
160.   END SELECT
161. END FUNCTION
162.  
163. FUNCTION FindBracketingPiece (square, player, board(), dir)
164.   IF board(square) = player THEN
165.     FindBracketingPiece = square
166.   ELSEIF board(square) = Opponent(player) THEN
167.     FindBracketingPiece = FindBracketingPiece(square + dir, player, board(), dir)
168.   END IF
169. END FUNCTION
170.  
171. FUNCTION GetMove
172.   DO
173.     CALL Mouse(3)
174.     IF bx AND 1 THEN
175.       y = (dx - tly) \ SquareWidth + 1
176.       x = (cx - tlx) \ SquareWidth + 1
177.     END IF
178.     IF 1 <= y AND y <= 8 AND 1 <= x AND x <= 8 THEN EXIT DO
179.   LOOP
180.   GetMove = 10 * y + x
181. END FUNCTION
182.  
183. SUB InitBoard
184.   FOR i = 0 TO 9
185.     board(i) = OUTER
186.     board(90 + i) = OUTER
187.     board(i * 10) = OUTER
188.     board(i * 10 + 9) = OUTER
189.   NEXT
190.   board(44) = 1
191.   board(45) = 2
192.   board(54) = 2
193.   board(55) = 1
194. END SUB
195.  
196. FUNCTION LegalP (move, player, board())
197.   IF board(move) <> EMPTY THEN LegalP = 0: EXIT FUNCTION
198.   FOR i = 1 TO 8
199.     x = WouldFlip(move, player, board(), AllDirections(i))
200.     IF x THEN LegalP = -1: EXIT FUNCTION
201.   NEXT
202. END FUNCTION
203.  
204. SUB MakeFlips (move, player, board(), dir)
205.   bracketer = WouldFlip(move, player, board(), dir)
206.   IF bracketer THEN
207.     FOR c = move + dir TO bracketer STEP dir
208.       board(c) = player
209.     NEXT
210.   END IF
211. END SUB
212.  
213. SUB MakeMove (move, player, board())
214.   board(move) = player
215.   FOR i = 1 TO 8
216.     CALL MakeFlips(move, player, board(), AllDirections(i))
217.   NEXT
218. END SUB
219.  
220. FUNCTION MaximizeDifference (player, board())
221.   DIM board2(100)
222.   best = -9999
223.   FOR y = 1 TO 8
224.     FOR x = 1 TO 8
225.       move = 10 * y + x
226.       IF LegalP(move, player, board()) THEN
227.         FOR i = 0 TO 99
228.           board2(i) = board(i)
229.         NEXT
230.         CALL MakeMove(move, player, board2())
231.         score = WeightedSquares(player, board2())
232.         IF score > best THEN best = score: bestmove = move
233.       END IF
234.     NEXT
235.   NEXT
236.   MaximizeDifference = bestmove
237. END FUNCTION
238.  
239. SUB Mouse (ax AS INTEGER)
240.  
241.   ml$ = "" ' -=<( Mouse Code )>=-
242.   ml$ = ml$ + CHR$(&H55) ' push bp               ; preserve BP register
243.   ml$ = ml$ + CHR$(&H89) + CHR$(&HE5) ' mov  bp, sp           ; copy SP to BP
244.   ml$ = ml$ + CHR$(&HB8) + CHR$(ax) + CHR$(&H0) '   mov  ax, #          ;   copy SUBFUNCTION to AX
245.   ml$ = ml$ + CHR$(&HCD) + CHR$(&H33) '   int  33             ;   call mouse interrupt
246.   ml$ = ml$ + CHR$(&H53) '   push bx             ;   preserve BX (again)
247.   ml$ = ml$ + CHR$(&H8B) + CHR$(&H5E) + CHR$(&H6) '   mov  bx, [bp+6]     ;   copy location of dx (last variable) to BX
248.   ml$ = ml$ + CHR$(&H89) + CHR$(&H17) '   mov  [bx], dx       ;   copy DX to dx location in BX
249.   ml$ = ml$ + CHR$(&H8B) + CHR$(&H5E) + CHR$(&H8) '   mov  bx, [bp+8]     ;   copy location of cx to BX
250.   ml$ = ml$ + CHR$(&H89) + CHR$(&HF) '   mov  [bx], cx       ;   copy CX to cx location in BX
251.   ml$ = ml$ + CHR$(&H8B) + CHR$(&H5E) + CHR$(&HC) '   mov  bx, [bp+C]     ;   copy location of ax to BX
252.   ml$ = ml$ + CHR$(&H89) + CHR$(&HF7) '   mov  [bx], ax       ;   copy AX to ax location in BX
253.   ml$ = ml$ + CHR$(&H8B) + CHR$(&H5E) + CHR$(&HA) '   mov  bx, [bp+A]     ;   copy location of bx to BX
254.   ml$ = ml$ + CHR$(&H58) '   pop  ax             ;   restore int 33's BX value to AX
255.   ml$ = ml$ + CHR$(&H89) + CHR$(&H7) '   mov  [bx], ax       ;   copy AX to bx location in BX
256.   ml$ = ml$ + CHR$(&H5D) ' pop  bp               ; restore BP
257.   ml$ = ml$ + CHR$(&HCA) + CHR$(&H8) + CHR$(&H0) ' retf 8                ; Return Far and skip 8 bytes of variables
258.   DEF SEG = SSEG(ml$) ' Set current segment this machine code segment
259.   offset% = SADD(ml$) ' Set offset to this machine code location
260.   CALL absolute(ax, bx, cx, dx, offset%) ' The actual call to this machine code
261.   DEF SEG ' Restore the default segment
262.  
263. END SUB
264.  
265. FUNCTION NextToPlay (board(), PreviousPlayer)
266.   opp = Opponent(PreviousPlayer)
267.   IF AnyLegalMove(opp, board()) THEN NextToPlay = opp: EXIT FUNCTION
268.   IF AnyLegalMove(PreviousPlayer, board()) THEN NextToPlay = PreviousPlayer
269. END FUNCTION
270.  
271. FUNCTION Opponent (player)
272.   IF player = WHITE THEN Opponent = BLACK
273.   IF player = BLACK THEN Opponent = WHITE
274. END FUNCTION
275.  
276. SUB ShowBd
277.   LINE (tlx, tly)-(brx, bry), 8, BF
278.   FOR i = 0 TO 8
279.     LINE (tlx + SquareWidth * i, tly)-(tlx + SquareWidth * i, bry)
280.     LINE (tlx, tly + SquareWidth * i)-(brx, tly + SquareWidth * i)
281.   NEXT
282.   FOR y = 1 TO 8
283.     FOR x = 1 TO 8
284.       IF board(10 * y + x) <> EMPTY THEN
285.         CIRCLE (tlx + SquareWidth * x - SquareWidth / 2, tly + SquareWidth * y - SquareWidth / 2), PieceRadius, Colour(board(10 * y + x))
286.         PAINT (tlx + SquareWidth * x - SquareWidth / 2, tly + SquareWidth * y - SquareWidth / 2), Colour(board(10 * y + x))
287.       END IF
288.     NEXT
289.   NEXT
290. END SUB
291.  
292. FUNCTION WeightedSquares (player, board())
293.   opp = Opponent(player)
294.   sum = 0
295.   FOR i = 0 TO 99
296.     IF board(i) = player THEN sum = sum + weights(i)
297.     IF board(i) = opp THEN sum = sum - weights(i)
298.   NEXT
299.   WeightedSquares = sum
300. END FUNCTION
301.  
302. FUNCTION WouldFlip (move, player, board(), dir)
303.   c = move + dir
304.   IF board(c) <> Opponent(player) THEN WouldFlip = 0: EXIT FUNCTION
305.   WouldFlip = FindBracketingPiece(c + dir, player, board(), dir)
306. END FUNCTION
307.  
308.  

Title: Re: Reversi / Othello Game (play against computer AI)
Post by: TempodiBasic on October 13, 2018, 10:45:38 am

Hi Codeguy

Thanks to share your code here.

I copy and paste it in QB64dev and I have got two errors....

1. at line 48 QB64 doesn't accept the formula to define brx so I convert brx to a shared variable
2. at line 258 I find a SSEG(ml$), but looking at wiki about DEF SEG  I see that if we use a variable address we must use VARSEG and so I correct the code

here the code that works in my machine (TOSHIBA) with 4GB ram and QB64dev

Code: QB64: [Select]

1. DECLARE FUNCTION AlphaBeta% (player%, board%(), achievable%, cutoff%, ply%)
2. DECLARE FUNCTION FinalValue% (player%, board%())
3. DECLARE FUNCTION WeightedSquares% (player%, board%())
4. DECLARE FUNCTION MaximizeDifference% (player%, board%())
5. DECLARE FUNCTION CountDifference% (player%, board%())
6. DECLARE SUB MakeMove (move%, player%, board%())
7. DECLARE SUB InitBoard ()
8. DECLARE FUNCTION LegalP% (move%, player%, board%())
9. DECLARE FUNCTION WouldFlip% (move%, player%, board%(), dir%)
10. DECLARE FUNCTION FindBracketingPiece% (square%, player%, board%(), dir%)
11. DECLARE FUNCTION NextToPlay% (board%(), PreviousPlayer%)
12. DECLARE FUNCTION AnyLegalMove% (player%, board%())
13. DECLARE FUNCTION Opponent% (player%)
14. DECLARE SUB MakeFlips (move%, player%, board%(), dir%)
15. DEFINT A-Z
16. DECLARE SUB Mouse (ax AS INTEGER)
17. DECLARE FUNCTION GetMove% ()
18. DECLARE FUNCTION Colour (i)
19. DECLARE SUB ShowBd ()
20. DIM SHARED board(100) AS INTEGER
21. DIM SHARED AllDirections(8) AS INTEGER
22. DIM SHARED weights(100) AS INTEGER
23. CLEAR , , 9999
24. FOR i = 1 TO 8
25.     READ AllDirections(i)
26. NEXT
27. DATA -11,-10,-9,-1,1,9,10,11
28.  
29. FOR i = 0 TO 99
30.     READ weights(i)
31. NEXT
32. DATA 0,0,0,0,0,0,0,0,0,0
33. DATA 0,120,-20,20,5,5,20,-20,120,0
34. DATA 0,-20,-0,-5,-5,-5,-5,-40,-20,0
35. DATA 0,20,-5,15,3,3,15,-5,20,0
36. DATA 0,5,-5,3,3,3,3,-5,5,0
37. DATA 0,5,-5,3,3,3,3,-5,5,0
38. DATA 0,20,-5,15,3,3,15,-5,20,0
39. DATA 0,-20,-0,-5,-5,-5,-5,-40,-20,0
40. DATA 0,120,-20,20,5,5,20,-20,120,0
41. DATA 0,0,0,0,0,0,0,0,0,0
42.  
43. CONST ScreenWidth = 640
44. CONST ScreenHeight = 480
45. CONST SquareWidth = ScreenHeight / 8
46. CONST tlx = (ScreenWidth - ScreenHeight) / 2
47. CONST tly = 0
48. DIM SHARED brx: brx = ScreenWidth - (ScreenWidth - ScreenHeight) / 2 'here CONST doesn't like to compiler
49. CONST bry = ScreenHeight
50. CONST PieceRadius = SquareWidth / 2 - 5
51. CONST EMPTY = 0
52. CONST BLACK = 1
53. CONST WHITE = 2
54. CONST OUTER = 3
55. CONST WinningValue = 32767
56. CONST LosingValue = -32767
57. CONST nply = 5
58.  
59. DIM SHARED bestm(nply) AS INTEGER
60. DIM SHARED ax AS INTEGER
61. ax = 0
62. DIM SHARED bx AS INTEGER
63. bx = 0
64. DIM SHARED cx AS INTEGER
65. cx = 0
66. DIM SHARED dx AS INTEGER
67. dx = 0
68.  
69.  
70.  
71. SCREEN 12
72. CALL InitBoard
73. CALL Mouse(0)
74. CALL Mouse(1)
75. player = BLACK
76. human = BLACK
77. computer = Opponent(human)
78. DO
79.     CALL ShowBd
80.     IF player = human THEN
81.         n = GetMove
82.         IF LegalP(n, player, board()) THEN
83.             CALL MakeMove(n, player, board())
84.             player = NextToPlay(board(), player)
85.         END IF
86.     END IF
87.     CALL ShowBd
88.     IF player = computer THEN
89.         n = AlphaBeta(player, board(), LosingValue, WinningValue, nply)
90.         move = bestm(nply)
91.         CALL MakeMove(move, player, board())
92.         player = NextToPlay(board(), player)
93.     END IF
94. LOOP UNTIL player = 0
95.  
96. FUNCTION AlphaBeta (player, board(), achievable, cutoff, ply)
97.     DIM board2(100)
98.     FOR i = 0 TO 99
99.         board2(i) = board(i)
100.     NEXT
101.     IF ply = 0 THEN
102.         AlphaBeta = WeightedSquares(player, board())
103.         EXIT FUNCTION
104.     END IF
105.     nlegal = 0
106.     FOR move = 0 TO 99
107.         IF LegalP(move, player, board()) THEN
108.             nlegal = nlegal + 1
109.             CALL MakeMove(move, player, board2())
110.             value = -AlphaBeta(Opponent(player), board2(), -cutoff, -achievable, ply - 1)
111.             IF value > achievable THEN
112.                 achievable = value
113.                 bestmove = move
114.             END IF
115.         END IF
116.     NEXT
117.     IF nlegal = 0 THEN
118.         IF AnyLegalMove(Opponent(player), board()) THEN
119.             AlphaBeta = -AlphaBeta(Opponent(player), board(), -cutoff, -achievable, ply - 1)
120.         ELSE
121.             AlphaBeta = FinalValue(player, board())
122.         END IF
123.     END IF
124.     bestm(ply) = bestmove
125. END FUNCTION
126.  
127. FUNCTION AnyLegalMove (player, board())
128.     FOR i = 0 TO 99
129.         IF LegalP(i, player, board()) THEN AnyLegalMove = -1: EXIT FUNCTION
130.     NEXT
131. END FUNCTION
132.  
133. FUNCTION Colour (i)
134.     IF i = BLACK THEN
135.         Colour = 0
136.     ELSE
137.         Colour = 15
138.     END IF
139. END FUNCTION
140.  
141. FUNCTION CountDifference (player, board())
142.     c = 0
143.     FOR y = 1 TO 8
144.         FOR x = 1 TO 8
145.             IF board(10 * y + x) = player THEN c = c + 1
146.             IF board(10 * y + x) = Opponent(player) THEN c = c - 1
147.         NEXT
148.     NEXT
149.     CountDifference = c
150. END FUNCTION
151.  
152. FUNCTION FinalValue (player, board())
153.     SELECT CASE SGN(CountDifference(player, board()))
154.         CASE -1
155.             FinalValue = LosingValue
156.         CASE 0
157.             FinalValue = 0
158.         CASE 1
159.             FinalValue = WinningValue
160.     END SELECT
161. END FUNCTION
162.  
163. FUNCTION FindBracketingPiece (square, player, board(), dir)
164.     IF board(square) = player THEN
165.         FindBracketingPiece = square
166.     ELSEIF board(square) = Opponent(player) THEN
167.         FindBracketingPiece = FindBracketingPiece(square + dir, player, board(), dir)
168.     END IF
169. END FUNCTION
170.  
171. FUNCTION GetMove
172.     DO
173.         CALL Mouse(3)
174.         IF bx AND 1 THEN
175.             y = (dx - tly) \ SquareWidth + 1
176.             x = (cx - tlx) \ SquareWidth + 1
177.         END IF
178.         IF 1 <= y AND y <= 8 AND 1 <= x AND x <= 8 THEN EXIT DO
179.     LOOP
180.     GetMove = 10 * y + x
181. END FUNCTION
182.  
183. SUB InitBoard
184.     FOR i = 0 TO 9
185.         board(i) = OUTER
186.         board(90 + i) = OUTER
187.         board(i * 10) = OUTER
188.         board(i * 10 + 9) = OUTER
189.     NEXT
190.     board(44) = 1
191.     board(45) = 2
192.     board(54) = 2
193.     board(55) = 1
194. END SUB
195.  
196. FUNCTION LegalP (move, player, board())
197.     IF board(move) <> EMPTY THEN LegalP = 0: EXIT FUNCTION
198.     FOR i = 1 TO 8
199.         x = WouldFlip(move, player, board(), AllDirections(i))
200.         IF x THEN LegalP = -1: EXIT FUNCTION
201.     NEXT
202. END FUNCTION
203.  
204. SUB MakeFlips (move, player, board(), dir)
205.     bracketer = WouldFlip(move, player, board(), dir)
206.     IF bracketer THEN
207.         FOR c = move + dir TO bracketer STEP dir
208.             board(c) = player
209.         NEXT
210.     END IF
211. END SUB
212.  
213. SUB MakeMove (move, player, board())
214.     board(move) = player
215.     FOR i = 1 TO 8
216.         CALL MakeFlips(move, player, board(), AllDirections(i))
217.     NEXT
218. END SUB
219.  
220. FUNCTION MaximizeDifference (player, board())
221.     DIM board2(100)
222.     best = -9999
223.     FOR y = 1 TO 8
224.         FOR x = 1 TO 8
225.             move = 10 * y + x
226.             IF LegalP(move, player, board()) THEN
227.                 FOR i = 0 TO 99
228.                     board2(i) = board(i)
229.                 NEXT
230.                 CALL MakeMove(move, player, board2())
231.                 score = WeightedSquares(player, board2())
232.                 IF score > best THEN best = score: bestmove = move
233.             END IF
234.         NEXT
235.     NEXT
236.     MaximizeDifference = bestmove
237. END FUNCTION
238.  
239. SUB Mouse (ax AS INTEGER)
240.  
241.     ml$ = "" ' -=<( Mouse Code )>=-
242.     ml$ = ml$ + CHR$(&H55) ' push bp               ; preserve BP register
243.     ml$ = ml$ + CHR$(&H89) + CHR$(&HE5) ' mov  bp, sp           ; copy SP to BP
244.     ml$ = ml$ + CHR$(&HB8) + CHR$(ax) + CHR$(&H0) '   mov  ax, #          ;   copy SUBFUNCTION to AX
245.     ml$ = ml$ + CHR$(&HCD) + CHR$(&H33) '   int  33             ;   call mouse interrupt
246.     ml$ = ml$ + CHR$(&H53) '   push bx             ;   preserve BX (again)
247.     ml$ = ml$ + CHR$(&H8B) + CHR$(&H5E) + CHR$(&H6) '   mov  bx, [bp+6]     ;   copy location of dx (last variable) to BX
248.     ml$ = ml$ + CHR$(&H89) + CHR$(&H17) '   mov  [bx], dx       ;   copy DX to dx location in BX
249.     ml$ = ml$ + CHR$(&H8B) + CHR$(&H5E) + CHR$(&H8) '   mov  bx, [bp+8]     ;   copy location of cx to BX
250.     ml$ = ml$ + CHR$(&H89) + CHR$(&HF) '   mov  [bx], cx       ;   copy CX to cx location in BX
251.     ml$ = ml$ + CHR$(&H8B) + CHR$(&H5E) + CHR$(&HC) '   mov  bx, [bp+C]     ;   copy location of ax to BX
252.     ml$ = ml$ + CHR$(&H89) + CHR$(&HF7) '   mov  [bx], ax       ;   copy AX to ax location in BX
253.     ml$ = ml$ + CHR$(&H8B) + CHR$(&H5E) + CHR$(&HA) '   mov  bx, [bp+A]     ;   copy location of bx to BX
254.     ml$ = ml$ + CHR$(&H58) '   pop  ax             ;   restore int 33's BX value to AX
255.     ml$ = ml$ + CHR$(&H89) + CHR$(&H7) '   mov  [bx], ax       ;   copy AX to bx location in BX
256.     ml$ = ml$ + CHR$(&H5D) ' pop  bp               ; restore BP
257.     ml$ = ml$ + CHR$(&HCA) + CHR$(&H8) + CHR$(&H0) ' retf 8                ; Return Far and skip 8 bytes of variables
258.     DEF SEG = VARSEG(ml$) ' Set current segment this machine code segment  'here is SSEG
259.     offset% = SADD(ml$) ' Set offset to this machine code location
260.     CALL ABSOLUTE(ax, bx, cx, dx, offset%) ' The actual call to this machine code
261.     DEF SEG ' Restore the default segment
262.  
263. END SUB
264.  
265. FUNCTION NextToPlay (board(), PreviousPlayer)
266.     opp = Opponent(PreviousPlayer)
267.     IF AnyLegalMove(opp, board()) THEN NextToPlay = opp: EXIT FUNCTION
268.     IF AnyLegalMove(PreviousPlayer, board()) THEN NextToPlay = PreviousPlayer
269. END FUNCTION
270.  
271. FUNCTION Opponent (player)
272.     IF player = WHITE THEN Opponent = BLACK
273.     IF player = BLACK THEN Opponent = WHITE
274. END FUNCTION
275.  
276. SUB ShowBd
277.     LINE (tlx, tly)-(brx, bry), 8, BF
278.     FOR i = 0 TO 8
279.         LINE (tlx + SquareWidth * i, tly)-(tlx + SquareWidth * i, bry)
280.         LINE (tlx, tly + SquareWidth * i)-(brx, tly + SquareWidth * i)
281.     NEXT
282.     FOR y = 1 TO 8
283.         FOR x = 1 TO 8
284.             IF board(10 * y + x) <> EMPTY THEN
285.                 CIRCLE (tlx + SquareWidth * x - SquareWidth / 2, tly + SquareWidth * y - SquareWidth / 2), PieceRadius, Colour(board(10 * y + x))
286.                 PAINT (tlx + SquareWidth * x - SquareWidth / 2, tly + SquareWidth * y - SquareWidth / 2), Colour(board(10 * y + x))
287.             END IF
288.         NEXT
289.     NEXT
290. END SUB
291.  
292. FUNCTION WeightedSquares (player, board())
293.     opp = Opponent(player)
294.     sum = 0
295.     FOR i = 0 TO 99
296.         IF board(i) = player THEN sum = sum + weights(i)
297.         IF board(i) = opp THEN sum = sum - weights(i)
298.     NEXT
299.     WeightedSquares = sum
300. END FUNCTION
301.  
302. FUNCTION WouldFlip (move, player, board(), dir)
303.     c = move + dir
304.     IF board(c) <> Opponent(player) THEN WouldFlip = 0: EXIT FUNCTION
305.     WouldFlip = FindBracketingPiece(c + dir, player, board(), dir)
306. END FUNCTION
307.  

see attachment for screenshot

Title: Re: Reversi / Othello Game (play against computer AI)
Post by: johnno56 on October 14, 2018, 04:51:35 pm

qbguy,

Thank you for the cool game. I was totally "cleaned up" but still a good game.

TempodiBasic.

Thank you for the corrections.

J

Text Only | Text with Attachments