QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Pete on October 15, 2021, 10:49:43 pm

Title: Is this at all possible in SCREEN 0?
Post by: Pete on October 15, 2021, 10:49:43 pm

Is there anyway in SCREEN 0 to make a screen overlay, and I'll attempt to explain.

A program has a window with a black background and multi-colored ascii images on it. Next step, make the characters on the screen grey, that's the easy part.... Next somehow make this grey on black screen a background image. Final step, write on top of that scree with translucent lettering, so the background bleeds through. This is easy to accomplish in HTML. Any chance it can be done in QB64?

Note: This is different than using two screens to make a popup window, although if that popup window could have a translucent background, I don't know, maybe that would work. But as a solid background, it's just a popup window that obliterates everything behind it. That I could do, but I'd rather have the overlay effect, if possible.

Pete

Title: Re: Is this at all possible in SCREEN 0?
Post by: SMcNeill on October 15, 2021, 11:30:07 pm

You can do this by rendering a hardware screen over the software one, but only the software will be screen 0.

Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 15, 2021, 11:40:38 pm

So I'll check out hardware images, here: http://www.qb64.org/wiki/Hardware_images

It may not work for me, as it sounds backwards to what I was thinking about, being the hardware screen being the background image, and the screen as the overlay. I've got so RA file stuff to do first, so I may not get to this for a day or two. This would be a neat effect, if it can be pulled off.

Thanks,

Pete

Title: Re: Is this at all possible in SCREEN 0?
Post by: SMcNeill on October 16, 2021, 06:27:14 am

Give this demo a quick whirl, @Pete.

Code: QB64: [Select]

1. $Color:32
2. Screen0 = _NewImage(80, 40, 0)
3. Screen Screen0
4.  
5. 'font usage here is just because my laptop has an insane resolution
6. 'of almost 4000x2000 pixels, and without it, everything is microscopic
7. 'on my machine.  Feel free to disable this if it makes the screen too
8. 'large for your PC to display properly.
9. font = _LoadFont("courbd.ttf", 48, "monospace")
10. If font <= 0 Then font = 16
11. _Font font
12.  
13. 'This is going to be the screen I use as an overlay.
14. Overlay = _NewImage(_Width * _FontWidth, _Height * _FontHeight, 32)
15.  
16. 'Now,I'm going to print something pretty on my Screen0.
17. _PaletteColor 1, Orange
18. _PaletteColor 2, SlateGray
19. Color 1, 2
20. For x = 20 To 60
21.     Locate 10, x: Print "*"
22.     Locate 30, x: Print "*"
23. Next
24. For y = 11 To 29
25.     Locate y, 20
26.     Print "*"; String$(39, " "); "*"
27. Next
28.  
29. 'Now the above is just Pete's background in Screen0.
30. 'Now I'm going to create the Overly
31.  
32. _Dest Overlay
33. For i = 200 To 1 Step -.25
34.     Circle (_Width \ 2, _Height \ 2), i, Orange
35. Next
36. Color MidnightBlue, 0
37. If font <= 0 Then font = 16
38. _Font font
39. text$ = "This is text wrote over the background"
40. _PrintString ((_Width - _PrintWidth(text$)) \ 2, _Height \ 2), text$
41.  
42. _Dest 0 'reset our dest back to the normal screen 0 screen
43.  
44. 'Turn our software overlay into a hardware image
45. Overlay_Hardware = _CopyImage(Overlay, 33)
46.  
47. 'And then my impressive main program to toggle between showing and not
48. 'showing the overlay.
49. Do
50.     k = _KeyHit
51.     If k = 32 Then Show_Overlay = Not Show_Overlay
52.     If Show_Overlay Then _PutImage (0, 0), Overlay_Hardware
53.     _Display
54.     _Limit 30
55. Loop Until k = 27
56.  
57. System
58.  
59.  

Now note, I wrote this on my laptop while still in bed, so there's some unnecessary crap in there that you might need to remove first.  My laptop is one of those with a stupid 3840x2048 resolution, which then scales all windows by 200% to effectively give itself 1920x1024 resolution....  Why the hell it doesn't just go with 1920x1024 and ignore the need for scaling, I don't have a clue!  Unfortunately, QB64 and the programs we write in it, are ones that ignore that automatic "scale to 200%) command, so the screen is too bleeping small to read or interact with on the monitor!  To fix that, I've had to use a font which will be larger than heck on normal resolution systems, so you might need to comment out that line with the _loadfont statement.

Otherwise, this is just a very simple little demo of using a hardware screen as an overlay for your SCREEN 0 screen. 

Hit space to toggle the overlay on or off.
Hit ESC to end the demo.

My Overlay here is nothing more than a simple "pumpkin" on the screen and a little text which will center itself over the Screen 0 background.

Title: Re: Is this at all possible in SCREEN 0?
Post by: Cobalt on October 16, 2021, 11:27:01 am

Having trouble visualizing just what it is your after Pete, do you have a screen shot?

if HTML does it I doubt screen 0 will, you will probably need a graphical screen mode. Unless your just referring to having a background "image" and the text overlaid upon it? Of course then you can just use the memory pages in screen 0 to Pcopy over top so that is probably not what you mean, since I know you have probably more knowledge of screen 0 than I ever will and would just do that if it was the effect you wanted.

Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 17, 2021, 01:35:07 pm

@Cobalt The code below will give you some more insight into what I'm talking about...

@SMcNeill HELP HELP, I'm stuck in a graphics screen and can't get out!

Code: QB64: [Select]

1. $COLOR:32
2. Screen0 = _NEWIMAGE(80, 25, 0)
3. SCREEN Screen0
4.  
5. Overlay = _NEWIMAGE(_WIDTH * _FONTWIDTH, _HEIGHT * _FONTHEIGHT, 32)
6.  
7. COLOR 0, 7
8. FOR x = 1 TO 25
9.     LOCATE x, 1: PRINT STRING$(80, 176);
10. NEXT
11.  
12. _DEST Overlay
13. COLOR MidnightBlue, 0
14.  
15. REDIM text$(5)
16. text$(1) = "This is a SCREEN 0 overlay method"
17. text$(2) = "used by the Amazing Steve and"
18. text$(3) = "modified by me to create a simple"
19. text$(4) = "text to screen overlay on a dotted"
20. text$(5) = "SCREEN 0 background!"
21.  
22. font = _LOADFONT("lucon.ttf", 25, "bold")
23. IF font <= 0 THEN font = 16
24. _FONT font
25.  
26. FOR k = 1 TO 5
27.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(text$(k))) \ 2, 40 + k * 40), text$(k)
28.  
29.     Overlay_Hardware = _COPYIMAGE(Overlay, 33)
30.  
31.     _PUTIMAGE (0, 0), Overlay_Hardware
32.     _DISPLAY
33.     _DELAY 1.75
34. NEXT
35.  
36. _FONT 16 'select inbuilt 8x16 default font
37. _FREEFONT font
38.  
39. msg$ = "Press any key to remove text."
40. _PRINTSTRING (10, 380), msg$
41.  
42. Overlay_Hardware = _COPYIMAGE(Overlay, 33)
43.  
44. _PUTIMAGE (0, 0), Overlay_Hardware
45. _DISPLAY
46. WHILE LEN(INKEY$): WEND ' Clear keyboard buffer in case user pressed a key during program run.
47. SLEEP
48.  
49. _DISPLAY ' Removes text.
50.  
51. _DEST 0 'Reset dest back to the normal screen 0.
52.  
53. SLEEP
54.  
55. REM SCREEN 0 ' From here down it needs to function like SCREEN 0 again.
56. COLOR 0, 7
57. msg$ = "Press any key to end..."
58. LOCATE 25, 1: PRINT msg$;
59. a$ = INPUT$(1)
60. SYSTEM
61.  

It's so cool, well, right up to the point where I noticed it doesn't really go back to a functioning SCREEN 0 text mode screen. Is there a way to get it back, for real? I tried combinations of _DEST _SOURCE, and just SCREEN 0, but so far, nothing I tried would print the black on white "Press any key to end..." message at the bottom right corner of the screen. Oh, let's just jump ahead and get the joke to just use... "END" out of the way! Haha.

Pete

Title: Re: Is this at all possible in SCREEN 0?
Post by: SMcNeill on October 17, 2021, 02:05:01 pm

Are you talking about adding an _AUTODISPLAY command after your last SLEEP statement?  That's not related to hardware imaging at all; it's just you swapping over to manual screen updates with _DISPLAY.

Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 17, 2021, 02:39:09 pm

Wait a minute. I may be getting it worked out with your _AUTODISPLAY recommendation. I needed to change the old way of clearing the key buffer for the input$(1) statement...

Code: QB64: [Select]

1. $COLOR:32
2. Screen0 = _NEWIMAGE(80, 25, 0)
3. SCREEN Screen0
4.  
5. Overlay = _NEWIMAGE(_WIDTH * _FONTWIDTH, _HEIGHT * _FONTHEIGHT, 32)
6.  
7. COLOR 0, 7
8. FOR x = 1 TO 25
9.     LOCATE x, 1: PRINT STRING$(80, 176);
10. NEXT
11.  
12. _DEST Overlay
13. COLOR MidnightBlue, 0
14.  
15. REDIM text$(5)
16. text$(1) = "This is a SCREEN 0 overlay method"
17. text$(2) = "used by the Amazing Steve and"
18. text$(3) = "modified by me to create a simple"
19. text$(4) = "text to screen overlay on a dotted"
20. text$(5) = "SCREEN 0 background!"
21.  
22. font = _LOADFONT("lucon.ttf", 25, "bold")
23. IF font <= 0 THEN font = 16
24. _FONT font
25.  
26. FOR k = 1 TO 5
27.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(text$(k))) \ 2, 40 + k * 40), text$(k)
28.  
29.     Overlay_Hardware = _COPYIMAGE(Overlay, 33)
30.  
31.     _PUTIMAGE (0, 0), Overlay_Hardware
32.     _DISPLAY
33.     ' _DELAY 1.75
34. NEXT
35.  
36. _FONT 16 'select inbuilt 8x16 default font
37. _FREEFONT font
38.  
39. msg$ = "Press any key to remove overlay, and press again to end."
40. _PRINTSTRING (10, 380), msg$
41.  
42. Overlay_Hardware = _COPYIMAGE(Overlay, 33)
43.  
44. _PUTIMAGE (0, 0), Overlay_Hardware
45. _DISPLAY
46.  
47. SLEEP
48.  
49. _DISPLAY ' Removes text.
50.  
51. _DEST 0 'Reset dest back to the normal screen 0.
52. SLEEP
53.  
54. _AUTODISPLAY
55. COLOR 0, 7
56. LOCATE 25, 1: msg$ = "Press any key to end..."
57. PRINT msg$;
58. WHILE LEN(INKEY$): WEND ' Clear keyboard buffer in case user pressed a key during program run.
59. a$ = INPUT$(1)
60. SYSTEM
61.  

So I tripped myself up for a bit using statements I don't often use, input$(1) with SLEEP, and the old key buffer clear routine, but I like to code them in, once in awhile, so I never completely forget them and other ways to code results, as well.

Anyway, thanks for the help with the overlay part. I'm certainly going to enjoy this effect!

Pete

Title: Re: Is this at all possible in SCREEN 0?
Post by: bplus on October 17, 2021, 03:00:21 pm

This?

Code: QB64: [Select]

1. $Color:32
2. Screen0 = _NewImage(80, 25, 0)
3. Screen Screen0
4.  
5. Overlay = _NewImage(_Width * _FontWidth, _Height * _FontHeight, 32)
6.  
7. Color 0, 7
8. For x = 1 To 25
9.     Locate x, 1: Print String$(80, 176);
10. Next
11.  
12. _Dest Overlay
13. Color MidnightBlue, 0
14.  
15. ReDim text$(5)
16. text$(1) = "This is a SCREEN 0 overlay method"
17. text$(2) = "used by the Amazing Steve and"
18. text$(3) = "modified by me to create a simple"
19. text$(4) = "text to screen overlay on a dotted"
20. text$(5) = "SCREEN 0 background!"
21.  
22. font = _LoadFont("lucon.ttf", 25, "bold")
23. If font <= 0 Then font = 16
24. _Font font
25.  
26. For k = 1 To 5
27.     _PrintString ((_Width - _PrintWidth(text$(k))) \ 2, 40 + k * 40), text$(k)
28.  
29.     Overlay_Hardware = _CopyImage(Overlay, 33)
30.  
31.     _PutImage (0, 0), Overlay_Hardware
32.     _Display
33.     _Delay 1.75
34. Next
35.  
36. _Font 16 'select inbuilt 8x16 default font
37. _FreeFont font
38.  
39. msg$ = "Press any key to remove text."
40. _PrintString (10, 380), msg$
41.  
42. Overlay_Hardware = _CopyImage(Overlay, 33)
43.  
44. _PutImage (0, 0), Overlay_Hardware
45. _Display
46. While Len(InKey$): Wend ' Clear keyboard buffer in case user pressed a key during program run.
47. Sleep
48.  
49. _AutoDisplay '
50. _FreeImage Overlay_Hardware
51. _Dest 0 'Reset dest back to the normal screen 0.
52. Color 15, 0
53. Screen 0
54. Cls
55.  
56.  
57.  

Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 17, 2021, 03:07:31 pm

@bplus Yes, I was editeding my post while you were posting this, so I got I got it working.

So _FREEIMAGE Overlay_Hardware is something I hadn't thought about yet. Thanks for bringing it up. I didn't need it for getting back into SCREEN 0 function, but I will need it to properly free up memory going forward, so thanks a HEAP, excuse the pun, for that!

Pete

Title: Re: Is this at all possible in SCREEN 0?
Post by: bplus on October 17, 2021, 03:08:31 pm

OK don't need Screen 0 again at end. I am assuming you are trying to normal Screen 0 conditions.

_AutoDisplay deactivates _Display, once you are in _Display Mode you have to say _Display everytime you want a screen update, _AutoDisplay cancels that.

Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 17, 2021, 03:14:37 pm

Yep. Anyway, I just added your _FREEIMAGE part, and this cake is baked!

Code: QB64: [Select]

1. $COLOR:32
2. Screen0 = _NEWIMAGE(80, 25, 0)
3. SCREEN Screen0
4.  
5. Overlay = _NEWIMAGE(_WIDTH * _FONTWIDTH, _HEIGHT * _FONTHEIGHT, 32)
6.  
7. COLOR 0, 7
8. FOR x = 1 TO 25
9.     LOCATE x, 1: PRINT STRING$(80, 176);
10. NEXT
11.  
12. _DEST Overlay
13. COLOR MidnightBlue, 0
14.  
15. REDIM text$(5)
16. text$(1) = "This is a SCREEN 0 overlay method"
17. text$(2) = "used by the Amazing Steve and"
18. text$(3) = "modified by me to create a simple"
19. text$(4) = "text to screen overlay on a dotted"
20. text$(5) = "SCREEN 0 background!"
21.  
22. font = _LOADFONT("lucon.ttf", 25, "bold")
23. IF font <= 0 THEN font = 16
24. _FONT font
25.  
26. FOR k = 1 TO 5
27.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(text$(k))) \ 2, 40 + k * 40), text$(k)
28.  
29.     Overlay_Hardware = _COPYIMAGE(Overlay, 33)
30.  
31.     _PUTIMAGE (0, 0), Overlay_Hardware
32.     _DISPLAY
33.     _DELAY 1.75
34. NEXT
35.  
36. _FONT 16 'select inbuilt 8x16 default font
37. _FREEFONT font
38.  
39. msg$ = "Press any key to remove text."
40. _PRINTSTRING (10, 380), msg$
41.  
42. Overlay_Hardware = _COPYIMAGE(Overlay, 33)
43.  
44. _PUTIMAGE (0, 0), Overlay_Hardware
45. _DISPLAY
46.  
47. SLEEP
48.  
49. _AUTODISPLAY '
50. _FREEIMAGE Overlay_Hardware
51. _DEST 0 'Reset dest back to the normal screen 0.
52.  
53. msg$ = "We are now back in pure SCREEN 0! Press any key to end."
54. LOCATE 12, 41 - LEN(msg$) \ 2
55. PRINT msg$;
56.  
57. WHILE LEN(INKEY$): WEND ' Clear keyboard buffer in case user pressed a key during program run.
58. a$ = INPUT$(1)
59. COLOR 7, 0
60. SCREEN 0
61. CLS
62. _DELAY 2
63. SYSTEM
64.  

I actually recall the need for _AUTODISPLAY. It was 6 months ago I used it to put a couple of nice graphics buttons in my SCREEN 0 WP app. Apparently SSD's aren't the only form of memory storage devices that are adversely affected by aging!

Thanks guys!

Pete

Title: Re: Is this at all possible in SCREEN 0?
Post by: SMcNeill on October 17, 2021, 07:43:31 pm

And here's something just a tad bit more complicated for you Pete -- I'm going to create a SCREEN 0 image and then use it as an UNDERLAY for a second SCREEN 0!!

Code: QB64: [Select]

1. Screen 0 'just to highlight that this is going to be a scren 0 underlay
2.  
3.  
4. Color 0, 14
5. Cls , 14
6. For y = 1 To 50
7.     Locate y, 1: Print "*"; String$(78, 32); "*";
8. Next
9.  
10. Locate 1, 1: Print String$(80, "*");
11. Locate 2, 40 - Len("Hello Pete!  I'm a SCREEN 0 Underlay!") \ 2: Print "Hello Pete!  I'm a SCREEN 0 Underlay!"
12. Locate 3, 1: Print String$(80, "*");
13. Locate 50, 1: Print String$(80, "*");
14.  
15. HW = _CopyImage(TextScreenToImage32(0), 33)
16. 'Now that we've created our screen that we want to use as a hardware underlay,
17. 'We now need to do at least a little tweaking to our normal screen 0 palette
18.  
19. _PaletteColor 1, 0 'set color 1 to become 0 alpha, 0 red, 0 blue, 0 green -- transparent black instead of solid black!
20. 'note that 0 is still the same old solid black as usual.
21. Color 31, 1 'I'm setting the text color to be blinking bright white on transparent black
22.  
23. _DisplayOrder _Hardware , _Software 'draw the hardware screen under the software screen
24.  
25. Do
26.     k = _KeyHit
27.     If k = 32 Then toggle = Not toggle
28.     Cls , 1 'clear the screen with a transparent black
29.     If toggle Then _PutImage (0, 0), HW 'and now our
30.     x = x - 1
31.     If x < 2 Then x = 66
32.     Locate 5, x: Print "HELLO SCROLL! ";
33.     _Limit 10
34.     _Display
35. Loop Until k = 27
36.  
37.  
38.  
39. Function TextScreenToImage32& (image&)
40.     d& = _Dest: s& = _Source
41.     Dim Plt(15) As Long
42.     _Source image&
43.     For i = 0 To 15: Plt(i) = _PaletteColor(i, image&): Next
44.     f& = _Font(image&)
45.     _Font f&
46.     fw& = _FontWidth
47.     fh& = _FontHeight
48.     w& = _Width * _FontWidth
49.     h& = _Height * _FontHeight '+ _HEIGHT
50.     l& = (_Width * _Height) * 2 'The screen is width * height in pixels.  (80X25) = 2000 X 2 bytes each = 4000 total bytes to hold a page of screen 0 text and color
51.     tempscreen& = _NewImage(w&, h& + _Height, 32)
52.     Screen0to32& = _NewImage(w&, h&, 32)
53.     _Dest tempscreen&
54.  
55.     Dim m As _MEM, b As _Unsigned _Byte, t As String * 1
56.     Dim o As _Offset
57.     m = _MemImage(image&)
58.     o = m.OFFSET
59.  
60.     _Font f&
61.  
62.     For i = 0 To l& - 2 Step 2
63.         _MemGet m, m.OFFSET + i, t
64.         _MemGet m, m.OFFSET + i + 1, b
65.         If b > 127 Then b = b - 128
66.         fgc = b Mod 16: bgc = b \ 16
67.         Color _RGB32(_Red(fgc, image&), _Green(fgc, image&), _Blue(fgc, image&)), _RGB32(_Red(bgc, image&), _Green(bgc, image&), _Blue(bgc, image&))
68.         Print t;
69.     Next
70.     _PutImage , tempscreen&, Screen0to32&, (0, 0)-(w&, h&)
71.     _FreeImage tempscreen&
72.     _Dest d&: _Source s&
73.     _MemFree m
74.     TextScreenToImage32 = Screen0to32&
75. End Function
76.  

Very similar to what we did before, with one main exception -- if you look closely, you'll see that I'm making my hardware screen render first, so it's going UNDER the SCREEN 0 screen that I'm then using and printing on like usual.  Heck, I'm even using BLINKING text on my screen here, and as you can tell, it's NOT affecting my screen background at all!  My nice colorful orange remains a nice colorful orange, with the scrolling text not affecting it at all.

Hit the SPACEBAR to toggle the underlay on/off, and ESC will end the  demo.  ;)

You don't have to just settle with using hardware images as an overlay, as I showed you before.  You can use them as an underlay as well.

(And once you add in GL images to the mix, then you get 3 layers which you can order as you want to suit your needs.)

Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 17, 2021, 10:02:14 pm

I can see a number of uses for overlays and underlays, and GL sideways lays! It's a lot more to get comfortable with though. I think remembering the keywords and order of use won't be too difficult, but what I suspect will be a hold up is trying to picture where to use _PUTIMAGE. In my mind, if you say LOCATE 15,40, I cant point to exactly on the screen where the next character will be displayed. I just don't have anywhere's close to that "feel" with PUTIMAGE, so coding is sure to become painstakingly when I work with a couple of these effects.

So what I plan to do next is check out using this to make a little nicer high score display for ASCII Invaders, Halloween Edition. I hope to have some time to do that this coming week.

Thanks,

Pete

Title: Re: Is this at all possible in SCREEN 0?
Post by: SMcNeill on October 17, 2021, 10:08:32 pm

Quote from: Pete on October 17, 2021, 10:02:14 pm

I can see a number of uses for overlays and underlays, and GL sideways lays! It's a lot more to get comfortable with though. I think remembering the keywords and order of use won't be too difficult, but what I suspect will be a hold up is trying to picture where to use _PUTIMAGE. In my mind, if you say LOCATE 15,40, I cant point to exactly on the screen where the next character will be displayed. I just don't have anywhere's close to that "feel" with PUTIMAGE, so coding is sure to become painstakingly when I work with a couple of these effects.

So what I plan to do next is check out using this to make a little nicer high score display for ASCII Invaders, Halloween Edition. I hope to have some time to do that this coming week.

Thanks,

Pete

Just _PUTIMAGE the same as LOCATE:

LOCATE 15,40
_PUTIMAGE (40 * _FONTWIDTH, 15 * _FONTHEIGHT)...

Or with a SUB to convert automatically.

SUB PutImageLoc (y , x, image)
    _PUTIMAGE (x * _FONTWIDTH, y * _FONTHEIGHT), image
END SUB

LOCATE 14,40
PutImageLoc 14, 40, Hardware_Image

Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 17, 2021, 10:52:57 pm

Beat me to it!

Yeah, the SUB concept is what I was considering. _PUTIMAGE drives me a bit crazy in that if reverses the row column order of LOCATE. Using the sub to do the thinking is a much more comfortable method of handling things at my age. The simple act of blowing my nose creates brain fog these days. Of course, I'd bet it would help if I stopped inhaling all the CO emissions from the charcoal when I'm barbecuing. I'm only guessing, of course, because I used the CO and smoke detectors for kindling, years ago. I could hear my neighbors say... Dammit, there goes Pete again, having another one of his BEEPING barbecues!

Pete 

Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 19, 2021, 03:22:38 am

So here's as far along as I am as of now. :D

Code: QB64: [Select]

1. $COLOR:32
2. Screen0 = _NEWIMAGE(80, 25, 0)
3. SCREEN Screen0
4. swidth = _WIDTH
5.  
6. DIM SHARED Overlay
7. REDIM SHARED hsdata$(5)
8. hsdata$(1) = " 01  AAA  069000  10-18-21 "
9. hsdata$(2) = " 01  BBB  053460  10-17-21 "
10. hsdata$(3) = " 01  CCC  045700  10-17-21 "
11. hsdata$(4) = " 01  DDD  034780  10-16-21 "
12. hsdata$(5) = " 01  EEE  025890  10-12-21 "
13.  
14. DIM SHARED intro%: intro% = -1
15.  
16. skip_intro:
17. DEFINT I
18. DIM SHARED lmargin%, rmargin%, topmargin%, screenwidth%, level, ibk, ileadingrow
19. DIM SHARED irow, icol, inextrnd, imaxalienmissiles, alienforce%, ileadingmax, imaxalienforce, ihits, score$
20.  
21. _SCREENMOVE _MIDDLE
22.  
23. score$ = "000000"
24. imaxalienforce = 6
25. imaxalienmissiles = 3
26. lmargin% = 2
27. rmargin% = 79
28. topmargin% = 3
29. ialiencolstat = 6
30. iwin = 3 ' 3 Levels.
31. screenwidth% = rmargin% - lmargin% + 1
32. ibk = 0 ' Background color
33.  
34. REM Make aliens
35. a1$ = "^^" + CHR$(79) + "^^  "
36. a$ = a1$ + a1$ + a1$ + a1$ + a1$ + a1$ + a1$ + a1$ + a1$ + a1$
37. alt1$ = "--" + CHR$(79) + "--  "
38. a$ = a1$ + alt1$ + a1$ + alt1$ + a1$ + alt1$ + a1$ + alt1$ + a1$ + alt1$
39. alt$ = alt1$ + a1$ + alt1$ + a1$ + alt1$ + a1$ + alt1$ + a1$ + alt1$ + a1$
40.  
41. DIM SHARED a(imaxalienforce) AS STRING * 68
42.  
43. CALL qbide
44.  
45. COLOR 8, 0
46. ialiencol = ialiencolstat
47. LOCATE 4, ialiencol
48. FOR i = 1 TO imaxalienforce
49.     IF i MOD 1 = 0 THEN PRINT
50.     LOCATE , ialiencol
51.     IF i = imaxalienforce THEN
52.         ileadingrow = CSRLIN: ileadingmax = ileadingrow
53.     END IF
54.     IF i \ 2 = i / 2 THEN a(i) = a$ ELSE a(i) = alt$
55.     PRINT a(i)
56. NEXT
57. _DELAY 3
58.  
59. Overlay = _NEWIMAGE(_WIDTH * _FONTWIDTH, _HEIGHT * _FONTHEIGHT, 32)
60.  
61. a = 14
62. OUT &H3C8, 0
63. OUT &H3C9, 20 - a
64. OUT &H3C9, 20 - a
65. OUT &H3C9, 20 - a
66.  
67. OUT &H3C8, 8
68. OUT &H3C9, 30 - a
69. OUT &H3C9, 30 - a
70. OUT &H3C9, 30 - a
71.  
72. OUT &H3C8, 7
73. OUT &H3C9, 30 - a
74. OUT &H3C9, 30 - a
75. OUT &H3C9, 30 - a
76.  
77. OUT &H3C8, 3
78. OUT &H3C9, 30 - a
79. OUT &H3C9, 30 - a
80. OUT &H3C9, 30 - a
81.  
82. _DELAY .5
83.  
84. _DEST Overlay
85.  
86. GOSUB pete
87.  
88. _FREEIMAGE Overlay
89. _FONT 16 'select inbuilt 8x16 default font
90. _FREEFONT font
91.  
92. SLEEP
93.  
94. _AUTODISPLAY
95.  
96. _DEST 0 'Reset dest back to the normal screen 0.
97.  
98. WHILE LEN(INKEY$): WEND ' Clear keyboard buffer in case user pressed a key during program run.
99. a$ = INPUT$(1)
100. COLOR 7, 0
101. SCREEN 0
102. CLS
103. _DELAY 1
104. SYSTEM
105.  
106. pete:
107. font = _LOADFONT("lucon.ttf", 20, "monospace")
108. IF font <= 0 THEN font = 16
109. _FONT font
110.  
111. bxy% = 3
112. bxx% = 13 '27
113. COLOR DarkOrange, 0
114. text$ = " " + CHR$(218) + STRING$(27, CHR$(196)) + CHR$(191) + " "
115. PSL bxy%, bxx% - 1, text$
116. FOR i = 1 TO 11
117.     text$ = " " + CHR$(179) + STRING$(27, CHR$(32)) + CHR$(179) + " "
118.     PSL bxy% + i, bxx% - 1, text$
119. NEXT
120. text$ = " " + CHR$(192) + STRING$(27, CHR$(196)) + CHR$(217) + " "
121. PSL bxy% + i, bxx% - 1, text$
122.  
123. COLOR Black, DarkOrange
124. text$ = "    NAME   SCORE    DATE   "
125. PSL bxy% + 1, bxx% + 1, text$
126.  
127. COLOR DarkOrange, 0
128. FOR i = 1 TO 5
129.     text$ = hsdata$(i)
130.     PSL bxy% + 1 + i * 2, bxx% + 1, text$
131. NEXT
132. RETURN
133.  
134. SUB PSL (y, x, text$)
135.     _PRINTSTRING ((x - 1) * _FONTWIDTH, (y - 1) * _FONTHEIGHT), text$
136.     Overlay_Hardware = _COPYIMAGE(Overlay, 33)
137.  
138.     _PUTIMAGE (0, 0), Overlay_Hardware
139.     _DISPLAY
140.  
141. END SUB
142.  
143. SUB PSLC (y, x, text$)
144.     _PRINTSTRING ((x - 1), (y - 1) * _FONTHEIGHT), text$
145. END SUB
146.  
147. SUB qbide
148.     PALETTE 2, 59
149.     COLOR 15, 0
150.     CLS
151.  
152.     COLOR 0, 7
153.     LOCATE 1, 1
154.     PRINT SPACE$(80)
155.     LOCATE 1, 1: PRINT "   File  Edit  View  Search  Run  Debug  Calls  Options                   Help"
156.  
157.     COLOR 7, 0 ' Black background.
158.  
159.     LOCATE 2, 1: PRINT CHR$(218)
160.     LOCATE 2, 2: PRINT STRING$(78, CHR$(196))
161.     LOCATE 2, 80: PRINT CHR$(191)
162.  
163.     LOCATE 2, 76: PRINT CHR$(180)
164.     LOCATE 2, 78: PRINT CHR$(195)
165.  
166.     COLOR 0, 7
167.     LOCATE 2, 77: PRINT CHR$(24)
168.     LOCATE 2, 36: PRINT " Untitled "
169.  
170.     COLOR 7, 0
171.     FOR Rows = 3 TO 24
172.         LOCATE Rows, 1: PRINT CHR$(179);
173.         LOCATE Rows, 80: PRINT CHR$(179);
174.     NEXT Rows
175.  
176.     COLOR 0, 3: LOCATE 25, 1: PRINT " <Shift+F1=Help> <F6=Window> <F2=Subs> <F5=Run> <F8=Step> ";
177.     LOCATE 25, 59: PRINT SPACE$(4);
178.     COLOR 0, 3
179.     LOCATE 25, 63: PRINT CHR$(179);
180.     LOCATE 25, 64: PRINT SPACE$(6);
181.     LOCATE 25, 68: PRINT "C  00001:001 ";
182.  
183. END SUB
184.  

That's right. I've gone completely batty! 🦇🦇🦇🦇🦇

Pete

Edited to remove Error 5 caused by incorrectly named variable in _FREEIMAGE statement. Thanks Jack!

Title: Re: Is this at all possible in SCREEN 0?
Post by: jack on October 19, 2021, 06:39:00 am

Pete it look good but there's a problem, as soon as I press a key I get

Code: [Select]

---------------------------
Unhandled Error #5 - untitled.exe
---------------------------
Line: 94 (in main module)
Illegal function call
Continue?
---------------------------
Yes   No   
---------------------------


Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 19, 2021, 11:17:47 am

I'll have a look....

Found it, _FREEIMAGE Overlay_Hardware at line 94.

I said this stuff was making me batty...

Ah, I should have coded that as: _FREEIMAGE Overlay

I'll edit that in the code.

Thanks Jack!

Pete 

Title: Re: Is this at all possible in SCREEN 0?
Post by: jack on October 19, 2021, 11:58:09 am

Pete, no crash but the game won't play
or was this only to show the transparency and not the game itself ?

Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 19, 2021, 12:15:21 pm

You have to put a quarter in, first.

Right, it's just to show the effect, which I haven't substituted into the game yet. I still have to convert using _PRINTSTRING with the alt key input routine to accomplish that.

The game, which does include a SCREEN 0 scoreboard and 5-highest scores database, is here in the "Competition" thread: https://www.qb64.org/forum/index.php?topic=4245.msg137017#msg137017

Pete 

Title: Re: Is this at all possible in SCREEN 0?
Post by: Pete on October 22, 2021, 02:04:41 pm

@SMcNeill Hey Steve, thanks again for sharing this technique. I know @Cobalt has a similar overlay method, too. He just augmented Marks Connect 4 project with a replica of the Connect 4 board, used as an overlay.

So I put a centering routine and non-centering routine in subs like you recommened. It helps me see what's going on in my head a lot better. The _FONTWIDTH and _FONTHEIGHT conversions make that easy.

Here's my keeper for the demo...

For versions 1.4 and up.

Code: QB64: [Select]

1. $COLOR:32
2. Screen0 = _NEWIMAGE(80, 25, 0)
3. SCREEN Screen0
4.  
5. overlay = _NEWIMAGE(_WIDTH * _FONTWIDTH, _HEIGHT * _FONTHEIGHT, 32)
6.  
7. COLOR 0, 7
8. FOR x = 1 TO 25
9.     LOCATE x, 1: PRINT STRING$(80, 176);
10. NEXT
11.  
12. _DEST overlay
13. COLOR MidnightBlue, 0
14.  
15. REDIM text$(5)
16. text$(1) = "This is a SCREEN 0 overlay method"
17. text$(2) = "used by the Amazing Steve and"
18. text$(3) = "modified by me to create a simple"
19. text$(4) = "text to screen overlay on a dotted"
20. text$(5) = "SCREEN 0 background!"
21.  
22. font = _LOADFONT("lucon.ttf", 25, "monospace")
23. IF font <= 0 THEN font = 16
24. _FONT font
25. _DELAY 1
26.  
27. startrow = 3
28. FOR k = 1 TO 5
29.     t$ = text$(k)
30.     y = startrow + k * 2 - 1 ' Double space.
31.  
32.     pslc y, t$, overlay, Overlay_hardware
33.  
34.     _DELAY .5
35. NEXT
36.  
37. _FONT 16 'select inbuilt 8x16 default font
38. _FREEFONT font ' Must be placed after the font is changed.
39.  
40. COLOR Black, 0
41. msg$ = "Press space bar to toggle overlay. Press Esc to end."
42.  
43. psl 25, 1, msg$, overlay, Overlay_hardware
44.  
45. DO
46.     _LIMIT 30
47.     b$ = INKEY$
48.     IF LEN(b$) THEN
49.         IF b$ = CHR$(27) THEN EXIT DO
50.         IF Show_Overlay THEN _PUTIMAGE (0, 0), Overlay_hardware
51.         Show_Overlay = NOT Show_Overlay
52.         _DISPLAY
53.     END IF
54. LOOP
55.  
56. _FREEIMAGE Overlay_hardware
57. _DEST 0 'Reset dest back to the normal screen 0.
58. _AUTODISPLAY
59. COLOR 0, 7
60. _DELAY .75
61. CLS
62. COLOR 1, 7
63. LOCATE 2, 2
64. PRINT "Hi, back in SCREEN 0. Bye!"
65. _DELAY 2.25
66. SYSTEM
67.  
68. SUB psl (y, x, t$, overlay, Overlay_hardware)
69.     _PRINTSTRING ((x - 1) * _FONTWIDTH, (y - 1) * _FONTHEIGHT), t$
70.     Overlay_hardware = _COPYIMAGE(overlay, 33)
71.     _PUTIMAGE (0, 0), Overlay_hardware
72.     _DISPLAY
73. END SUB
74.  
75. SUB pslc (y, t$, overlay, Overlay_hardware)
76.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(t$)) \ 2, (y - 1) * _FONTHEIGHT), t$
77.     Overlay_hardware = _COPYIMAGE(overlay, 33)
78.     _PUTIMAGE (0, 0), Overlay_hardware
79.     _DISPLAY
80. END SUB

Oh, and this for Version 1.3 (No $COLOR:32)

Code: QB64: [Select]

1. Screen0 = _NEWIMAGE(80, 25, 0)
2. SCREEN Screen0
3.  
4. overlay = _NEWIMAGE(_WIDTH * _FONTWIDTH, _HEIGHT * _FONTHEIGHT, 32)
5.  
6. COLOR 0, 7
7. FOR x = 1 TO 25
8.     LOCATE x, 1: PRINT STRING$(80, 176);
9. NEXT
10.  
11. _DEST overlay
12. COLOR _RGB(0, 0, 102), 0
13.  
14. REDIM text$(5)
15. text$(1) = "This is a SCREEN 0 overlay method"
16. text$(2) = "used by the Amazing Steve and"
17. text$(3) = "modified by me to create a simple"
18. text$(4) = "text to screen overlay on a dotted"
19. text$(5) = "SCREEN 0 background!"
20.  
21. font = _LOADFONT("lucon.ttf", 25, "monospace")
22. IF font <= 0 THEN font = 16
23. _FONT font
24. _DELAY 1
25.  
26. startrow = 3
27. FOR k = 1 TO 5
28.     t$ = text$(k)
29.     y = startrow + k * 2 - 1 ' Double space.
30.  
31.     pslc y, t$, overlay, Overlay_hardware
32.  
33.     _DELAY .5
34. NEXT
35.  
36. _FONT 16 'select inbuilt 8x16 default font
37. _FREEFONT font ' Must be placed after the font is changed.
38.  
39. COLOR _RGB(20, 20, 20), 0
40. msg$ = "Press space bar to toggle overlay. Press Esc to end."
41.  
42. psl 25, 1, msg$, overlay, Overlay_hardware
43.  
44. DO
45.     _LIMIT 30
46.     b$ = INKEY$
47.     IF LEN(b$) THEN
48.         IF b$ = CHR$(27) THEN EXIT DO
49.         IF Show_Overlay THEN _PUTIMAGE (0, 0), Overlay_hardware
50.         Show_Overlay = NOT Show_Overlay
51.         _DISPLAY
52.     END IF
53. LOOP
54.  
55. _FREEIMAGE Overlay_hardware
56. _DEST 0 'Reset dest back to the normal screen 0.
57. _AUTODISPLAY
58. COLOR 0, 7
59. _DELAY .75
60. CLS
61. COLOR 1, 7
62. LOCATE 2, 2
63. PRINT "Hi, back in SCREEN 0. Bye!"
64. _DELAY 2.25
65. SYSTEM
66.  
67. SUB psl (y, x, t$, overlay, Overlay_hardware)
68.     _PRINTSTRING ((x - 1) * _FONTWIDTH, (y - 1) * _FONTHEIGHT), t$
69.     Overlay_hardware = _COPYIMAGE(overlay, 33)
70.     _PUTIMAGE (0, 0), Overlay_hardware
71.     _DISPLAY
72. END SUB
73.  
74. SUB pslc (y, t$, overlay, Overlay_hardware)
75.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(t$)) \ 2, (y - 1) * _FONTHEIGHT), t$
76.     Overlay_hardware = _COPYIMAGE(overlay, 33)
77.     _PUTIMAGE (0, 0), Overlay_hardware
78.     _DISPLAY
79. END SUB
80.  

Pete

Text Only | Text with Attachments