Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: bplus on May 09, 2021, 02:14:49 am

Title: 2 Ball Collision with an itsy-bitsy-teeny-tiny little bit of trig
Post by: bplus on May 09, 2021, 02:14:49 am
Code: QB64: [Select]
  1. '  Collision Study Mouse and Ball.bas for QB64 fork (B+=MGA) 2017-08-23
  2. 'updated from: Collision study mouse and ball.bas for QB64 fork (B+=MGA) trans 2017-08-20
  3. 'translated from "collision mouse study.bas"  SmallBASIC version 2017-01-10
  4. 'which was modify the yab version from six posts to one mouse
  5.  
  6. Const xmax = 800
  7. Const ymax = 600
  8. Screen _NewImage(xmax, ymax, 32)
  9. _Title "Collision Study: Mouse versus Ball - bplus"
  10.  
  11. Const RADIUS = 30 ' radius for both ball and angle
  12. Const SPEED = 5
  13. ba = _Pi(1 / 6) 'ball angle in radians
  14. bx = xmax / 2 'ball x
  15. by = ymax / 2 'ball y
  16.  
  17.  
  19.     Cls , _RGB(30, 70, 48)
  20.     If _KeyHit = 27 Then End 'pressed escape goodbye!
  21.  
  22.     'paddle px, py location
  23.     While _MouseInput: Wend  ' <<<<<<<<<< this code so old I had to fix this
  24.     px = _MouseX: py = _MouseY
  25.  
  26.     pbDistance = Sqr((px - bx) ^ 2 + (py - by) ^ 2)
  27.     'LOCATE 1, 1: PRINT px, py, pbDistance  'debug
  28.  
  29.     'show paddle
  30.     For i = RADIUS To 0 Step -1
  31.         Color _RGB(255 - i * 5, 0, 0)
  32.         CircleFill px, py, i
  33.     Next
  34.  
  35.     'update ball hit paddle
  36.     If Sqr((px - bx) ^ 2 + (py - by) ^ 2) < RADIUS * 2 Then ba = _Atan2(by - py, bx - px)
  37.  
  38.     'handle ball hit border
  39.     If bx < 0 + RADIUS Then ba = _Pi(1) - ba: bx = RADIUS
  40.     If bx > xmax - RADIUS Then ba = _Pi(1) - ba: bx = xmax - RADIUS
  41.     If by < 0 + RADIUS Then ba = -ba: by = RADIUS
  42.     If by > ymax - RADIUS Then ba = -ba: by = ymax - RADIUS
  43.  
  44.     'ball angle adjustments to keep between 0 and 2*pi
  45.     If ba > 2 * _Pi(1) Then ba = ba - _Pi(2)
  46.     If ba < 0 Then ba = ba + _Pi(2)
  47.  
  48.     'OK the ball is here
  49.     bx = bx + Cos(ba) * SPEED
  50.     by = by + Sin(ba) * SPEED
  51.  
  52.     'show ball
  53.     For i = RADIUS To 0 Step -1
  54.         Color _RGB(255 - i * 6, 255 - i * 6, 255 - i * 6)
  55.         CircleFill bx, by, i
  56.     Next
  57.  
  58.     'update screen and keep loops under 61 per second
  59.     _Display
  60.     _Limit 60
  62.  
  63. 'Steve McNeil's  copied from his forum
  64. Sub CircleFill (CX As Long, CY As Long, R As Long)
  65.     Dim subRADIUS As Long, RadiusError As Long
  66.     Dim X As Long, Y As Long
  67.  
  68.     subRADIUS = Abs(R)
  69.     RadiusError = -subRADIUS
  70.     X = subRADIUS
  71.     Y = 0
  72.  
  73.     If subRADIUS = 0 Then PSet (CX, CY): Exit Sub
  74.  
  75.     ' Draw the middle span here so we don't draw it twice in the main loop,
  76.     ' which would be a problem with blending turned on.
  77.     Line (CX - X, CY)-(CX + X, CY), , BF
  78.  
  79.     While X > Y
  80.         RadiusError = RadiusError + Y * 2 + 1
  81.         If RadiusError >= 0 Then
  82.             If X <> Y + 1 Then
  83.                 Line (CX - Y, CY - X)-(CX + Y, CY - X), , BF
  84.                 Line (CX - Y, CY + X)-(CX + Y, CY + X), , BF
  85.             End If
  86.             X = X - 1
  87.             RadiusError = RadiusError - X * 2
  88.         End If
  89.         Y = Y + 1
  90.         Line (CX - X, CY - Y)-(CX + X, CY - Y), , BF
  91.         Line (CX - X, CY + Y)-(CX + X, CY + Y), , BF
  92.     Wend
  94.  
  95.  
  96.  

Title: Re: 2 Ball Collision with an itsy-bitsy-teeny-tiny little bit of trig
Post by: johnno56 on May 09, 2021, 06:39:38 am
I can prove that you are clairvoyant.... Can you guess my next question? lol
Title: Re: 2 Ball Collision with an itsy-bitsy-teeny-tiny little bit of trig
Post by: SMcNeill on May 09, 2021, 09:07:11 am
Quote from: johnno56 on May 09, 2021, 06:39:38 am
I can prove that you are clairvoyant.... Can you guess my next question? lol

Does it come in Blue?
Title: Re: 2 Ball Collision with an itsy-bitsy-teeny-tiny little bit of trig
Post by: Abacus on May 09, 2021, 10:13:14 am
Very cool!
Title: Re: 2 Ball Collision with an itsy-bitsy-teeny-tiny little bit of trig
Post by: justsomeguy on May 09, 2021, 10:33:37 am
Edit: http://kishimotostudios.com/articles/circle_collision/ has a very nice explanation on how it works

Very Nice!

May propose a small optimization? If you are looking for circle to circle collisions, there is a faster way and it does not involve square roots which are normally slower.

I borrowed this from my physics engine and it may be useful to you. I'm not sure about the mathamatics behind it but it works great.
Code: QB64: [Select]
  1. FUNCTION circleCircleCollision (cx1 AS SINGLE, cy1 AS SINGLE, radius1 AS SINGLE, cx2 AS SINGLE, cy2 AS SINGLE, radius2 AS SINGLE)
  2.     DIM AS SINGLE dx, dy, vlq, radius
  3.     dx = cx1 - cx2
  4.     dy = cy1 - cy2
  5.     vlq = dx * dx + dy * dy
  6.     radius = radius1 + radius2
  7.     circleCircleCollision = (vlq >= radius * radius)

I even made a little demo so that you can verify that it works.

Code: QB64: [Select]
  1. DIM h$(1): h$(0) = "Hit": h$(1) = "No Hit"
  2. DIM hs$
  3. _TITLE "Circle Collison Example"
  4. SCREEN _NEWIMAGE(800, 600, 32)
  5.  
  6. DIM AS SINGLE cx1, cy1, rad1, cx2, cy2, rad2
  7. cx1 = _WIDTH / 2
  8. cy1 = _HEIGHT / 2
  9. rad1 = 100
  10. rad2 = 50
  11.  
  13.     CLS
  15.         cx2 = _MOUSEX
  16.         cy2 = _MOUSEY
  17.         rad2 = rad2 + _MOUSEWHEEL
  18.     LOOP
  19.  
  20.     CIRCLE (cx1, cy1), rad1
  21.     CIRCLE (cx2, cy2), rad2
  22.  
  23.     hit = circleCircleCollision(cx1, cy1, rad1, cx2, cy2, rad2)
  24.     hs$ = h$(ABS(hit))
  25.     _PRINTSTRING (_WIDTH / 2 - (_PRINTWIDTH(hs$)) / 2, _HEIGHT * .75), hs$
  26.  
  27.     _DISPLAY
  28.     _LIMIT 60
  31.  
  32. FUNCTION circleCircleCollision (cx1 AS SINGLE, cy1 AS SINGLE, radius1 AS SINGLE, cx2 AS SINGLE, cy2 AS SINGLE, radius2 AS SINGLE)
  33.     DIM AS SINGLE dx, dy, vlq, radius
  34.     dx = cx1 - cx2
  35.     dy = cy1 - cy2
  36.     vlq = dx * dx + dy * dy
  37.     radius = radius1 + radius2
  38.     circleCircleCollision = (vlq >= radius * radius)


 
Title: Re: 2 Ball Collision with an itsy-bitsy-teeny-tiny little bit of trig
Post by: bplus on May 09, 2021, 12:38:17 pm
Thanks guys,

@johnno56 coffee is ready now :)

@justsomeguy  yes I like loosing the SQR for distance calc, not really needed and I think x*x is better than x^2 as well. This gives me idea for further optimizing, I will experiment a little, thanks again.

PS this isn't really 2 ball collision, I realized after posting, but very handy for a game with a ball and paddle! I went on to Air Hockey after this study and a variation of Break-out with roundish paddle gives one more control of the angle of ball return.
Title: Re: 2 Ball Collision with an itsy-bitsy-teeny-tiny little bit of trig
Post by: bplus on May 10, 2021, 09:18:38 pm
At the moment of collision when the 2 balls are kissing each other, you need the angle the one ball is to the other.

Using  ballRadianAngleBall2ToBall1 = _ATan2(ball2Y - ball1Y, ball2X - ball1X)
and    ballRadianAngleBall1ToBall2 = _ATan2(ball1Y - ball2Y, ball1X - ball2X)

The QB64 functions convert Degree To Radian units:  _D2R(degreeAngle)
           and complementary Radian To Degree units:  _R2D(RadianAngle)

Here is a demo to show ball angles to each other at moment of collision:
Code: QB64: [Select]
  1. _Title "Angle of Ball to each other at moment of collision, press any to move outer ball around inner" 'B+ 2021-05-10
  2. ' 2021-05-10  fixed arrow so points from base x,y To angle
  3.  
  4. Screen _NewImage(800, 600, 32)
  5. _Delay .25
  8. x1 = 400: y1 = 300 'at middle of screen
  9. '
  10. ' now take a known ball angle 45 degree ( so we can check it with the trig calc ) to that point South East
  11. ' lets say add 100 to x1, y1 for x2, y2
  12. x2 = 500: y2 = 400
  13.  
  14. ' now at what = radius will make the 2 balls kiss ( ie like at moment of collision so I can show trig comes up with 45 degrees)
  15. distanceBetweenCenters = Sqr((x1 - x2) ^ 2 + (y1 - y2) ^ 2)
  16. radiusForBothBalls = distanceBetweenCenters / 2
  17. 'now we can draw the balls
  18. Circle (x1, y1), radiusForBothBalls
  19. Circle (x2, y2), radiusForBothBalls
  20.  
  21. angleDegreesB2toB1 = _R2D(_Atan2(y2 - y1, x2 - x1))
  22. Print "angleDegreesB2toB1 "; angleDegreesB2toB1
  23. ArrowTo x1, y1, _D2R(angleDegreesB2toB1), 60, &HFFFFFF00
  24.  
  25.  
  26. angleDegreesB1toB2 = _R2D(_Atan2(y1 - y2, x1 - x2))
  27. Print "angleDegreesB1toB2 "; angleDegreesB1toB2
  28. ArrowTo x2, y2, _D2R(angleDegreesB1toB2), 60, &HFFFFFF00
  29.  
  30. 'OK now lets go around the clock
  31. a = _Pi(.25) ' 45 degrees
  32. radius = Sqr((400 - 500) ^ 2 + (300 - 400) ^ 2) ' move outer circle around inner every 5 degree
  34.     Cls
  35.     Print "Angle of outer ball to center of screen ="; Int(10000 * _R2D(a)) / 10000 mod 360  ' edit: to keep number in ball park
  36.     x2 = 400 + radius * Cos(a)
  37.     y2 = 300 + radius * Sin(a)
  38.     Circle (x1, y1), radiusForBothBalls
  39.     Circle (x2, y2), radiusForBothBalls
  40.  
  41.     angleDegreesB2toB1 = Int(10000 * _R2D(_Atan2(y2 - y1, x2 - x1))) / 10000
  42.     Print "angleDegreesB2toB1 "; angleDegreesB2toB1
  43.     ArrowTo x1, y1, _D2R(angleDegreesB2toB1), 60, &HFFFFFF00
  44.  
  45.     angleDegreesB1toB2 = Int(10000 * _R2D(_Atan2(y1 - y2, x1 - x2))) / 10000
  46.     Print "angleDegreesB1toB2 "; angleDegreesB1toB2
  47.     ArrowTo x2, y2, _D2R(angleDegreesB1toB2), 60, &HFFFFFF00
  48.     Sleep
  49.     a = a + _Pi(5 / 180)
  51.  
  52. Sub ArrowTo (BaseX As Long, BaseY As Long, rAngle As Double, lngth As Long, colr As _Unsigned Long)
  53.     Dim As Long x1, y1, x2, y2, x3, y3
  54.     x1 = BaseX + lngth * Cos(rAngle)
  55.     y1 = BaseY + lngth * Sin(rAngle)
  56.     x2 = BaseX + .8 * lngth * Cos(rAngle - _Pi(.05))
  57.     y2 = BaseY + .8 * lngth * Sin(rAngle - _Pi(.05))
  58.     x3 = BaseX + .8 * lngth * Cos(rAngle + _Pi(.05))
  59.     y3 = BaseY + .8 * lngth * Sin(rAngle + _Pi(.05))
  60.     Line (BaseX, BaseY)-(x1, y1), colr
  61.     Line (x1, y1)-(x2, y2), colr
  62.     Line (x1, y1)-(x3, y3), colr
  64.  

PS all that extra calc for Degree Angle was attempt to print nice numbers without a bunch of decimal junk, just using INT(DegreeAngle) was often 1 off of nice (advancing around circle 5 degrees at so 45, 50, 55,... was what was supposed to be showing).

You can use this method when ever you need to know the angle one point is to another.
Text Only | Text with Attachments