QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: SMcNeill on November 09, 2021, 04:29:04 pm

Title: Resizing Screen Demo
Post by: SMcNeill on November 09, 2021, 04:29:04 pm

I had someone send me a message asking about how to use $RESIZE to set a screen to reflow text (not stretch or scale it), so I thought I'd write up a quick little demo and share with everyone.

Code: QB64: [Select]

1. Dim Shared As Long DW, DH, DisplayScreen, WorkScreen, Font, FontSize
2. Dim Shared As Long ScreenWidth, ScreenHeight
3.  
4. Dim Shared As Long Room
5.  
6.  
7. _Title "X-Mas Adventure"
8. '$Dynamic
9. $Color:32
10. $Resize:On
11. _Resize On
12. DefLng A-Z
13. Randomize Timer
14.  
15.  
16.  
17. DW = _DesktopWidth: DH = _DesktopHeight
18. If DW > 1920 Then 'I'm going to assume it's a super highres screen
19.     DisplayScreen = _NewImage(1280, 960, 32)
20.     FontSize = 40
21. Else
22.     DisplayScreen = _NewImage(640, 480, 32)
23.     FontSize = 20
24. End If
25.  
26. Screen DisplayScreen
27. Font = _LoadFont("courbd.ttf", FontSize, "monospace")
28. _Font Font
29.  
30.  
31.  
32.  
33. Do
34.     Cls , 0
35.     k = _KeyHit
36.     If _Resize Then resize
37.  
38.     Select Case k
39.         Case 27: System
40.     End Select
41.  
42.  
43.     Select Case Room
44.         Case 0: TitleScreen
45.         Case 1: Room1
46.     End Select
47.  
48.  
49.     _Limit 30
50.     _Display
51. Loop
52.  
53.  
54.  
55. Sub Room1
56.     Print "This is just a demo of a resizable screen and how we'd adjust our text to give us more words per row with a wide screen and fewer words with a narrower screen.  This will also change font size automatically to a much larger font, if your screen resolution is greater than 1920 pizels wide, and still look proper for you.  This is just a demo and really does nothing beyond this point..."
57.     Print
58.     Print "Note, there is *NO* word-wrap built into this demo."
59. End Sub
60.  
61.  
62. Sub TitleScreen
63.     Static Delay#
64.     If Delay# = 0 Then Delay# = ExtendedTimer + 10.0 '10 seconds to view and resize my pretty little title screen
65.     If Delay# < ExtendedTimer Then
66.         Room = 1
67.     End If
68.     Text1$ = "Resizing Screen Demo"
69.     Text2$ = "By. SMcNeill"
70.     Text3$ = "2021"
71.     Top = (_Height - _FontHeight * 3) / 2
72.     CenterText Text1$, Top
73.     CenterText Text2$, Top + _FontHeight
74.     CenterText Text3$, Top + _FontHeight * 2
75. End Sub
76.  
77. Sub CenterText (text$, Ypos)
78.     CenterX = (_Width - _PrintWidth(text$)) / 2
79.     _PrintString (CenterX, Ypos), text$
80. End Sub
81.  
82.  
83. Sub resize
84.     RX = _ResizeWidth: RY = _ResizeHeight
85.     _Font 16
86.     tempscreen = _NewImage(RX, RY, 32)
87.     Screen tempscreen
88.     _FreeImage DisplayScreen
89.     DisplayScreen = tempscreen
90.     _Font Font
91.     ScreenWidth = _Width / _FontWidth
92.     ScreenHeight = _Height / _FontHeight
93. End Sub
94.  
95. Function ExtendedTimer##
96.     d$ = Date$
97.     l = InStr(d$, "-")
98.     l1 = InStr(l + 1, d$, "-")
99.     m = Val(Left$(d$, l))
100.     d = Val(Mid$(d$, l + 1))
101.     y = Val(Mid$(d$, l1 + 1)) - 1970
102.     For i = 1 To m
103.         Select Case i 'Add the number of days for each previous month passed
104.             Case 1: d = d 'January doestn't have any carry over days.
105.             Case 2, 4, 6, 8, 9, 11: d = d + 31
106.             Case 3: d = d + 28
107.             Case 5, 7, 10, 12: d = d + 30
108.         End Select
109.     Next
110.     For i = 1 To y
111.         d = d + 365
112.     Next
113.     For i = 2 To y Step 4
114.         If m > 2 Then d = d + 1 'add an extra day for leap year every 4 years, starting in 1970
115.     Next
116.     d = d - 1 'for year 2000
117.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
118.     ExtendedTimer## = (s~&& + Timer)
119. End Function
120.  

Now this makes a simple little program for us with a resizable screen.  The first screen is nothing but some text that centers itself for us as a simple title screen.  It's configured to remain visible for 10 seconds while you play with the size of the screen and watch the text move to reposition itself always into the center of your screen, regardless of the dimensions you set.  (Unless you scrunch the screen too small, of course.  I'm keeping the demo simple here, so there's no limit to how large/small you can make your screen, and if it's too small, the text won't have room to display properly, so be aware of that.  :P )

Note the resize SUB in particular -- it's the one which is in charge of the screen dimensions:

Code: QB64: [Select]

1. Sub resize
2.     RX = _ResizeWidth: RY = _ResizeHeight
3.     _Font 16
4.     tempscreen = _NewImage(RX, RY, 32)
5.     Screen tempscreen
6.     _FreeImage DisplayScreen
7.     DisplayScreen = tempscreen
8.     _Font Font
9.     ScreenWidth = _Width / _FontWidth
10.     ScreenHeight = _Height / _FontHeight
11. End Sub

    RX = _ResizeWidth: RY = _ResizeHeight -- read the resized dimensions
    _Font 16  -- get ready to free the screen by making certain to swap to a default font for the display
    tempscreen = _NewImage(RX, RY, 32) -- make the new screen
    Screen tempscreen -- swap to the new screen
    _FreeImage DisplayScreen -- free the old screen
    DisplayScreen = tempscreen -- make the new screen the old screen
    _Font Font -- set the proper font back for the new screen

And that's basically the whole process in a nutshell!

If anyone has questions about this little resizing technique, feel free to ask, and I'll answer all I can for you guys until the process makes sense to everybody.  It's really not as difficult as some people make it out to be.  ;)

Text Only | Text with Attachments