QB64.org Forum

Active Forums => Programs => Topic started by: bplus on March 01, 2022, 09:20:09 am

Title: Rotating Pyramid
Post by: bplus on March 01, 2022, 09:20:09 am

Another quickie for this morning and Aurels Forum: http://basic4all.info8-hosting.info/index.php

Showing Aurel how he might do this more satisfactory with his MicroA interpreter with this QB64 example:

Code: QB64: [Select]

1. _Title "Rotating Pyramid" 'b+ 2022-03-01
2. Screen 12
3. cx = _Width / 2
4. ax = cx: ay = 50 ' apex
5. ex = cx: ey = 330 ' ellipse
6. xr = cx * .7: yr = .33 * xr
7. Do
8.     Cls
9.     x1 = ex + xr * Cos(a): y1 = ey + yr * Sin(a)
10.     x2 = ex + xr * Cos(a + _Pi * .5): y2 = ey + yr * Sin(a + _Pi * .5)
11.     x3 = ex + xr * Cos(a + _Pi): y3 = ey + yr * Sin(a + _Pi)
12.     x4 = ex + xr * Cos(a + _Pi * 1.5): y4 = ey + yr * Sin(a + _Pi * 1.5)
13.     l x1, y1, x2, y2
14.     l x2, y2, x3, y3
15.     l x3, y3, x4, y4
16.     l x4, y4, x1, y1
17.     l x1, y1, ax, ay
18.     l x2, y2, ax, ay
19.     l x3, y3, ax, ay
20.     l x4, y4, ax, ay
21.     a = a + .01
22.     _Display
23.     _Limit 30
24. Loop Until _KeyDown(27)
25.  
26. Sub l (a, b, c, d) ' this is just way easier to code lines Aurel you dont need this part
27.     Line (a, b)-(c, d)
28. End Sub
29.  

 

Title: Re: Rotating Pyramid
Post by: SquirrelMonkey on March 05, 2022, 05:18:52 pm

Quote from: bplus on March 01, 2022, 09:20:09 am

Another quickie for this morning and Aurels Forum: http://basic4all.info8-hosting.info/index.php

Showing Aurel how he might do this more satisfactory with his MicroA interpreter with this QB64 example:

Code: QB64: [Select]

1. _Title "Rotating Pyramid" 'b+ 2022-03-01
2. Screen 12
3. cx = _Width / 2
4. ax = cx: ay = 50 ' apex
5. ex = cx: ey = 330 ' ellipse
6. xr = cx * .7: yr = .33 * xr
7. Do
8.     Cls
9.     x1 = ex + xr * Cos(a): y1 = ey + yr * Sin(a)
10.     x2 = ex + xr * Cos(a + _Pi * .5): y2 = ey + yr * Sin(a + _Pi * .5)
11.     x3 = ex + xr * Cos(a + _Pi): y3 = ey + yr * Sin(a + _Pi)
12.     x4 = ex + xr * Cos(a + _Pi * 1.5): y4 = ey + yr * Sin(a + _Pi * 1.5)
13.     l x1, y1, x2, y2
14.     l x2, y2, x3, y3
15.     l x3, y3, x4, y4
16.     l x4, y4, x1, y1
17.     l x1, y1, ax, ay
18.     l x2, y2, ax, ay
19.     l x3, y3, ax, ay
20.     l x4, y4, ax, ay
21.     a = a + .01
22.     _Display
23.     _Limit 30
24. Loop Until _KeyDown(27)
25.  
26. Sub l (a, b, c, d) ' this is just way easier to code lines Aurel you dont need this part
27.     Line (a, b)-(c, d)
28. End Sub
29.  

 

Love this, reminds me of the demo scene.

Title: Re: Rotating Pyramid
Post by: bplus on March 06, 2022, 03:29:53 pm

Ah yeah, _vince has posted the code for this. Beats the heck out of mine but mine was intended to run on a very simple interpreter.

I shall attempt to summon the god of Rotating Pyramids @_vince  please sir, show us how to do it! :)

Title: Re: Rotating Pyramid
Post by: _vince on March 06, 2022, 03:50:39 pm

B+ mode time!

Code: QB64: [Select]

1. const d = 300
2. const z0 = 550
3. const oy = -210
4.  
5. dim shared pi
6. pi = 4*atn(1)
7.  
8. dim x(14), y(14), z(14)
9.  x( 0) =  0:  y( 0) =   0:  z( 0) =  0
10.  x( 1) = 50:  y( 1) =-140:  z( 1) = 50
11.  x( 2) =-50:  y( 2) =-140:  z( 2) = 50
12.  x( 3) =-50:  y( 3) =-140:  z( 3) =-50
13.  x( 4) = 50:  y( 4) =-140:  z( 4) =-50
14.  x( 5) = 50:  y( 5) =-140:  z( 5) = 50
15.  
16. zoom = 5
17.  
18. sw = 640
19. sh = 480
20.  
21. screen 12
22.  
23. a = 0
24. do
25.         cls
26.  
27.         a=a+0.01
28.  
29.         xx = x(0)
30.         yy = y(0)
31.         zz = z(0)
32.         rot xx, zz, a
33.         proj p0, q0, xx, yy, zz
34.  
35.         'draw all triangles
36.         for i=1 to 4
37.                 x1 = x(i)
38.                 y1 = y(i)
39.                 z1 = z(i)
40.                 rot x1, z1, a
41.  
42.                 x2 = x(i + 1)
43.                 y2 = y(i + 1)
44.                 z2 = z(i + 1)
45.                 rot x2, z2, a
46.  
47.                 c = _rgb(70,70,70)
48.  
49.                 proj p, q, x1, y1, z1
50.                 pset (sw/2 + zoom*p0, sh/2 - zoom*q0 + oy), c
51.                 line -(sw/2 + zoom*p, sh/2 - zoom*q + oy), c
52.  
53.                 proj p, q, x2, y2, z2
54.                 line -(sw/2 + zoom*p, sh/2 - zoom*q + oy), c
55.                 line -(sw/2 + zoom*p0, sh/2 - zoom*q0 + oy), c
56.         next
57.  
58.         'draw the visible triangles
59.         for i=1 to 4
60.                 x1 = x(i)
61.                 y1 = y(i)
62.                 z1 = z(i)
63.                 rot x1, z1, a
64.  
65.                 x2 = x(i + 1)
66.                 y2 = y(i + 1)
67.                 z2 = z(i + 1)
68.                 rot x2, z2, a
69.  
70.                 'vector cross product
71.                 'cx = y1*z2 - z1*y2
72.                 'cy = x1*z2 - z1*x2
73.                 cz = x1*y2 - y1*x2
74.  
75.                 if cz >= 0 then
76.                         c = _rgb(255,255,255)
77.  
78.                         proj p, q, x1, y1, z1
79.                         pset (sw/2 + zoom*p0, sh/2 - zoom*q0 + oy), c
80.                         line -(sw/2 + zoom*p, sh/2 - zoom*q + oy), c
81.  
82.                         proj p, q, x2, y2, z2
83.                         line -(sw/2 + zoom*p, sh/2 - zoom*q + oy), c
84.                         line -(sw/2 + zoom*p0, sh/2 - zoom*q0 + oy), c
85.                 end if 
86.         next
87.  
88.         _display
89.         _limit 30
90. loop until _keyhit = 27
91. sleep
92. system
93.  
94. 'rotate
95. sub rot(x, y, a)
96.         xx = x*cos(a) - y*sin(a)
97.         yy = x*sin(a) + y*cos(a)
98.         x = xx
99.         y = yy
100. end sub
101.  
102. 'perspective projection
103. sub proj(p, q, x, y, z)
104.         dz = z0 + z
105.         p = x*d/dz
106.         q = y*d/dz
107. end sub
108.  
109.  

Title: Re: Rotating Pyramid
Post by: bplus on March 06, 2022, 06:15:55 pm

Now all we have to do is rotate that apex around the sphere.

The god of Rotating Pyramids' work is never done.

Title: Re: Rotating Pyramid
Post by: _vince on March 08, 2022, 07:16:48 am

B+ mod #2

seems my calculations are inaccurate, maybe someone can fix why

Code: QB64: [Select]

1. defdbl a-z
2.  
3. const d = 300
4. const z0 = 550
5. const oy = 00
6.  
7. dim shared pi
8. pi = 4*atn(1)
9.  
10. dim x(5), y(5), z(5)
11.  x( 0) =  0:  y( 0) = 70:  z( 0) =  0
12.  x( 1) = 70:  y( 1) =-70:  z( 1) = 70
13.  x( 2) =-70:  y( 2) =-70:  z( 2) = 70
14.  x( 3) =-70:  y( 3) =-70:  z( 3) =-70
15.  x( 4) = 70:  y( 4) =-70:  z( 4) =-70
16.  x( 5) = 70:  y( 5) =-70:  z( 5) = 70
17.  
18. zoom = 4
19.  
20. sw = 640
21. sh = 480
22.  
23. screen _newimage(sw,sh,32)
24.  
25. a = 0
26. do
27.         cls
28.  
29.         a = a + 0.01
30.  
31.         xx = x(0)
32.         yy = y(0)
33.         zz = z(0)
34.  
35.         rot yy, zz, a
36.         rot xx, zz, a
37.  
38.         proj p0, q0, xx, yy, zz
39.  
40.         'draw all triangles
41.         for i=1 to 4
42.                 x1 = x(i)
43.                 y1 = y(i)
44.                 z1 = z(i)
45.        
46.                 rot y1, z1, a
47.                 rot x1, z1, a
48.                
49.        
50.                 x2 = x(i + 1)
51.                 y2 = y(i + 1)
52.                 z2 = z(i + 1)
53.        
54.                 rot y2, z2, a
55.                 rot x2, z2, a
56.        
57.                 c = _rgb(35,35,35)
58.        
59.                 proj p, q, x1, y1, z1
60.                 pset (sw/2 + zoom*p0, sh/2 - zoom*q0 + oy), c
61.                 line -(sw/2 + zoom*p, sh/2 - zoom*q + oy), c
62.        
63.                 proj p, q, x2, y2, z2
64.                 line -(sw/2 + zoom*p, sh/2 - zoom*q + oy), c
65.                 line -(sw/2 + zoom*p0, sh/2 - zoom*q0 + oy), c
66.         next
67.  
68.         'draw the visible triangles
69.         for i=1 to 4
70.                 x1 = x(i)
71.                 y1 = y(i)
72.                 z1 = z(i)
73.  
74.                 rot y1, z1, a
75.                 rot x1, z1, a
76.  
77.                 x2 = x(i + 1)
78.                 y2 = y(i + 1)
79.                 z2 = z(i + 1)
80.  
81.                 rot y2, z2, a
82.                 rot x2, z2, a
83.        
84.                 'vector cross product
85.                 cz = (x1 - xx)*(y2 - yy) - (y1 - yy)*(x2 - xx)
86.  
87.                 if cz > 0 then
88.                         c = _rgb(255,255,255)
89.        
90.                         proj p, q, x1, y1, z1
91.                         pset (sw/2 + zoom*p0, sh/2 - zoom*q0 + oy), c
92.                         line -(sw/2 + zoom*p, sh/2 - zoom*q + oy), c
93.        
94.                         proj p, q, x2, y2, z2
95.                         line -(sw/2 + zoom*p, sh/2 - zoom*q + oy), c
96.                         line -(sw/2 + zoom*p0, sh/2 - zoom*q0 + oy), c
97.                 end if 
98.         next
99.  
100.         'draw the base
101.         xx = x(1)
102.         yy = y(1)
103.         zz = z(1)
104.         rot yy, zz, a
105.         rot xx, zz, a
106.  
107.         x1 = x(2)
108.         y1 = y(2)
109.         z1 = z(2)
110.         rot y1, z1, a
111.         rot x1, z1, a
112.  
113.         x2 = x(3)
114.         y2 = y(3)
115.         z2 = z(3)
116.         rot y2, z2, a
117.         rot x2, z2, a
118.  
119.         cz = (x1 - xx)*(y2 - yy) - (y1 - yy)*(x2 - xx)
120.  
121.         if cz < 0 then
122.                 c = _rgb(255,255,255)
123.                 proj p0, q0, xx, yy, zz
124.                 pset (sw/2 + zoom*p0, sh/2 - zoom*q0 + oy), c
125.                 for i=2 to 5
126.                         xx = x(i)
127.                         yy = y(i)
128.                         zz = z(i)
129.  
130.                         rot yy, zz, a
131.                         rot xx, zz, a
132.  
133.                         proj p, q, xx, yy, zz
134.                         line -(sw/2 + zoom*p, sh/2 - zoom*q + oy), c
135.                 next
136.         end if
137.  
138.         _display
139.         _limit 30
140. loop until _keyhit = 27
141. sleep
142. system
143.  
144. 'rotate
145. sub rot(x, y, a)
146.         xx = x*cos(a) - y*sin(a)
147.         yy = x*sin(a) + y*cos(a)
148.         x = xx
149.         y = yy
150. end sub
151.  
152. 'perspective projection
153. sub proj(p, q, x, y, z)
154.         dz = z0 + z
155.         p = x*d/dz
156.         q = y*d/dz
157. end sub
158.  
159.  

Title: Re: Rotating Pyramid
Post by: bplus on March 08, 2022, 09:46:24 am

Hey, not bad, the only thing I see less that perfect is the apex remaining on the left side.

Text Only | Text with Attachments