QB64.org Forum

Active Forums => Programs => Topic started by: Dav on November 19, 2021, 01:19:41 pm

Title: Simple File Selection box for graphical modes (Now works in Linux too)
Post by: Dav on November 19, 2021, 01:19:41 pm

This is an update to a simple file section box FUNCTION I made a while back.  The old one wouldn't work in Linux at all - this one does.  Not trying to replace the great direntry.h method, but just throwing in a single FUNCTION alternative easy to stick in a program.   Tested this in Windows and Linux Mint (new fan) and it seems to work correctly and the same in both (can't test it in Mac).

(Special thanks to the Linux guys in this (https://www.qb64.org/forum/index.php?topic=4399.0) thread).

- Dav

EDIT: 11/23/2021 - Fixed file list bug under Linux to show all files when *.* used.

Code: QB64: [Select]

1. '==============
2. 'FILESELECT.BAS  v1.1
3. '==============
4. 'Simple file selector box for graphical screen modes.
5. 'Coded by Dav, NOV/2021 (with the kind help of the QB64.org forum gurus!)
6.  
7. '* NOW WORKS UNDER LINUX!
8.  
9. 'Navigate through directories and select a file.
10. 'Use ARROWS, PAGE Up/Down, HOME, END to scroll list.
11. 'Press ENTER to select highlighted file or enter highlighted dir.
12. 'ESC will cancel and close box
13.  
14. 'things to do: auto center box on screen, and ditch x/y input?
15. '              ...will need to adjust box size based on file/dir chr length
16. '              Add user defined colors instead...?
17.  
18.  
19. SCREEN _NEWIMAGE(700, 500, 32)
20. _SCREENMOVE _MIDDLE
21.  
22. '=== draw a background
23. CLS , _RGB(32, 32, 32)
24. FOR x = 1 TO _WIDTH STEP 3
25.     FOR y = 1 TO _HEIGHT STEP 3
26.         PSET (x, y), _RGB(RND * 255, RND * 255, RND * 255)
27.     NEXT
28. NEXT
29.  
30. '=== Ask user to select a file
31. a$ = FileSelect$(5, 15, 20, 55, "*.*")
32.  
33. IF a$ <> "" THEN
34.     PRINT "You selected: "; a$
35. END IF
36.  
37. END
38.  
39.  
40. FUNCTION FileSelect$ (y, x, y2, x2, Filespec$)
41.  
42.     '=== save original place of cursor
43.     origy = CSRLIN
44.     origx = POS(1)
45.  
46.     '=== save colors
47.     fg& = _DEFAULTCOLOR
48.     bg& = _BACKGROUNDCOLOR
49.  
50.     '=== Save whole screen
51.     DIM scr1 AS _MEM, scr2 AS _MEM
52.     scr1 = _MEMIMAGE(0): scr2 = _MEMNEW(scr1.SIZE)
53.     _MEMCOPY scr1, scr1.OFFSET, scr1.SIZE TO scr2, scr2.OFFSET
54.  
55.     '=== Generate a unique temp filename to use based on date + timer
56.     tmp$ = "_qb64_" + DATE$ + "_" + LTRIM$(STR$(INT(TIMER))) + ".tmp"
57.     IF INSTR(_OS$, "LINUX") THEN tmp$ = "/tmp/" + tmp$
58.  
59.     loadagain:
60.  
61.     top = 0
62.     selection = 0
63.  
64.     '=== list directories
65.     IF INSTR(_OS$, "LINUX") THEN
66.         SHELL _HIDE "find . -maxdepth 1 -type d > " + tmp$
67.     ELSE
68.         SHELL _HIDE "dir /b /A:D > " + tmp$
69.     END IF
70.  
71.     '=== make room for names
72.     REDIM FileNames$(10000) 'space for 10000 filenames
73.  
74.     '=== only show the ".." when not at root dir
75.     IF LEN(_CWD$) <> 3 THEN
76.         FileNames$(0) = ".."
77.         LineCount = 1
78.     ELSE
79.         LineCount = 0
80.     END IF
81.  
82.     '=== Open temp file
83.     FF = FREEFILE
84.     OPEN tmp$ FOR INPUT AS #FF
85.  
86.     WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
87.         LINE INPUT #FF, rl$
88.  
89.         '=== load, ignoring the . entry added under Linux
90.         IF rl$ <> "." THEN
91.  
92.             'also remove the ./ added at the beginning when under linux
93.             IF INSTR(_OS$, "LINUX") THEN
94.                 IF LEFT$(rl$, 2) = "./" THEN
95.                     rl$ = RIGHT$(rl$, LEN(rl$) - 2)
96.                 END IF
97.             END IF
98.  
99.             FileNames$(LineCount) = "[" + rl$ + "]"
100.             LineCount = LineCount + 1
101.  
102.         END IF
103.     WEND
104.  
105.     CLOSE #FF
106.  
107.     '=== now grab list of files...
108.     IF INSTR(_OS$, "LINUX") THEN
109.         SHELL _HIDE "rm " + tmp$
110.         IF Filespec$ = "*.*" THEN Filespec$ = ""
111.         SHELL _HIDE "find -maxdepth 1 -type f -name '" + Filespec$ + "*' > " + tmp$
112.     ELSE
113.         SHELL _HIDE "del " + tmp$
114.         SHELL _HIDE "dir /b /A:-D " + Filespec$ + " > " + tmp$
115.     END IF
116.  
117.     '=== open temp file
118.     FF = FREEFILE
119.     OPEN tmp$ FOR INPUT AS #FF
120.  
121.     WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
122.  
123.         LINE INPUT #FF, rl$
124.  
125.         '=== load, ignoring the generated temp file...
126.         IF rl$ <> tmp$ THEN
127.  
128.             'also remove the ./ added at the beginning when under linux
129.             IF INSTR(_OS$, "LINUX") THEN
130.                 IF LEFT$(rl$, 2) = "./" THEN
131.                     rl$ = RIGHT$(rl$, LEN(rl$) - 2)
132.                 END IF
133.             END IF
134.  
135.             FileNames$(LineCount) = rl$
136.             LineCount = LineCount + 1
137.         END IF
138.  
139.     WEND
140.     CLOSE #FF
141.  
142.     '=== Remove the temp file created
143.     IF INSTR(_OS$, "LINUX") THEN
144.         SHELL _HIDE "rm " + tmp$
145.     ELSE
146.         SHELL _HIDE "del " + tmp$
147.     END IF
148.  
149.  
150.     '=== draw a box
151.     COLOR _RGB(100, 100, 255)
152.     FOR l = 0 TO y2 + 1
153.         LOCATE y + l, x: PRINT STRING$(x2 + 4, CHR$(219));
154.     NEXT
155.  
156.     '=== show current working dir at top
157.     COLOR _RGB(255, 255, 255), _RGB(100, 100, 255)
158.     CurDir$ = _CWD$
159.     '=== Shorten it is too long, for display purposes
160.     IF LEN(CurDir$) > x2 - x THEN
161.         CurDir$ = MID$(CurDir$, 1, x2 - x - 3) + "..."
162.     END IF
163.     LOCATE y, x + 2: PRINT CurDir$;
164.  
165.     '=== scroll through list...
166.     DO
167.  
168.         FOR l = 0 TO (y2 - 1)
169.  
170.             LOCATE (y + 1) + l, (x + 2)
171.             IF l + top = selection THEN
172.                 COLOR _RGB(0, 0, 64), _RGB(255, 255, 255) 'selected line
173.             ELSE
174.                 COLOR _RGB(255, 255, 255), _RGB(0, 0, 64) 'regular
175.                 '=== directories get a different color...
176.                 IF MID$(FileNames$(top + l), 1, 1) = "[" THEN
177.                     COLOR _RGB(255, 255, 0), _RGB(0, 0, 64)
178.                 END IF
179.             END IF
180.  
181.             PRINT LEFT$(FileNames$(top + l) + STRING$(x2, " "), x2);
182.  
183.         NEXT
184.  
185.         '=== Get user input
186.  
187.         k$ = INKEY$
188.         SELECT CASE k$
189.  
190.             CASE IS = CHR$(0) + CHR$(72) 'Up arrow
191.                 IF selection > 0 THEN selection = selection - 1
192.                 IF selection < top THEN top = selection
193.  
194.             CASE IS = CHR$(0) + CHR$(80) 'Down Arrow
195.                 IF selection < (LineCount - 1) THEN selection = selection + 1
196.                 IF selection > (top + (y2 - 2)) THEN top = selection - y2 + 1
197.  
198.             CASE IS = CHR$(0) + CHR$(73) 'Page up
199.                 top = top - y2
200.                 selection = selection - y2
201.                 IF top < 0 THEN top = 0
202.                 IF selection < 0 THEN selection = 0
203.  
204.             CASE IS = CHR$(0) + CHR$(81) 'Page Down
205.                 top = top + y2
206.                 selection = selection + y2
207.                 IF top >= LineCount - y2 THEN top = LineCount - y2
208.                 IF top < 0 THEN top = 0
209.                 IF selection >= LineCount THEN selection = LineCount - 1
210.  
211.             CASE IS = CHR$(0) + CHR$(71) 'Home
212.                 top = 0: selection = 0
213.  
214.             CASE IS = CHR$(0) + CHR$(79) 'End
215.                 selection = LineCount - 1
216.                 top = selection - y2 + 1
217.                 IF top < 0 THEN top = 0
218.  
219.             CASE IS = CHR$(27) ' ESC cancels
220.                 FileSelect$ = ""
221.                 EXIT DO
222.  
223.             CASE IS = CHR$(13) 'Enter
224.                 '=== if .. then go up one dir
225.                 IF RTRIM$(FileNames$(selection)) = ".." THEN
226.                     cd$ = _CWD$
227.                     IF INSTR(_OS$, "LINUX") THEN
228.                         cd$ = LEFT$(cd$, _INSTRREV(cd$, "/"))
229.                     ELSE
230.                         cd$ = LEFT$(cd$, _INSTRREV(cd$, "\"))
231.                     END IF
232.                     CHDIR cd$
233.                     ERASE FileNames$
234.                     GOTO loadagain
235.                 END IF
236.  
237.                 'see if directory
238.                 test$ = RTRIM$(FileNames$(selection))
239.                 IF LEFT$(test$, 1) = "[" THEN
240.                     test$ = MID$(test$, 2, LEN(test$) - 2)
241.                     CHDIR test$
242.                     ERASE FileNames$
243.                     GOTO loadagain
244.                 ELSE
245.                     IF INSTR(_OS$, "LINUX") THEN
246.                         IF RIGHT$(_CWD$, 1) = "/" THEN
247.                             C$ = _CWD$
248.                         ELSE
249.                             C$ = _CWD$ + "/"
250.                         END IF
251.                     ELSE
252.                         IF RIGHT$(_CWD$, 1) = "\" THEN
253.                             C$ = _CWD$
254.                         ELSE
255.                             C$ = _CWD$ + "\"
256.                         END IF
257.                     END IF
258.  
259.                     FileSelect$ = C$ + RTRIM$(FileNames$(selection))
260.                     EXIT DO
261.  
262.                 END IF
263.  
264.         END SELECT
265.  
266.     LOOP
267.  
268.     _KEYCLEAR
269.  
270.     '=== Restore the whole screen
271.     _MEMCOPY scr2, scr2.OFFSET, scr2.SIZE TO scr1, scr1.OFFSET
272.     _MEMFREE scr1: _MEMFREE scr2
273.  
274.     '=== restore original y,x and color
275.     LOCATE origy, origx
276.  
277.     COLOR fg&, bg&
278.  
279. END FUNCTION
280.  
281.  
282.  

Title: Re: Simple File Selection box for graphical modes (Now works in Linux too)
Post by: johnno56 on November 19, 2021, 02:30:02 pm

Well, I for one, think this application is quite impressive. My first instinct was to use the mouse, but keyboard, works for me as well. Very nicely done indeed...

J

Title: Re: Simple File Selection box for graphical modes (Now works in Linux too)
Post by: Dav on November 23, 2021, 07:39:49 am

Thanks, @johnno56.  I'm missing something under linux it appears - no executable files are being displayed in the list.  I'm going have to study the linux file system and commands.

EDIT: I made a quick fix under Linux that seems to work  for now.  Not the best solution, but I need to uderstand more the way Linux uses wildcards to update further.  I Added this to the Linux area when getting a file list. Now all files are listed:

Code: QB64: [Select]

1. IF Filespec$ = "*.*" THEN Filespec$ = ""

- Dav

Text Only | Text with Attachments