Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: PMACKAY on August 27, 2018, 06:24:58 am

Title: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 27, 2018, 06:24:58 am
I can make my own character set using pset, but how can i change the defaults to print using _printstring (x,y),my character so i can keep the speed and work with the system how it is

on microbee you just poke into a memory address and type pcg (user defined) and use the normal print commands
same as for commodore64, ti, sega, bbc so how can i do this. 8x8, 8x16, 16x16.
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: bplus on August 27, 2018, 09:23:23 am
You could make your own "print" character sub.

Setup character draw subs that use pset or lines or circles or ... that fit into a character block 8x16.

sub printChar x, y, charID
select case charID
case c1& : drawC1 x, y
case c2& : drawC2 x, y
...
end select
end sub

sub drawC1 x, y
pset (? + x, ? + y), color?
line ( ? + x, ? + y)-step(?, ?), color?
circle(? + x, ? + y), r, color?
... a bunch of drawing instructions to make the character, all offset by the x, y place to put the top left corner of block.
end sub

with such you can control the colors more than you could with with a font character. You can even make the characters scalable.
This is like making your own tiles.
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: bplus on August 27, 2018, 09:34:03 am
You can also draw all the characters in advance into image handles and use _putimage where you want the character.
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: Petr on August 27, 2018, 10:38:03 am
Code: QB64: [Select]
  1. DIM SHARED chars(255) AS LONG
  2. SCREEN _NEWIMAGE(800, 600, 32)
  3.  
  4. FOR Ascii = 0 TO 255
  5.     chars(Ascii) = _NEWIMAGE(10, 20, 32)
  6.     _DEST chars(Ascii)
  7.     _PRINTSTRING (0, 0), CHR$(Ascii), chars(Ascii)
  8. NEXT Ascii
  10.  
  11. Prnt "What you think? Something this?", 1, 10, 10, 20, 15
  13. Prnt "You have many options in QB64...", 2, 10, 500, 20, -15
  14.  
  15.  
  16.  
  17. SUB Prnt (text AS STRING, size AS INTEGER, StartX AS INTEGER, StartY AS INTEGER, Xspace AS INTEGER, Yspace AS INTEGER)
  18.     x = StartX
  19.     y = StartY
  20.     FOR f = 1 TO LEN(text)
  21.         ch = ASC(text, f)
  22.         x = x + Xspace
  23.         IF x MOD 5 = 0 THEN y = y + Yspace
  24.         _PUTIMAGE (x, y)-(x + (size * 16), y + (size * (8 * f))), chars(ch), 0
  25.         _DELAY .1
  26.     NEXT
  28.  
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: Petr on August 27, 2018, 10:53:47 am
Or see here https://www.qb64.org/forum/index.php?topic=311.msg2031#msg2031. You can use _LoadFont and _Font before save points to array, then this point you can view as quads or circles or 3D objects....
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: Cobalt on August 27, 2018, 10:57:17 am
I would use something like Davey W Taylor's Font Editor to make a new BIOS font and then load that. Galleon set me up a way to  get it to load in QB64. Just put the Charset.h in the QB64 directory.

DECLARE LIBRARY "charset"
 SUB Charset_8x8 (BYVAL o AS _OFFSET)
 SUB Charset_8x16 (BYVAL o AS _OFFSET)
END DECLARE
DIM SHARED c16(7, 15, 255) AS _UNSIGNED _BYTE, charload AS _UNSIGNED _BYTE

Code: QB64: [Select]
  1. CONST TRUE = -1, FALSE = NOT TRUE
  2. SUB loadreapingfont
  3.  OPEN "reaping.fnt" FOR BINARY AS #1
  4.  FOR c% = 0 TO 255
  5.   FOR y% = 0 TO 15
  6.    GET #1, , charload
  7.    FOR x% = 0 TO 7 'STEP -1
  8.     IF readbit(x%, charload) THEN c16(7 - x%, y%, c%) = 1 'any non-0 value should work
  9.    NEXT
  10.   NEXT
  14.  
  15. FUNCTION readbit (bit%, value%)
  16.  IF value% AND 2 ^ bit% THEN readbit = TRUE ELSE readbit = FALSE
  18.  

And I still use a POKE routine to display the text on screen 0 anyway. But that 'should' still work with normal PRINT or _PRINTSTRING in other screen modes as a 8x16 font. I think it will work with a 8x8 too but thats stuck on .NETs forum and until Galleon gets a backup copy to us to have here it maybe lost. Since I only use 8x16 I cut out the code for the 8x8 and don't have a copy.

Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 27, 2018, 01:08:29 pm
Quote from: Cobalt on August 27, 2018, 10:57:17 am
I would use something like Davey W Taylor's Font Editor to make a new BIOS font and then load that. Galleon set me up a way to  get it to load in QB64. Just put the Charset.h in the QB64 directory.

DECLARE LIBRARY "charset"
 SUB Charset_8x8 (BYVAL o AS _OFFSET)
 SUB Charset_8x16 (BYVAL o AS _OFFSET)
END DECLARE
DIM SHARED c16(7, 15, 255) AS _UNSIGNED _BYTE, charload AS _UNSIGNED _BYTE

Code: QB64: [Select]
  1. CONST TRUE = -1, FALSE = NOT TRUE
  2. SUB loadreapingfont
  3.  OPEN "reaping.fnt" FOR BINARY AS #1
  4.  FOR c% = 0 TO 255
  5.   FOR y% = 0 TO 15
  6.    GET #1, , charload
  7.    FOR x% = 0 TO 7 'STEP -1
  8.     IF readbit(x%, charload) THEN c16(7 - x%, y%, c%) = 1 'any non-0 value should work
  9.    NEXT
  10.   NEXT
  14.  
  15. FUNCTION readbit (bit%, value%)
  16.  IF value% AND 2 ^ bit% THEN readbit = TRUE ELSE readbit = FALSE
  18.  

And I still use a POKE routine to display the text on screen 0 anyway. But that 'should' still work with normal PRINT or _PRINTSTRING in other screen modes as a 8x16 font. I think it will work with a 8x8 too but thats stuck on .NETs forum and until Galleon gets a backup copy to us to have here it maybe lost. Since I only use 8x16 I cut out the code for the 8x8 and don't have a copy.
thank you. this is what was looking for. as for 8 x 8 i can just double the length anyway :) cheers
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 27, 2018, 01:12:37 pm
thank you guys for the kind help.... :) I will jump straight to it... when i wake up    3:12am here in australia. ZZZzzzZZzzZ   me
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: johnno56 on August 27, 2018, 04:28:36 pm
Melbourne. Where are you?

J
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: johnno56 on August 27, 2018, 04:58:03 pm
I used to have an Amstrad (8bit) back in the mid to late 80's and it, like the commodore and others, could redefine characters. I think they were re definable for two reasons. 1. If you had a LOT of patience - a new character set and 2. To create 8x8 tiles. I think the idea is, it is quicker to display a 64 pixel 'text' tile than it is to plot a 64 pixel tile. After all, a 4 mhz cpu, can only do SO much... lol

The method of 'mapping' the characters was using pencil and paper... Not as easy as THIS program. Great Job! Ah the memories...

J
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: bplus on August 28, 2018, 01:17:24 am
Ascii Character Editor sounded interesting, here is what I came up with today:
Code: QB64: [Select]
  1. _TITLE "Ascii Character Editor"
  2. 'started 2018-08-27 by bplus
  3. 'QB64 X 64 version 1.2 20180228/86  from git b301f92
  4.  
  5. '========================== Instructions: =================================
  6. '
  7. ' Arrow keys move the highlighter around, spacebar toggles tile on/off
  8. ' or just click with mouse to do the same.
  9.  
  10. ' Click buttons to either
  11. ' 1. Enter an ascii by number to edit.
  12. ' 2. Enter a character by pressing the key(s) from which the anscii number is taken.
  13. ' 3. Save a modified character.
  14. ' 4. Save all edits made to flie called "Character Set.DAT".
  15. ' Note: If want to work with more sets, just rename Character Set.DAT
  16. '       If that file isn't found, this app will start from scratch.
  17. '
  18. '==========================================================================
  19.  
  20. CONST CW = 8
  21. CONST CH = 16
  22. CONST SQ = 25
  23. CONST XOFF = 60
  24. CONST YOFF = 80
  25. CONST WW = 800
  26. CONST WH = 600
  27. SCREEN _NEWIMAGE(WW, WH, 32)
  28. _SCREENMOVE (1280 - WW) / 2 + 30, (760 - WH) / 2
  29. DIM SHARED AN%, CX, CY, BLK AS _UNSIGNED LONG, WHT AS _UNSIGNED LONG, FILE$
  30. DIM SHARED MAP(CW + 2, CH + 2) AS STRING * 1
  31. DIM SHARED CS(256) AS STRING * 128
  32. WHT = _RGB32(255, 255, 255)
  33. BLK = _RGB32(0, 0, 0)
  34.  
  35. '==============================   main
  36.  
  37. 'see if there is a file in the works to load else start from scratch
  38. IF _FILEEXISTS("Character Set.DAT") THEN
  39.     OPEN "Character Set.DAT" FOR INPUT AS #1
  40.     FOR i = 1 TO 256
  41.         INPUT #1, CS(i - 1)
  42.     NEXT
  43.     CLOSE #1
  44.     FILE$ = "Character Set.DAT"
  46.     FOR a = 0 TO 255
  47.         CLS
  48.         _PRINTSTRING (0, 0), CHR$(a)
  49.         b$ = ""
  50.         FOR y = 0 TO CH - 1
  51.             FOR x = 0 TO CW - 1
  52.                 IF POINT(x, y) <> BLK THEN b$ = b$ + "1" ELSE b$ = b$ + "0"
  53.             NEXT
  54.         NEXT
  55.         CS(a) = b$
  56.     NEXT
  57.     FILE$ = "Nothing saved yet."
  59.  
  60. FOR i = 1 TO 128
  61.     PRINT MID$(CS(1), i, 1);
  62.     IF i MOD CW = 0 THEN PRINT
  64. 'END
  65. 'sample B for starters
  66. AN% = 66
  67. load AN%
  68. CX = 1: CY = 1
  72.         mx = _MOUSEX
  73.         my = _MOUSEY
  74.         _DELAY .2
  75.         'ascii #  to edit
  76.         IF mx > 500 AND mx < 700 AND my > 50 AND my < 100 THEN
  77.             COLOR WHT, 0
  78.             LINE (500, 50)-(700, 100), BLK, BF
  79.             LOCATE 5, 67: INPUT "Ascii # "; a%
  80.             IF a% >= 0 AND a% <= 255 THEN AN% = a%: load AN%
  81.         END IF
  82.         'chr$  to edit
  83.         IF mx > 500 AND mx < 700 AND my > 110 AND my < 160 THEN
  84.             COLOR WHT, 0
  85.             LINE (500, 110)-(700, 160), BLK, BF
  86.             LOCATE 9, 67: INPUT "Enter Chr$ "; char$
  87.             a% = ASC(char$)
  88.             IF a% >= 0 AND a% <= 255 THEN AN% = a%: load AN%
  89.         END IF
  90.         'save character edit
  91.         IF mx > 500 AND mx < 700 AND my > 170 AND my < 220 THEN
  92.             b$ = ""
  93.             FOR y = 1 TO CH
  94.                 FOR x = 1 TO CW
  95.                     b$ = b$ + MAP(x, y)
  96.                 NEXT
  97.             NEXT
  98.             CS(AN%) = b$
  99.             COLOR WHT, 0
  100.             LINE (500, 170)-(700, 220), BLK, BF
  101.             LOCATE 13, 67: PRINT " Character recorded. "
  102.             _DISPLAY
  103.             _DELAY 1.5
  104.         END IF
  105.         'file character set
  106.         IF mx > 500 AND mx < 700 AND my > 230 AND my < 280 THEN
  107.             COLOR WHT, 0
  108.             LINE (500, 230)-(700, 280), BLK, BF
  109.             OPEN "Character Set.DAT" FOR OUTPUT AS #1
  110.             FOR a = 0 TO 255
  111.                 PRINT #1, CS(a)
  112.             NEXT
  113.             CLOSE #1
  114.             LOCATE 16, 65: PRINT "Filed Character Set.DAT"
  115.             _DISPLAY
  116.             _DELAY 1.5
  117.         END IF
  118.  
  119.         'mouse over edit box, toggle tiles and update cursor
  120.         tx = (mx - XOFF) \ SQ: ty = (my - YOFF) \ SQ
  121.         IF tx >= 1 AND tx <= CW AND ty >= 1 AND ty <= CH THEN
  122.             CX = tx: CY = ty
  123.             IF MAP(CX, CY) = "1" THEN MAP(CX, CY) = "0" ELSE MAP(CX, CY) = "1"
  124.         END IF
  125.     END IF
  126.     KH& = _KEYHIT
  127.     SELECT CASE KH&
  128.         CASE 32 'space bar
  129.             IF MAP(CX, CY) = "1" THEN MAP(CX, CY) = "0" ELSE MAP(CX, CY) = "1"
  130.         CASE 18432 'up
  131.             IF CY - 1 >= 1 THEN CY = CY - 1
  132.         CASE 20480 'down
  133.             IF CY + 1 <= CH THEN CY = CY + 1
  134.         CASE 19200 'left
  135.             IF CX - 1 >= 1 THEN CX = CX - 1
  136.         CASE 19712 'right
  137.             IF CX + 1 <= CW THEN CX = CX + 1
  138.     END SELECT
  139.  
  140.     IF _KEYDOWN(27) THEN END
  141.     update
  142.     _DISPLAY
  143.     _LIMIT 60
  145.  
  146. SUB load (asci)
  147.     FOR i = 1 TO 128
  148.         y = i \ CW + 1
  149.         x = i MOD CW: IF x = 0 THEN x = 8: y = y - 1
  150.         MAP(x, y) = MID$(CS(asci), i, 1)
  151.     NEXT
  153.  
  154. SUB update
  155.     COLOR WHT, _RGB32(100, 110, 100): CLS
  156.     drwBtn 500, 50, "Load map with Ascii"
  157.     drwBtn 500, 110, "Load map with Chr$"
  158.     drwBtn 500, 170, "Save Character Edit"
  159.     drwBtn 500, 230, "File Character Set"
  160.     COLOR _RGB32(250, 225, 255), _RGB32(100, 110, 100)
  161.     _PRINTSTRING (398, 400), "Current Ascii% =" + STR$(AN%) + " or CHR$(" + LTRIM$(STR$(AN%)) + ") = " + CHR$(AN%)
  162.     _PRINTSTRING (398, 440), "File: " + FILE$
  163.     LINE (XOFF - 1, YOFF - 1)-STEP((CW + 2) * SQ + 2, (CH + 2) * SQ + 2), _RGB32(255, 255, 0), B
  164.     LINE (XOFF + 1, YOFF + 1)-STEP((CW + 2) * SQ, (CH + 2) * SQ), BLK, B
  165.     LINE (XOFF, YOFF)-STEP((CW + 2) * SQ, (CH + 2) * SQ), _RGB32(255, 80, 0), BF
  166.     FOR y = 1 TO CH
  167.         FOR x = 1 TO CW
  168.             IF MAP(x, y) = "1" THEN c& = _RGB32(200, 200, 200) ELSE c& = _RGB32(0, 0, 0)
  169.             LINE ((x) * SQ + XOFF, (y) * SQ + YOFF)-STEP(SQ - 2, SQ - 2), c&, BF
  170.         NEXT
  171.     NEXT
  172.     ' let's see actual size!
  173.     COLOR _RGB32(255, 255, 0), _RGB32(100, 110, 100)
  174.     FOR i = 1 TO 4
  175.         drwChar XOFF + 16 * (i * 2), .5 * YOFF - (16 * i) / 2, AN%, i
  176.     NEXT
  177.     'highlight sqr
  178.     LINE (CX * SQ - 1 + XOFF, CY * SQ - 1 + YOFF)-STEP(SQ, SQ), WHT, B
  179.  
  181.  
  182. SUB drwBtn (x, y, s$)
  183.     th = 16: tw = 8 * LEN(s$): gray& = _RGB32(190, 190, 190)
  184.     LINE (x, y)-STEP(200, 50), _RGB32(0, 0, 0), BF
  185.     LINE (x, y)-STEP(197, 47), _RGB32(255, 255, 255), BF
  186.     LINE (x + 1, y + 1)-STEP(197, 47), gray&, BF
  187.     COLOR _RGB32(0, 0, 0), gray&
  188.     _PRINTSTRING (x + 100 - 4 * LEN(s$), y + 17), s$
  190.  
  191. SUB drwChar (x0, y0, ascn, size) 'what ever the present color is set at
  192.     FOR y = 0 TO CH - 1
  193.         FOR x = 0 TO CW - 1
  194.             i = i + 1
  195.             IF MID$(CS(ascn), i, 1) = "1" THEN LINE (x0 + x * size, y0 + y * size)-STEP(size - 1, size - 1), , BF
  196.         NEXT
  197.     NEXT
  199.  
 [ This attachment cannot be displayed inline in 'Print Page' view ]  

Then a quick little demo, showing table:
Code: QB64: [Select]
  1. _TITLE "Using custom characters"
  2. 'started 2018-08-27 by bplus
  3. 'QB64 X 64 version 1.2 20180228/86  from git b301f92
  4.  
  5.  
  6. CONST CW = 8
  7. CONST CH = 16
  8. CONST WW = 800
  9. CONST WH = 600
  10. CONST MAPW = 30
  11. CONST MAPH = 20
  12. CONST sq = 20
  13. SCREEN _NEWIMAGE(WW, WH, 32)
  14. _SCREENMOVE (1280 - WW) / 2 + 30, (760 - WH) / 2
  15. DIM SHARED AN%, CX, CY, BLK AS _UNSIGNED LONG, WHT AS _UNSIGNED LONG, FILE$
  16. DIM SHARED MAP(CW + 2, CH + 2) AS STRING * 1
  17. DIM SHARED CS(256) AS STRING * 128
  18. WHT = _RGB32(255, 255, 255)
  19. BLK = _RGB32(0, 0, 0)
  20.  
  21. '==============================   main
  22.  
  23. i = 0
  24. FOR y = 10 TO 500 STEP 40
  25.     FOR x = 10 TO 700 STEP 40
  26.         drwChar x, y, i, 2
  27.         i = i + 1
  28.         IF i > 155 THEN END
  29.     NEXT
  31.  
  32. SUB drwChar (x0, y0, ascn, size) 'what ever the present color is set at
  33.     'CS() DIM SHARED in starting setup
  34.     STATIC beenHere
  35.     IF beenHere = 0 THEN
  36.         'see if there is a file in the works to load else start from scratch
  37.         IF _FILEEXISTS("Character Set.DAT") THEN
  38.             OPEN "Character Set.DAT" FOR INPUT AS #1
  39.             FOR i = 1 TO 256
  40.                 INPUT #1, CS(i - 1)
  41.             NEXT
  42.             CLOSE #1
  43.             FILE$ = "Character Set.DAT"
  44.         ELSE
  45.             PRINT "Can't find Character Set.DAT file, goodbye!"
  46.             END
  47.         END IF
  48.         beenHere = -1
  49.     END IF
  50.     FOR y = 0 TO CH - 1
  51.         FOR x = 0 TO CW - 1
  52.             i = i + 1
  53.             IF MID$(CS(ascn), i, 1) = "1" THEN LINE (x0 + x * size, y0 + y * size)-STEP(size - 1, size - 1), , BF
  54.         NEXT
  55.     NEXT
  57.  
 [ This attachment cannot be displayed inline in 'Print Page' view ]  
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: FellippeHeitor on August 28, 2018, 01:38:49 am
Now that was quick, bplus! And it does look good too!
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: johnno56 on August 28, 2018, 04:24:47 am
Just curious. Why are the characters 8x16? The old characters were 8x8...

J
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: bplus on August 28, 2018, 08:43:07 am
I was using QB64 default font. BTW, these characters can't be printed in normal PRINT statement, they are copied so all original characters remain intact and you make your own print statements by stringing the 8x16 tiles together or resize them and draw bigger!

If QB64 is not fast enough (it usually is), draw the characters to image handles as Petr has shown and make your own _printstring sub.
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 28, 2018, 09:20:44 am
Quote from: johnno56 on August 27, 2018, 04:58:03 pm
I used to have an Amstrad (8bit) back in the mid to late 80's and it, like the commodore and others, could redefine characters. I think they were re definable for two reasons. 1. If you had a LOT of patience - a new character set and 2. To create 8x8 tiles. I think the idea is, it is quicker to display a 64 pixel 'text' tile than it is to plot a 64 pixel tile. After all, a 4 mhz cpu, can only do SO much... lol

The method of 'mapping' the characters was using pencil and paper... Not as easy as THIS program. Great Job! Ah the memories...

J

this is what i want, not to make a new sub or thing, just straight out replacement of the character. redifine it.... the routine is faster to just print rather then slow the computer down using pset (x,y): i am able to rip character roms from original roms, but i just want to change a few not the whole set. its really to make my game more appealing... a monster as a monster. brick as bricks and so on. the ascii is great but now i want to be more creative.
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 28, 2018, 09:55:24 am
Cobal. I seem to get an error message Segmentation fault (core dumped)I am not sure if I am doing something wrong.
   or I am missing something somewhere.
It is what I am after though...

DECLARE LIBRARY ".\Extensions\charset"
    SUB Charset_8x8 (BYVAL o AS _OFFSET)
    SUB Charset_8x16 (BYVAL o AS _OFFSET)
END DECLARE
DIM SHARED c16(7, 15, 255) AS _UNSIGNED _BYTE, charload AS _UNSIGNED _BYTE
CONST TRUE = -1, FALSE = NOT TRUE
 
 
 
loadreapingfont
Charset_8x16 (c16)
FOR i = 1 TO 255
    PRINT CHR$(i);
NEXT i
 
 
 
 
 
 
END
 
SUB loadreapingfont
    OPEN ".\FONT\char256.bin" FOR BINARY AS #1
    FOR c% = 0 TO 255
        FOR y% = 0 TO 15
            GET #1, , charload
            FOR x% = 0 TO 7 'STEP -1
                IF readbit(x%, charload) THEN c16(7 - x%, y%, c%) = 1 'any non-0 value should work
            NEXT
        NEXT
    NEXT
    CLOSE
END SUB
 
FUNCTION readbit (bit%, value%)
    IF value% AND 2 ^ bit% THEN readbit = TRUE ELSE readbit = FALSE
END FUNCTION
 there is an 8x16 font set here to downloadwas only using to test, but goes into error
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: Cobalt on August 28, 2018, 10:37:07 am
I've never seen that error(or any other than file not found) before.
,But it looks like this line:

"Charset_8x16 (c16) "

try changing it to:

Charset_8x16 _OFFSET(c16(0, 0, 0))

and you should be good to go.

Just FYI, you can change the name of the loader if you want, LOADREAPINGFONT the game I was working on was Reaping the Dungeon and thats how that got its name, its a bit long but worked for the project.
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 28, 2018, 06:55:52 pm
Quote from: PMACKAY on August 28, 2018, 09:55:24 am
Cobal. I seem to get an error message Segmentation fault (core dumped)I am not sure if I am doing something wrong.
   or I am missing something somewhere.
It is what I am after though...

DECLARE LIBRARY ".\Extensions\charset"
    SUB Charset_8x8 (BYVAL o AS _OFFSET)
    SUB Charset_8x16 (BYVAL o AS _OFFSET)
END DECLARE
DIM SHARED c16(7, 15, 255) AS _UNSIGNED _BYTE, charload AS _UNSIGNED _BYTE
CONST TRUE = -1, FALSE = NOT TRUE
 
 
 
loadreapingfont
Charset_8x16 (c16)
FOR i = 1 TO 255
    PRINT CHR$(i);
NEXT i
 
 
 
 
 
 
END
 
SUB loadreapingfont
    OPEN ".\FONT\char256.bin" FOR BINARY AS #1
    FOR c% = 0 TO 255
        FOR y% = 0 TO 15
            GET #1, , charload
            FOR x% = 0 TO 7 'STEP -1
                IF readbit(x%, charload) THEN c16(7 - x%, y%, c%) = 1 'any non-0 value should work
            NEXT
        NEXT
    NEXT
    CLOSE
END SUB
 
FUNCTION readbit (bit%, value%)
    IF value% AND 2 ^ bit% THEN readbit = TRUE ELSE readbit = FALSE
END FUNCTION
 there is an 8x16 font set here to downloadwas only using to test, but goes into error



Thank you cobalt... this works great. happy as a pig in mud :)
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 28, 2018, 07:55:30 pm
Great stuff, I have ripped into the code and now works with 8x8 fonts.... Have also added.. Fonts were in reverse now fixed. this is just exactly what I wanted... Thank you heaps.


thank you every one for your input.


Now just to work out how to change the individual chars. (this is good). I understand it is in 8 bit string format, gets converted to binary then put in ram 1 bit at a time..
1+2+4+8+16+32+64+128 = 255 (easy old school stuff)

x^i,     funny i am stuffed for math but i can program :)
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 28, 2018, 10:59:39 pm
Worked out... thank you
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 29, 2018, 09:55:08 am
Here is a look at the routine working
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: Cobalt on August 29, 2018, 10:29:25 am
that is looking really cool.
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 29, 2018, 10:57:10 am
I have managed to get the game to feel like it multi tasks. So simple to add stuff now. Just a timer and animate does the rest. Thanks for the awesome .h


I was scared to use pset for drawing as the way i update my screen in the game... there is lots of speed to be had. So lots more stuff can be done.
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on August 29, 2018, 11:10:45 am
In cobalt routine if you do a for i% = 0 to 15 step 2
If readbit
If readbit again with +1
Next i%

That will double the 8x8 into the 8x16

Or if you leave the second one out it will make it look like scanlines on an old tv. Pretty cool.

Remove the 7-x% (just have x%) and it will reverse the character data... eg mirror it or flip
Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: PMACKAY on September 15, 2018, 08:54:40 pm
Just curious, is it possible to have charset.h make 16x16 and 32x32 chars. i know i can put characters together AB to give double width (16x16) but that uses two ASCII chars. can it work to give (a 16x16) rather than using two chars and losing a character.

AB
CD = 32 x 32 but I am wanting A = 32x32 (or at-least 16x16)

Pset works but I prefer AscII as much faster due to already programed in the system.

Wanting this as have a new idea for some different games.



Title: Re: redifine character set... something like on commodore64 or pcg on microbee
Post by: Cobalt on September 16, 2018, 12:09:41 am
not sure, that would be a question for Galleon, he is the one that set this up for me way back when. But he is unfortunatly no longer a part of the team. Steve or Fellippe might be able to figure it out, at least they would be your best bet.
You may have to make a BMP(or PNG) and load it. then you could place the characters with _PUTIMAGE and have that make the characters 16x16 or 32x32 in a graphics mode though.
Text Only | Text with Attachments