Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: bplus on January 07, 2022, 11:48:47 pm

Title: Wordle - a new word game
Post by: bplus on January 07, 2022, 11:48:47 pm
Pretty easy to figure out, read title bar for instructions:
Code: QB64: [Select]
  1. _Title "Wordle: 6 guesses to get 5 letter word, enter guess or nothing to quit, yellow is right letter wrong place, green is right letter right place."
  2. Randomize Timer ' b+ 20220107
  3. f& = _LoadFont("arial.ttf", 24, "MONOSPACE")
  4. Screen _NewImage(1024, 600, 32)
  5. _ScreenMove 100, 100
  6. Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  7. Do ' again new round
  8.     Cls
  9.     Open "5 Letter Words.txt" For Input As #1 'grab a word, this is fast enough
  10.     nWord = Int(Rnd * 2104) + 1
  11.     For i = 1 To nWord
  12.         Input #1, w$
  13.     Next
  14.     Close #1
  15.     'Locate 20, 60: Print w$ ' for debug or cheat
  16.     printRow = 0
  17.     For i = 1 To 6 ' allowed 6 guesses
  18.         hits = 0 ' how many letters are dead right?
  19.         tryAgain: ' opps too many or few letters in guess
  20.         printRow = printRow + 1 ' track left print line for inputs mostly
  21.         Locate printRow, 1: Print " "; _Trim$(Str$(i)); "# ";
  22.         Input "Enter a 5 letter word for your guess "; guess$
  23.         If guess$ = "" Then System
  24.         If Len(guess$) <> 5 Then Sound 50, 4: printRow = printRow + 1: Print "Try again": GoTo tryAgain
  25.         _Font f&
  26.         For letter = 1 To 5
  27.             Locate i, letter + 30
  28.             If Mid$(w$, letter, 1) = Mid$(guess$, letter, 1) Then
  29.                 hits = hits + 1
  30.                 Color _RGB32(0, 0, 0), _RGB32(0, 128, 0)
  31.             ElseIf InStr(w$, Mid$(guess$, letter, 1)) Then
  32.                 Color _RGB32(0, 0, 0), _RGB32(255, 255, 0)
  33.             Else
  34.                 Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  35.             End If
  36.             Print Mid$(guess$, letter, 1)
  37.         Next
  38.         _Font 16
  39.         Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  40.         If hits = 5 Then Locate printRow + 1: Print "You got it!": _Delay 3: GoTo skip
  41.     Next
  42.     Sound 50, 4
  43.     printRow = printRow + 2
  44.     Locate printRow, 1: Print "The word was "; w$
  45.     _Delay 3
  46.     skip:
  48.  

The zip contains source, exe for Windows, 2 word files and the code to convert one to "5 Letter Words.txt" file.
  [ This attachment cannot be displayed inline in 'Print Page' view ]  
Title: Re: Wordle - a new word game
Post by: euklides on January 08, 2022, 04:29:29 am
A letter mastermind...
Title: Re: Wordle - a new word game
Post by: bplus on January 08, 2022, 01:38:21 pm
Quote from: euklides on January 08, 2022, 04:29:29 am
A letter mastermind...

Yes, and Bulls and Cows game with digits, but Wordle has the advantage of knowing which and where the dead right letter(s) is(are). On the other hand there are usually less colors than digits more than double, and less digits than letters more than double. On the other, other hand, colors can be doubled up (or more eg, all 4 the same) in Mastermind and they are usually all unique in Bulls and Cows and how I made Wordle.
Title: Re: Wordle - a new word game
Post by: GronkleNut on January 10, 2022, 05:23:24 pm
Fun, although I think the rules are slightly different to those you've implemented, you can't just put in random letters for your guess you have to put in a valid 5 letter word - hopefully easy to check the user entered guess word is in the word list before evaluating/highlighting the guess.
Title: Re: Wordle - a new word game
Post by: bplus on January 10, 2022, 05:38:12 pm
So someone finally gets around to posting some code for Wordle at LB, tsh73 of course!

He brought up some interesting things:
1. Using console (no color coding) he Capitalized the right letters in the wrong place and he [boxed] the letters in the right place.
2. He demands the word guesses be in the dictionary he is using! That is a really hard to do twist compared to my strategy of going in sets of abcde, fghij, klmno,... and getting all the letters in at most 5.
OK I confess being dumbfounded if I had to use real word guesses, unless....

Here is my Wordle 2, your guesses must be a word in the dictionary but you get the dictionary list to select the Word from!!! Further I tried my select item from array code and it sucked without a speedy scroll bar to jump from A to Z fast!

So WTH I loaded the list into yours and mine designated or default .txt Editor from a Shell command.

Now to get the word you select from the list into the Game app you Copy the word into the Clipboard and then Click the Game app to get the focus back to that and hit Enter. The app reads the word from Clipboard as your next guess.

So the code for Wordle 2 isn't much more than Wordle 1:
Code: QB64: [Select]
  2. _Title "Wordle 2: 6 guesses to get 5 letter word, enter guess or nothing to quit, yellow is right letter wrong place, green is right letter right place."
  4.  
  5. ' b+ 2022-01-09 Wordle 2: this version you have to select words from word list for your guess
  6. '2022-01-10 working but selecting words from wordlist is really slow, need to allow letters to jump up and down the list faster!
  7. ' Today we will select word from opened text editor
  8. ' 1) copy word to clipboard
  9. ' 2) signal this program you've got the new word loaded in clipboard
  10. ' Get rid of the ' words in "5 Letter Words.txt" file, too unexpected. So rewrite the file builder from unixdict.txt OK 9 words removed.
  11.  
  12. Dim As Long f, topWord, printRow, nGuess, hits, letter
  13. Dim answer$, guess$, k$
  14.  
  15. f = _LoadFont("arial.ttf", 24, "MONOSPACE") ' a nice font for displaying Game letters with color
  16. Screen _NewImage(600, 400, 32) ' leave room for Editor window next to this QB64 app
  17. _ScreenMove 200, 200
  18. Color _RGB32(200, 200, 200), _RGB32(0, 0, 0) ' not too bright white on black for normal print
  19.  
  20. Dim dict(1 To 10000) As String ' oversized array to load word list
  21. Open "5 Letter Words.txt" For Input As #1 ' this file uses 5 unique letters, allot of 5 letter 1st names in here
  23.     topWord = topWord + 1
  24.     Input #1, dict(topWord)
  27. Shell _DontWait Chr$(34) + "5 Letter Words.txt" + Chr$(34)
  28.  
  29. Do ' again new round
  30.     Cls
  31.     Locate 24, 6: Print "You have to click the QB64 app to get focus back into the app.";
  32.     answer$ = dict(Int(Rnd * topWord) + 1) ' pick new word to guess
  33.     printRow = 0 ' reset for round
  34.     For nGuess = 1 To 6 ' allowed 6 guesses
  35.         hits = 0 ' how many letters are dead right? reset
  36.         printRow = printRow + 1 ' track left print line for inputs display mostly
  37.  
  38.         ' here we are to select a word from word list in the Editor we opened and copy it to clipboard
  39.         ' you have to click the QB64 app to get focus back into the app.
  40.         Locate 23, 3: Print "Select a word from Editor and copy to clipboard, press enter when done."
  41.         k$ = InKey$
  42.         While k$ <> Chr$(13): k$ = InKey$: Wend
  43.         guess$ = _Trim$(_Clipboard$)
  44.         If guess$ = "" Then System
  45.         Locate 23, 1: Print Space$(75);
  46.         Locate printRow, 1: Print nGuess; guess$
  47.  
  48.         _Font f&
  49.         For letter = 1 To 5
  50.             Locate nGuess + 1, letter + 16
  51.             If Mid$(answer$, letter, 1) = Mid$(guess$, letter, 1) Then
  52.                 hits = hits + 1
  53.                 Color _RGB32(0, 0, 0), _RGB32(0, 128, 0)
  54.             ElseIf InStr(answer$, Mid$(guess$, letter, 1)) Then
  55.                 Color _RGB32(0, 0, 0), _RGB32(255, 255, 0)
  56.             Else
  57.                 Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  58.             End If
  59.             Print Mid$(guess$, letter, 1)
  60.         Next
  61.         _Font 16
  62.         Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  63.         If hits = 5 Then Locate 13, 45: Print "You got it! ...zzz": Sleep: GoTo skip
  64.     Next
  65.     Sound 50, 4
  66.     Locate 16, 38: Print "The word was "; answer$; "  ...zzz"
  67.     Sleep
  68.     skip:
  69.     _Font 16
  71.  

You can use the old "5 Letter Words.txt", I found it contained words with an ' so I modified the "Make 5 Letter Word file.bas to this:
Code: QB64: [Select]
  1. Open "unixdict.txt" For Input As #1
  2. Open "5 Letter Words.txt" For Output As #2
  4.     Input #1, w$
  5.     If InStr(w$, "'") Then 'skip
  6.     Else
  7.         good = 1
  8.         If Len(w$) = 5 Then
  9.             For i = 1 To 4
  10.                 If InStr(i + 1, w$, Mid$(w$, i, 1)) Then good = 0: Exit For
  11.             Next
  12.             If good Then Print #2, w$
  13.         End If
  14.     End If
  17. Print "5 Letter Words.txt, file ready."
  18.  
It removes 9 words from file. The unixdict.txt is still in zip of the first post.

  [ This attachment cannot be displayed inline in 'Print Page' view ]  
Title: Re: Wordle - a new word game
Post by: bplus on January 10, 2022, 05:39:55 pm
Quote from: GronkleNut on January 10, 2022, 05:23:24 pm
Fun, although I think the rules are slightly different to those you've implemented, you can't just put in random letters for your guess you have to put in a valid 5 letter word - hopefully easy to check the user entered guess word is in the word list before evaluating/highlighting the guess.

Hi @GronkleNut

Yeah just posted Wordle 2 with rule of using real words, thanks. :)
Title: Re: Wordle - a new word game
Post by: Statsman1 on January 10, 2022, 06:45:06 pm
Looks great, I love this game, but as an avid Wordle player, I must add that duplicate letters ARE permitted in Wordle.  I looked at the dictionary file supplied, and words like ANNEX, COCOA and BUDDY are legitimate Wordle entries, but are not in the dictionary file.
Title: Re: Wordle - a new word game
Post by: bplus on January 10, 2022, 06:56:50 pm
Quote from: Statsman1 on January 10, 2022, 06:45:06 pm
Looks great, I love this game, but as an avid Wordle player, I must add that duplicate letters ARE permitted in Wordle.  I looked at the dictionary file supplied, and words like ANNEX, COCOA and BUDDY are legitimate Wordle entries, but are not in the dictionary file.

Sorry, never heard of let alone played it. I thought unique letter set would be easier to code.

Well there is always my Wordle 3 or yours? @Statsman1 ;-)) BTW always been fascinated by symbol in your avatar, curious about the real origin.
Title: Re: Wordle - a new word game
Post by: Statsman1 on January 10, 2022, 07:06:57 pm
Hey @bplus -

No problem, your Wordle is excellent.  I am not sure I could code anything to allow for the duplicate of letters anytime soon, though I imagine it would simply be a little more recursive comparing (to wit - instead of stopping when you find the character in the word, you have to check each character in a guess to see if it matches each letter in the solution, cannot just stop the search after finding the first instance of E in ELECT if the guess is TRADE).

As for the symbol - well, it is an ankh, an Egyptian symbol that means life.  You see this in hieroglyphics and all sorts of ancient Egyptian symbolism.  How it became MY talisman is a little less exotic - Ultima IV for the Apple II is my favorite video game of all time.  I adopted the ankh, when I bought the original game back in 1985, as my good-luck charm, and have carried it all through my life.  I have the very same one that came with the game, back in ‘85, on a chain that I wear from time to time, and I have a couple of other metal ankhs here and there around the house.

Kinda silly, I know, but Ultima IV, and the ankh, have meant a lot to me in 35 years.  :)
Title: Re: Wordle - a new word game
Post by: bplus on January 11, 2022, 01:05:18 am
OK Wordle 3 handles repeated letters, it was a little tricky when more than 1 letter in guess matches a letter in the answer to match. A little better instructions screen at start too.
Code: QB64: [Select]
  2. _Title "Wordle 3" ' b+ 2022-01-10 allow repeated letters in Word Game
  4.  
  5. ' b+ 2022-01-09 Wordle 2: this version you have to select words from word list for your guess
  6. '2022-01-10 working but selecting words from wordlist is really slow, need to allow letters to jump up and down the list faster!
  7. ' Today we will select word from opened text editor
  8. ' 1) copy word to clipboard
  9. ' 2) signal this program you've got the new word loaded in clipboard
  10. ' Get rid of the ' words in "5 Letter Words.txt" file, too unexpected. So rewrite the file builder from unixdict.txt OK 9 words removed.
  11.  
  12. ' 2022-01-10 Wordle 3: allow repeated letters (make it even harder! to play and code?)
  13. ' Revise "Make 5 Letter Words W3.bas" code to rebuild "5 Letter Words W3.txt" with words with repeating letters.
  14.  
  15. Dim As Long f, topWord, printRow, nGuess, hits, letter, p, colorCode(1 To 5)
  16. Dim answer$, guess$, k$, blank$
  17.  
  18. f = _LoadFont("arial.ttf", 24, "MONOSPACE") ' a nice font for displaying Game letters with color
  19. Screen _NewImage(600, 400, 32) ' leave room for Editor window next to this QB64 app
  20. _ScreenMove 200, 200
  21. Color _RGB32(200, 200, 200), _RGB32(0, 0, 0) ' not too bright white on black for normal print
  22. '      123456789012345678901234567890123456789012345678901234567890123456789012345
  23. Locate 8, 1
  24. Print "                          The Skinny on Wordle:"
  26. Print "                You get 6 tries to guess a 5 letter word."
  27. Print "          A letter color coded yellow is right letter wrong place."
  28. Print "          A letter color coded green is right letter right place."
  30. Print "            ...zzz  means to press a key to continue ...zzz"
  32.  
  33. Dim dict(1 To 10000) As String ' oversized array to load word list
  34. Open "5 Letter Words W3.txt" For Input As #1 ' W3 version allows repeated letters, allot of 5 letter 1st names in here
  36.     topWord = topWord + 1
  37.     Input #1, dict(topWord)
  40. Shell _DontWait Chr$(34) + "5 Letter Words W3.txt" + Chr$(34)
  41.  
  42. Do ' again new round
  43.     Cls
  44.     Locate 24, 6: Print "You have to click the QB64 app to get focus back into the app.";
  45.     answer$ = dict(Int(Rnd * topWord) + 1) ' pick new word to guess
  46.     printRow = 0 ' reset for round
  47.     For nGuess = 1 To 6 ' allowed 6 guesses
  48.         hits = 0 ' how many letters are dead right? reset
  49.         printRow = printRow + 1 ' track left print line for inputs display mostly
  50.         ' here we are to select a word from word list in the Editor we opened and copy it to clipboard
  51.         Locate 23, 3: Print "Select a word from Editor and copy to clipboard, press enter when done."
  52.         k$ = InKey$
  53.         While k$ <> Chr$(13): k$ = InKey$: Wend
  54.         guess$ = _Trim$(_Clipboard$)
  55.         If guess$ = "" Then System
  56.         Locate 23, 1: Print Space$(75);
  57.         Locate printRow + 3, 10: Print nGuess; guess$
  58.         _Font f&
  59.         blank$ = answer$ ' we use blank to remove letters as we assign colors
  60.         Erase colorCode
  61.         For letter = 1 To 5
  62.             If Mid$(answer$, letter, 1) = Mid$(guess$, letter, 1) Then
  63.                 hits = hits + 1
  64.                 Mid$(blank$, letter, 1) = " " ' remove green letters taken by direct hits
  65.                 colorCode(letter) = 3
  66.             End If
  67.         Next
  68.         For letter = 1 To 5
  69.             If colorCode(letter) <> 3 Then
  70.                 p = InStr(blank$, Mid$(guess$, letter, 1))
  71.                 If p > 0 Then
  72.                     colorCode(letter) = 2
  73.                     Mid$(blank$, p, 1) = " " ' remove so can't color again
  74.                 End If
  75.             End If
  76.         Next
  77.         For letter = 1 To 5 ' now to display our colorful feedback about the guess
  78.             Locate nGuess + 1, letter + 16
  79.             If colorCode(letter) = 3 Then
  80.                 Color _RGB32(0, 0, 0), _RGB32(0, 128, 0)
  81.             ElseIf colorCode(letter) = 2 Then
  82.                 Color _RGB32(0, 0, 0), _RGB32(255, 255, 0)
  83.             Else
  84.                 Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  85.             End If
  86.             Print Mid$(guess$, letter, 1)
  87.         Next
  88.         _Font 16
  89.         Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  90.         If hits = 5 Then Locate 13, 45: Print "You got it! ...zzz": Sleep: GoTo skip
  91.     Next
  92.     Sound 50, 4
  93.     Locate 16, 38: Print "The word was "; answer$; "  ...zzz"
  94.     Sleep
  95.     skip:
  96.     _Font 16
  98.  

You will also need the new Make file to assemble the 5 Letter Words W3 List that allow repeated letters, saved under a modified name so as a different file is made so the old list works with older version of game.
Code: QB64: [Select]
  1. Open "unixdict.txt" For Input As #1
  2. Open "5 Letter Words W3.txt" For Output As #2
  4.     Input #1, w$
  5.     If InStr(w$, "'") Then 'skip
  6.     Else
  7.         If Len(w$) = 5 Then Print #2, w$
  8.     End If
  11. Print "5 Letter Words W3.txt, file ready."
  12.  
Again the unixdict.txt file is in the zip in first post of this thread.

 
Title: Re: Wordle - a new word game
Post by: Statsman1 on January 11, 2022, 11:41:09 am
Awesome, @bplus!!
Title: Re: Wordle - a new word game
Post by: bplus on January 11, 2022, 01:16:43 pm
Quote from: Statsman1 on January 11, 2022, 11:41:09 am
Awesome, @bplus!!

Thanks I hope you noticed the example I chose for screen shot :)
Title: Re: Wordle - a new word game
Post by: Statsman1 on January 11, 2022, 02:15:25 pm
I did notice, that is how I know you 100% test your programs!  :)
Title: Re: Wordle - a new word game
Post by: Statsman1 on January 11, 2022, 02:35:35 pm
Of course, now my afternoon productivity is going down the tubes....

Title: Re: Wordle - a new word game
Post by: bplus on January 11, 2022, 04:22:44 pm
Call it the vital service of Beta Testing. :)
Title: Re: Wordle - a new word game
Post by: SMcNeill on January 11, 2022, 11:07:37 pm
Now, for version 4, it needs to have a difficulty screen where you choose words from 3 to 10 letters.

Personally, I imagine a game with 3 letter words would be hard as heck to guess, whereas s 10-letter word would be relatively simple (counter-intuitively).  Three letters, you have less chance to get a letter on a guess, and there's soooo many 3-letter words with minute variance in them!  Bat, but, bot, bit, bet... even if you get the b and t, there's 5 unique choices for the middle letter alone!  10-letter words, on the other hand, have more chances to guess a letter from them, and a much smaller pool of words to try and march from.
Title: Re: Wordle - a new word game
Post by: bplus on January 12, 2022, 05:19:53 am
OK version 4 you chose number of letters / number of guesses for your level, why not :)

For 3 letter words with 3 word guesses: pie, tau, soy
you learn what vowels you have plus 3 common consonants, likely hit with 2 of 3.
Title: Re: Wordle - a new word game
Post by: bplus on January 12, 2022, 08:05:28 am
OK to prepare for Wordle 4, I cleaned out the unixdict.txt of 757 words that had punctuation or digits in them to Clean_Dict.txt. Then in 2nd part of code, Make N Letter Word Files.bas below, I made 10 files according to word length. Included with the code for making those files I have listed the word counts for each file in comments at the end.

Code: QB64: [Select]
  1. ' Make "Clean_Dict.txt" pure letters only b+ 2022-01-12
  2. DefLng A-Z
  3. Open "unixdict.txt" For Input As #1
  4. Open "Clean_Dict.txt" For Output As #2
  6.     Input #1, w$
  7.     lw = Len(w$)
  8.     If (lw > 2) And (lw < 13) Then ' word lengths 3 to 12, makes 9 files
  9.         i = 1: OK = -1
  10.         While i <= lw ' check for pure letter words
  11.             If (Asc(w$, i) < 97) Or (Asc(w$, i) > 122) Then OK = 0: Exit While
  12.             i = i + 1
  13.         Wend
  14.         If OK Then Print #2, w$
  15.     End If
  18. Print "Clean_Dict.txt, file ready."
  19.  
  20. ' Note: Clean_Dict.txt has 757 words less than unixdict.txt
  21.  
  22. ' Part 2 make 9 N_Letter_Word.txt files
  23. For N = 3 To 12
  24.     Open _Trim$(Str$(N)) + "_Letter_Words.txt" For Output As #N
  26. Open "Clean_Dict.txt" For Input As #1
  28.     Input #1, w$
  29.     Select Case Len(w$)
  30.         Case 3: Print #3, w$
  31.         Case 4: Print #4, w$
  32.         Case 5: Print #5, w$
  33.         Case 6: Print #6, w$
  34.         Case 7: Print #7, w$
  35.         Case 8: Print #8, w$
  36.         Case 9: Print #9, w$
  37.         Case 10: Print #10, w$
  38.         Case 11: Print #11, w$
  39.         Case 12: Print #12, w$
  40.     End Select
  43. Print "10 N_letter_Words.txt files should be ready."
  44.  
  45. ' N letters - number of words in file
  46. ' 3 - 753
  47. ' 4 - 2176
  48. ' 5 - 3145   the other 5 Letter Words W3.txt had u.s.a that was removed with above code
  49. ' 6 - 3852
  50. ' 7 - 4042
  51. ' 8 - 3608
  52. ' 9 - 3088
  53. ' 10 - 1971
  54. ' 11 - 1120
  55. ' 12 - 592
  56.  
  57.  

Reading through 3_Letter_Words.txt you will find non words like aaa or nne so be glad you can view the dictionary as you play the game! :)

Again I remind that unixdict.txt is in the zip of post at the start of this thread.

OK onto mod Wordle 4...
Title: Re: Wordle - a new word game
Post by: SMcNeill on January 12, 2022, 09:30:02 am
Quote from: bplus on January 12, 2022, 05:19:53 am
OK version 4 you chose number of letters / number of guesses for your level, why not :)

For 3 letter words with 3 word guesses: pie, tau, soy
you learn what vowels you have plus 3 common consonants, likely hit with 2 of 3.

My point is the difficulty of getting the last letter.

Lets say you guess SOY.  OY is correct and in the proper place -- that's guess #1.

Boy
Coy
Foy
Goy
Hoy
Joy
Roy
Soy
Toy

You have 4 guesses now to determine which of those 8 letters go into the first slot.

You could try RuT to rule out R and T.
HoG.
JiF

But if none of those work, you're still stuck with 2 choices B and C for the last letter, giving you a 50% chance to win, even if you play your cards perfect.

Or: bat, cat, dat, fat, gat, hat,  kat, lat, mat, nat, pat, rat, sat, tat, vat.... 15 choices ending in AT,...  :P


Title: Re: Wordle - a new word game
Post by: Statsman1 on January 12, 2022, 10:21:10 am
Maybe 3 letters in 6 guesses is too hard, due to the shortness of the word, the number of 3-letter words with common letters, and the overall number of combinations?

5 letters AND being forced to use real words to guess is important, I think, to being able to get to the word in 6 guesses.  I admit I got a Wordle on the 2nd guess the other day, but that was remarkably lucky, I usually get there between 3 and 5 guesses. 

Using openers like STARE, CLOUD and MINTY burn up 14 unique letters - all 6 vowels and most popular consonants in 3 guesses - I feel like, by that point, there is no way you cannot get it by 6 guesses.  Logic plays a huge part in it after that.

Using 3 letter words doesn’t get enough letters out there in the first few guesses to hope to arrive, logically, at the word by the end of 6 guesses, as mentioned by @SMcNeill, especially if the word chosen has a ton of first-letters that go with the last two - ?at, ?ar, ?en…there are loads of those.  It becomes a real roll of the dice.

Maybe 5 letters is the sweet spot between “relying on luck” and “reasonable number of guesses required”?
Title: Re: Wordle - a new word game
Post by: bplus on January 12, 2022, 10:33:14 am
Here it is, the answer to all Steve's challenges (so far):

Wordle 4 with advanced level options:
Code: QB64: [Select]
  2. _Title "Wordle 4" ' b+ 2022-01-12 as Steve suggested add option to choose how many letters, how many guesses
  4.  
  5. ' b+ 2022-01-09 Wordle 2: this version you have to select words from word list for your guess
  6. '2022-01-10 working but selecting words from wordlist is really slow, need to allow letters to jump up and down the list faster!
  7. ' Today we will select word from opened text editor
  8. ' 1) copy word to clipboard
  9. ' 2) signal this program you've got the new word loaded in clipboard
  10. ' Get rid of the ' words in "5 Letter Words.txt" file, too unexpected. So rewrite the file builder from unixdict.txt OK 9 words removed.
  11.  
  12. ' 2022-01-10 Wordle 3: allow repeated letters (make it even harder! to play and code?)
  13. ' Revise "Make 5 Letter Words W3.bas" code to rebuild "5 Letter Words W3.txt" with words with repeating letters.
  14.  
  15. ' 2022-01-12 Worde 4: prep word files by running, Make N Letter Word files.bas, (posted at forum already.)
  16.  
  17. '  All the variables use here
  18. Dim As Long f, NLetters, NGuesses, topWord, printRow, nGuess, hits, letter, p
  19. '  ReDim colorCode(1 To NLetters)
  20. Dim wordFile$, answer$, guess$, k$, blank$
  21.  
  22. f = _LoadFont("arial.ttf", 24, "MONOSPACE") ' a nice font for displaying Game letters with color
  23. Screen _NewImage(600, 400, 32) ' leave room for Editor window next to this QB64 app
  24. _ScreenMove 200, 200
  25. Color _RGB32(200, 200, 200), _RGB32(0, 0, 0) ' not too bright white on black for normal print
  26. '      123456789012345678901234567890123456789012345678901234567890123456789012345
  27. Locate 8, 1
  28. Print "                          The Skinny on Wordle:"
  30. Print "     In Standard Wordle Game, you get 6 tries to guess a 5 letter word.    "
  31. Print "          A letter color coded yellow is right letter wrong place."
  32. Print "          A letter color coded green is right letter right place."
  33. Print "                 ...zzz  means to press a key to continue."
  35. Print "              Press <a> to run an advanced level Wordle Game,"
  36. Print "                  any other to play Standard Wordle Game."
  37. k$ = InKey$
  38. While Len(k$) = 0: k$ = InKey$: Wend
  39. If k$ = "a" Then 'advanced level
  40.     Cls
  41.     lAgain:
  42.     Input "Please enter the number of letters (3-12) of words to play "; NLetters
  43.     If NLetters < 3 Or NLetters > 12 Then GoTo lAgain
  44.     gAgain:
  45.     Input "Please enter the number of guesses (2-10) to allow yourself "; NGuesses
  46.     If NGuesses < 2 Or NGuesses > 10 Then GoTo gAgain
  47.     _Title "Wordle 4 Advanced Options:" + Str$(NLetters) + " Letter Words with" + Str$(NGuesses) + " guesses allowed."
  49.     NLetters = 5: NGuesses = 6
  51. wordFile$ = _Trim$(Str$(NLetters)) + "_Letter_Words.txt"
  52. Dim dict(1 To 10000) As String ' oversized array to load word list
  53. Open wordFile$ For Input As #1 ' W3 version allows repeated letters, allot of 5 letter 1st names in here
  55.     topWord = topWord + 1
  56.     Input #1, dict(topWord)
  59. Shell _DontWait Chr$(34) + wordFile$ + Chr$(34)
  60.  
  61. Do ' again new round
  62.     Cls
  63.     Locate 24, 6: Print "You have to click the QB64 app to get focus back into the app.";
  64.     answer$ = dict(Int(Rnd * topWord) + 1) ' pick new word to guess
  65.     printRow = 0 ' reset for round
  66.     For nGuess = 1 To NGuesses ' allowed 6 guesses (in Standard Game)
  67.         hits = 0 ' how many letters are dead right? reset
  68.         printRow = printRow + 1 ' track left print line for inputs display mostly
  69.         ' here we are to select a word from word list in the Editor we opened and copy it to clipboard
  70.         Locate 23, 3: Print "Select a word from Editor and copy to clipboard, press enter when done."
  71.         k$ = InKey$
  72.         While k$ <> Chr$(13): k$ = InKey$: Wend
  73.         guess$ = _Trim$(_Clipboard$)
  74.         If guess$ = "" Then System
  75.         Locate 23, 1: Print Space$(75);
  76.         Locate printRow + 3, 10: Print nGuess; guess$
  77.         _Font f&
  78.         blank$ = answer$ ' we use blank to remove letters as we assign colors
  79.         ReDim colorCode(1 To NLetters)
  80.         For letter = 1 To NLetters
  81.             If Mid$(answer$, letter, 1) = Mid$(guess$, letter, 1) Then
  82.                 hits = hits + 1
  83.                 Mid$(blank$, letter, 1) = " " ' remove green letters taken by direct hits
  84.                 colorCode(letter) = 3
  85.             End If
  86.         Next
  87.         For letter = 1 To NLetters
  88.             If colorCode(letter) <> 3 Then
  89.                 p = InStr(blank$, Mid$(guess$, letter, 1))
  90.                 If p > 0 Then
  91.                     colorCode(letter) = 2
  92.                     Mid$(blank$, p, 1) = " " ' remove so can't color again
  93.                 End If
  94.             End If
  95.         Next
  96.         For letter = 1 To NLetters ' now to display our colorful feedback about the guess
  97.             Locate nGuess + 1, letter + 13
  98.             If colorCode(letter) = 3 Then
  99.                 Color _RGB32(0, 0, 0), _RGB32(0, 128, 0)
  100.             ElseIf colorCode(letter) = 2 Then
  101.                 Color _RGB32(0, 0, 0), _RGB32(255, 255, 0)
  102.             Else
  103.                 Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  104.             End If
  105.             Print Mid$(guess$, letter, 1)
  106.         Next
  107.         _Font 16
  108.         Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  109.         If hits = NLetters Then Locate 13, 45: Print "You got it! ...zzz": Sleep: GoTo skip
  110.     Next
  111.     Sound 50, 4
  112.     Locate 16, 38: Print "The word was "; answer$; "  ...zzz"
  113.     Sleep
  114.     skip:
  115.     _Font 16
  117.  

 
 

 


 

Title: Re: Wordle - a new word game
Post by: Dimster on January 12, 2022, 10:48:48 am
This could morph into the new Babble. It would be interesting to guess the English word PIE for the Russian word meaning PIE, or Italian for PIE, or French for PIE etc. Pie is not a good example as the English versions has duplicate meanings, so lets go with WIND .... crap that a duplicate as well ... maybe morphing to the new Babble is a stretch.
Title: Re: Wordle - a new word game
Post by: Statsman1 on January 12, 2022, 11:15:42 am
Love it!  @bplus - for a guy who never played it, you are killing it here!!  :)
Title: Re: Wordle - a new word game
Post by: bplus on January 12, 2022, 11:27:12 am
Thanks @Statsman1

@Dimster I will look into Babble, as possible option or more ideas.

I have a fixed a couple of feedback Locate's to fit on screen with maximun letters 12 and maximum guesses 10 for the advanced levels:
Code: QB64: [Select]
  2. _Title "Wordle 4" ' b+ 2022-01-12 as Steve suggested add option to choose how many letters, how many guesses
  4.  
  5. ' b+ 2022-01-09 Wordle 2: this version you have to select words from word list for your guess
  6. '2022-01-10 working but selecting words from wordlist is really slow, need to allow letters to jump up and down the list faster!
  7. ' Today we will select word from opened text editor
  8. ' 1) copy word to clipboard
  9. ' 2) signal this program you've got the new word loaded in clipboard
  10. ' Get rid of the ' words in "5 Letter Words.txt" file, too unexpected. So rewrite the file builder from unixdict.txt OK 9 words removed.
  11.  
  12. ' 2022-01-10 Wordle 3: allow repeated letters (make it even harder! to play and code?)
  13. ' Revise "Make 5 Letter Words W3.bas" code to rebuild "5 Letter Words W3.txt" with words with repeating letters.
  14.  
  15. ' 2022-01-12 Worde 4: prep word files by running, Make N Letter Word files.bas, (posted at forum already.)
  16. ' fix some feedback Locates rfor maximum guesses and letters
  17.  
  18. '  All the variables use here
  19. Dim As Long f, NLetters, NGuesses, topWord, printRow, nGuess, hits, letter, p
  20. '  ReDim colorCode(1 To NLetters)
  21. Dim wordFile$, answer$, guess$, k$, blank$
  22.  
  23. f = _LoadFont("arial.ttf", 24, "MONOSPACE") ' a nice font for displaying Game letters with color
  24. Screen _NewImage(600, 400, 32) ' leave room for Editor window next to this QB64 app
  25. _ScreenMove 200, 200
  26. Color _RGB32(200, 200, 200), _RGB32(0, 0, 0) ' not too bright white on black for normal print
  27. '      123456789012345678901234567890123456789012345678901234567890123456789012345
  28. Locate 8, 1
  29. Print "                          The Skinny on Wordle:"
  31. Print "     In Standard Wordle Game, you get 6 tries to guess a 5 letter word.    "
  32. Print "          A letter color coded yellow is right letter wrong place."
  33. Print "          A letter color coded green is right letter right place."
  34. Print "                 ...zzz  means to press a key to continue."
  36. Print "              Press <a> to run an advanced level Wordle Game,"
  37. Print "                  any other to play Standard Wordle Game."
  38. k$ = InKey$
  39. While Len(k$) = 0: k$ = InKey$: Wend
  40. If k$ = "a" Then 'advanced level
  41.     Cls
  42.     lAgain:
  43.     Input "Please enter the number of letters (3-12) of words to play "; NLetters
  44.     If NLetters < 3 Or NLetters > 12 Then GoTo lAgain
  45.     gAgain:
  46.     Input "Please enter the number of guesses (2-10) to allow yourself "; NGuesses
  47.     If NGuesses < 2 Or NGuesses > 10 Then GoTo gAgain
  48.     _Title "Wordle 4 Advanced Options:" + Str$(NLetters) + " Letter Words with" + Str$(NGuesses) + " guesses allowed."
  50.     NLetters = 5: NGuesses = 6
  52. wordFile$ = _Trim$(Str$(NLetters)) + "_Letter_Words.txt"
  53. Dim dict(1 To 10000) As String ' oversized array to load word list
  54. Open wordFile$ For Input As #1 ' W3 version allows repeated letters, allot of 5 letter 1st names in here
  56.     topWord = topWord + 1
  57.     Input #1, dict(topWord)
  60. Shell _DontWait Chr$(34) + wordFile$ + Chr$(34)
  61.  
  62. Do ' again new round
  63.     Cls
  64.     Locate 24, 6: Print "You have to click the QB64 app to get focus back into the app.";
  65.     answer$ = dict(Int(Rnd * topWord) + 1) ' pick new word to guess
  66.     printRow = 0 ' reset for round
  67.     For nGuess = 1 To NGuesses ' allowed 6 guesses (in Standard Game)
  68.         hits = 0 ' how many letters are dead right? reset
  69.         printRow = printRow + 1 ' track left print line for inputs display mostly
  70.         ' here we are to select a word from word list in the Editor we opened and copy it to clipboard
  71.         Locate 23, 3: Print "Select a word from Editor and copy to clipboard, press enter when done."
  72.         k$ = InKey$
  73.         While k$ <> Chr$(13): k$ = InKey$: Wend
  74.         guess$ = _Trim$(_Clipboard$)
  75.         If guess$ = "" Then System
  76.         Locate 23, 1: Print Space$(75);
  77.         Locate printRow + 3, 10: Print nGuess; guess$
  78.         _Font f&
  79.         blank$ = answer$ ' we use blank to remove letters as we assign colors
  80.         ReDim colorCode(1 To NLetters)
  81.         For letter = 1 To NLetters
  82.             If Mid$(answer$, letter, 1) = Mid$(guess$, letter, 1) Then
  83.                 hits = hits + 1
  84.                 Mid$(blank$, letter, 1) = " " ' remove green letters taken by direct hits
  85.                 colorCode(letter) = 3
  86.             End If
  87.         Next
  88.         For letter = 1 To NLetters
  89.             If colorCode(letter) <> 3 Then
  90.                 p = InStr(blank$, Mid$(guess$, letter, 1))
  91.                 If p > 0 Then
  92.                     colorCode(letter) = 2
  93.                     Mid$(blank$, p, 1) = " " ' remove so can't color again
  94.                 End If
  95.             End If
  96.         Next
  97.         For letter = 1 To NLetters ' now to display our colorful feedback about the guess
  98.             Locate nGuess + 1, letter + 13
  99.             If colorCode(letter) = 3 Then
  100.                 Color _RGB32(0, 0, 0), _RGB32(0, 128, 0)
  101.             ElseIf colorCode(letter) = 2 Then
  102.                 Color _RGB32(0, 0, 0), _RGB32(255, 255, 0)
  103.             Else
  104.                 Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  105.             End If
  106.             Print Mid$(guess$, letter, 1)
  107.         Next
  108.         _Font 16
  109.         Color _RGB32(200, 200, 200), _RGB32(0, 0, 0)
  110.         If hits = NLetters Then Locate 15, 5: Print "You got it! ...zzz": Sleep: GoTo skip
  111.     Next
  112.     Sound 50, 4
  113.     Locate 16, 2: Print "The word was "; answer$; "  ...zzz"
  114.     Sleep
  115.     skip:
  116.     _Font 16
  118.  

Unless Beta testers find more things, I will post whole package in one zip for Best Answer a little later.
Title: Re: Wordle - a new word game
Post by: bplus on January 12, 2022, 03:16:26 pm
Quote from: Dimster on January 12, 2022, 10:48:48 am
This could morph into the new Babble. It would be interesting to guess the English word PIE for the Russian word meaning PIE, or Italian for PIE, or French for PIE etc. Pie is not a good example as the English versions has duplicate meanings, so lets go with WIND .... crap that a duplicate as well ... maybe morphing to the new Babble is a stretch.

@Dimster did you babble the word game Boggle?
Title: Re: Wordle - a new word game
Post by: Dimster on January 13, 2022, 10:30:33 am
Boggle? Had to look that one up....1972....pre digital era. Can't say I ever played it but I do recall a square plastic filled with chicklets with numbers on them. The idea was to get the numbers in order. A 2d version of the 3d rubric cube filled with colors.
Title: Re: Wordle - a new word game
Post by: bplus on January 13, 2022, 11:48:10 am
Quote from: Dimster on January 13, 2022, 10:30:33 am
Boggle? Had to look that one up....1972....pre digital era. Can't say I ever played it but I do recall a square plastic filled with chicklets with numbers on them. The idea was to get the numbers in order. A 2d version of the 3d rubric cube filled with colors.

The "chicklets" are die with Letters in Boggle:
https://qb64forum.alephc.xyz/index.php?topic=4570.0

@Dimster maybe you can find a good link of what you are talking about?
Title: Re: Wordle - a new word game
Post by: SMcNeill on January 13, 2022, 02:06:18 pm
From my memory of Boggle, the game pieces were made like scrabble, but with the bottom hollowed out, making them look more like the keys on a keyboard, if you've ever pulled those out from the board.

The purpose was to allow for words to build over another...

A vertical word might be:

C
H
E
A
T

For the next turn, the other person might want to spell the word PEON....  A valid way to do that was to:

C
H
E
A
PEON

The hollow bottom P would stack on top of the T and overwrite it, leaving both words "Cheap" and "Peon" to score off from...

Similar to Scrabble, but with that one main word-building difference.
Title: Re: Wordle - a new word game
Post by: STxAxTIC on January 13, 2022, 02:09:57 pm
This game was called UpWords. Boggle was different.

  [ This attachment cannot be displayed inline in 'Print Page' view ]  
Title: Re: Wordle - a new word game
Post by: Statsman1 on January 13, 2022, 02:16:38 pm
Boggle was 16 6-sided cubes (each side had a letter) that were scrambled (shaken up) and then settled into a 4x4 grid.  (Or, later, 5x5) The idea was to make as many unique words out of the cubes that were touching each other, using each cube once, before the timer expired.  Longer word = more points.

Unique because if you found it and your opponent did too, nobody got credit for it.
Title: Re: Wordle - a new word game
Post by: Dimster on January 13, 2022, 03:30:04 pm
https://begin.babbel.com/ (https://begin.babbel.com/) - I believe this title is based on the biblical Tower of Babble. I was thinking your Wordle game could add the "game" aspect to the Babble educationally/utility bent program.
Title: Re: Wordle - a new word game
Post by: bplus on January 13, 2022, 06:12:04 pm
Quote from: Dimster on January 13, 2022, 03:30:04 pm
https://begin.babbel.com/ (https://begin.babbel.com/) - I believe this title is based on the biblical Tower of Babble. I was thinking your Wordle game could add the "game" aspect to the Babble educationally/utility bent program.

Oh man that's for teaching foreign languages. LOL
Text Only | Text with Attachments