QB64.org Forum

Active Forums => Programs => Topic started by: bplus on April 09, 2021, 09:37:55 pm

Title: Xor Magic ^2
Post by: bplus on April 09, 2021, 09:37:55 pm

Code: QB64: [Select]

1. _Title "XOR Magic ^2" ' b+ revisit 2021-04-09
2. Screen _NewImage(768, 512, 32)
3. _Delay .25
4. _ScreenMove _Middle
5.  
6. For y = 0 To _Height
7.     For x = 0 To _Width
8.         PSet (x, y), _RGB(x Mod 256, (x Mod 256 Xor y) Mod 256, y Mod 256)
9.     Next
10. Next
11. Do
12.     red = Rnd * 255 \ 1
13.     green = Rnd * 255 \ 1
14.     blue = Rnd * 255 \ 1
15.     _Title "XOR Magic ^2 " + Str$(red) + Str$(green) + Str$(blue)
16.     For y = 0 To _Height
17.         For x = 0 To _Width
18.             c~& = Point(x, y)
19.             cAnalysis c~&, r, g, b, a
20.             PSet (x, y), _RGB32(r Xor red, g Xor green, b Xor blue, a)
21.         Next
22.     Next
23.     _Limit 3
24. Loop
25.  
26. Sub cAnalysis (c As _Unsigned Long, outRed, outGrn, outBlu, outAlp)
27.     outRed = _Red32(c): outGrn = _Green32(c): outBlu = _Blue32(c): outAlp = _Alpha32(c)
28. End Sub
29.  
30.  

Title: Re: Xor Magic ^2
Post by: euklides on April 10, 2021, 11:29:47 am

Very useful for making Scottish kilts !!! :)

Title: Re: Xor Magic ^2
Post by: Ashish on April 10, 2021, 11:31:48 am

Hi @bplus
Nice graphics! I like it! :)
I modified your a code a little and I have used _MEM instead of POINT for getting color (_MEM is faster than POINT )

Code: QB64: [Select]

1. _Title "XOR Magic ^2" ' b+ revisit 2021-04-09
2. 'MEM mod by Ashish
3. Screen _NewImage(768, 512, 32)
4. _Delay .25
5. _ScreenMove _Middle
6.  
7. For y = 0 To _Height
8.     For x = 0 To _Width
9.         PSet (x, y), _RGB(x Mod 256, (x Mod 256 Xor y) Mod 256, y Mod 256)
10.     Next
11. Next
12. Dim m As _MEM
13. m = _MemImage(0)
14.  
15. Do
16.     red = Rnd * 255 \ 1
17.     green = Rnd * 255 \ 1
18.     blue = Rnd * 255 \ 1
19.     _Title "XOR Magic ^2 " + Str$(red) + Str$(green) + Str$(blue)
20.     For y = 0 To _Height - 1
21.         For x = 0 To _Width - 1
22.             b = _MemGet(m, m.OFFSET + (y * _Width + x) * 4, _Unsigned _Byte)
23.             g = _MemGet(m, m.OFFSET + (y * _Width + x) * 4 + 1, _Unsigned _Byte)
24.             r = _MemGet(m, m.OFFSET + (y * _Width + x) * 4 + 2, _Unsigned _Byte)
25.             a = _MemGet(m, m.OFFSET + (y * _Width + x) * 4 + 3, _Unsigned _Byte)
26.             'c~& = Point(x, y)
27.             'cAnalysis c~&, r, g, b, a
28.             PSet (x, y), _RGB32(r Xor red, g Xor green, b Xor blue, a)
29.         Next
30.     Next
31.     _Limit 10
32. Loop
33.  
34. Sub cAnalysis (c As _Unsigned Long, outRed, outGrn, outBlu, outAlp)
35.     outRed = _Red32(c): outGrn = _Green32(c): outBlu = _Blue32(c): outAlp = _Alpha32(c)
36. End Sub
37.  
38.  
39.  
40.  

Title: Re: Xor Magic ^2
Post by: bplus on April 10, 2021, 12:56:32 pm

Thanks!

@Ashish that is very nice demo for getting colors and using mem techniques.

Title: Re: Xor Magic ^2
Post by: SMcNeill on April 10, 2021, 04:45:54 pm

Quote from: Ashish on April 10, 2021, 11:31:48 am

Hi @bplus
Nice graphics! I like it! :)
I modified your a code a little and I have used _MEM instead of POINT for getting color (_MEM is faster than POINT )

Code: QB64: [Select]

1. _Title "XOR Magic ^2" ' b+ revisit 2021-04-09
2. 'MEM mod by Ashish
3. Screen _NewImage(768, 512, 32)
4. _Delay .25
5. _ScreenMove _Middle
6.  
7. For y = 0 To _Height
8.     For x = 0 To _Width
9.         PSet (x, y), _RGB(x Mod 256, (x Mod 256 Xor y) Mod 256, y Mod 256)
10.     Next
11. Next
12. Dim m As _MEM
13. m = _MemImage(0)
14.  
15. Do
16.     red = Rnd * 255 \ 1
17.     green = Rnd * 255 \ 1
18.     blue = Rnd * 255 \ 1
19.     _Title "XOR Magic ^2 " + Str$(red) + Str$(green) + Str$(blue)
20.     For y = 0 To _Height - 1
21.         For x = 0 To _Width - 1
22.             b = _MemGet(m, m.OFFSET + (y * _Width + x) * 4, _Unsigned _Byte)
23.             g = _MemGet(m, m.OFFSET + (y * _Width + x) * 4 + 1, _Unsigned _Byte)
24.             r = _MemGet(m, m.OFFSET + (y * _Width + x) * 4 + 2, _Unsigned _Byte)
25.             a = _MemGet(m, m.OFFSET + (y * _Width + x) * 4 + 3, _Unsigned _Byte)
26.             'c~& = Point(x, y)
27.             'cAnalysis c~&, r, g, b, a
28.             PSet (x, y), _RGB32(r Xor red, g Xor green, b Xor blue, a)
29.         Next
30.     Next
31.     _Limit 10
32. Loop
33.  
34. Sub cAnalysis (c As _Unsigned Long, outRed, outGrn, outBlu, outAlp)
35.     outRed = _Red32(c): outGrn = _Green32(c): outBlu = _Blue32(c): outAlp = _Alpha32(c)
36. End Sub
37.  
38.  
39.  
40.  

If you’re looking for speed, move as much math as possible outside your loop.

  For y = 0 To (_Height -1) * 4 * _WIDTH STEP 4 * _WIDTH
        For x = 0 To (_Width - 1) * 4 STEP 4
            t = y + x
            b = _MemGet(m, m.OFFSET + t, _Unsigned _Byte)
            g = _MemGet(m, m.OFFSET + t + 1, _Unsigned _Byte)
            r = _MemGet(m, m.OFFSET + t + 2, _Unsigned _Byte)
            a = _MemGet(m, m.OFFSET + t + 3, _Unsigned _Byte)
            'c~& = Point(x, y)
            'cAnalysis c~&, r, g, b, a
            PSet (x, y), _RGB32(r Xor red, g Xor green, b Xor blue, a)
        Next
    Next

The fewer math calculations you do inside your loop, the faster it can process — which can really affect performance with _MEM.

Personally, since this checks the whole screen, I’d just make it a simple DO...LOOP

t = 0
DO UNTIL t >= m.size
    b = _MemGet(m, m.OFFSET + t, _Unsigned _Byte)
    g = _MemGet(m, m.OFFSET + t + 1, _Unsigned _Byte)
    r = _MemGet(m, m.OFFSET + t + 2, _Unsigned _Byte)
    _MEMPUT m, m.OFFSET + t, _RGB32(r Xor red, g Xor green, b Xor blue) AS STRING * 3
    t = t + 4
LOOP

Once it’s right, $CHECKING:OFF before it and $CHECKING:ON after it, and you’re not going to get it any faster.  (And since you’re not changing alpha levels at all, I don’t think you’re going to need to read or write them either, unless I’m missing something.)

Title: Re: Xor Magic ^2
Post by: bplus on April 10, 2021, 05:21:36 pm

Code: QB64: [Select]

1.   _Limit 10

Really don't need speed, the above is already too fast to appreciate the varieties of color combinations.

I am sure in a 3D Game it would be different story.

Title: Re: Xor Magic ^2
Post by: SMcNeill on April 10, 2021, 08:04:43 pm

Quote from: bplus on April 10, 2021, 05:21:36 pm

Code: QB64: [Select]

1.   _Limit 10

Really don't need speed, the above is already too fast to appreciate the varieties of color combinations.

I am sure in a 3D Game it would be different story.

Aye.  With a limit 10, POINT would be sufficient enough.  I just mentioned the difference with _MEM for: “ that is very nice demo for getting colors and using mem techniques”. 

I figured an example of how to optimize those MEM techniques might be useful  as well. ;D

Title: Re: Xor Magic ^2
Post by: NOVARSEG on April 11, 2021, 04:30:11 am

With MEM, the for next loops are not needed because _MEMIMAGE does all the work.

Slight mod on Steve's code example

Ya I like to DIM everything.  If T is DIMed as an INTEGER the code crashes so that's why it is DIMed as a _UNSIGNED LONG

If T is DIMed as a SINGLE it works too, but I think the _UNSIGNED LONG is faster?

That is another reason why DEFINT A-Z   is bad practice.

DEFINT A-Z is just like buying a set of tools with one missing.

Code: QB64: [Select]

1. DIM T AS _UNSIGNED LONG
2. DIM Handle AS LONG
3.  
4. Handle = _NEWIMAGE(500, 500, 32)
5.  
6. SCREEN Handle
7.  
8. DIM M AS _MEM
9. M = _MEMIMAGE(Handle)
10.  
11.  
12. DIM r AS _UNSIGNED _BYTE
13. DIM g AS _UNSIGNED _BYTE
14. DIM b AS _UNSIGNED _BYTE
15. DIM a AS _UNSIGNED _BYTE
16.  
17. LOCATE 10, 20: PRINT "SIZE OF IMAGE IS "; M.SIZE; "BYTES"
18.  
19.  
20. LL1:
21. T = 0
22. DO UNTIL T >= M.SIZE
23.     b = _MEMGET(M, M.OFFSET + T, _UNSIGNED _BYTE)
24.     b = b XOR 255
25.     _MEMPUT M, M.OFFSET + T, b
26.  
27.     g = _MEMGET(M, M.OFFSET + T + 1, _UNSIGNED _BYTE)
28.     g = g XOR 255
29.     _MEMPUT M, M.OFFSET + T + 1, g
30.  
31.     r = _MEMGET(M, M.OFFSET + T + 2, _UNSIGNED _BYTE)
32.     r = r XOR 0
33.     _MEMPUT M, M.OFFSET + T + 2, r
34.  
35.     T = T + 4
36. LOOP
37.  
38. DO
39.     i$ = INKEY$
40.     IF i$ = CHR$(27) THEN EXIT DO
41.     _DELAY 1: GOTO LL1
42. LOOP
43.  
44. END
45.  

Title: Re: Xor Magic ^2
Post by: TempodiBasic on April 11, 2021, 06:05:08 am

@bplus
your squared pattern of colors have ipnotized me!

Cool!

Title: Re: Xor Magic ^2
Post by: bplus on April 11, 2021, 12:33:58 pm

Quote from: NOVARSEG on April 11, 2021, 04:30:11 am

With MEM, the for next loops are not needed because _MEMIMAGE does all the work.

Slight mod on Steve's code example

Ya I like to DIM everything.  If T is DIMed as an INTEGER the code crashes so that's why it is DIMed as a _UNSIGNED LONG

If T is DIMed as a SINGLE it works too, but I think the _UNSIGNED LONG is faster?

That is another reason why DEFINT A-Z   is bad practice.

DEFINT A-Z is just like buying a set of tools with one missing.

Code: QB64: [Select]

1. DIM T AS _UNSIGNED LONG
2. DIM Handle AS LONG
3.  
4. Handle = _NEWIMAGE(500, 500, 32)
5.  
6. SCREEN Handle
7.  
8. DIM M AS _MEM
9. M = _MEMIMAGE(Handle)
10.  
11.  
12. DIM r AS _UNSIGNED _BYTE
13. DIM g AS _UNSIGNED _BYTE
14. DIM b AS _UNSIGNED _BYTE
15. DIM a AS _UNSIGNED _BYTE
16.  
17. LOCATE 10, 20: PRINT "SIZE OF IMAGE IS "; M.SIZE; "BYTES"
18.  
19.  
20. LL1:
21. T = 0
22. DO UNTIL T >= M.SIZE
23.     b = _MEMGET(M, M.OFFSET + T, _UNSIGNED _BYTE)
24.     b = b XOR 255
25.     _MEMPUT M, M.OFFSET + T, b
26.  
27.     g = _MEMGET(M, M.OFFSET + T + 1, _UNSIGNED _BYTE)
28.     g = g XOR 255
29.     _MEMPUT M, M.OFFSET + T + 1, g
30.  
31.     r = _MEMGET(M, M.OFFSET + T + 2, _UNSIGNED _BYTE)
32.     r = r XOR 0
33.     _MEMPUT M, M.OFFSET + T + 2, r
34.  
35.     T = T + 4
36. LOOP
37.  
38. DO
39.     i$ = INKEY$
40.     IF i$ = CHR$(27) THEN EXIT DO
41.     _DELAY 1: GOTO LL1
42. LOOP
43.  
44. END
45.  

Yes, good practice to Dim or ReDIM everything.

@NOVARSEG  can you see why T as INTEGER is bad idea?

Quote

DEFINT A-Z is just like buying a set of tools with one missing.

These days we should use DefLng A-Z where we used DEFINT in old days, because Longs may actually be faster certainly wont be significantly slower and gives you much more range.

Missing a tool? Only if you expect that to cover everything. On the other hand, it could serve as a crack filler, automatically dimensioning variables you haven't formally dimensioned.

Title: Re: Xor Magic ^2
Post by: SMcNeill on April 11, 2021, 05:45:07 pm

T as an integer works fine, as long as your image is less than 32767 bytes.  As a long, it works for images less than 2,147,483,647 bytes.

I’d suggest  making T an OFFSET, since you’re working with _MEM.

Title: Re: Xor Magic ^2
Post by: NOVARSEG on April 11, 2021, 10:09:41 pm

A possible bug in QB64??

So I'm running this code

Code: QB64: [Select]

1. DIM T AS _UNSIGNED LONG
2. DIM Handle AS LONG
3.  
4. Handle = _NEWIMAGE(500, 50, 32)
5.  
6. SCREEN Handle
7.  
8. DIM M AS _MEM
9. M = _MEMIMAGE(Handle)
10.  
11.  
12. DIM r AS _UNSIGNED _BYTE
13. DIM g AS _UNSIGNED _BYTE
14. DIM b AS _UNSIGNED _BYTE
15. DIM a AS _UNSIGNED _BYTE
16.  
17. 'LOCATE 10, 20: PRINT "SIZE OF IMAGE IS "; M.SIZE; "BYTES"
18. PRINT "SIZE OF IMAGE IS "; M.SIZE; "BYTES"
19.  
20. LL1:
21. T = 0
22. DO UNTIL T >= M.SIZE
23.     b = _MEMGET(M, M.OFFSET + T, _UNSIGNED _BYTE)
24.     b = b XOR 255
25.     _MEMPUT M, M.OFFSET + T, b
26.  
27.     g = _MEMGET(M, M.OFFSET + T + 1, _UNSIGNED _BYTE)
28.     g = g XOR 255
29.     _MEMPUT M, M.OFFSET + T + 1, g
30.  
31.     r = _MEMGET(M, M.OFFSET + T + 2, _UNSIGNED _BYTE)
32.     r = r XOR 0
33.     _MEMPUT M, M.OFFSET + T + 2, r
34.  
35.     T = T + 4
36. LOOP
37.  
38. DO
39.     i$ = INKEY$
40.     IF i$ = CHR$(27) THEN EXIT DO
41.     _DELAY 1: GOTO LL1
42. LOOP
43.  
44. END

and can see the text display on screen

when I change
Handle = _NEWIMAGE(500, 50, 32)

to

Handle = _NEWIMAGE(500, 40, 32)

The text no longer displays, why?

more tests
Handle = _NEWIMAGE(500, 48, 32) displays text

Handle = _NEWIMAGE(500, 47, 32)  does not display text

Title: Re: Xor Magic ^2
Post by: NOVARSEG on April 11, 2021, 11:23:54 pm

more tests

changing line

PRINT "SIZE OF IMAGE IS "; M.SIZE; "BYTES"
to
PRINT "SIZE OF IMAGE IS "; M.SIZE; "BYTES";

works. 

Handle = _NEWIMAGE(500, 16, 32) displays text

Handle = _NEWIMAGE(500, 15, 32)  does not display text

It looks like text is 16 pixels high.  Without the semi colon there is an additional 2 lines of  what looks to be line feeds

Title: Re: Xor Magic ^2
Post by: NOVARSEG on April 12, 2021, 03:31:26 am

Blinking cursor with MEM

The lines with MEMGET can be commented out and it still works.

Code: QB64: [Select]

1. DIM T AS _UNSIGNED LONG
2. DIM Handle AS LONG
3. DIM curWidth AS INTEGER
4. DIM curPosX AS INTEGER
5. DIM curOffset AS _UNSIGNED LONG
6. DIM Text AS STRING
7.  
8. Text = "Blinking cursor with MEM"
9.  
10. Handle = _NEWIMAGE(500, 300, 32)
11.  
12. SCREEN Handle
13.  
14. DIM M AS _MEM
15. M = _MEMIMAGE(Handle)
16.  
17.  
18. DIM r AS _UNSIGNED _BYTE
19. DIM g AS _UNSIGNED _BYTE
20. DIM b AS _UNSIGNED _BYTE
21. 'DIM a AS _UNSIGNED _BYTE
22. _FULLSCREEN
23. curWidth = (_PRINTWIDTH(CHR$(a)) - 2) * 4
24.  
25. curPosX = _PRINTWIDTH(Text) * 4
26.  
27. PRINT
28. PRINT Text
29.  
30. curOffset = 4 * _WIDTH * (14 + 16) + curPosX
31. LL1:
32.  
33. FOR T = curOffset TO curOffset + curWidth STEP 4
34.  
35.     b = _MEMGET(M, M.OFFSET + T, _UNSIGNED _BYTE)
36.     b = 255
37.     _MEMPUT M, M.OFFSET + T, b
38.  
39.     g = _MEMGET(M, M.OFFSET + T + 1, _UNSIGNED _BYTE)
40.     g = 255
41.     _MEMPUT M, M.OFFSET + T + 1, g
42.  
43.     r = _MEMGET(M, M.OFFSET + T + 2, _UNSIGNED _BYTE)
44.     r = 0
45.     _MEMPUT M, M.OFFSET + T + 2, r
46. NEXT T
47.  
48. _DELAY .3
49.  
50. FOR T = curOffset TO curOffset + curWidth STEP 4
51.  
52.     b = _MEMGET(M, M.OFFSET + T, _UNSIGNED _BYTE)
53.     b = 0
54.     _MEMPUT M, M.OFFSET + T, b
55.  
56.     g = _MEMGET(M, M.OFFSET + T + 1, _UNSIGNED _BYTE)
57.     g = 0
58.     _MEMPUT M, M.OFFSET + T + 1, g
59.  
60.     r = _MEMGET(M, M.OFFSET + T + 2, _UNSIGNED _BYTE)
61.     r = 0
62.     _MEMPUT M, M.OFFSET + T + 2, r
63. NEXT T
64.  
65. _DELAY .3
66. i$ = INKEY$
67. IF i$ = CHR$(27) THEN END
68. GOTO LL1
69.  

Title: Re: Xor Magic ^2
Post by: NOVARSEG on April 12, 2021, 04:30:25 am

Moving cursor with MEM

Code: QB64: [Select]

1. DIM T AS _UNSIGNED LONG
2. DIM Handle AS LONG
3. DIM curWidth AS INTEGER
4. DIM curPosX AS INTEGER
5. DIM curOffset AS _UNSIGNED LONG
6. DIM Text AS STRING
7.  
8. Text = "Moving cursor with MEM"
9.  
10. Handle = _NEWIMAGE(400, 400, 32)
11.  
12. SCREEN Handle
13.  
14. DIM M AS _MEM
15. M = _MEMIMAGE(Handle)
16.  
17. DIM r AS _UNSIGNED _BYTE
18. DIM g AS _UNSIGNED _BYTE
19. DIM b AS _UNSIGNED _BYTE
20. 'DIM a AS _UNSIGNED _BYTE
21. _FULLSCREEN
22. curWidth = (_PRINTWIDTH(CHR$(a)) - 2) * 4
23.  
24. curPosX = _PRINTWIDTH(Text) * 4
25.  
26. PRINT
27. PRINT "  l to move left, r to move right"
28. PRINT Text
29.  
30. curOffset = 4 * _WIDTH * (15 + 32) + curPosX
31. FOR T = curOffset TO curOffset + curWidth STEP 4
32.  
33.     'b = _MEMGET(M, M.OFFSET + T, _UNSIGNED _BYTE)
34.     b = 255
35.     _MEMPUT M, M.OFFSET + T, b
36.  
37.     'g = _MEMGET(M, M.OFFSET + T + 1, _UNSIGNED _BYTE)
38.     g = 255
39.     _MEMPUT M, M.OFFSET + T + 1, g
40.  
41.     ' r = _MEMGET(M, M.OFFSET + T + 2, _UNSIGNED _BYTE)
42.     r = 0
43.     _MEMPUT M, M.OFFSET + T + 2, r
44. NEXT T
45.  
46. DO
47.     i$ = INKEY$
48.     IF i$ = CHR$(27) THEN END
49.  
50.     IF i$ = "l" AND curPosX > 0 THEN
51.         GOSUB curoff
52.         curPosX = curPosX - _PRINTWIDTH(CHR$(a)) * 4
53.         curOffset = 4 * _WIDTH * (15 + 32) + curPosX
54.         GOSUB curon
55.     END IF
56.  
57.     IF i$ = "r" AND curPosX + _PRINTWIDTH(CHR$(a)) * 4 < _WIDTH * 4 THEN
58.         GOSUB curoff
59.         curPosX = curPosX + _PRINTWIDTH(CHR$(a)) * 4
60.         curOffset = 4 * _WIDTH * (15 + 32) + curPosX
61.         GOSUB curon
62.     END IF
63. LOOP
64.  
65. curon:
66. FOR T = curOffset TO curOffset + curWidth STEP 4
67.  
68.     'b = _MEMGET(M, M.OFFSET + T, _UNSIGNED _BYTE)
69.     b = 255
70.     _MEMPUT M, M.OFFSET + T, b
71.  
72.     'g = _MEMGET(M, M.OFFSET + T + 1, _UNSIGNED _BYTE)
73.     g = 255
74.     _MEMPUT M, M.OFFSET + T + 1, g
75.  
76.     ' r = _MEMGET(M, M.OFFSET + T + 2, _UNSIGNED _BYTE)
77.     r = 0
78.     _MEMPUT M, M.OFFSET + T + 2, r
79. NEXT T
80.  
81. RETURN
82.  
83.  
84. curoff:
85.  
86. FOR T = curOffset TO curOffset + curWidth STEP 4
87.  
88.     'b = _MEMGET(M, M.OFFSET + T, _UNSIGNED _BYTE)
89.     b = 0
90.     _MEMPUT M, M.OFFSET + T, b
91.  
92.     ' g = _MEMGET(M, M.OFFSET + T + 1, _UNSIGNED _BYTE)
93.     g = 0
94.     _MEMPUT M, M.OFFSET + T + 1, g
95.  
96.     'r = _MEMGET(M, M.OFFSET + T + 2, _UNSIGNED _BYTE)
97.     r = 0
98.     _MEMPUT M, M.OFFSET + T + 2, r
99. NEXT T
100. RETURN
101.  

Title: Re: Xor Magic ^2
Post by: bplus on April 12, 2021, 11:06:01 am

@NOVARSEG not seeing the relationship to Xor in your last posts.

Title: Re: Xor Magic ^2
Post by: SpriggsySpriggs on April 12, 2021, 11:08:41 am

Could be another hijacked post!

Title: Re: Xor Magic ^2
Post by: NOVARSEG on April 12, 2021, 02:58:48 pm

Yep the thread went off topic but did not want to start a new thread

 XOR and other logic operators combined with memput and memget allow full control of cursor position and color


The code was just a simplified version.  I think XOR can be used to turn a cursor on and off.

Title: Re: Xor Magic ^2
Post by: bplus on April 12, 2021, 10:32:19 pm

More Xor Magic, use Xor to find the missing number from a set of integers from 1 to n:

Code: QB64: [Select]

1. _Title "Find missing number" 'b+ 2021-04-12
2. ' given an array of integers for 1 to n find the missing integer
3.  
4. Randomize Timer
5. DefLng A-Z
6. n = Int(Rnd * 100) + 2 ' pick a number n of integers
7. Dim nums(1 To n) ' set an array of numbers
8. For i = 1 To n: nums(i) = i: Next
9. For i = n To 2 Step -1 ' shuffle  the array
10.     Swap nums(Int(i * Rnd) + 1), nums(i)
11. Next
12.  
13. 'remove one of the integers
14. r = Int(n * Rnd) + 1
15. removed = nums(r) 'save number
16. nums(r) = 0
17.  
18. 'find missing number  one way to find the missing number
19. For i = 1 To n
20.     sum = sum + nums(i)
21. Next
22. missing = n * (n + 1) / 2 - sum 'subtract sum from the formula for sum of integers 1 to n = n*(n+1)/2
23. Print "Missing number found by difference for formula for sum of 1 to n integers and sum of integers in array."
24. Print missing, removed
25.  
26. ' now we shall find the missing number using Xor alone!
27. missing = 0
28. For i = 1 To n
29.     missing = missing Xor i
30.     missing = missing Xor nums(i)
31. Next
32. Print: Print "Xor found missing compared to removed was:"
33. Print missing, removed
34.  
35.  

Title: Re: Xor Magic ^2
Post by: NOVARSEG on April 13, 2021, 01:34:00 am

Can Alice and Bob find the missing number?

Title: Re: Xor Magic ^2
Post by: bplus on April 13, 2021, 11:42:13 am

And Bob and Alice can create a deck of 52 shuffled numbers using Xor (instead of =):

Code: QB64: [Select]

1. _Title "Find duplicate number" 'b+ 2021-04-13
2. ' lets create a deck of 52 shuffled numbers with Xor
3.  
4. Randomize Timer
5. DefLng A-Z 'every variable, array and function is long
6.  
7. ReDim nums(1 To 52) ' set an array of numbers
8.  
9. 'obviously the first pick won't duplicate
10. nums(1) = RandomPicker1To52
11. index = 2
12.  
13. pickAgain:
14. pick = RandomPicker1To52
15. For i = 1 To index - 1
16.     If (nums(i) Xor pick) = 0 Then GoTo pickAgain 'it was a duplicate
17. Next
18. nums(index) = pick
19. index = index + 1
20. If index <= 52 GoTo pickAgain
21.  
22. 'display results
23. For i = 1 To 52: Print nums(i);: Next  'shouldn't be any duplicates or missing numbers, 1 to 52
24.  
25. Function RandomPicker1To52
26.     RandomPicker1To52 = Int(Rnd * 52) + 1
27. End Function
28.  
29.  

Text Only | Text with Attachments