QB64.org Forum

Active Forums => Programs => Topic started by: Ashish on May 19, 2021, 01:59:39 am

Title: Music Visualiser 2D
Post by: Ashish on May 19, 2021, 01:59:39 am

Hey everyone! When I learned about _MEMSOUND by watching Fellippe's video on QB64 Team channel.. I had an
idea to visualise the sound...

REPLACE the value of file_name$ to your sound file.

Have fun!!

Code: QB64: [Select]

1. '#####################
2. ' Music Visualiser 2D
3. ' By Ashish
4. ' 18 May, 2021
5. '#####################
6.  
7. file_name$ = "rolling.mp3" '<<---- replace with your file name with a sound file you have
8. $Let DEBUG = 1
9.  
10. $If DEBUG Then
11.     $Console
12.     _Echo "loading sound"
13. $End If
14. Dim song&
15.  
16. song& = _SndOpen(file_name$)
17. If song& = 0 Then Print "Load failed.": End
18.  
19. _Title "Music Visualiser 2D"
20. Type vec3
21.     As Single x, y, z
22. End Type
23. Type vec2
24.     As Single x, y
25. End Type
26. Declare Library
27.     Sub gluLookAt (ByVal eyeX#, Byval eyeY#, Byval eyeZ#, Byval centerX#, Byval centerY#, Byval centerZ#, Byval upX#, Byval upY#, Byval upZ#)
28. End Declare
29. Screen _NewImage(800, 600, 32)
30. Dim Shared leftChannel As _MEM, rightChannel As _MEM
31. Dim Shared stereo As _Byte, glAllow As _Byte
32. Dim Shared leftData(0 To 360) As Single, rightData(0 To 360) As Single, colorData(0 To 360) As vec3
33. Dim tmp_color As _Unsigned Long
34. For i = 0 To 360
35.     tmp_color = hsb~&(i * (255 / 360), 255, 128, 255)
36.     colorData(i).x = _Red(tmp_color) / 255
37.     colorData(i).y = _Green(tmp_color) / 255
38.     colorData(i).z = _Blue(tmp_color) / 255
39. Next
40.  
41. leftChannel = _MemSound(song&, 1)
42. rightChannel = _MemSound(song&, 2)
43. If leftChannel.SIZE = 0 Then
44.     Print "An error occurred."
45.     End
46. End If
47. If rightChannel.SIZE = 0 Then
48.     $If DEBUG Then
49.         _Echo "sound is mono"
50.     $End If
51.     stereo = 0
52. Else
53.     $If DEBUG Then
54.         _Echo "sound is stereo"
55.     $End If
56.     stereo = 1
57. End If
58.  
59. Dim i As _Offset, j As _Offset
60. i = 0
61. glAllow = 1
62. _FPS 60
63. _SndPlay song&
64. Do
65.  
66.  
67.  
68.     For n = 0 To 360
69.         _MemGet leftChannel, leftChannel.OFFSET + i + j, a1% 'get sound data
70.         leftData(n) = a1% * 0.00001
71.         If stereo = 1 Then
72.             _MemGet rightChannel, rightChannel.OFFSET + i + j, a2%
73.             rightData(n) = a2% * 0.00001
74.         End If
75.         j = j + 2
76.         If i + j + 2 > leftChannel.SIZE Then Exit Do
77.         If stereo = 1 And i + j + 2 > rightChannel.SIZE Then Exit Do
78.     Next
79.     i = i + 2 * (44100 / 60)
80.     j = 0
81.     If i + 2 > leftChannel.SIZE Then Exit Do
82.     If stereo = 1 And i + j + 2 > rightChannel.SIZE Then Exit Do
83.     _Limit 60
84. Loop
85.  
86.  
87. _SndClose song& 'closing the sound releases the mem blocks
88.  
89. Sub _GL ()
90.     Static glInit
91.     If glAllow = 0 Then
92.         Exit Sub
93.     End If
94.     If glInit = 0 Then
95.         glInit = 1
96.         _glViewport 0, 0, _Width, _Height
97.         $If DEBUG Then
98.             _Echo "_GL() : initialization done. glInit set to 1"
99.         $End If
100.     End If
101.  
102.     'projection setup
103.     _glMatrixMode _GL_PROJECTION
104.     _glLoadIdentity
105.     _gluPerspective 50, _Width / _Height, 0.1, 50
106.  
107.     _glMatrixMode _GL_MODELVIEW
108.     _glLoadIdentity
109.     gluLookAt 0, 0, 3, 0, 0, 0, 0, 1, 0
110.  
111.  
112.  
113.     _glBegin _GL_LINES
114.     For i = 0 To 360
115.         c = Int(map(Abs(leftData(i)), 0, 0.7, 0, 360))
116.         _glColor3f colorData(c).x, colorData(c).y, colorData(c).z
117.         _glVertex2f -1, 0
118.         _glVertex2f -1 + (0.5 + leftData(i)) * Cos(_D2R(i)), (0.5 + leftData(i)) * Sin(_D2R(i))
119.         _glVertex2f 1, 0
120.         If stereo = 0 Then
121.  
122.             _glVertex2f 1 + (0.5 + leftData(i)) * Cos(_D2R(i)), (0.5 + leftData(i)) * Sin(_D2R(i))
123.         Else
124.             _glVertex2f 1 + (0.5 + rightData(i)) * Cos(_D2R(i)), (0.5 + rightData(i)) * Sin(_D2R(i))
125.         End If
126.     Next
127.     _glEnd
128.     _glFlush
129. End Sub
130.  
131.  
132. 'function from
133. 'p5js.bas
134. 'http://bit.ly/p5jsbas
135. Function map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
136.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
137. End Function
138.  
139.  
140. 'method adapted form http://stackoverflow.com/questions/4106363/converting-rgb-to-hsb-colors
141. Function hsb~& (__H As _Float, __S As _Float, __B As _Float, A As _Float)
142.     Dim H As _Float, S As _Float, B As _Float
143.  
144.     H = map(__H, 0, 255, 0, 360)
145.     S = map(__S, 0, 255, 0, 1)
146.     B = map(__B, 0, 255, 0, 1)
147.  
148.     If S = 0 Then
149.         hsb~& = _RGBA32(B * 255, B * 255, B * 255, A)
150.         Exit Function
151.     End If
152.  
153.     Dim fmx As _Float, fmn As _Float
154.     Dim fmd As _Float, iSextant As Integer
155.     Dim imx As Integer, imd As Integer, imn As Integer
156.  
157.     If B > .5 Then
158.         fmx = B - (B * S) + S
159.         fmn = B + (B * S) - S
160.     Else
161.         fmx = B + (B * S)
162.         fmn = B - (B * S)
163.     End If
164.  
165.     iSextant = Int(H / 60)
166.  
167.     If H >= 300 Then
168.         H = H - 360
169.     End If
170.  
171.     H = H / 60
172.     H = H - (2 * Int(((iSextant + 1) Mod 6) / 2))
173.  
174.     If iSextant Mod 2 = 0 Then
175.         fmd = (H * (fmx - fmn)) + fmn
176.     Else
177.         fmd = fmn - (H * (fmx - fmn))
178.     End If
179.  
180.     imx = _Round(fmx * 255)
181.     imd = _Round(fmd * 255)
182.     imn = _Round(fmn * 255)
183.  
184.     Select Case Int(iSextant)
185.         Case 1
186.             hsb~& = _RGBA32(imd, imx, imn, A)
187.         Case 2
188.             hsb~& = _RGBA32(imn, imx, imd, A)
189.         Case 3
190.             hsb~& = _RGBA32(imn, imd, imx, A)
191.         Case 4
192.             hsb~& = _RGBA32(imd, imn, imx, A)
193.         Case 5
194.             hsb~& = _RGBA32(imx, imn, imd, A)
195.         Case Else
196.             hsb~& = _RGBA32(imx, imd, imn, A)
197.     End Select
198.  
199. End Function
200.  

Title: Re: Music Visualiser 2D
Post by: johnno56 on May 19, 2021, 07:51:23 am

That's pretty cool.... Look at the display 'cross-eyed' and focus on the center image...

Title: Re: Music Visualiser 2D
Post by: Ashish on May 20, 2021, 01:21:38 am

Thank you, @johnno56 !

Title: Re: Music Visualiser 2D
Post by: Dav on May 20, 2021, 10:40:38 am

That's cool, Ashish!  Inspires me to tinker around making a sound visualizer too.  Thanks for posting.

- Dav 

Text Only | Text with Attachments