QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Cobalt on December 08, 2021, 04:23:35 pm

Title: A question about _INFLATE$\_DEFLATE$ usage
Post by: Cobalt on December 08, 2021, 04:23:35 pm

I was looking into using these commands for my World Builder program to help with the saved map size issue it is facing now. Recent changes, things I just did last night and today, have ballooned the file size to several megs.

Looking at the WIKI the commands take string values. Now my map data is made up of UDTs and integer arrays. How would I go about using these commands to compress the map size when saved?

Title: Re: A question about _INFLATE$\_DEFLATE$ usage
Post by: SpriggsySpriggs on December 08, 2021, 04:27:39 pm

I would make a MEM block and then store all of your map data in it. Then, make a string equal to the size of the memory block. Get the contents of the memory block using MEMGET and store it in the string. Use DEFLATE$ on the string. Now you've compressed the raw map data and can store it elsewhere. Basically use INFLATE$ and reverse the process to unpack.

Title: Re: A question about _INFLATE$\_DEFLATE$ usage
Post by: SMcNeill on December 08, 2021, 06:02:10 pm

Like so:

Code: QB64: [Select]

1. Type DataType 'A datatype to use as an example
2.     x As String * 112
3.     y As Long
4.     z As Long
5. End Type
6.  
7. Dim junk As DataType
8. junk.x = "Hello World.Hello World.Hello World.Hello World.Hello World.Hello World.Hello World.Hello World.Hello World."
9. junk.y = 1 '
   
10. junk.z = 65 'A
11.  
12. C$ = Compression(junk)
13. Print "120 bytes compressed down to "; Len(C$); "bytes."
14. Print
15. Print "And our restored data (as an uncompressed string) is:"
16. Print
17. Print _Inflate$(C$)
18. Print
19.  
20. Print "And our restored data (as an our variable type foo) is:"
21. Dim foo As DataType
22. DeCompression foo, C$
23. Print foo.x
24. Print foo.y
25. Print foo.z
26.  
27.  
28. End
29.  
30. Function Compression$ (t As DataType) 'And here, we want to set up the actual sub to work with our example datatype.
31.     Dim m As _MEM
32.     m = _Mem(t)
33.     temp$ = Space$(m.SIZE)
34.     _MemGet m, m.OFFSET, temp$
35.     Compression$ = _Deflate$(temp$)
36.     _MemFree m
37. End Function
38.  
39. Sub DeCompression (t As DataType, temp$) 'And here, we want to set up the actual sub to work with our example datatype.
40.     Dim m As _MEM
41.     m = _Mem(t)
42.     _MemPut m, m.OFFSET, _Inflate$(temp$)
43.     _MemFree m
44. End Sub
45.  
46.  

Text Only | Text with Attachments