QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: fistfullofnails on April 22, 2021, 07:30:26 pm

Title: help with arrays and DATA to make game maps
Post by: fistfullofnails on April 22, 2021, 07:30:26 pm

Is there a tutorial somewhere explaining how to design maps using arrays and DATA.  I've got a book on QB64 on kindle by an author called 'Iam Beourd' haha, and he/she gets into designing a map.  They lay out a DATA table consisting of the numbers 0-5 or so, with a zero representing an empty room, a one representing a room containing an enemy, and so on.  I'm having difficulty understanding how it all comes together.  Especially how the player navigates through these rooms and the computer knowing which one you are in.  I'm also have trouble how 'inforoom' is actually working to give statements about each room.  And finally, the math being used to place the "wall" graphics is something I don't really get at all.  Is there a simpler version of something similar that is explained for dummies, or is this as dumbed down as it gets and I just happen to be dumber?

Code: QB64: [Select]

1. _Title "MAZER"
2.  
3. Screen _NewImage(800, 600, 32)
4. Dim map(10, 10) As Integer
5.  
6. Dim textwin&
7. Dim textbox&
8.  
9. textwin& = _NewImage(200, 200, 32)
10. textbox& = _NewImage(410, 200, 32)
11.  
12. Dim roominfo(10) As String
13.  
14. newgame:
15. GoSub prep
16.  
17. Do Until k$ = "q"
18.     Cls
19.     GoSub drawmap
20.     k$ = InKey$
21.     Select Case map(x, y)
22.         Case 1: GoSub infoport
23.         Case 2: GoSub charger
24.         Case 3: GoSub infoport
25.         Case 4: GoSub creature
26.         Case 5: GoSub shuttle
27.     End Select
28.     _Display
29. Loop
30. End
31.  
32. drawmap:
33. 'background
34. Line (80, 80)-(520, 520), _RGB(128, 15, 15), BF
35. 'floor
36. Line (100, 100)-(300, 300), _RGB(128, 150, 150), BF
37. 'the walls are drawn if value in matrix is 0
38. 'west wall
39. If map(x - 1, y) = 0 Then
40.     Line (100, 100)-(110, 300), _RGB(61, 94, 188), BF
41. Else
42.     If k$ = "a" Then x = x - 1
43. End If
44.  
45. 'east wall
46. If map(x + 1, y) = 0 Then
47.     Line (290, 100)-(300, 300), _RGB(61, 94, 188), BF
48. Else
49.     If k$ = "d" Then x = x + 1
50. End If
51.  
52. 'north wall
53. If map(x, y - 1) = 0 Then
54.     Line (100, 100)-(300, 110), _RGB(61, 94, 188), BF
55. Else
56.     If k$ = "w" Then y = y - 1
57. End If
58.  
59. 'south wall
60. If map(x, y + 1) = 0 Then
61.     Line (100, 290)-(300, 300), _RGB(61, 94, 188), BF
62. Else
63.     If k$ = "s" Then y = y + 1
64. End If
65. Return
66.  
67. 'subroutine tht gives feedback for rooms
68. infoport:
69. _Dest textbox& 'after this, anything written goes to this image
70. Cls
71. Print "In search of an escape shuttle, you navigate the rooms.";
72. Print "Try to avoid alien nests. Some rooms contain a zapper reloader.";
73. Print "Run out of zaps though, and the aliens will have you."
74. Print " USE w, a, s, d to move between rooms."
75. Print " q quits the game"
76.  
77. _Dest textwin&
78. Cls
79. Print roominfo(map(x, y))
80. _Dest 0 'this sets us back to drawing in the window
81. _PutImage (100, 310), textbox& 'draws lower text box
82. _PutImage (310, 100), textwin& 'draws right text box
83. Return
84.  
85. charger:
86. zap = 3
87. map(x, y) = 3
88. _Dest textbox&
89. Cls
90. Print "you found a charger!"
91. Print "your zapper has "; zap; "blasts"
92. Print "the charger broke!"
93. Print "You can't use it again."
94.  
95. _Dest textwin&
96. Cls
97. Print "hit any key"
98. _Dest 0 'back to drawing in window
99. _PutImage (100, 310), textbox&
100. _PutImage (310, 100), textwin&
101. _Display
102. Do Until InKey$ <> ""
103. Loop
104. Return
105.  
106. creature:
107. If zap > 0 Then
108.     zap = zap - 1
109.     map(x, y) = 3
110. Else
111.     GoTo gameover
112. End If
113.  
114. _Dest textbox&
115. Cls
116. Print "You used a blast!"
117. Print "Your zapper has "; zap; " blasts left"
118. Print "the creature is gone, the next"
119. Print "is scraped now."
120.  
121. _Dest textwin&
122. Cls
123. Print "hit enter key"
124.  
125. _Dest 0
126. _PutImage (100, 310), textbox&
127. _PutImage (310, 100), textwin&
128. _Display
129. Do Until InKey$ <> ""
130. Loop
131. Return
132.  
133. shuttle:
134. _Dest textbox&
135. Cls
136. Print "You made it to the shuttle."
137. Print "Still sealed and scanned safe"
138. Print "You escape the ship and set a beacon"
139. Print "It says NEVER BOARD THIS SHIP!"
140. _Dest textwin&
141. Cls
142. Print "Try Again (Y/N)?"
143. _Dest 0
144. _PutImage (100, 310), textbox&
145. _PutImage (310, 100), textwin&
146. GoTo try
147.  
148. 'you ran out of zapper loads and alien gets you
149.  
150. gameover:
151. _Dest textbox&
152. Cls
153. Print "Being as your zapper is empty, the creature"
154. Print "eats you slowly.  THE END."
155. Print "Your regret, is never warning others from"
156. Print "coming to this ship."
157.  
158. _Dest textwin&
159. Cls
160. Print "Try Again (Y/N)?";
161. _Dest 0
162. _PutImage (100, 310), textbox&
163. _PutImage (310, 100), textwin&
164. GoTo try
165.  
166. 'decide to try again
167.  
168. try:
169. _Display
170. Input m$
171. If m$ = "Y" Or m$ = "y" Then GoTo newgame
172. End
173.  
174. 'code for default values for game and loads map
175.  
176. prep:
177.  
178. 'load map from data
179. Restore mapdata 'restore points to label in data table
180. ' this loads map
181. For y = 0 To 10
182.     For x = 0 To 10
183.         Read map(x, y)
184.     Next
185. Next
186.  
187. zap = 3
188. x = 1
189. y = 1
190. 'table of text for describing each room
191. roominfo(1) = "The room is empty"
192. roominfo(2) = "zapper filled"
193. roominfo(3) = "scrap litters the floor"
194. roominfo(4) = "creature!"
195. roominfo(5) = "shuttle to safety"
196.  
197. Return
198.  
199. 'data table laid out in grid for a map
200. 'will read this to a 2 dimensional array and interpret the numbers
201. '0 is wall, 1 empty room, 2 refills zapper, etc
202.  
203. mapdata:
204.  
205. Data 0,0,0,0,0,0,0,0,0,0,0
206. Data 0,1,1,1,4,1,1,1,1,1,0
207. Data 0,1,1,1,2,1,1,4,1,1,0
208. Data 0,1,1,1,1,1,1,1,1,1,0
209. Data 0,0,0,0,0,0,0,1,0,0,0
210. Data 0,2,1,4,1,4,1,1,1,1,0
211. Data 0,0,1,0,0,0,0,0,0,0,0
212. Data 0,1,1,0,4,1,1,1,1,1,0
213. Data 0,2,1,0,1,4,1,1,5,1,0
214. Data 0,1,1,1,1,4,1,1,1,1,0
215. Data 0,0,0,0,0,0,0,0,0,0,0
216.  
217.  

Title: Re: help with arrays and DATA to make game maps
Post by: Unseen Machine on April 22, 2021, 07:53:01 pm

Its only got the up arrow coded, you can do the rest...good luck and happy coding

unseen

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(400, 400, 32)
2.  
3. '// create map array 10 * 10
4. DIM Map(9, 9) AS _BYTE
5.  
6. '// your position
7. DIM You(1) AS INTEGER '// array index ref : 0 = column, 1= row
8.  
9. '// load the data
10.  
11. FOR row% = 0 TO 9
12.   FOR col% = 0 TO 9
13.     READ Block%
14.     IF Block% < 9 THEN
15.       Map(col%, row%) = Block%
16.     ELSE
17.       You(0) = col%
18.       You(1) = row%
19.     END IF
20.   NEXT
21. NEXT
22.  
23.  
24.  
25. DO
26.  
27.   _LIMIT 30
28.   CLS
29.  
30.   KB$ = INKEY$
31.  
32.   SELECT CASE KB$
33.     CASE CHR$(0) + CHR$(72) ' Up
34.       IF You(1) > 0 THEN
35.         IF Map(You(0), You(1) - 1) = 0 THEN '//you can move into the square
36.           You(1) = You(1) - 1
37.         END IF
38.       ELSE '// Your path is blocked
39.  
40.       END IF
41.     CASE CHR$(0) + CHR$(77) ' Right
42.     CASE CHR$(0) + CHR$(80) ' Down
43.     CASE CHR$(0) + CHR$(75) ' Left
44.  
45.   END SELECT
46.  
47.   '// drawing
48.   y% = 0
49.   FOR row% = 0 TO 9
50.     x% = 0
51.     FOR col% = 0 TO 9
52.       IF Map(col%, row%) = 1 THEN
53.         LINE (x%, y%)-(x% + 20, y% + 20), _RGB32(255, 120, 120), BF
54.       ELSE
55.         IF You(0) = col% AND You(1) = row% THEN
56.  
57.           LINE (x%, y%)-(x% + 20, y% + 20), _RGB32(55, 120, 120), BF
58.         END IF
59.       END IF
60.  
61.       x% = x% + 20
62.     NEXT
63.     y% = y% + 20
64.   NEXT
65.  
66.   _DISPLAY
67.  
68. LOOP
69.  
70.  
71.  
72.  
73.  
74. DATA 1,1,1,1,1,1,1,1,1,1
75. DATA 0,0,0,0,0,0,0,0,0,0
76. DATA 0,0,0,0,0,0,0,0,0,0
77. DATA 0,0,0,0,0,0,0,0,0,0
78. DATA 0,0,0,0,0,0,0,0,0,0
79. DATA 0,0,0,0,9,0,0,0,0,0
80. DATA 0,0,0,0,0,0,0,0,0,0
81. DATA 0,0,0,0,0,0,0,0,0,0
82. DATA 0,0,0,0,0,0,0,0,0,0
83. DATA 0,0,0,0,0,0,0,0,0,0
84.  

Dont cheat! Heres an edit, now as a basic "game", get the key to ope the door...

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(400, 400, 32)
2.  
3. '// create map array 10 * 10
4. DIM Map(9, 9) AS _BYTE
5.  
6. '// your position
7. DIM You(1) AS INTEGER '// array index ref : 0 = column, 1= row
8.  
9. '// load the data
10.  
11. FOR row% = 0 TO 9
12.   FOR col% = 0 TO 9
13.     READ Block%
14.     IF Block% < 9 THEN
15.       Map(col%, row%) = Block%
16.     ELSE
17.       You(0) = col%
18.       You(1) = row%
19.     END IF
20.   NEXT
21. NEXT
22.  
23.  
24.  
25. DO
26.  
27.   _LIMIT 30
28.   CLS
29.  
30.   KB$ = INKEY$
31.  
32.   SELECT CASE KB$
33.  
34.     CASE CHR$(0) + CHR$(72) ' Up
35.  
36.       IF You(1) > 0 THEN
37.         IF Map(You(0), You(1) - 1) = 0 THEN '//you can move into the square
38.           You(1) = You(1) - 1
39.  
40.         ELSEIF Map(You(0), You(1) - 1) = 2 THEN
41.           Map(You(0), You(1) - 1) = 0
42.           HaveKey% = -1
43.           You(1) = You(1) - 1
44.         ELSEIF Map(You(0), You(1) - 1) = 3 THEN '// the exit
45.           IF HaveKey% THEN
46.             '// Win level
47.             END '// exit
48.           END IF
49.         END IF
50.       END IF
51.  
52.     CASE CHR$(0) + CHR$(77) ' Right
53.  
54.       IF You(0) < 9 THEN
55.         IF Map(You(0) + 1, You(1)) = 0 THEN '//you can move into the square
56.           You(0) = You(0) + 1
57.         ELSEIF Map(You(0) + 1, You(1)) = 2 THEN
58.           Map(You(0) + 1, You(1)) = 0
59.           HaveKey% = -1
60.           You(0) = You(0) + 1
61.         ELSEIF Map(You(0) + 1, You(1)) = 3 THEN '// the exit
62.           IF HaveKey% THEN
63.             END '// exit
64.           END IF
65.         END IF
66.       END IF
67.  
68.     CASE CHR$(0) + CHR$(80) ' Down
69.  
70.       IF You(1) < 9 THEN
71.         IF Map(You(0), You(1) + 1) = 0 THEN '//you can move into the square
72.           You(1) = You(1) + 1
73.  
74.         ELSEIF Map(You(0), You(1) + 1) = 2 THEN
75.           Map(You(0), You(1) + 1) = 0
76.           HaveKey% = -1
77.           You(1) = You(1) + 1
78.         ELSEIF Map(You(0), You(1) + 1) = 3 THEN '// the exit
79.           IF HaveKey% THEN
80.             '// Win level
81.             END '// exit
82.           END IF
83.         END IF
84.       END IF
85.  
86.     CASE CHR$(0) + CHR$(75) ' Left
87.  
88.       IF You(0) > 0 THEN
89.         IF Map(You(0) - 1, You(1)) = 0 THEN '//you can move into the square
90.           You(0) = You(0) - 1
91.         ELSEIF Map(You(0) - 1, You(1)) = 2 THEN
92.           Map(You(0) - 1, You(1)) = 0
93.           HaveKey% = -1
94.           You(0) = You(0) - 1
95.         ELSEIF Map(You(0) - 1, You(1)) = 3 THEN '// the exit
96.           IF HaveKey% THEN
97.             '// Win level
98.             END '// exit
99.           END IF
100.         END IF
101.       END IF
102.  
103.   END SELECT
104.  
105.   '// drawing
106.   y% = 0
107.   FOR row% = 0 TO 9
108.     x% = 0
109.     FOR col% = 0 TO 9
110.       SELECT CASE Map(col%, row%)
111.         CASE 1
112.           LINE (x%, y%)-(x% + 20, y% + 20), _RGB32(255, 120, 120), BF
113.         CASE 2 '// the Key
114.           COLOR _RGB32(0, 255, 0)
115.           _PRINTSTRING (x%, y%), CHR$(0) + CHR$(135)
116.  
117.         CASE 3 '// The exit
118.           LINE (x%, y%)-(x% + 20, y% + 20), _RGB32(0, 255, 0), BF
119.  
120.         CASE ELSE
121.           IF You(0) = col% AND You(1) = row% THEN
122.  
123.             LINE (x%, y%)-(x% + 20, y% + 20), _RGB32(55, 120, 120), BF
124.           END IF
125.       END SELECT
126.  
127.       x% = x% + 20
128.     NEXT
129.     y% = y% + 20
130.   NEXT
131.  
132.   _DISPLAY
133.  
134. LOOP
135.  
136.  
137.  
138.  
139.  
140. DATA 1,1,1,1,1,1,1,1,1,1
141. DATA 1,0,0,0,1,0,0,0,0,1
142. DATA 1,0,1,0,0,0,1,1,0,1
143. DATA 1,0,1,1,1,0,1,0,0,1
144. DATA 1,0,1,0,1,0,1,0,1,1
145. DATA 1,0,0,2,1,0,1,0,0,0
146. DATA 1,0,1,1,1,0,1,0,1,1
147. DATA 1,0,1,0,0,0,1,0,1,1
148. DATA 9,0,1,0,0,0,1,0,0,3
149. DATA 1,1,1,1,1,1,1,1,1,1
150.  

Title: Re: help with arrays and DATA to make game maps
Post by: fistfullofnails on April 23, 2021, 01:17:32 pm

 READ Block%
    IF Block% < 9 THEN
      Map(col%, row%) = Block%

So the program just jumps to the first DATA it sees and uses the nested FOR loop to read that into the map array?  And then the map array is being put into another variable called Block%?  I'm not understanding the purpose of determining if Block% is less than 9 in the if statement.

 IF Map(You(0), You(1) - 1) = 0

I cannot figure out how this math is being done.  Say I was  at location 3,4.  How does this math get solved?  "Map(3, 4 - 1) " is how I'm looking at it.  Or is it taking that grid location's value, which I think is 0, and then doing the math on it.  "0 - 1" and comparing it to zero?

Title: Re: help with arrays and DATA to make game maps
Post by: bplus on April 23, 2021, 02:26:32 pm

Quote

'// your position
DIM You(1) AS INTEGER '// array index ref : 0 = column, 1= row

Looks like you() is a tiny little array you(0) = column you are in, and you(1) = row you are in.

Quote

"Map(3, 4 - 1) " is how I'm looking at it.

Yes! if that map value = 0 then you can move into it.

Title: Re: help with arrays and DATA to make game maps
Post by: 191Brian on April 23, 2021, 02:30:45 pm

Hi

It is reading the data into the variable BLOCK% and if it is less than 9 it writes the value into the map array, the 9 in the data indicates the start position of the player which is set in the else part 
ELSE
      You(0) = col%
      You(1) = row%

IF Map(You(0), You(1) - 1) = 0 is testing if the cell the player is trying to move to is an empty (0) i.e not a wall (1) note this if statement changes depending on which direction the player is trying to move.

Title: Re: help with arrays and DATA to make game maps
Post by: Unseen Machine on April 23, 2021, 04:52:41 pm

Thanks to everyone for answering, it's my bad cause yeah, my lack of comments...it's all ways been a bad side of my coding.

The way to do it to have different rooms like the first post describes would be to have the level data blocks (rooms) contain the room index and the size of the room then you could use a _MEM block to store all the data in a single array. Then with a simple method (i can think of a few) when you exit a room the map would contain the index of the room your moving into. You the just REDIM the map array, load the relevant data from the _MEM block and woosh...youve got a basic dungeon engine...it's easy enough to change the painted blocks to textures, and then if you wanna really push it you can easily make a Wolfenstein style raycaster and youre in 3D!

I'll have a look at maybe implementing a basic version of a multi room map but ill add more comments.

Unseen

Title: Re: help with arrays and DATA to make game maps
Post by: fistfullofnails on April 24, 2021, 05:55:57 pm

Thanks for your explanations folks.  I literally spent four hours last night staring at the first two sections of Unseen's code before feeling like I was starting to get it.  I ended up rewriting little parts of those sections and adding print statements to those parts to show me what was actually happening in those parts.  For example, I'd just make up a smaller 2 d array and data set, then run through it, but actually print out what it was reading and so forth.  for example

Code: QB64: [Select]

1. Dim map(4, 4) As Integer
2.  
3.  
4. For row% = 0 To 4
5.     For col% = 0 To 4
6.         Read area%
7.         map(col%, row%) = area%
8.         Print "map"; col%; ","; row%; " is equal to: "; area%
9.  
10.     Next
11. Next

I think I was starting to get the drawing part after looking at it briefly toward the end of my night.  Guess i'll spend a couple hours with it as well later.
What immediately jumped out to me at first in the drawing part, was the question as to why the y% and z% variable received the value of 0 in the places that they did.

Code: QB64: [Select]

1.     y% = 0
2.     For row% = 0 To 9
3.         x% = 0
4.         For col% = 0 To 9

Is there perhaps anything I could apply these concepts to that will give me practice that may be a bit easier to wrap my head around at first?  Or should i just keep inducing headaches into myself?  Maybe I've gotten in too far before understanding some simpler concepts?  Finally, thank you for your time everyone that has tried to help me.

Title: Re: help with arrays and DATA to make game maps
Post by: bplus on April 24, 2021, 06:36:17 pm

Yeah, here is how I would do drawing, forget about x, y use square and scale map blocks to any size though be careful with _PRINTSTRING:

Code: QB64: [Select]

1. '// drawing
2. Const square = 70
3. Screen _NewImage(square * 10, square * 10, 32)
4.  
5. '// create map array 10 * 10
6. Dim Map(9, 9) As _Byte
7.  
8. '// your position
9. Dim You(1) As Integer '// array index ref : 0 = column, 1= row
10.  
11. '// load the data
12.  
13. For row% = 0 To 9
14.     For col% = 0 To 9
15.         Read Block%
16.         If Block% < 9 Then
17.             Map(col%, row%) = Block%
18.         Else
19.             You(0) = col%
20.             You(1) = row%
21.         End If
22.     Next
23. Next
24.  
25.  
26.  
27. Do
28.  
29.     _Limit 30
30.     Cls
31.  
32.     KB$ = InKey$
33.  
34.     Select Case KB$
35.  
36.         Case Chr$(0) + Chr$(72) ' Up
37.  
38.             If You(1) > 0 Then
39.                 If Map(You(0), You(1) - 1) = 0 Then '//you can move into the square
40.                     You(1) = You(1) - 1
41.  
42.                 ElseIf Map(You(0), You(1) - 1) = 2 Then
43.                     Map(You(0), You(1) - 1) = 0
44.                     HaveKey% = -1
45.                     You(1) = You(1) - 1
46.                 ElseIf Map(You(0), You(1) - 1) = 3 Then '// the exit
47.                     If HaveKey% Then
48.                         '// Win level
49.                         End '// exit
50.                     End If
51.                 End If
52.             End If
53.  
54.         Case Chr$(0) + Chr$(77) ' Right
55.  
56.             If You(0) < 9 Then
57.                 If Map(You(0) + 1, You(1)) = 0 Then '//you can move into the square
58.                     You(0) = You(0) + 1
59.                 ElseIf Map(You(0) + 1, You(1)) = 2 Then
60.                     Map(You(0) + 1, You(1)) = 0
61.                     HaveKey% = -1
62.                     You(0) = You(0) + 1
63.                 ElseIf Map(You(0) + 1, You(1)) = 3 Then '// the exit
64.                     If HaveKey% Then
65.                         End '// exit
66.                     End If
67.                 End If
68.             End If
69.  
70.         Case Chr$(0) + Chr$(80) ' Down
71.  
72.             If You(1) < 9 Then
73.                 If Map(You(0), You(1) + 1) = 0 Then '//you can move into the square
74.                     You(1) = You(1) + 1
75.  
76.                 ElseIf Map(You(0), You(1) + 1) = 2 Then
77.                     Map(You(0), You(1) + 1) = 0
78.                     HaveKey% = -1
79.                     You(1) = You(1) + 1
80.                 ElseIf Map(You(0), You(1) + 1) = 3 Then '// the exit
81.                     If HaveKey% Then
82.                         '// Win level
83.                         End '// exit
84.                     End If
85.                 End If
86.             End If
87.  
88.         Case Chr$(0) + Chr$(75) ' Left
89.  
90.             If You(0) > 0 Then
91.                 If Map(You(0) - 1, You(1)) = 0 Then '//you can move into the square
92.                     You(0) = You(0) - 1
93.                 ElseIf Map(You(0) - 1, You(1)) = 2 Then
94.                     Map(You(0) - 1, You(1)) = 0
95.                     HaveKey% = -1
96.                     You(0) = You(0) - 1
97.                 ElseIf Map(You(0) - 1, You(1)) = 3 Then '// the exit
98.                     If HaveKey% Then
99.                         '// Win level
100.                         End '// exit
101.                     End If
102.                 End If
103.             End If
104.  
105.     End Select
106.  
107.     '// drawing
108.     For row% = 0 To 9
109.         For col% = 0 To 9
110.             Select Case Map(col%, row%)
111.                 Case 1
112.                     Line (col% * square, row% * square)-Step(square, square), _RGB32(255, 120, 120), BF
113.                 Case 2 '// the Key
114.                     Color _RGB32(0, 255, 0)
115.                     _PrintString (col% * square + square / 2 - 10, row% * square + square / 2 - 8), Chr$(0) + Chr$(135)
116.                 Case 3 '// The exit
117.                     Line (col% * square, row% * square)-Step(square, square), _RGB32(0, 255, 0), BF
118.                 Case Else
119.                     If You(0) = col% And You(1) = row% Then
120.                         Line (col% * square, row% * square)-Step(square, square), _RGB32(55, 120, 120), BF
121.                     End If
122.             End Select
123.             Line (col% * square, row% * square)-Step(square, square), &HFFFFFF00, B
124.         Next
125.     Next
126.     _Display
127. Loop
128.  
129.  
130. Data 1,1,1,1,1,1,1,1,1,1
131. Data 1,0,0,0,1,0,0,0,0,1
132. Data 1,0,1,0,0,0,1,1,0,1
133. Data 1,0,1,1,1,0,1,0,0,1
134. Data 1,0,1,0,1,0,1,0,1,1
135. Data 1,0,0,2,1,0,1,0,0,0
136. Data 1,0,1,1,1,0,1,0,1,1
137. Data 1,0,1,0,0,0,1,0,1,1
138. Data 9,0,1,0,0,0,1,0,0,3
139. Data 1,1,1,1,1,1,1,1,1,1
140.  
141.  
142.  

Edit: to scale squares
EDIT again to center key at any scale

Title: Re: help with arrays and DATA to make game maps
Post by: Unseen Machine on April 24, 2021, 07:55:52 pm

So...i'll try my best to help...

X% and y% are reset to 0 each time cause that's where drawing starts from. They are then increased by 20 pixels each loop of the FOR blocks. Try changing them and see the map move around, id suggest trying to make it auto center to the screen...for that you'll need

X% = half of _SCREENWIDTH minus (half size of the column count of the array * the block size (20))
Ill let you figure out Y%

If you resize the map array you need to resize the DATA blocks to the same size. Id suggest a REDIM SHARED for the map array and then before reading the map data read two extra bits of data to size the array. i.e for a level thats 6 * 8

Read Col%
Read Row%
REDIM SHARED MAP(Col%, Row%)
Load the data 

LevelOne: '// Line ref? For use with RESTORE so you can have data stored in any order you like and then just jump to it.
DATA 5, 7
DATA .....THE level data here,


You can easily make the for loop code into a SUB so you can call it repeatedly. The FOR loops would be changed to use the Col%/Row% values.

The drawing method is just the most basic method i could think of, in this sort of thing you would usually use a tile sheet and the DATA would be tile indices. For things like platform games you use multiple arrays for background, level, special objects, sprites etc...

Happy coding and reel free to ask anything else you need help with.

Unseen

Title: Re: help with arrays and DATA to make game maps
Post by: bplus on April 25, 2021, 03:24:59 pm

Most tiles are square?

Text Only | Text with Attachments