QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Richard on June 12, 2021, 08:36:43 pm

Title: How to determine available memory left?
Post by: Richard on June 12, 2021, 08:36:43 pm

With Windows 10 x64 - how to determine the available memory left in a QB64 program?

Ideally without say resizing an array until error condition - any API code available?

Title: Re: How to determine available memory left?
Post by: SpriggsySpriggs on June 12, 2021, 08:47:54 pm

Check https://pvs-studio.com/en/blog/posts/k0036/ (https://pvs-studio.com/en/blog/posts/k0036/) to see how much a program gets. Use https://docs.microsoft.com/en-us/windows/win32/api/sysinfoapi/nf-sysinfoapi-globalmemorystatusex (https://docs.microsoft.com/en-us/windows/win32/api/sysinfoapi/nf-sysinfoapi-globalmemorystatusex) to check memory

Title: Re: How to determine available memory left?
Post by: SpriggsySpriggs on June 12, 2021, 09:10:01 pm

Code: QB64 $NOPREFIX: [Select]

1. $NoPrefix
2. Option Explicit
3.  
4. Type MEMORYSTATUSEX
5.     As Long dwLength, dwMemoryLoad
6.     As Unsigned Integer64 ullTotalPhys, ullAvailPhys, ullTotalPageFile, ullAvailPageFile, ullTotalVirtual, ullAvailVirtual, ullAvailExtendedVirtual
7. End Type
8.  
9. Type FILETIME
10.     As Long dwLowDateTime, dwHighDateTime
11. End Type
12.  
13. Screen NewImage(640, 480, 32)
14.  
15. Title "Memory API"
16. Do
17.     Limit 1
18.     Cls
19.  
20.     Print Using "CPU used: ###.##%"; Int(GetCPULoad * 10000) / 100
21.     Print
22.  
23.     Print Using "Memory used: ###%"; MemInUsePercent
24.     Print
25.  
26.     Print "Total Physical Memory: "
27.     Print Using "   ####################, bytes"; TotalPhysicalMem
28.     Print
29.  
30.     Print "Free Physical Memory: "
31.     Print Using "   ####################, bytes"; FreePhysicalMem
32.     Print
33.  
34.     Print "Total Paging File: "
35.     Print Using "   ####################, bytes"; TotalPagingFile
36.     Print
37.  
38.     Print "Free Paging File: "
39.     Print Using "   ####################, bytes"; FreePagingFile
40.     Print
41.  
42.     Print "Total Virtual Memory: "
43.     Print Using "   ####################, bytes"; TotalVirtualMem
44.     Print
45.  
46.     Print "Free Virtual Memory:"
47.     Print Using "   ####################, bytes"; FreeVirtualMem
48.     Print
49.  
50.     Print "Free Extended Virtual Memory:"
51.     Print Using "   ####################, bytes"; FreeExtendedMem
52.     Display
53. Loop
54.  
55. Declare CustomType Library
56.     Sub GlobalMemoryStatus Alias "GlobalMemoryStatusEx" (ByVal lpBuffer As Offset)
57.     Function GetSystemTimes%% (ByVal lpIdleTime As Offset, Byval lpKernelTime As Offset, Byval lpUserTime As Offset)
58. End Declare
59.  
60.  
61. Function MemInUsePercent~& ()
62.     Dim As MEMORYSTATUSEX statex
63.     statex.dwLength = Len(statex)
64.     GlobalMemoryStatus Offset(statex)
65.     MemInUsePercent = statex.dwMemoryLoad
66. End Function
67.  
68. Function TotalPhysicalMem~&& ()
69.     Dim As MEMORYSTATUSEX statex
70.     statex.dwLength = Len(statex)
71.     GlobalMemoryStatus Offset(statex)
72.     TotalPhysicalMem = statex.ullTotalPhys
73. End Function
74.  
75. Function FreePhysicalMem~&& ()
76.     Dim As MEMORYSTATUSEX statex
77.     statex.dwLength = Len(statex)
78.     GlobalMemoryStatus Offset(statex)
79.     FreePhysicalMem = statex.ullAvailPhys
80. End Function
81.  
82. Function TotalPagingFile~&& ()
83.     Dim As MEMORYSTATUSEX statex
84.     statex.dwLength = Len(statex)
85.     GlobalMemoryStatus Offset(statex)
86.     TotalPagingFile = statex.ullTotalPageFile
87. End Function
88.  
89. Function FreePagingFile~&& ()
90.     Dim As MEMORYSTATUSEX statex
91.     statex.dwLength = Len(statex)
92.     GlobalMemoryStatus Offset(statex)
93.     FreePagingFile = statex.ullAvailPageFile
94. End Function
95.  
96. Function TotalVirtualMem~&& ()
97.     Dim As MEMORYSTATUSEX statex
98.     statex.dwLength = Len(statex)
99.     GlobalMemoryStatus Offset(statex)
100.     TotalVirtualMem = statex.ullTotalVirtual
101. End Function
102.  
103. Function FreeVirtualMem~&& ()
104.     Dim As MEMORYSTATUSEX statex
105.     statex.dwLength = Len(statex)
106.     GlobalMemoryStatus Offset(statex)
107.     FreeVirtualMem = statex.ullAvailVirtual
108. End Function
109.  
110. Function FreeExtendedMem~&& ()
111.     Dim As MEMORYSTATUSEX statex
112.     statex.dwLength = Len(statex)
113.     GlobalMemoryStatus Offset(statex)
114.     FreeExtendedMem = statex.ullAvailExtendedVirtual
115. End Function
116.  
117. Function CalculateCPULoad## (idleTicks As Unsigned Integer64, totalTicks As Unsigned Integer64) Static
118.     Static As Unsigned Integer64 previousTotalTicks, previousIdleTicks
119.     Dim As Unsigned Integer64 totalTicksSinceLastTime, idleTicksSinceLastTime
120.     totalTicksSinceLastTime = totalTicks - previousTotalTicks
121.     idleTicksSinceLastTime = idleTicks - previousIdleTicks
122.     Dim As Float ret
123.     ret = 1.0
124.     If totalTicksSinceLastTime > 0 Then
125.         If 1.0 - (idleTicksSinceLastTime / totalTicksSinceLastTime) >= 0 Then
126.             ret = 1.0 - (idleTicksSinceLastTime / totalTicksSinceLastTime)
127.         End If
128.     Else ret = 1.0
129.     End If
130.     previousTotalTicks = totalTicks
131.     previousIdleTicks = idleTicks
132.     CalculateCPULoad = ret
133. End Function
134.  
135. Function FileTimeToInt64~&& (ft As FILETIME) Static
136.     FileTimeToInt64 = SHL(ft.dwHighDateTime, 32) Or ft.dwLowDateTime
137. End Function
138.  
139. Function GetCPULoad## ()
140.     Dim As FILETIME idleTime, kernelTime, userTime
141.     If GetSystemTimes(Offset(idleTime), Offset(kernelTime), Offset(userTime)) Then
142.         GetCPULoad = CalculateCPULoad(FileTimeToInt64(idleTime), FileTimeToInt64(kernelTime) + FileTimeToInt64(userTime))
143.     Else
144.         GetCPULoad = -1.0
145.     End If
146. End Function

Title: Re: How to determine available memory left?
Post by: SMcNeill on June 12, 2021, 09:55:23 pm

Is there a limit, if you compile with the 64-bit version of QB64?  I guess if you max out ram + hard drive usage, but that’s either one massive program or one helluva memory leak!

Title: Re: How to determine available memory left?
Post by: Richard on June 12, 2021, 10:12:42 pm

@SpriggsySpriggs

Just tried to use your code above into my program (Qb64 v1.5 stable release) but the IDE gives error:-

Expected variablename AS type or END TYPE on line 12

LINE#11     Type MEMORYSTATUSEX
LINE #12    As Long dwLength, dwMemoryLoad

(I had extra lines of my code at beginning)

I recalled a similar kind of problem when using your pipecom (but which worked OK I think in a dev build - but because of Compiler error with dev build that you and Fellippe already working on I had to go back to the v1.5 stable build).

Title: Re: How to determine available memory left?
Post by: Richard on June 12, 2021, 11:28:30 pm

@moises1953

Thanks again for your reply in the link below (I thought I had asked the question before but for a totally different reason!)

https://www.qb64.org/forum/index.php?topic=3750.msg131094#msg131094
 (https://www.qb64.org/forum/index.php?topic=3750.msg131094#msg131094)





@SpriggsySpriggs

Thanks for your reply earlier on - if it is too difficult for you to fix at this stage, please place on hold. I located @moises1953 reply earlier that I had forgotten about. I am confused as to why the "millions" of IDE errors using your code in v1.5 stable build but for instance your pipecom I recall worked with a dev build. 

Title: Re: How to determine available memory left?
Post by: SpriggsySpriggs on June 13, 2021, 12:04:58 am

Oh yeah I'm not supporting any one-off codes at all. They all come as-is

Text Only | Text with Attachments