Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: johnno56 on July 31, 2021, 05:23:26 am

Title: QB64 Pong
Post by: johnno56 on July 31, 2021, 05:23:26 am
I know... This game has been "done to death"... Now it's my turn... lol

BPlus,

This was originally coded with Naalaa then SDLBasic the RCBasic and now QB64.
This is a direct conversion and may not be optimized... No. Definitely NOT optimized... for QB64.
It's playable but could do with a "once over" to bring it up to scratch.

Notes:

Computer can be easily beaten... not sure how to make it harder.
Each time the ball is hit, it will gradually, increase speed. Could be faster...
(computer controlled player is a bit too slow...)
First to 9 points.
Player is mouse controlled.
"Borrowed" your AABB from your shooter...

J

  [ This attachment cannot be displayed inline in 'Print Page' view ]  
Title: Re: QB64 Pong
Post by: bplus on July 31, 2021, 10:11:56 am
Quote
"Borrowed" your AABB from your shooter...

?

Look forward to checking it out.  :)
Title: Re: QB64 Pong
Post by: bplus on July 31, 2021, 11:39:11 am
Looks and sounds fabulous!

Nicely commented code, this makes ball return a little unpredictable which is good thing for pong:
Code: QB64: [Select]
  1.             '   The ball hits the player's paddle
  2.             '
  3.             If RectCollide(plyX, plyY - 48, 20, 96, Int(ballX), Int(ballY), 16, 16) = 1 Then
  4.                 human = plyHit
  5.                 playerHit = 1
  6.                 _SndPlay (Hit)
  7.                 dy = (ballY - plyY) / 64
  8.                 dx = 0.5
  9.                 k = 1 / Sqr(dx * dx + dy * dy)
  10.                 ballDX = k * dx
  11.                 ballDY = k * dy
  12.                 ballSpeed = ballSpeed * 1.1
  13.                 If ballSpeed > maxSpeed Then ballSpeed = maxSpeed
  14.             End If
  15.  
  16.  

You are right it could be faster.
Title: Re: QB64 Pong
Post by: johnno56 on July 31, 2021, 06:02:48 pm
The object of the original Naalaa version was to start slowly and slightly speed up with each ball strike until it reaches a preset maximum speed. Setting the initial and maxSpeed or changing the ballSpeed multiplier from 1.1 to something higher is not a problem. It's the speed of the computer's paddle. It is designed so as to "lag" to give the player a chance to win. It doesn't take long before the player can "out wit" the computer. That kind of puts a "wet blanket" on the game's "flow". I will continue to experiment and if I find the "lag factor", and can successfully change it, I will let you know... In the meantime.... It's always a mean time for coffee...
Title: Re: QB64 Pong
Post by: johnno56 on August 01, 2021, 06:01:08 am
"Shooter?"

Torpedo Shooter (sdlbasic 2016-08-23) - Almost 5 years ago! lol
Title: Re: QB64 Pong
Post by: DANILIN on August 01, 2021, 07:55:58 am
matrix pingpong 15 years later HD

Title: Re: QB64 Pong
Post by: johnno56 on August 01, 2021, 08:02:22 am
Very cool... But I would find it a bit difficult to code a game like that one... lol
Title: Re: QB64 Pong
Post by: bplus on August 01, 2021, 11:26:17 am
Hey @johnno56

I dusted off my pong game, looking for assets ;-))

Code: QB64: [Select]
  2. _Title "Reflective Pong" 'try a modern structured approach 2019-06-20 by B+
  3. ' 2020-08-28 fix how ball starts
  4. ' 2021-07-31 fix AI play when ball is behind paddle, just give up the point too ugly otherwise
  5.  
  7. Const xmax = 800, ymax = 600
  8. Screen _NewImage(xmax, ymax, 32)
  9. _ScreenMove 300, 40
  10.  
  11. Type Rectangle
  12.     x As Single
  13.     y As Single
  14.     w As Single
  15.     h As Single
  16.     clr As _Unsigned Long
  19.     x As Single
  20.     y As Single
  21.     s As Single
  22.     a As Single
  23.     r As Integer
  24.     clr As _Unsigned Long
  26. Type Player
  27.     id As String
  28.     pdl As Rectangle
  29.     pts As Integer
  31. Dim Shared human As Player, computer As Player, table As Rectangle, ball As Circle, cx, cy, midC
  33. initGame
  34. playGame
  35.  
  36. Sub initGame 'most of theses remain constant                     start with table
  37.     Dim mult As Integer, l As String
  38.     l = Chr$(10)
  39.     table.x = 50: table.y = 150: table.w = 700: table.h = 400: table.clr = &HFF005046
  40.     computer.id = "Computer": computer.pts = 0 '            computer on the left
  41.     computer.pdl.w = 15: computer.pdl.clr = &HFF0000FF
  42.     computer.pdl.x = table.x + 3 * computer.pdl.w
  43.     human.id = "Human": human.pts = 0 '
  44.     tryAgain: '                                             human player on the right
  45.     Cls
  46.     Print "  Levels, Enter:" + l + "  1 for Super Pro" + l + "  2 for Pro" + l + "  3 Human" + l + "  4 Handicapped" + l + "  5 Bigger Handicap" + l + "  6 Help Me!" + l
  47.     Input ""; mult
  48.     If mult < 1 Or mult > 6 Then Beep: GoTo tryAgain
  49.     Select Case mult
  50.         Case 1: human.id = "Super Pro"
  51.         Case 2: human.id = "Pro"
  52.         Case 3: human.id = "Human"
  53.         Case 4: human.id = "Handicapped"
  54.         Case 5: human.id = "Bigger Handicap"
  55.         Case 6: human.id = "Help Me!": mult = 12
  56.     End Select
  57.     human.pdl.w = mult * 5: human.pdl.h = 40: human.pdl.clr = &HFFFF0000
  58.     ball.s = 5: ball.r = 5: ball.clr = &HFFFFFFFF '                     ball
  59.     midC = table.x + .25 * table.w
  60.     Print: Print: Print "    Move your mouse to position the red circle (paddle)..."
  61.     Sleep 2
  63.  
  64. Sub playGame
  65.     Dim mx, my, inbounds
  66.     Do
  67.         getBallRolling
  68.         inbounds = 1
  69.         While inbounds
  70.             While _MouseInput: Wend
  71.             my = _MouseY: mx = _MouseX
  72.             If my > table.y And my <= table.y + table.h Then '    update human paddle
  73.                 If mx > table.x + .5 * table.w And mx < table.x + table.w Then
  74.                     human.pdl.x = mx: human.pdl.y = my
  75.                 End If
  76.             End If
  77.  
  78.             cx = cx + _Pi(1 / 80): cy = cy + _Pi(1 / 40)
  79.             If ball.x > computer.pdl.x Then
  80.                 computer.pdl.x = midC + (.5 * midC - 10) * Sin(cx)
  81.                 computer.pdl.y = ball.y + 20 * Sin(cy)
  82.             End If
  83.  
  84.             If computer.pdl.y - computer.pdl.h < table.y Then computer.pdl.y = table.y + computer.pdl.h
  85.             If computer.pdl.y + computer.pdl.h > table.y + table.h Then computer.pdl.y = table.y + table.h - computer.pdl.h
  86.  
  87.             ball.x = ball.x + ball.s * Cos(ball.a): ball.y = ball.y + ball.s * Sin(ball.a) '  update ball
  88.             'past the table edge? or paddle edge
  89.             If dist(human.pdl.x, human.pdl.y, ball.x, ball.y) < ball.r + human.pdl.w Then 'ball finds human paddle
  90.                 ball.a = _Atan2(ball.y - human.pdl.y, ball.x - human.pdl.x)
  91.                 ball.x = ball.x + 2 * ball.s * Cos(ball.a)
  92.                 ball.y = ball.y + 2 * ball.s * Sin(ball.a)
  93.  
  94.             ElseIf dist(computer.pdl.x, computer.pdl.y, ball.x, ball.y) < ball.r + computer.pdl.w Then 'ball finds AI paddle
  95.                 ball.a = _Atan2(ball.y - computer.pdl.y, ball.x - computer.pdl.x)
  96.                 ball.x = ball.x + 2 * ball.s * Cos(ball.a)
  97.                 ball.y = ball.y + 2 * ball.s * Sin(ball.a)
  98.  
  99.             ElseIf ball.x <= computer.pdl.x - 2 * computer.pdl.w Then '            ball paste left edge
  100.                 inbounds = 0: human.pts = human.pts + 1
  101.  
  102.             ElseIf ball.x + ball.r >= table.x + table.w Then '                ball paste right edge
  103.                 inbounds = 0: computer.pts = computer.pts + 1
  104.  
  105.             ElseIf ball.y - ball.r <= table.y Then '                                          top edge
  106.                 ball.a = -ball.a
  107.                 ball.y = table.y + ball.r
  108.  
  109.             ElseIf ball.y + ball.r >= table.y + table.h Then '                            bottom edge
  110.                 ball.a = -ball.a
  111.                 ball.y = table.y + table.h - ball.r
  112.             End If
  113.             drawGame
  114.             _Display
  115.             _Limit 90
  116.         Wend
  117.         _Delay .5
  118.     Loop Until human.pts = 21 Or computer.pts = 21
  120.  
  121. Sub getBallRolling
  122.     Dim d, ra, s$, tstart, my, mx
  123.  
  124.     computer.pdl.y = table.y + (table.h - computer.pdl.h) / 2 '       center paddles y
  125.     If Rnd < .5 Then d = _Pi / 2 Else d = -_Pi / 2 '                 ball movement absolutely  more dx than dy
  126.     ra = Rnd * _Pi(.15)
  127.     If Rnd < .5 Then ball.a = d - ra Else ball.a = d + ra
  128.     ball.x = table.x + .5 * table.w
  129.     If ball.a > _Pi(.5) And ball.a < _Pi(1.5) Then
  130.         computer.pdl.x = table.x + .1 * table.w
  131.     Else
  132.         computer.pdl.x = table.x + computer.pdl.w
  133.     End If
  134.     ball.y = table.y + table.h / 2
  135.     tstart = Timer(.001)
  136.     While Timer(.001) - tstart < 2 ' <<<<<<<<<<<<<<<< This allows player to get es paddle alligned with mouse
  137.         While _MouseInput: Wend
  138.         mx = _MouseX: my = _MouseY
  139.         If my > table.y And my <= table.y + table.h Then '    update human paddle
  140.             If mx > table.x + .5 * table.w And mx < table.x + table.w Then
  141.                 human.pdl.x = mx: human.pdl.y = my - human.pdl.h / 2
  142.             End If
  143.         End If
  144.         drawGame
  145.         s$ = "Get ready for random serve..."
  146.         Color , table.clr
  147.         _PrintString (table.x + (table.w - 8 * Len(s$)) / 2, table.y + table.h / 2 - 8), s$
  148.         Color , &HFF000000
  149.         _Display
  150.         _Limit 60
  151.     Wend
  153.  
  154. Sub drawGame
  155.     Dim s$
  156.     Cls
  157.     _PrintString (table.x + 120, table.y / 2 - 4), computer.id + ":" + Str$(computer.pts)
  158.     s$ = human.id + ":" + Str$(human.pts)
  159.     _PrintString (table.x + table.w - 8 * Len(s$) - 120, table.y / 2 - 4), s$
  160.     Line (table.x, table.y)-Step(table.w, table.h), table.clr, BF 'table
  161.     Line (table.x, table.y)-Step(table.w, table.h), &HFFFFFFFF, B 'table
  162.     Line (table.x + table.w / 2, table.y)-Step(0, table.h), &HFFFFFFFF
  163.     fcirc computer.pdl.x, computer.pdl.y, computer.pdl.w, computer.pdl.clr
  164.     fcirc human.pdl.x, human.pdl.y, human.pdl.w, human.pdl.clr
  165.     fcirc ball.x, ball.y, ball.r, ball.clr
  167.  
  168. Function dist (x1, y1, x2, y2)
  169.     dist = ((x1 - x2) ^ 2 + (y1 - y2) ^ 2) ^ .5
  171.  
  172. Sub fcirc (CX As Integer, CY As Integer, R As Integer, C As _Unsigned Long)
  173.     Dim Radius As Integer, RadiusError As Integer
  174.     Dim X As Integer, Y As Integer
  175.     Radius = Abs(R): RadiusError = -Radius: X = Radius: Y = 0
  176.     If Radius = 0 Then PSet (CX, CY), C: Exit Sub
  177.     Line (CX - X, CY)-(CX + X, CY), C, BF
  178.     While X > Y
  179.         RadiusError = RadiusError + Y * 2 + 1
  180.         If RadiusError >= 0 Then
  181.             If X <> Y + 1 Then
  182.                 Line (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
  183.                 Line (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
  184.             End If
  185.             X = X - 1
  186.             RadiusError = RadiusError - X * 2
  187.         End If
  188.         Y = Y + 1
  189.         Line (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
  190.         Line (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
  191.     Wend
  193.  
  194.  
Title: Re: QB64 Pong
Post by: johnno56 on August 01, 2021, 05:04:34 pm
I dunno... If you swap the lawn or clay surface to something much colder and smoother.... This game reminds me of another... Can't quite put my finger on it... lol

The fill circle function is quite fast. Two paddles and a fast moving ball... Have you tested the number of circles before lagging occurs? Homework...

I like the "Help Me" option... Unlike most 'tennis' games, I could actually hit the ball more than once... nice feature.

In regards to graphics, would I be correct in assuming that, curved paddles would be preferred so as to maintain an air of unpredictability?
Originally, you had the player setup as a rectangle... But, calculating the distance between two circles, would be quicker than including collision detection... Cool...
If ever you decided to use collision detection, you could use AABB, because the ball is quite small and can be treated as a square... On the subject of the ball... The colour could be white, yellow or even lime green. Steer clear or black. Black would make it look like a puck. Puck? Interesting... Just a thought...

Speaking of lawn and clay... perhaps either allowing the player to choose or randomly select a surface could effect the player's "friction". eg: if the surface is clay, then the surface friction is less - similar to ice but not so much - ice? Interesting.... and the lawn would have greater friction so as to make player movement more responsive... Just another though...

Here's another weird thought... I know... three in one day... Who knew?  lol  If the player is using the 'easier' paddles then perhaps the player's paddle can reduce in size with each ball strike... Striker? Interesting... Just yet another thought...  I'm going to stop there. Fear of wearing out the old grey matter is reason enough... But, the best reason is, coffee...

Have a great day!

J
Title: Re: QB64 Pong
Post by: johnno56 on August 02, 2021, 04:53:24 pm
Bplus.

In regards to graphics... I'm toying with the idea of a horror/comedy look... Just a concept... Player is a zombie the computer is an eyeball and the ball is a skull... With the right backing track, sound effects, images and fonts (all free of course) it could make for an amusing project... Not 100% certain of success but might be good for a giggle... Also testing a simple menu operated by arrows and space keys... another crazy thought... Have critters walk across the players side of the court. If the player can hit them with the "ball" then a game point is removed from the computer...  anyway... best get the game working before adding more stuff... This could be fun...
Title: Re: QB64 Pong
Post by: bplus on August 02, 2021, 05:31:01 pm
Oh yeah, a creepy crawler Break-out game!
Title: Re: QB64 Pong
Post by: johnno56 on August 02, 2021, 06:19:16 pm
Creepy break-out? Hmm... Interesting. I like the sound of that... Moo Ha Ha....
Title: Re: QB64 Pong
Post by: TempodiBasic on August 02, 2021, 06:34:33 pm
Quote
matrix pingpong 15 years later HD
LOL

@jonnho56
Cool
Title: Re: QB64 Pong
Post by: TempodiBasic on August 02, 2021, 07:03:54 pm
I forgot the screenshot
  [ This attachment cannot be displayed inline in 'Print Page' view ]  
Title: Re: QB64 Pong
Post by: johnno56 on August 02, 2021, 07:50:33 pm
I can take no credit. It was merely a modification of the original Naalaa listing by Marcus Johannsen.
Text Only | Text with Attachments