Print Page - Random Access Files

Active Forums => QB64 Discussion => Topic started by: pinology on August 28, 2018, 03:50:57 pm

Title: Random Access Files
Post by: pinology on August 28, 2018, 03:50:57 pm

i'm writing a program that keeps stats for my game. I created a random access file and it worked great for two players when I created the file with the two records manually. So now I know its only a couple lines but what do I have to add to have it add user input name$ and have it check to see if the name already exists and create a new record if it doesn't

Title: Re: Random Access Files
Post by: bplus on August 28, 2018, 04:42:39 pm

Welcome pinology!

Is this a homework problem?

Well regardless, the first example here:
http://qb64.org/wiki/RANDOM
might be adapted to your very question!

Title: Re: Random Access Files
Post by: FellippeHeitor on August 28, 2018, 09:21:00 pm

Welcome to the forum, pinology.

That does sound like homework.

Can you share what you've already got? We can give tips from that.

Title: Re: Random Access Files
Post by: SMcNeill on August 28, 2018, 09:39:01 pm

From my past experience helping folks with this type problem, the point where I find they run into issues is with the string comparisons from length issues...

Often, for random access files, a TYPE is used to store data, which sets strings to a specific length:

TYPE DataType
FirstName AS STRING * 20
LastName AS STRING * 20
Age AS _BYTE
END TYPE

DIM MyFile AS DataType

'Read in a record

INPUT firstname$ 'Get the name

IF firstname$ = MyFile.FirstName THEN
'Do Stuff

***********************

Now, with the above, chances are you'll NEVER find a first name that matches.

Reason??

The file might have a first name of "Bob" in it, and we might type the name "Bob" into the program, but no match is made.... Why?

MyFile.FirstName is a record of 20 characters, as defined by our TYPE. It's "Bob ", with 17 spaces at the end, instead of just "Bob".

If this *is* your issue, trim the strings to compare first:

IF LTRIM$(RTRIM$(firstname$)) = LTRIM$(RTRIM$(MyFile.FirstName)) THEN
'Do stuff

Title: Re: Random Access Files
Post by: pinology on August 29, 2018, 12:16:00 am

cool thanks for the welcomes and responses guys. Think i'll try smcneills first I feel like a total idiot I must have 100 if then lines in my program but I have been stuck all day forgetting i could just use the dot operator with it to search my file also I probably would have forgot to ltrim and rtrim it too. thanks. no it isn't homework all it's a game I'm writing, just that I haven't done any programming in about 30 years and have forgotten most of what I knew about random access files and back then I was using gw basic and a little bit of q basic it had just come out. this qb64 was totally new to me but I love it and am getting into programming again. I love the _putimage and _sndopen stuff, back then I never learned to progam a mouse either took me a couple of weeks to figure all that out. Actually got most of that done by reading your guys posts but after getting stuck I figured I might as well join and see if I could get an answer and thank you guys so Thanks Guys

Title: Re: Random Access Files
Post by: TerryRitchie on August 29, 2018, 12:22:30 am

Wow, I cut my teeth on GWBasic (Gee-Whiz Basic) too when I moved to the PC platform. QBasic was a god-send. Line numbers ... bleh. :)

Glad to have you as a member pinology ... welcome!

Title: Re: Random Access Files
Post by: bplus on August 29, 2018, 12:38:22 am

From the example I pointed out, I took the part that looked handy and commented it. The function will return the record number for Bob (=search$) if Bob is in a record, 0 if not in record.

Code: QB64: [Select]

FUNCTION RecordPos (file$, search$)
    f = FREEFILE
    OPEN file$ FOR INPUT AS #f
    FL = LOF(f)
    dat$ = INPUT$(FL, f) '<<<<<<<<<<<<<<<<<<<<< this takes the whole file and loads it into one giant string =dat$
    CLOSE f
    recpos = INSTR(dat$, search$) '>>>>>>>>>>>>>>>>>>>>>> this seaches the giant string for Bob, if finds Bob returns the position in string
    IF recpos THEN RecordPos = recpos \ recLEN + 1 ELSE RecordPos = 0 ' >>> this converts the find position in string to a record number for Random access of that record
END FUNCTION
 

Title: Re: Random Access Files
Post by: pinology on August 30, 2018, 02:23:52 am

thanks b plus I copied that code I was going to use seek and a counter but that looks way eaiser. line numbers where kinda neat terry if you forgot a line you could just give it a number in the middle

Title: Re: Random Access Files
Post by: codeguy on August 30, 2018, 04:25:08 am

if your records are in sorted order by what you seek, you can use Binary Search and make things MUCH faster, especially for very large files containing thousands, millions or billions+ records. Also, your drives will thank you.

Code: QB64: [Select]

FUNCTION BinarySearch& (channel%, therecord AS record, search$)
    Lowsearch& = 1 '* this is the lowest valid record number in a random access file
    HighSearch& = LOF(channel%) / LEN(therecord) '* this is the number of records based on UDT length
    DO
        middlesearch& = Lowsearch& + (HighSearch& - Lowsearch&) \ 2
        GET #channel%, middlesearch&, therecord
        IF UCASE$(LTRIM$(RTRIM$(therecord.firstname))) < UCASE$(LTRIM$(RTRIM$(search$))) THEN
            Lowsearch& = middlesearch& + 1
        ELSEIF UCASE$(LTRIM$(RTRIM$(therecord.firstname))) > UCASE$(LTRIM$(RTRIM$(search$))) THEN
            HighSearch& = middlesearch& - 1
        ELSE
            EXIT DO
        END IF
    LOOP until HighSearch& < Lowsearch&
    IF HighSearch& < Lowsearch& THEN
    '* indexes crossed means a match was not found
        BinarySearch& = 0
    ELSE
        BinarySearch& = middlesearch&
    END IF
END FUNCTION
 

Title: Re: Random Access Files
Post by: bplus on August 30, 2018, 09:41:55 am

Hi pinology,

I have to warn with the search method I showed, if people have names like Billybob or Bbbob (the stutterer) those Bobs will be found before real Bob (case insensitive searching), a capital B at start (but that means they go into record like that) and a space after Bob to set search$ to (case sensitive search), will prevent some false positives.

With 2 going on 3 records probably not a problem.

Title: Re: Random Access Files
Post by: pinology on August 31, 2018, 04:06:00 pm

thanks for all the help guys i'm kinda stuck here trying to incorporate that function bplus gave me into what I had started so i'll post my code and hopefully someone can lead me in the right direction I feel like an idiot for having to ask again at this point but have only been using qb64 for about a month now but I have a large data file when someone besides me and danny want to play I have to go into it manually and add them to the program

TYPE kstats
name AS STRING * 10
ktg AS LONG 'keiths total games
ktw AS LONG 'keiths total wins
kgd AS LONG 'keiths games against dan
kwd AS LONG 'keiths wins against dan
kab AS LONG 'keiths at bats
kh AS LONG 'keiths hits
ka AS DOUBLE 'keiths average

END TYPE
DIM SHARED keith AS kstats
recordlen% = LEN(keith)
keith.name = "Keith": keith.ktg = 0: keith.ktw = 0: keith.kgd = 0: keith.kwd = 0: keith.kab = 0: keith.kh = 0: keith.ka = 0
OPEN "kdata " FOR RANDOM AS #1
PUT #1, 1, keith
CLOSE #1

TYPE dstats
name AS STRING * 10
dtg AS LONG 'dans total games
dtw AS LONG 'dans total wins
dgk AS LONG 'dans games against keith
dwk AS LONG 'dans wins against keith
dab AS LONG 'dans at bats
dh AS LONG 'dans hits
da AS DOUBLE 'dans average

END TYPE
DIM SHARED danny AS dstats
recordlen% = LEN(danny)
danny.name = "Danny": danny.dtg = 0: danny.dtw = 0: danny.dgk = 0: danny.dwk = 0: danny.dab = 0: danny.dh = 0: danny.da = 0
OPEN "ddata " FOR RANDOM AS #2
PUT #2, 1, danny
CLOSE #2

'from here down my guesses on how to change what i started as 2 seperate random files into one big data file to be able to add names
'first i only need one type with all the same variables the exception being games against other players but just make a seperate file for that
'i'm kinda getting lost here if i use kdata as the type for each record and players for the big data file i'm thinking it would go something like

'open "players" for random as #1
'get #1,,kdata
'close #1
'then the two players enter their names
'input "Player 1 Enter your name ";player1$
'input "Player 2 Enter your name ";player2$
'kdata.name = player1$
'then i would have to call the recordpos function which i'm not sure how to do and check to see if player1 is already on file and what record number
'and when it gets back call it again to check player2

FUNCTION RecordPos (file$, search$) 'file$ = ddata search$ = danny.name
f = FREEFILE
OPEN file$ FOR INPUT AS #f 'file$ = ddata
FL = LOF(f)
dat$ = INPUT$(FL, f) '<<<<<<<<<<<<<<<<<<<<< this takes the whole file and loads it into one giant string =dat$
CLOSE f
recpos = INSTR(dat$, search$) '>>>>>>>>>>>>>>>>>>>>>> this seaches the giant string for Bob, if finds Bob returns the position in string
IF recpos THEN RecordPos = recpos \ recLEN + 1 ELSE RecordPos = 0 ' >>> this converts the find position in string to a record number for Random access of that record
END FUNCTION

Title: Re: Random Access Files
Post by: pinology on August 31, 2018, 04:39:21 pm

thanks codeguy I've never worked with binary files but might have to end up giving that a try i'm supposing the the random file can be opened as binary in the function?

Title: Re: Random Access Files
Post by: bplus on August 31, 2018, 05:17:42 pm

Hmm... this is a thinker because what you are tracking is a cross between a database and a spreadsheet, more spread sheet maybe. A spreadsheet would summarize data that a Database might track, total games, totals of anything and with that averages. I was thinking this would be a simple high score tracker.

I always think of a data base tracking info of one event in this case a game between 2 players

Player Game Database Record
GameDate as string or date, length depends of date format
OpponentName as string length depends on longest name a player might have
PlayerAtBats as integer
PlayerHits as integer ( _Byte for me :D )
PlayerWinTF as _byte

just everything fact you want to track for each player. Databases are recorder's more than they are processors.

In your case, I would advise each game has 2 files to fill out, one record for each player's file (since you are planning a separate file for each player anyway, let's do it from start.)

After database is set up and recording games, then you can run the stats for each player by opening up the file for each player and count things and do averages and write a report.

So now we need a file for each player, file$ = playerName$ + ".DAT"
BUT Heck!
you don't even have to know if a player has a file yet! Because when you open a file for random it is already started!
So with each game open each player's random access ".DAT" from game folder and file the record by adding the new record to the end of the file ie count the records and put the new one in as count + 1.

So pinology, what's you take on what I have said so far?

Title: Re: Random Access Files
Post by: pinology on August 31, 2018, 05:53:03 pm

I like it for some reason doing the database by date never occurred to me and like you said can start with the two files already created that will take care of the searching the whole database but I wouldn't want to open a random file for every new player would I? just a record right? then after input of the 2 names in fact that is the only input from the keyboard rest is all mouse if say I had like 50 different players I could just assign the new player the next available file number instead of record number and have that be there id number for the next time they play like if input$ = "joe" then filenum = 48. I could work that but seems like a lot of files and wouldn't I need 50 if thens to check the previous file numbers for names. your getting me going there and is that close to what you were trying to say

Title: Re: Random Access Files
Post by: SMcNeill on August 31, 2018, 06:03:54 pm

See if something like this is what you're looking for:

Code: QB64: [Select]

TYPE player
    name AS STRING * 10
    tg AS LONG 'total games
    tw AS LONG 'total wins
    gao AS STRING * 40 'games against others  (up to 10 players)
    wao AS STRING * 40 'wins against others (up to 10 players)
    ab AS LONG 'at bats
    h AS LONG 'hits
    a AS DOUBLE 'average
END TYPE
 
DIM Record AS player, pname AS STRING * 10, temp AS LONG
OPEN "MyDatabase.txt" FOR RANDOM AS #1 LEN = LEN(Record)
 
SCREEN _NEWIMAGE(800, 600, 32)
 
 
DO
    INPUT "Enter Player's Name: ", pname
    IF pname = "" THEN CLOSE: END
    MaxRecord = LOF(1) \ LEN(Record)
    RecordNumber = 0
    FOR i = 1 TO MaxRecord
        GET #1, i, Record
        IF Record.name = pname THEN 'we found the record
            PRINT 'view existing record
            PRINT "RECORD FOUND:"
            PRINT "Player Name: "; Record.name
            PRINT "Total Games: "; Record.tg
            PRINT "Total Wins: "; Record.tg
            FOR x = 1 TO 10
                PRINT "Games Against Player"; x; ":";
                PRINT CVL(MID$(Record.gao, 4 * x - 3, 4))
                PRINT "Wins Against Player"; x; ":";
                PRINT CVL(MID$(Record.wao, 4 * x - 3, 4))
            NEXT
            PRINT "At Bat: "; player.ab
            PRINT "Hits: "; player.h
            PRINT "Average: "; player.a
            RecordNumber = i
            EXIT FOR 'no need to search any more once we're found
        END IF
    NEXT
    IF RecordNumber = 0 THEN 'we didn't find anyone
        PRINT
        PRINT "NEW RECORD:"
        RecordNumber = MaxRecord + 1
    END IF
    Record.name = pname
    PRINT "Player Name: "; Record.name 'add a new record, or update an old one.
    INPUT "Total Games: ", Record.tg
    INPUT "Total Wins: ", Record.tg
    FOR x = 1 TO 10
        PRINT "Games Against Player"; x; ":";
        INPUT "", temp
        MID$(Record.gao, 4 * x - 3, 4) = MKL$(temp)
        PRINT "Wins Against Player"; x; ":";
        INPUT "", temp
        MID$(Record.wao, 4 * x - 3, 4) = MKL$(temp)
    NEXT
    INPUT "At Bat: ", player.ab
    INPUT "Hits: ", player.h
    INPUT "Average: ", player.a
    PUT #1, RecordNumber, Record
LOOP

Note, this will always ask you to update a record once it finds it, but it should be able to handle finding and returning files automatically, as well as creating new ones when it doesn't find them.

Note 2: This also has a limited data set for up to 10 players to be tracked at once. You'd need to tweak the string size to set it for the max number of players you want to track.

Note 3: If I was going to seriously use something like this, I'd change it so that the INPUT used a basic menu system so the user could update the fields they wanted, without having to reenter everything each time they viewed a record.

But, as a little demo, this might be able to help you on the road to being able to do what you were talking about. ;)

Title: Re: Random Access Files
Post by: bplus on August 31, 2018, 06:15:46 pm

Yeah, Steve's looks easier, specially since it's already written! ;)

I was trying to accommodate stats between players because rivalries are a big thing with players, usually!

5 files, 500 files, we are leaving it up to the OS to do the file (playerName.dat) searching, = 0 things to code, don't let number of files scare you.

So Steve is saying one file, and one record for each player and that record will only contain the current status of stats of each player.

I have advised one data base file for each player with dates and opponents you can code all sorts of questions to ask your data base files. BTW Getting a list of files is not so hard either specially if the all end in".DAT". Yes, a little more complex but we do love to code don't we? ;-))

Title: Re: Random Access Files
Post by: SMcNeill on August 31, 2018, 06:38:52 pm

Quote from: bplus on August 31, 2018, 06:15:46 pm

Yeah, Steve's looks easier, specially since it's already written! ;)

I was trying to accommodate stats between players because rivalries are a big thing with players, usually!

5 files, 500 files, we are leaving it up to the OS to do the file (playerName.dat) searching, = 0 things to code, don't let number of files scare you.

My little example still lets you track stats between players (though I'd probably tweak it to store Win-Loss-Draw instead of just Wins), as long as you know the player's record number. (That info should probably be displayed along with the name, but I just tossed that little demo together while eatting supper and taking a break from my little map maker...)

(And 500 files scare me, personally; I'm always afraid I'll leave a crapload out if I ever need to zip them up and port them to another machine. Which, if I'm being honest, is why I created QBDbase and have huge databases much to large to load/run in a 32-bit OS. I'd personally rather have one massive database than 500 small ones.)

There's a lot of things I think should be added/expanded upon, if someone was going to use it for a serious data base project. My first suggestions for improvement would be:

1) Error Check user input. Make names ALL CAPS to avoid input/search issues. Make certain somebody doesn't enter -14 for games played...

2) Display the record number with each record, for user ease of knowing who's who.

3) Display name as well as number when displaying, or asking for, "Games against", "Wins against", "Loss against"...

4) Change from "auto-update ALL" to a menu system so you can choose what elements to update. Why change/renter stats for all 10 players, when you just played one of them?

I'd definitely want to make some alterations to make the demo a little more foolproof and user-friendly, but it should be a nice "core" to help show you how to get started for the project. ;)

Title: Re: Random Access Files
Post by: bplus on August 31, 2018, 07:49:03 pm

Steve:

Quote

My little example still lets you track stats between players...

Yes, I see that now very nice! Go with Steve's example!

Title: Re: Random Access Files
Post by: pinology on September 01, 2018, 01:19:48 am

ya mcneil that just like what I was trying to do and got close a couple times on my trial runs ya looks like what I was questioning when I put all those rems on that post trying to figure out how to use that recordpos function thanks guys this forum way cool. I could stop by and help out the people that have the really easy questions but you guys are pretty good

Title: Re: Random Access Files
Post by: pinology on September 01, 2018, 01:23:29 am

ya and I won't have any problems hopefully taking care of those notes you left. but actually the game is going to be writing all the stats players will be able to fix some misclicks during the game but not go edit there own stats, gonna have it so they can zero them out and start over every few months if they want to

Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: pinology on August 28, 2018, 03:50:57 pm