QB64.org Forum

Active Forums => Programs => Topic started by: SpriggsySpriggs on May 06, 2021, 04:25:05 pm

Title: Child Processes in QB64 using WinAPI
Post by: SpriggsySpriggs on May 06, 2021, 04:25:05 pm

This code below uses WinAPI to read in a file called "loremipsum.txt" and sends it to the child and is then routed back to the parent through the STD handles. The below code is based on an example from the MSDN here (https://docs.microsoft.com/en-us/windows/win32/procthread/creating-a-child-process-with-redirected-input-and-output/).

Parent code:

Code: QB64: [Select]

1. Option _Explicit
2. $Console:Only
3. _Title "Parent Process"
4.  
5. Type SECURITY_ATTRIBUTES
6.     As Long nLength
7.     $If 64BIT Then
8.         As Long padding
9.     $End If
10.     As _Offset lpSecurityDescriptor
11.     As Long bInheritHandle
12.     $If 64BIT Then
13.         As Long padding2
14.     $End If
15. End Type
16.  
17. Type STARTUPINFO
18.     As Long cb
19.     $If 64BIT Then
20.         As Long padding
21.     $End If
22.     As _Offset lpReserved, lpDesktop, lpTitle
23.     As Long dwX, dwY, dwXSize, dwYSize, dwXCountChars, dwYCountChars, dwFillAttribute, dwFlags
24.     As Integer wShowWindow, cbReserved2
25.     $If 64BIT Then
26.         As Long padding2
27.     $End If
28.     As _Offset lpReserved2, hStdInput, hStdOutput, hStdError
29. End Type
30.  
31. Type PROCESS_INFORMATION
32.     As _Offset hProcess, hThread
33.     As Long dwProcessId
34.     $If 64BIT Then
35.         As Long padding
36.     $End If
37. End Type
38.  
39. Const STARTF_USESTDHANDLES = &H00000100
40. Const CREATE_NO_WINDOW = &H8000000
41. Const HANDLE_FLAG_INHERIT = &H00000001
42. Const BUFSIZE = 4096
43. Const STD_OUTPUT_HANDLE = -11
44. Const GENERIC_READ = &H80000000
45. Const OPEN_EXISTING = 3
46. Const FILE_ATTRIBUTE_READONLY = 1
47. Const INVALID_HANDLE_VALUE = -1
48.  
49. Declare CustomType Library
50.     Function CreatePipe%% (ByVal hReadPipe As _Offset, Byval hWritePipe As _Offset, Byval lpPipeAttributes As _Offset, Byval nSize As Long)
51.     Function CreateProcess%% Alias CreateProcessA (ByVal lpApplicationName As _Offset, Byval lpCommandLine As _Offset, Byval lpProcessAttributes As _Offset, Byval lpThreadAttributes As _Offset, Byval bInheritHandles As Integer, Byval dwCreationFlags As Long, Byval lpEnvironment As _Offset, Byval lpCurrentDirectory As _Offset, Byval lpStartupInfor As _Offset, Byval lpProcessInformation As _Offset)
52.     Function HandleClose%% Alias "CloseHandle" (ByVal hObject As _Offset)
53.     Function ReadFile%% (ByVal hFile As _Offset, Byval lpBuffer As _Offset, Byval nNumberOfBytesToRead As Long, Byval lpNumberOfBytesRead As _Offset, Byval lpOverlapped As _Offset)
54.     Function WriteFile%% (ByVal hFile As _Offset, Byval lpBuffer As _Offset, Byval nNumberOfBytesToWrite As Long, Byval lpNumberOfBytesWritten As _Offset, Byval lpOverlapped As _Offset)
55.     Function GetStdHandle%& (ByVal nStdHandle As Long)
56.     Function SetHandleInformation%% (ByVal hObject As _Offset, Byval dwMask As Long, Byval dwFlags As Long)
57.     Function CreateFile%& Alias "CreateFileA" (lpFileName As String, Byval dwDesiredAccess As Long, Byval dwSharedMode As Long, Byval lpSecurityAttributes As _Offset, Byval dwCreationDisposition As Long, Byval dwFlagsAndAttributes As Long, Byval hTemplateFile As _Offset)
58.     Function GetLastError& ()
59. End Declare
60.  
61. Dim Shared As _Offset hChildStd_IN_Rd, hChildStd_IN_Wr, hChildStd_OUT_Rd, hChildStd_OUT_Wr, hInputFile
62.  
63. Dim As SECURITY_ATTRIBUTES saAttr
64.  
65. Print "->Start of parent execution."
66.  
67. saAttr.nLength = Len(saAttr)
68. saAttr.bInheritHandle = 1
69. saAttr.lpSecurityDescriptor = 0
70.  
71. If CreatePipe(_Offset(hChildStd_OUT_Rd), _Offset(hChildStd_OUT_Wr), _Offset(saAttr), 0) = 0 Then
72.     ErrorExit "StdoutRd CreatePipe"
73. End If
74.  
75. If SetHandleInformation(hChildStd_OUT_Rd, HANDLE_FLAG_INHERIT, 0) = 0 Then
76.     ErrorExit "Stdout SetHandleInformation"
77. End If
78.  
79. If CreatePipe(_Offset(hChildStd_IN_Rd), _Offset(hChildStd_IN_Wr), _Offset(saAttr), 0) = 0 Then
80.     ErrorExit "Stdin CreatePipe"
81. End If
82.  
83. If SetHandleInformation(hChildStd_IN_Wr, HANDLE_FLAG_INHERIT, 0) = 0 Then
84.     ErrorExit "Stdin SetHandleInformation"
85. End If
86.  
87. CreateChildProcess
88.  
89. WriteToPipe
90. Print "Contents of loremipsum.txt written to child STDIN pipe"
91. Print "Contents of child process STDOUT:"
92. ReadFromPipe
93. Print "->End of parent execution"
94.  
95. Sleep
96.  
97. Sub CreateChildProcess ()
98.     Dim As String szCmdline: szCmdline = "Child Process" + Chr$(0)
99.     Dim As PROCESS_INFORMATION piProcInfo
100.     Dim As STARTUPINFO siStartInfo
101.     Dim As _Byte bSuccess
102.  
103.     siStartInfo.cb = Len(siStartInfo)
104.     siStartInfo.hStdError = hChildStd_OUT_Wr
105.     siStartInfo.hStdOutput = hChildStd_OUT_Wr
106.     siStartInfo.hStdInput = hChildStd_IN_Rd
107.     siStartInfo.dwFlags = STARTF_USESTDHANDLES
108.  
109.     bSuccess = CreateProcess(0, _Offset(szCmdline), 0, 0, 1, CREATE_NO_WINDOW, 0, 0, _Offset(siStartInfo), _Offset(piProcInfo))
110.     If bSuccess = 0 Then
111.         ErrorExit "CreateProcess"
112.     Else
113.         Dim As _Byte closeh
114.         closeh = HandleClose(piProcInfo.hProcess)
115.         closeh = HandleClose(piProcInfo.hThread)
116.         closeh = HandleClose(hChildStd_OUT_Wr)
117.         closeh = HandleClose(hChildStd_IN_Rd)
118.     End If
119. End Sub
120.  
121. Sub WriteToPipe ()
122.     Dim As Long dwRead, dwWritten
123.     Dim As String * BUFSIZE chBuf
124.     Dim As _Byte bSuccess
125.  
126.     Dim As _Offset hInputFile: hInputFile = CreateFile("loremipsum.txt" + Chr$(0), GENERIC_READ, 0, 0, OPEN_EXISTING, FILE_ATTRIBUTE_READONLY, 0)
127.     Do
128.         bSuccess = ReadFile(hInputFile, _Offset(chBuf), BUFSIZE, _Offset(dwRead), 0)
129.         If bSuccess = 0 Or dwRead = 0 Then Exit Do
130.         bSuccess = WriteFile(hChildStd_IN_Wr, _Offset(chBuf), dwRead, _Offset(dwWritten), 0)
131.         If bSuccess = 0 Then Exit Do
132.     Loop
133.     If hInputFile = INVALID_HANDLE_VALUE Then
134.         ErrorExit "CreateFile"
135.     End If
136.  
137.     If HandleClose(hChildStd_IN_Wr) = 0 Then
138.         ErrorExit "StdInWr CloseHandle"
139.     End If
140.     Dim As _Byte closeh: closeh = HandleClose(hInputFile)
141. End Sub
142.  
143. Sub ReadFromPipe ()
144.     Dim As Long dwRead, dwWritten
145.     Dim As String * BUFSIZE chBuf
146.     Dim As _Byte bSuccess
147.     Dim As _Offset hParentStdOut: hParentStdOut = GetStdHandle(STD_OUTPUT_HANDLE)
148.     Do
149.         bSuccess = ReadFile(hChildStd_OUT_Rd, _Offset(chBuf), BUFSIZE, _Offset(dwRead), 0)
150.         If bSuccess = 0 Or dwRead = 0 Then Exit Do
151.         Print Mid$(chBuf, 1, dwRead)
152.     Loop
153. End Sub
154.  
155. Sub ErrorExit (Reason As String)
156.     Print Reason, GetLastError
157.     End
158. End Sub

Child code:

Code: QB64: [Select]

1. Option _Explicit
2. $Console:Only
3. _Title "Child Process"
4.  
5. Const BUFSIZE = 4096
6. Const STD_OUTPUT_HANDLE = -11
7. Const STD_INPUT_HANDLE = -10
8. Const STD_ERROR_HANDLE = -12
9. Const INVALID_HANDLE_VALUE = -1
10.  
11. Declare CustomType Library
12.     Function ReadFile%% (ByVal hFile As _Offset, Byval lpBuffer As _Offset, Byval nNumberOfBytesToRead As Long, Byval lpNumberOfBytesRead As _Offset, Byval lpOverlapped As _Offset)
13.     Function GetStdHandle%& (ByVal nStdHandle As Long)
14.     Sub ExitProcess (ByVal uExitCode As _Unsigned Long)
15. End Declare
16.  
17. Dim As String * BUFSIZE chBuf
18. Dim As Long dwRead, dwWritten
19. Dim As _Offset hStdin, hStdout
20. Dim As _Byte bSuccess
21.  
22. hStdin = GetStdHandle(STD_INPUT_HANDLE)
23.  
24. If hStdout = INVALID_HANDLE_VALUE Then
25.     ExitProcess 1
26. End If
27.  
28. Print " ** This is a message from the child process. **"
29.  
30. Do
31.     bSuccess = ReadFile(hStdin, _Offset(chBuf), BUFSIZE, _Offset(dwRead), 0)
32.     Print Mid$(chBuf, 1, dwRead);
33.     If bSuccess = 0 Or dwRead = 0 Then
34.         Exit Do
35.     End If
36. Loop
37. System 0

And the text file for the test:
 

And a screenshot of how it should look:
 

Title: Re: Child Processes in QB64 using WinAPI
Post by: justsomeguy on May 06, 2021, 06:07:25 pm

@SpriggsySpriggs This is very well written code.

I see some tricks that I was unaware of, like ' $If 64BIT Then ... $End If' and using 'len' to find the size of a structure.

This appears to be similar to the 'fork' that you mentioned on one of my posts. Is the intent to use the child processes for extra processing and concurrency?

Title: Re: Child Processes in QB64 using WinAPI
Post by: SpriggsySpriggs on May 06, 2021, 06:15:44 pm

@justsomeguy In a sense, yes. These two executables run simultaneously. One could adjust some logic and make them talk back and forth to each other constantly. This is similar to Fellippe's InForm UIEditor. His program uses two executables, launches the child from the parent, and uses TCP/IP communication to send and receive between them.

Title: Re: Child Processes in QB64 using WinAPI
Post by: TempodiBasic on May 07, 2021, 03:59:07 am

Hi Spriggsy
Cool example!
Thanks to share.

Title: Re: Child Processes in QB64 using WinAPI
Post by: TempodiBasic on May 07, 2021, 04:11:38 am

@SpriggsySpriggs
sorry but I find a bug!
I think so because I got this result that is quiet different from your result!
see here
  [ This attachment cannot be displayed inline in 'Print Page' view ]  

Title: Re: Child Processes in QB64 using WinAPI
Post by: SpriggsySpriggs on May 07, 2021, 07:15:44 am

@TempodiBasic Glad to see you got it working!

Text Only | Text with Attachments