QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: krovit on November 01, 2021, 06:29:18 pm

Title: Click
Post by: krovit on November 01, 2021, 06:29:18 pm

Hello everyone,

the question of controlling the click and double click of the mouse I had solved with the code that follows.
The function is called to capture the double click.

It's probably not a great code either but it worked until version 1.6 of QB64.
I upgraded to version 2.1 of QB64 but the compiler stops and reports this error (see image).

Any ideas on this?

Code: QB64: [Select]

1. FUNCTION Click%
2.         DO
3.                 provj$=inkey$
4.                 provxxw& = _KEYHIT
5.                
6.                 IF _EXIT THEN call Fine  'click sulla X della finestra
7.                 WHILE _MOUSEINPUT: WEND
8.         mb = _MOUSEBUTTON(1) OR _MOUSEBUTTON(2) OR _MOUSEBUTTON(3)  '-1=preme / 0=solleva
9.                 IF mb AND oldMouse = 0 THEN
10.                         passato=0
11.                         IF plusClick%(timer) = 2 THEN
12.                                 Click%=2
13.                         else
14.                                 Click%=1
15.                         end if
16.                 END IF
17.                 oldMouse = mb
18.     LOOP UNTIL Click%  or provj$<>"" or provxxw&<>0 or _MOUSEWHEEL <> 0
19.        
20. END FUNCTION
21. FUNCTION plusClick%(t1#)
22. static passato,t2#
23.         DO
24.                 provj$=inkey$
25.                 provxxw& = _KEYHIT
26.  
27.         WHILE _MOUSEINPUT: WEND
28.         mb2 = _MOUSEBUTTON(1) OR _MOUSEBUTTON(2) OR _MOUSEBUTTON(3)  '-1=preme / 0=solleva
29.         IF mb2=0 THEN  'rilasciato
30.                         if timer-t2# <.3 then
31.                                 t2#=timer
32.                                 t1#=timer
33.                                 passato=0
34.                                 plusClick%=2
35.                                 exit FUNCTION
36.                         end     if
37.                         if timer-t1#<.3 then
38.                                 if passato=0 then  'primo rilascio entro il tempo
39.                                         passato=38
40.                                         t1#=timer
41.                                         t2#=timer
42.                                         plusClick%=1
43.                                 elseif passato=38 then  'rilascio ignorato
44.                                         passato=0
45.                                         t1#=timer
46.                                         t2#=timer
47.                                         plusClick%=1
48.                                 end if
49.                         else  'tempo passato in ogni caso
50.                                 t1#=timer
51.                                 t2#=timer
52.                                 passato=0
53.                                 plusClick%=1
54.                         end if
55.                 END IF
56.                
57.     LOOP until plusClick% or provj$<>"" or provxxw&<>0 or _MOUSEWHEEL <> 0
58. END FUNCTION
59.  

Title: Re: Click
Post by: bplus on November 01, 2021, 06:44:07 pm

Missing elements of program, the IDE is red lining at line 6 because subroutine, fine, not present.

QB64 Version 2.1 does not exist, maybe you mean 2.01?

Ah! It's line 57 that is probably hanging you up, use another variable name not the function name, plusClick%, for this line:

Code: QB64: [Select]

1. LOOP until plusClick% or provj$<>"" or provxxw&<>0 or _MOUSEWHEEL <> 0
2.  

I'd say use pC% = such and such until after loop and then say:
plusClick% = pC% before leaving function to set the Function value.

Like this:

Code: QB64: [Select]

1. Function Click%
2.     Do
3.         provj$ = InKey$
4.         provxxw& = _KeyHit
5.  
6.         ' If _Exit Then call Fine  'click sulla X della finestra   <<<< missing fine subroutine
7.         While _MouseInput: Wend
8.         mb = _MouseButton(1) Or _MouseButton(2) Or _MouseButton(3) '-1=preme / 0=solleva
9.         If mb And oldMouse = 0 Then
10.             passato = 0
11.             If plusClick%(Timer) = 2 Then
12.                 Click% = 2
13.             Else
14.                 Click% = 1
15.             End If
16.         End If
17.         oldMouse = mb
18.     Loop Until Click% Or provj$ <> "" Or provxxw& <> 0 Or _MouseWheel <> 0
19.  
20. End Function
21. Function plusClick% (t1#)
22.     Static passato, t2#
23.     Do
24.         provj$ = InKey$
25.         provxxw& = _KeyHit
26.  
27.         While _MouseInput: Wend
28.         mb2 = _MouseButton(1) Or _MouseButton(2) Or _MouseButton(3) '-1=preme / 0=solleva
29.         If mb2 = 0 Then 'rilasciato
30.             If Timer - t2# < .3 Then
31.                 t2# = Timer
32.                 t1# = Timer
33.                 passato = 0
34.                 pC% = 2
35.                 Exit Function
36.             End If
37.             If Timer - t1# < .3 Then
38.                 If passato = 0 Then 'primo rilascio entro il tempo
39.                     passato = 38
40.                     t1# = Timer
41.                     t2# = Timer
42.                     pC% = 1
43.                 ElseIf passato = 38 Then 'rilascio ignorato
44.                     passato = 0
45.                     t1# = Timer
46.                     t2# = Timer
47.                     pC% = 1
48.                 End If
49.             Else 'tempo passato in ogni caso
50.                 t1# = Timer
51.                 t2# = Timer
52.                 passato = 0
53.                 pC% = 1
54.             End If
55.         End If
56.  
57.     Loop Until pC% Or provj$ <> "" Or provxxw& <> 0 Or _MouseWheel <> 0
58.     plusClick% = pC%
59. End Function
60.  
61.  
62.  

Title: Re: Click
Post by: bplus on November 01, 2021, 07:16:19 pm

Oh you might need to fix this too, same way:

Code: QB64: [Select]

1. Function Click%
2.     Do
3.         provj$ = InKey$
4.         provxxw& = _KeyHit
5.  
6.         ' If _Exit Then call Fine  'click sulla X della finestra   <<<< missing fine subroutine
7.         While _MouseInput: Wend
8.         mb = _MouseButton(1) Or _MouseButton(2) Or _MouseButton(3) '-1=preme / 0=solleva
9.         If mb And oldMouse = 0 Then
10.             passato = 0
11.             If plusClick%(Timer) = 2 Then
12.                 Cl% = 2
13.             Else
14.                 Cl% = 1
15.             End If
16.         End If
17.         oldMouse = mb
18.     Loop Until Cl% Or provj$ <> "" Or provxxw& <> 0 Or _MouseWheel <> 0
19.     Click% = Cl%
20. End Function
21.  
22.  
23.  

Title: Re: Click
Post by: Cobalt on November 01, 2021, 07:50:42 pm

Quote from: bplus on November 01, 2021, 06:44:07 pm

Missing elements of program, the IDE is red lining at line 6 because subroutine, fine, not present.

QB64 Version 2.1 does not exist, maybe you mean 2.01?

Technically neither does 2.01, as its actually 2.0.1
But oddly enough if you look at his screen cap it does say V2.1? 🤷‍♂️

Title: Re: Click
Post by: bplus on November 01, 2021, 08:03:49 pm

Well I got all the digits right ;-))
  [ This attachment cannot be displayed inline in 'Print Page' view ]  

BTW my screen says v2.0

Title: Re: Click
Post by: Pete on November 01, 2021, 11:41:59 pm

I use a timer for detecting double clicks, too. https://www.qb64.org/forum/index.php?topic=4262.msg136424#msg136424

There are many ways to code this, but the #1 criteria is, does it work?

Pete

Title: Re: Click
Post by: SMcNeill on November 02, 2021, 12:29:35 am

FUNCTION plusClick%(t1#)
.
.
...STUFF
.
.
    LOOP until plusClick% or provj$<>"" or provxxw&<>0 or _MOUSEWHEEL <> 0


The issue lies in the above.  plusClick is your function name, and the glitch where you could use it in such a manner has been fixed.  You're now trying to recursively call your routine over and over, and that no longer works.

You'll need to assign a temp variable to the code, inside the FUNCTION routine, instead of using plusClick% itself, until you get to the final assignment where plusClick = *whatever*.

Title: Re: Click
Post by: krovit on November 02, 2021, 04:31:42 am

Thanks Pete, I will also check your interesting method.

The proposed solutions work.

In short, it is a matter of avoiding "shortcuts" and sliding routines and functions in a linear way, without jumps.



However, I confess, I am worried!

The solutions don't seem to solve what seems to be a compiler problem.

In fact, filed the problem of this post, the compilation went on BUT stops countless times showing the same error message "Incorrect number of arguments passed to function".

The error occurs on rather trivial single commands, related to the execution of functions (these, perhaps, I will have to review them considering what has been said before) but also on the simple command SWAP (inside a function)

In short... something has changed since version 1.6 and 2.0.1. (2.1 in the window).
The compiler now seems more attentive to the flow of instructions, as well as syntax, as is normal for us to be.
The problem - if there is, but I think so - is how the compiler treats the code associated with the functions.
Checking all the code inside the functions is not easy (there are many!) and above all it is not easy to understand how the compiler "reasons" now to avoid errors in the future.

Sure, I could continue with the 1.6 but it's not a good policy to ignore the updates and improvements.

Title: Re: Click
Post by: SMcNeill on November 02, 2021, 05:03:10 am

Think of it as writing a function for COS...

Function COS (angle)

DO
   ...some math
LOOP UNTIL COS = whatever

Now, it's obvious here that COS is a function that we all know and love...  The LOOP UNTIL COS = whatever line is going to error out on us, obviously.  Right?  After all, we didn't tell it what angle we wanted to use with the function COS (angle).


You're doing the *exact* same thing with your custom function:

FUNCTION plusClick%(t1#)

DO
    ...STUFF
LOOP UNTIL plusClick% <> 0

plusClick is a function which wants a (t1#) passed to it.  Where's the (t1#) that you're passing to the call to the function in the LOOP UNTIL line??

You're calling the function without passing it any value for the parameter, thus the "Incorrect number of arguments passed to function" error.

Title: Re: Click
Post by: Pete on November 02, 2021, 08:16:40 am

This one is interesting in a lot of ways.

1) Before version 2.0 the IDE allowed the parameter to be absent. I would not have expected it to miss that coding error. I guess this part of the break in function warning issued with this newer release.

2) Before version 2.0, the code, as written, would run without crashing. Now, unless the recursive function calls are fixed, as in my remake, below, the recursive calls in the Click% function cause it to crash.

3) The modified code works, but just as in the original code, it does not disallow for the reporting of a double click from more than the same button. In other words, we can get a recorded double click by clicking left then right, left then middle, or middle and right or middle and left. Also, it will report a double click if we hold a mouse button down and then release and quickly click it. This is not a traditional double click, at least not in Windows systems.

Anyway, if it helps, here is the modified code, which will run n V2.0...

Code: QB64: [Select]

1. DO
2.     PRINT Click%
3.     _LIMIT 30
4. LOOP
5.  
6. FUNCTION Click%
7.     DO
8.         provj$ = INKEY$
9.         provxxw& = _KEYHIT
10.  
11.         'IF _EXIT THEN call Fine  'click sulla X della finestra
12.         WHILE _MOUSEINPUT: WEND
13.         mb = _MOUSEBUTTON(1) OR _MOUSEBUTTON(2) OR _MOUSEBUTTON(3) '-1=preme / 0=solleva
14.         IF mb AND oldMouse = 0 THEN
15.             passato = 0
16.             IF plusClick%(TIMER) = 2 THEN
17.                 Click% = 2
18.                 EXIT DO ' <--------------- Exit loop and function here.
19.             ELSE
20.                 Click% = 1
21.                 EXIT DO ' <--------------- Exit loop and function here.
22.             END IF
23.         END IF
24.         oldMouse = mb
25.     LOOP UNTIL provj$ <> "" OR provxxw& <> 0 OR _MOUSEWHEEL <> 0
26.  
27. END FUNCTION
28. FUNCTION plusClick% (t1#)
29.  
30.     STATIC passato, t2#
31.     DO
32.         provj$ = INKEY$
33.         provxxw& = _KEYHIT
34.  
35.         WHILE _MOUSEINPUT: WEND
36.         mb2 = _MOUSEBUTTON(1) OR _MOUSEBUTTON(2) OR _MOUSEBUTTON(3) '-1=preme / 0=solleva
37.         IF mb2 = 0 THEN 'rilasciato
38.             IF TIMER - t2# < .3 THEN
39.                 t2# = TIMER
40.                 t1# = TIMER
41.                 passato = 0
42.                 plusClick% = 2
43.                 EXIT DO ' <--------------- Exit loop and function here.
44.             END IF
45.             IF TIMER - t1# < .3 THEN
46.                 IF passato = 0 THEN 'primo rilascio entro il tempo
47.                     passato = 38
48.                     t1# = TIMER
49.                     t2# = TIMER
50.                     plusClick% = 1
51.                     EXIT DO ' <--------------- Exit loop and function here.
52.                 ELSEIF passato = 38 THEN 'rilascio ignorato
53.                     passato = 0
54.                     t1# = TIMER
55.                     t2# = TIMER
56.                     plusClick% = 1
57.                     EXIT DO ' <--------------- Exit loop and function here.
58.                 END IF
59.             ELSE 'tempo passato in ogni caso
60.                 t1# = TIMER
61.                 t2# = TIMER
62.                 passato = 0
63.                 plusClick% = 1
64.                 EXIT DO ' <--------------- Exit loop and function here.
65.             END IF
66.         END IF
67.  
68.     LOOP UNTIL provj$ <> "" OR provxxw& <> 0 OR _MOUSEWHEEL <> 0
69. END FUNCTION

Now if you will excuse me, I have to get back to my work in the Virginia Governor election. I've made 1,000 phone calls so far. I would have made more, but on that one-thousandth call, Steve finally figured out it was me calling each time, and shut off his phone!

Pete

Title: Re: Click
Post by: krovit on November 03, 2021, 03:12:29 am

Ah Pete! Real life! Incredible... there is also that...

Thank you for your time and valuable information

I believe that the problem lies in recursiveness: it must be carefully avoided

Title: Re: Click
Post by: krovit on November 03, 2021, 08:32:27 am

To better clarify things I attach the small and stupid program that follows (and that is useless!) that is compilable with versions up to 1.61 but not with 2.01

Code: QB64: [Select]

1. flag = 1
2. v0$ = "10"
3. v1$ = "2021"
4.  
5. Print inser$(flag, v0$, v1$)
6.  
7. End
8.  
9. Function inser$ (flag, v0$, v1$)
10.  
11.     If flag = 0 Then
12.         Swap inser$, v0$
13.     Else
14.         Swap inser$, v1$
15.     End If
16.  
17. End Function
18.  

Text Only | Text with Attachments