Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: PMACKAY on July 30, 2018, 11:09:09 pm

Title: Poke to screen 0 for speed
Post by: PMACKAY on July 30, 2018, 11:09:09 pm
how can i make a sub that will poke to screen 0 fast. i want to have more speed at printing text. with color.

only want it to poke one ascii at a time : replace locate x,y:print "j"; with just a sub eg. loc x,y,char$

needs to be faster then locate and print

this is sort of what want

for i%=1 to 40
     for j%=1 to 25
          b$=mid$(screenmem$(j%),i%,1)
          loc x,y,b$
     next j%
next i%
_display

need speed as needs to go through this routine as in frames per second


will defseg=0 and other commands be slower than just locate x,y:print mid$(screenmem$(j%),i%,1)

thinking of making a boulderdash in ibm ascii
Title: Re: Poke to screen 0 for speed
Post by: SMcNeill on July 30, 2018, 11:38:20 pm
Use _MEMPUT and _MEMGET for direct memory access.  ;)
Title: Re: Poke to screen 0 for speed
Post by: FellippeHeitor on July 30, 2018, 11:38:52 pm
Or, for simplicity:

_PRINTSTRING (x, y), text$
Title: Re: Poke to screen 0 for speed
Post by: Cobalt on July 31, 2018, 01:29:50 pm
or if you want to go real old skool,
Code: QB64: [Select]
  1. SUB reaprint (Layer%, x%, y%, text$, col%)
  2.  DEF SEG = &HB800
  3.  l% = Layer% * 4096
  4.  xloc% = x% * 2
  5.  yloc% = y%
  6.  IF LEN(LTRIM$(RTRIM$(text$))) > 1 THEN
  7.   FOR I% = 1 TO LEN(text$)
  8.    t$ = MID$(text$, I%, 1)
  9.    t% = ASC(t$)
  10.    POKE l% + 0 + xloc% + (yloc% * 160), t%
  11.    POKE l% + 1 + xloc% + (yloc% * 160), col%
  12.    xloc% = xloc% + 2
  13.    IF xloc% = 160 THEN xloc% = 0: yloc% = yloc% + 1
  14.   NEXT I%
  15.  ELSEIF LEN(text$) = 1 THEN
  16.   t% = ASC(text$)
  17.   POKE l% + 0 + xloc% + (yloc% * 160), t%
  18.   POKE l% + 1 + xloc% + (yloc% * 160), col%
  22.  

in nutshell
 DEF SEG = &HB800           'text memory seg
  POKE  offset% + 0 , t%   'character
  POKE  offset% + 1, col% 'color
 DEF SEG                           'restore memory seg

in todays terms there really isn't any speed gain from this method anymore its just a matter of whether or not you like using it.
Which I still do anyway.

by that I mean vs SMcNiell's MEMGET\PUT suggestion and FellippeHeitors _PRINTSTRING suggestion
Title: Re: Poke to screen 0 for speed
Post by: FellippeHeitor on July 31, 2018, 01:35:36 pm
Quote from: Cobalt on July 31, 2018, 01:29:50 pm
in todays terms there really isn't any speed gain from this method anymore its just a matter of whether or not you like using it.
Which I still do anyway.

by that I mean vs SMcNiell's MEMGET\PUT suggestion and FellippeHeitors _PRINTSTRING suggestion

There's no speed gain anymore because VGA memory is emulated and is, in the background, essentially doing what _PRINTSTRING is.
Title: Re: Poke to screen 0 for speed
Post by: SkyCharger001 on August 03, 2018, 01:50:46 pm
MEMGET/PUT allow you to bypass some checks performed by the normal graphical functions.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 14, 2018, 07:37:02 am
Would you be able to show me a small example on how to use _memget/memput


I need to speed up this a lot more with a faster way to print. its not slow and runs perfect but i want to start adding more stuff to this.


works perfect and boulders drop as should. like boulder dash.


ANIMATE:

_LIMIT 1000: FOR I% = 2 TO 19: FOR J% = 11 TO 2 STEP -1
        COLOR 14, 0
        B$ = MID$(MAP$(J%), I%, 1)
        C$ = MID$(MAP$(J% - 1), I%, 1)
        IF B$ = " " AND C$ = "O" THEN MID$(MAP$(J%), I%, 1) = "O": MID$(MAP$(J% - 1), I%, 1) = " ": SOUND INT(RND(1) * 400) + 1030, .03
        IF B$ = " " AND C$ = "D" AND INT(RND(1) * 2) = 1 THEN MID$(MAP$(J%), I%, 1) = "D": MID$(MAP$(J% - 1), I%, 1) = " ": SOUND INT(RND(1) * 400) + 5030, .04
        IF B$ = "v" AND C$ = "D" AND INT(RND(1) * 6) = 5 THEN MID$(MAP$(J%), I%, 1) = "D": MID$(MAP$(J% - 1), I%, 1) = " ": SOUND INT(RND(1) * 400) + 6030, .04
NEXT J%: NEXT I%
PRINTMAP:

FOR I% = 1 TO 20: FOR J% = 1 TO 12
        B$ = MID$(MAP$(J%), I%, 1)
        SELECT CASE B$
            CASE "B"
                COLOR BRICK%, BACK%: B$ = CHR$(178)
            CASE "D"
                COLOR DIAMOND%, FORG%: B$ = CHR$(4)
            CASE "3"
                COLOR BRICK%, BACK%
            CASE " "
                COLOR BACK%, FORG%: B$ = " "
            CASE "."
                COLOR DIRT%, FORG%: B$ = CHR$(176)
            CASE "M"
                COLOR MONSTER%, FORG%: B$ = CHR$(234)
            CASE "m"
                COLOR MONSTER%, FORG%: B$ = CHR$(232)
            CASE "X"
                COLOR BACK%, EXITDOOR%: B$ = CHR$(127)
            CASE "O"
                COLOR ROCK%, FORG%: B$ = "o"
            CASE "v"
                COLOR MAN%, FORG%: B$ = CHR$(2)
        END SELECT
        LOCATE J% + 2, I%: PRINT B$;
NEXT J%: NEXT I%
_DISPLAY
RETURN
Title: Re: Poke to screen 0 for speed
Post by: SMcNeill on August 14, 2018, 07:56:35 am
One easy change which I immediately see which would vastly improve this would be to use ASC instead of MID$.

    B = ASC(MAP$(J%), I%)
    C= ASC(MAP$(J% - 1), I%)

Then use ASC values in your IF statements, such as substituting 32 for the space. (I'm on my iPad ATM and don't have a handy chart for value substitutions.)

I imagine the performance will increase dramatically.
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 14, 2018, 08:21:54 am
Does _Limit work outside a loop? But that won't speed up things...

Does SOUND delay the action in loop? ie does execution wait for sound to finish before proceeding with next step?
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 14, 2018, 08:24:38 am
i was thinking of rewriting the whole section including map$ form

dim screenmem$(?) to dim screenx%(?),screeny%(?)

then data from "????????????" to ?,?,?,?,?,?,? and doing away with mid$ altogether to get more speed


and where select case is no more char$, would change to ascII char and only have a color change as the ascii char already set


do you think it would be much faster
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 14, 2018, 08:31:27 am
the sound works perfect on my pc for speed limit. the animation is the right speed. but i just want stuff to execute faster as i am going to get my monsters to animat in the loop also


good pickup on limit.. going to remove it.
Title: Re: Poke to screen 0 for speed
Post by: FellippeHeitor on August 14, 2018, 08:35:14 am
Quote
Does _Limit work outside a loop?

Yes, provided it is in a section that'll be repeated with GOTO or GOSUB for example.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 14, 2018, 08:41:26 am
i added below my bas file... it is not complete. this is just the very first to see how things work. it will run. but thinking of recoding from the start. new keyboard routine needed. new arrays.. instead of strings just two single arrays


arrow keys to move, q to quit.
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 14, 2018, 11:11:20 am
Hi PMACKAY,

To me, it seems most natural to use an x by y, 2 dimensional array eg things are located by an x, y coordinate.

Say a diamond is located at x=10, y=12 or map$(10, 12) = "D" or "Diamond"

or a map can be of numbers where say a diamond = 100  so map%(10, 12) = 100.

This is not to say dash isn't dashing!  ;) though I haven't quit have figured out the object of the game yet. I ended up stuck in a corner buried by rocks, yikes! ;)

PS Data could be loaded in from a file, a file created in a map making app.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 14, 2018, 11:19:09 am
I have redone the work. the download is here. much faster if you take out the loop with wait &h3da,8 out. not complete but working. will work on more now. but much better
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 14, 2018, 11:28:19 am
Ha! that's fast work. May I ask what is the object of game?
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 14, 2018, 11:33:55 am
the topic at the moment is to collect all diamonds, what out for getting blocked in by boulders, there are going to be some monsters that can chase and kill you, and get through the levels, i am not to sure what to do yet. just mucking about. i will do a level editor to go with this. but one thing first is getting this to work
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 14, 2018, 11:46:04 am
Well you got the 2 dimensional array map array fast enough!

You are doing odd thing (to me) for polling key presses, _keydown is great for picking up which key or key combo was pressed.

IF _KEYDOWN(32) then print "You pressed space bar."

http://qb64.org/wiki/KEYDOWN

Of course, just because I think your method is odd or complicated doesn't mean it's wrong or won't work.

All these key press polling methods have problem of clearing the buffer to tell if a key was meant to be pressed once or many times in a row. Usually the QB64 assumes many times and it is hard to move one space at time with arrows.
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 14, 2018, 11:55:27 am
I wonder why the CASE is not indenting here:

  [ This attachment cannot be displayed inline in 'Print Page' view ]  
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 14, 2018, 11:55:42 am
the keyboard is alway hard on the pc. think the interupt is the issue as it reads it so quick and fills the buffer. i have just fixed a few things on it now


i think the case is not indentting as i have more than one on a line
Title: Re: Poke to screen 0 for speed
Post by: FellippeHeitor on August 14, 2018, 12:01:48 pm
Quote from: bplus on August 14, 2018, 11:55:27 am
I wonder why the CASE is not indenting here:

  [ This attachment cannot be displayed inline in 'Print Page' view ]

Excessive grouping is giving the IDE a hard time.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 14, 2018, 12:06:11 pm
select case and end select can be made to run as one line. just looks tight.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 14, 2018, 12:23:16 pm
time for bed for me
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 14, 2018, 12:45:33 pm
;)

I tried it with _KEYDOWN and clearing last _KEYDOWN so that one key press = one space moved
Code: QB64: [Select]
  1. DEFINT A-Z: DIM screenmem%(22, 12)
  3. GOSUB readlev: GOSUB displaymap: GOSUB animate: score = 0
  5.  
  6.     screenmem%(mx%, my%) = 1
  7.     GOSUB animate
  8.     screenmem%(mx%, my%) = 32
  9.  
  10.     IF _KEYDOWN(18432) THEN 'up
  11.         IF screenmem%(mx%, my% - 1) = 32 OR screenmem%(mx%, my% - 1) = 176 THEN my% = my% - 1
  12.         WHILE _KEYDOWN(18432): _LIMIT 200: WEND
  13.     END IF
  14.  
  15.     IF _KEYDOWN(20480) THEN 'down
  16.         IF screenmem%(mx%, my% + 1) = 32 OR screenmem%(mx%, my% + 1) = 176 THEN my% = my% + 1
  17.         IF screenmem%(mx%, my% + 1) = 4 THEN my% = my% + 1: score = score + 1
  18.         WHILE _KEYDOWN(20480): _LIMIT 200: WEND
  19.     END IF
  20.  
  21.     IF _KEYDOWN(19200) THEN 'left
  22.         IF screenmem%(mx% - 1, my%) = 32 OR screenmem%(mx% - 1, my%) = 176 THEN mx% = mx% - 1
  23.         IF screenmem%(mx% - 1, my%) = 79 AND screenmem%(mx% - 2, my%) = 32 THEN screenmem%(mx% - 2, my%) = 79: screenmem%(mx% - 1, my%) = 32: mx% = mx% - 1
  24.         IF screenmem%(mx% - 1, my%) = 4 THEN mx% = mx% - 1: score = score + 1
  25.         WHILE _KEYDOWN(19200): _LIMIT 200: WEND
  26.     END IF
  27.  
  28.  
  29.     IF _KEYDOWN(19712) THEN 'right
  30.         IF screenmem%(mx% + 1, my%) = 32 OR screenmem%(mx% + 1, my%) = 176 THEN mx% = mx% + 1
  31.         IF screenmem%(mx% + 1, my%) = 79 AND screenmem%(mx% + 2, my%) = 32 THEN screenmem%(mx% + 2, my%) = 79: screenmem%(mx% + 1, my%) = 32: mx% = mx% + 1
  32.         IF screenmem%(mx% + 1, my%) = 4 THEN mx% = mx% + 1: score = score + 1
  33.         WHILE _KEYDOWN(19712): _LIMIT 200: WEND
  34.     END IF
  35.  
  36.     _LIMIT 100
  37. LOOP UNTIL _KEYDOWN(27) 'escape
  38.  
  40.  
  41. animate:
  42.  
  43. FOR i = 1 TO 19
  44.     FOR j = 11 TO 1 STEP -1
  45.         IF screenmem%(i, j) = 79 AND screenmem%(i, j + 1) = 32 THEN screenmem%(i, j) = 32: screenmem%(i, j + 1) = 79
  46.         IF screenmem%(i, j) = 4 AND screenmem%(i, j + 1) = 32 THEN screenmem%(i, j) = 32: screenmem%(i, j + 1) = 4
  47.     NEXT j
  49.  
  50. displaymap:
  51.  
  52. FOR i = 1 TO 12
  53.     FOR j = 1 TO 20
  54.         b = screenmem%(j, i)
  55.         COLOR 4
  56.         SELECT CASE b
  57.         CASE 79: COLOR 15: CASE 177: COLOR 4
  58.         CASE 234: COLOR 2: CASE 235: COLOR 2
  59.         CASE 176: COLOR 6: CASE 1: COLOR 14
  60.         CASE 219: COLOR 4: CASE 4: COLOR 1
  61.         END SELECT
  62.         _PRINTSTRING (j, i), CHR$(b)
  63.     NEXT j
  65. COLOR 6: _PRINTSTRING (4, 13), "SCORE - " + STR$(score)
  67.  
  68. readlev:
  69.  
  70. FOR i = 1 TO 12
  71.     READ map$
  72.     FOR j = 1 TO 20
  73.         b$ = MID$(map$, j, 1)
  74.         IF b$ = "B" THEN b = 177
  75.         IF b$ = " " THEN b = 32
  76.         IF b$ = "M" THEN b = 234
  77.         IF b$ = "m" THEN b = 235
  78.         IF b$ = "v" THEN b = 1: mx% = j: my% = i
  79.         IF b$ = "O" THEN b = 79
  80.         IF b$ = "." THEN b = 176
  81.         IF b$ = "X" THEN b = 219
  82.         IF b$ = "D" THEN b = 4
  83.         screenmem%(j, i) = b
  84.     NEXT j
  86.  
  88.  
  89. DATA "BBBBBBBBBBBBBBBBBBBB"
  90. DATA "BOODBM       BODODOB"
  91. DATA "B...BB... OO B.OOO.B"
  92. DATA "B.BBB..O. .. B.....B"
  93. DATA "B.....O.O       .O.B"
  94. DATA "B.O.O.BDBvBBBBB ...X"
  95. DATA "BO....BBB BODOB O..B"
  96. DATA "B.......B BDODB .OOB"
  97. DATA "B..O.O..B BBOBB ...B"
  98. DATA "B.O.O.O.B ..... .O.B"
  99. DATA "B.OD.DO.B   m   .ODB"
  100. DATA "BBBBBBBBBBXBBBBBBBBB"
  101.  
  102.  

I will have to think about how to get that diamond in bottom right corner without being buried in rocks!
Title: Re: Poke to screen 0 for speed
Post by: FellippeHeitor on August 14, 2018, 01:08:33 pm
You seem to fail to grasp that _KEYDOWN will return -1 for as long as the key is held down. It doesn't need clearing (and isn't even affected by _KEYCLEAR).

The use of _KEYDOWN is awesome for games because it allows you to react to multiple keys at once.

Code: QB64: [Select]
  1. x = 40
  2. y = 12
  3.  
  5.     IF _KEYDOWN(18432) THEN y = y - 1
  6.     IF _KEYDOWN(20480) THEN y = y + 1
  7.     IF _KEYDOWN(19200) THEN x = x - 1
  8.     IF _KEYDOWN(19712) THEN x = x + 1
  9.  
  10.     IF y < 1 THEN y = 1
  11.     IF y > 25 THEN y = 25
  12.     IF x < 1 THEN x = 1
  13.     IF x > 80 THEN x = 80
  14.  
  15.     CLS
  16.     COLOR 7
  17.     PRINT "You can go up/down/left/right but also diagonally"
  18.     PRINT "if you hold more than one key at a time."
  19.  
  20.     COLOR 10
  21.     _PRINTSTRING (x, y), CHR$(254)
  22.     _DISPLAY
  23.     _LIMIT 30

Now if you want...

Quote
one key press = one space moved

...then you're better off sticking to old ways and using INKEY$ (or even _KEYHIT).
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 14, 2018, 01:22:59 pm
Quote from: FellippeHeitor on August 14, 2018, 01:08:33 pm
You seem to fail to grasp that _KEYDOWN will return -1 for as long as the key is held down. It doesn't need clearing (and isn't even affected by _KEYCLEAR).

The use of _KEYDOWN is awesome for games because it allows you to react to multiple keys at once.

Code: QB64: [Select]
  1. x = 40
  2. y = 12
  3.  
  5.     IF _KEYDOWN(18432) THEN y = y - 1
  6.     IF _KEYDOWN(20480) THEN y = y + 1
  7.     IF _KEYDOWN(19200) THEN x = x - 1
  8.     IF _KEYDOWN(19712) THEN x = x + 1
  9.  
  10.     IF y < 1 THEN y = 1
  11.     IF y > 25 THEN y = 25
  12.     IF x < 1 THEN x = 1
  13.     IF x > 80 THEN x = 80
  14.  
  15.     CLS
  16.     COLOR 7
  17.     PRINT "You can go up/down/left/right but also diagonally"
  18.     PRINT "if you hold more than one key at a time."
  19.  
  20.     COLOR 10
  21.     _PRINTSTRING (x, y), CHR$(254)
  22.     _DISPLAY
  23.     _LIMIT 30

Now if you want...

Quote
one key press = one space moved

...then you're better off sticking to old ways and using INKEY$ (or even _KEYHIT).

All the methods I have tried for polling keys have trouble with too much response with out some sort of delay or clearing of key buffer. The same goes for mouse.
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 14, 2018, 02:00:54 pm
To show you what I am talking about, here is a little mod to the demo:
Code: QB64: [Select]
  1. x = 40
  2. y = 12
  3.  
  5.     IF _KEYDOWN(18432) THEN y = y - 1
  6.     IF _KEYDOWN(20480) THEN y = y + 1
  7.     IF _KEYDOWN(19200) THEN x = x - 1
  8.     IF _KEYDOWN(19712) THEN x = x + 1
  9.  
  10.     IF y < 1 THEN y = 1
  11.     IF y > 25 THEN y = 25
  12.     IF x < 1 THEN x = 1
  13.     IF x > 80 THEN x = 80
  14.  
  15.     CLS
  16.     COLOR 7
  17.     PRINT "You can go up/down/left/right but also diagonally"
  18.     PRINT "if you hold more than one key at a time."
  19.     PRINT
  20.     PRINT "Now try to stop the moving dot inside the blue ( )"
  21.  
  22.     COLOR 9
  23.     _PRINTSTRING (10, 6), "( )"
  24.     _PRINTSTRING (30, 10), "( )"
  25.     _PRINTSTRING (1, 12), "( )"
  26.  
  27.     COLOR 10
  28.     _PRINTSTRING (x, y), CHR$(254)
  29.     _DISPLAY
  30.     _LIMIT 30
  32.  

It does work better with INKEY$
Code: QB64: [Select]
  1.     k$ = INKEY$
  2.     IF k$ = "u" THEN y = y - 1
  3.     IF k$ = "d" THEN y = y + 1
  4.     IF k$ = "l" THEN x = x - 1
  5.     IF k$ = "r" THEN x = x + 1
  6.  
Title: Re: Poke to screen 0 for speed
Post by: FellippeHeitor on August 14, 2018, 02:28:39 pm
So there you have it, we agree. For cases where you need a single entry, INKEY$ or _KEYHIT.

_KEYDOWN has its own range of uses.
Title: Re: Poke to screen 0 for speed
Post by: SMcNeill on August 14, 2018, 05:30:34 pm
Taking a look at your code, I have a few questions for you:

1) Why make keystate so hard to comprehend, when what it's doing is really very simple:

Code: QB64: [Select]
  1. FOR k = 0 TO 127 '255
  2.     keystate(k) = 1 'keystate(k) = -((k AND 128) = 0)

The code you're using is running the formula from 0 to 255, and placing the value of 1 in the first 128 elements of the array (0 to 127), and then placing 0 in the next 128 elements.  It works, but it's some of the best code obfuscation I've seen in ages.  You can see how much simpler, and easier to read and understand, the changes I'd make are, above.

2) Same question with the DATA array.  Why read it as a single line for "B", "X", "V" and such, and then have to break it down with MID$ to get the numeric values you want from that data -- after running it through a value conversion routine? 

Isn't it much simpler to just change the DATA so that it represents what you're actually using?

Code: QB64: [Select]
  1. DATA "±±±±±±±±±±±±±±±±±±±±"
  2. DATA "±OO±ê       ±OOO±"
  3. DATA "±°°°±±°°° OO ±°OOO°±"
  4. DATA "±°±±±°°O° °° ±°°°°°±"
  5. DATA "±°°°°°O°O       °O°±"
  6. DATA "±°O°O°±±±±±±± °°°Û"
  7. DATA "±O°°°°±±± ±OO± O°°±"
  8. DATA "±°°°°°°°± ±O± °OO±"
  9. DATA "±°°O°O°°± ±±O±± °°°±"
  10. DATA "±°O°O°O°± °°°°° °O°±"
  11. DATA "±°O°O°±   ë   °O±"
  12. DATA "±±±±±±±±±±Û±±±±±±±±±"
  13.  

Note that the above doesn't display all pretty for me here on the forums, but it works just fine in QB64's IDE which supports the extended ASCII characters.

Also note, with the above, all we need to read that DATA and use it is the following little routine:

Code: QB64: [Select]
  1. readlev:
  2.  
  3. FOR i = 1 TO 12
  4.     READ map$
  5.     FOR j = 1 TO 20
  6.         b = ASC(map$, j)
  7.         IF b = 1 THEN mx% = j: my% = i
  8.         screenmem%(j, i) = b
  9.     NEXT j
  11.  

Doesn't that seem a wee bit simpler?

Or, even better, I prefer to break the DATA down to the ASC values and store them independent as the following:

Code: QB64: [Select]
  1. DATA 177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177
  2. DATA 177,79,79,4,177,234,32,32,32,32,32,32,32,177,79,4,79,4,79,177
  3. DATA 177,176,176,176,177,177,176,176,176,32,79,79,32,177,176,79,79,79,176,177
  4. DATA 177,176,177,177,177,176,176,79,176,32,176,176,32,177,176,176,176,176,176,177
  5. DATA 177,176,176,176,176,176,79,176,79,32,32,32,32,32,32,32,176,79,176,177
  6. DATA 177,176,79,176,79,176,177,4,177,1,177,177,177,177,177,32,176,176,176,219
  7. DATA 177,79,176,176,176,176,177,177,177,32,177,79,4,79,177,32,79,176,176,177
  8. DATA 177,176,176,176,176,176,176,176,177,32,177,4,79,4,177,32,176,79,79,177
  9. DATA 177,176,176,79,176,79,176,176,177,32,177,177,79,177,177,32,176,176,176,177
  10. DATA 177,176,79,176,79,176,79,176,177,32,176,176,176,176,176,32,176,79,176,177
  11. DATA 177,176,79,4,176,4,79,176,177,32,32,32,235,32,32,32,176,79,4,177
  12. DATA 177,177,177,177,177,177,177,177,177,177,219,177,177,177,177,177,177,177,177,177

And, with the DATA stored as we actually need it, all we have to do is the following to use it in our program:

Code: QB64: [Select]
  1. readlev:
  2.  
  3. FOR i = 1 TO 12
  4.     FOR j = 1 TO 20
  5.         READ screenmem(j, i)
  6.         IF screenmem(j, i) = 1 THEN mx% = j: my% = i
  7.     NEXT j
  9.  

It doesn't get any simpler -- or faster -- than that!  ;)

My overall changes to your last set of code that you shared would end up looking like the following:

Code: QB64: [Select]
  1. DEFINT A-Z
  2. DIM screenmem%(22, 12), kbd(255), keystate(255)
  3.  
  4. 'Why complicate the following with hard to understand math, when a much simpler method exists which is way easier to understand?
  5.  
  6. FOR k = 0 TO 127 '255
  7.     keystate(k) = 1 'keystate(k) = -((k AND 128) = 0)
  9.  
  11.  
  12.  
  13. GOSUB readlev
  14. score = 0
  15. GOSUB displaymap
  16. GOSUB animate
  18.  
  19.     screenmem%(mx%, my%) = 1
  20.     k = INP(&H60): kbd(k AND 127) = keystate(k)
  21.     xv = kbd(77) - kbd(75)
  22.     yv = kbd(80) - kbd(72)
  23.     GOSUB animate
  24.     screenmem%(mx%, my%) = 32
  25.     IF xv = -1 AND screenmem%(mx% - 1, my%) = 32 THEN mx% = mx% - 1
  26.     IF xv = 1 AND screenmem%(mx% + 1, my%) = 32 THEN mx% = mx% + 1
  27.     IF yv = -1 AND screenmem%(mx%, my% - 1) = 32 THEN my% = my% - 1
  28.     IF yv = 1 AND screenmem%(mx%, my% + 1) = 32 THEN my% = my% + 1
  29.     IF xv = -1 AND screenmem%(mx% - 1, my%) = 176 THEN mx% = mx% - 1: GOTO skp
  30.     IF xv = 1 AND screenmem%(mx% + 1, my%) = 176 THEN mx% = mx% + 1: GOTO skp
  31.     IF yv = -1 AND screenmem%(mx%, my% - 1) = 176 THEN my% = my% - 1: GOTO skp
  32.     IF yv = 1 AND screenmem%(mx%, my% + 1) = 176 THEN my% = my% + 1: GOTO skp
  33.     IF xv = -1 AND screenmem%(mx% - 1, my%) = 79 AND screenmem%(mx% - 2, my%) = 32 THEN screenmem%(mx% - 2, my%) = 79: screenmem%(mx% - 1, my%) = 32: mx% = mx% - 1
  34.     IF xv = 1 AND screenmem%(mx% + 1, my%) = 79 AND screenmem%(mx% + 2, my%) = 32 THEN screenmem%(mx% + 2, my%) = 79: screenmem%(mx% + 1, my%) = 32: mx% = mx% + 1
  35.     IF xv = -1 AND screenmem%(mx% - 1, my%) = 4 THEN mx% = mx% - 1: score = score + 1
  36.     IF xv = 1 AND screenmem%(mx% + 1, my%) = 4 THEN mx% = mx% + 1: score = score + 1
  37.     IF yv = 1 AND screenmem%(mx%, my% + 1) = 4 THEN my% = my% + 1: score = score + 1
  38.     skp:
  39.     _DELAY 0.10
  40.  
  41. LOOP UNTIL kbd(1) 'escape key exits
  42.  
  44.  
  45.  
  46.  
  47.  
  48.  
  49. animate:
  50.  
  51. FOR i = 1 TO 19
  52.     FOR j = 11 TO 1 STEP -1
  53.         IF screenmem%(i, j) = 79 AND screenmem%(i, j + 1) = 32 THEN screenmem%(i, j) = 32: screenmem%(i, j + 1) = 79
  54.         IF screenmem%(i, j) = 4 AND screenmem%(i, j + 1) = 32 THEN screenmem%(i, j) = 32: screenmem%(i, j + 1) = 4
  55.     NEXT j
  57.  
  58. displaymap:
  59.  
  60. FOR i = 1 TO 12
  61.     FOR j = 1 TO 20
  62.         b = screenmem%(j, i)
  63.         SELECT CASE b
  64.             CASE 79: COLOR 15
  65.             CASE 177: COLOR 4
  66.             CASE 234: COLOR 2
  67.             CASE 235: COLOR 2
  68.             CASE 176: COLOR 6
  69.             CASE 1: COLOR 14
  70.             CASE 219: COLOR 4
  71.             CASE 4: COLOR 1
  72.         END SELECT
  73.         _PRINTSTRING (j, i), CHR$(b)
  74.     NEXT j
  76. COLOR 6: _PRINTSTRING (4, 13), "SCORE - " + STR$(score)
  78.  
  79. readlev:
  80.  
  81. FOR i = 1 TO 12
  82.     FOR j = 1 TO 20
  83.         READ screenmem(j, i)
  84.         IF screenmem(j, i) = 1 THEN mx% = j: my% = i
  85.     NEXT j
  87.  
  89.  
  90.  
  91.  
  92. DATA 177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177
  93. DATA 177,79,79,4,177,234,32,32,32,32,32,32,32,177,79,4,79,4,79,177
  94. DATA 177,176,176,176,177,177,176,176,176,32,79,79,32,177,176,79,79,79,176,177
  95. DATA 177,176,177,177,177,176,176,79,176,32,176,176,32,177,176,176,176,176,176,177
  96. DATA 177,176,176,176,176,176,79,176,79,32,32,32,32,32,32,32,176,79,176,177
  97. DATA 177,176,79,176,79,176,177,4,177,1,177,177,177,177,177,32,176,176,176,219
  98. DATA 177,79,176,176,176,176,177,177,177,32,177,79,4,79,177,32,79,176,176,177
  99. DATA 177,176,176,176,176,176,176,176,177,32,177,4,79,4,177,32,176,79,79,177
  100. DATA 177,176,176,79,176,79,176,176,177,32,177,177,79,177,177,32,176,176,176,177
  101. DATA 177,176,79,176,79,176,79,176,177,32,176,176,176,176,176,32,176,79,176,177
  102. DATA 177,176,79,4,176,4,79,176,177,32,32,32,235,32,32,32,176,79,4,177
  103. DATA 177,177,177,177,177,177,177,177,177,177,219,177,177,177,177,177,177,177,177,177
  104.  
  105. 'The above DATA statements correspond directly to the ASCII values of each spot on the grid below
  106. 'DATA "±±±±±±±±±±±±±±±±±±±±"
  107. 'DATA "±OO±ê       ±OOO±"
  108. 'DATA "±°°°±±°°° OO ±°OOO°±"
  109. 'DATA "±°±±±°°O° °° ±°°°°°±"
  110. 'DATA "±°°°°°O°O       °O°±"
  111. 'DATA "±°O°O°±±±±±±± °°°Û"
  112. 'DATA "±O°°°°±±± ±OO± O°°±"
  113. 'DATA "±°°°°°°°± ±O± °OO±"
  114. 'DATA "±°°O°O°°± ±±O±± °°°±"
  115. 'DATA "±°O°O°O°± °°°°° °O°±"
  116. 'DATA "±°O°O°±   ë   °O±"
  117. 'DATA "±±±±±±±±±±Û±±±±±±±±±"
  118.  

Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 08:09:33 am
thank you for your tips. i found the keyboard routine over the net somewhere. i auctaully need the key left and right if pressed with space bar (space bar + left or space bar + right) to grab the diamond two spaces over so as to take a diamond without the rock in center falling in...


......O......
..D.v.......   so if spacebar pressed and direction will grab diamond without moving


Title: Re: Poke to screen 0 for speed
Post by: bplus on August 15, 2018, 09:25:23 am
Quote from: PMACKAY on August 15, 2018, 08:09:33 am
thank you for your tips. i found the keyboard routine over the net somewhere. i auctaully need the key left and right if pressed with space bar (space bar + left or space bar + right) to grab the diamond two spaces over so as to take a diamond without the rock in center falling in...


......O......
..D.v.......   so if spacebar pressed and direction will grab diamond without moving




Well _keydown can catch multiple keys but it will have you dancing around the spot you want to stop at.

You could set a diamond grabbing mode with one key press make the grab the next and then set the mode off automatically when a diamond is grabbed. Just add code for arrow keys when diamond grabbing mode is on.

A spacebar press could just toggle the mode on but you would probably like it to toggle diamond grabbing mode between on/off.
Title: Re: Poke to screen 0 for speed
Post by: FellippeHeitor on August 15, 2018, 09:40:56 am
If _KEYDOWN is too fast, reduce _LIMIT.
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 15, 2018, 09:58:12 am
AH, could check _keydown on spacebar while handling the arrow keys with inkey$ or_keyhit.

Is there a rule of thumb when to use INKEY$ and when to use _KEYHIT?
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 10:11:59 am
i want to change a little thing with the keyboard input. i want to hold shit and arrow to pull a single rock. with my keyboard routine how can i use the shift with the arrow.
Title: Re: Poke to screen 0 for speed
Post by: FellippeHeitor on August 15, 2018, 10:13:31 am
INKEY$ works as it did in Qbasic.

_KEYHIT has the advantage of returning both positive (pressed) and negative (released) key codes as well as extended codes for CTRL, SHIFT, etc.

In the end, there's no rule of thumb. You must evaluate your need for detail in the input.
Title: Re: Poke to screen 0 for speed
Post by: FellippeHeitor on August 15, 2018, 10:16:41 am
Quote from: PMACKAY on August 15, 2018, 10:11:59 am
i want to change a little thing with the keyboard input. i want to hold shit and arrow to pull a single rock. with my keyboard routine how can i use the shift with the arrow.

Detect if SHIFT is being held down with _KEYDOWN:

Code: QB64: [Select]
  1. IF _KEYDOWN(100303) OR _KEYDOWN(100304) THEN PRINT "SHIFT is being held down"
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 15, 2018, 10:32:21 am
Oh released is a different number than holding with _keyhit, that is useful!

That is important difference. That would be good for stepping with arrow keys (check when they are released).
At that moment, check is _KEYDOWN(shift key or spacebar) for handling the special functions.



Psuedo code outline for handling key hits

KH& = _KEYHIT
If KH& < 0 then 'released keys check the arrow numbers
     SB% = _KEYDOWN(32) 'spacebar
     SHFT% = _KEYDOWN(shift&)
     if KH& = rightarrow& then
          if SB% then 'do right arrow + spacebar stuff
          if SHFT% then 'do right arrow +shift stuff
     end if
end if

look OK?
Title: Re: Poke to screen 0 for speed
Post by: FellippeHeitor on August 15, 2018, 10:37:17 am
Looks convoluted, but looks aren't important if it works, right? Let us know.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 10:40:31 am
very interesting. have moved my maps to a data file also. so no more mess in the main.
Title: Re: Poke to screen 0 for speed
Post by: SMcNeill on August 15, 2018, 11:00:54 am
Quote from: bplus on August 15, 2018, 10:32:21 am
Oh released is a different number than holding with _keyhit, that is useful!

That is important difference. That would be good for stepping with arrow keys (check when they are released).
At that moment, check is _KEYDOWN(shift key or spacebar) for handling the special functions.



Psuedo code outline for handling key hits

KH& = _KEYHIT
If KH& < 0 then 'released keys check the arrow numbers
     SB% = _KEYDOWN(32) 'spacebar
     SHFT% = _KEYDOWN(shift&)
     if KH& = rightarrow& then
          if SB% then 'do right arrow + spacebar stuff
          if SHFT% then 'do right arrow +shift stuff
     end if
end if

look OK?

Why not just set a flag and check it?

K = _KEYHIT
IF K = ArrowCodeWanted AND ArrowFlagSet = 0 THEN
   'Do Arrow Stuff
   ArrowFlagSet = -1 'Set the flag
END IF

IF K = -ArrowCodeWanted THEN ArrowFlagSet = 0 'Let go of arrow key before accepting its input again

Now you only deal with arrow keys which are pushed down manually and not just held down.
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 15, 2018, 11:08:18 am
Right just tested throwing out if HB% < 0 line:

Code: QB64: [Select]
  1. DEFINT A-Z: DIM screenmem%(22, 12)
  3. GOSUB readlev: GOSUB displaymap: GOSUB animate: score = 0
  5.  
  6.     screenmem%(mx%, my%) = 1
  7.     GOSUB animate
  8.     screenmem%(mx%, my%) = 32
  9.     KH& = _KEYHIT
  10.     SB% = _KEYDOWN(32) 'spacebar
  11.     SHFT% = _KEYDOWN(100303) OR _KEYDOWN(100304)
  12.  
  13.     IF KH& = -18432 THEN 'up
  14.         IF screenmem%(mx%, my% - 1) = 32 OR screenmem%(mx%, my% - 1) = 176 THEN my% = my% - 1
  15.  
  16.     END IF
  17.  
  18.     IF KH& = -20480 THEN 'down
  19.         IF screenmem%(mx%, my% + 1) = 32 OR screenmem%(mx%, my% + 1) = 176 THEN my% = my% + 1
  20.         IF screenmem%(mx%, my% + 1) = 4 THEN my% = my% + 1: score = score + 1
  21.  
  22.     END IF
  23.  
  24.     IF KH& = -19200 THEN 'left
  25.         IF screenmem%(mx% - 1, my%) = 32 OR screenmem%(mx% - 1, my%) = 176 THEN mx% = mx% - 1
  26.         IF screenmem%(mx% - 1, my%) = 79 AND screenmem%(mx% - 2, my%) = 32 THEN screenmem%(mx% - 2, my%) = 79: screenmem%(mx% - 1, my%) = 32: mx% = mx% - 1
  27.         IF screenmem%(mx% - 1, my%) = 4 THEN mx% = mx% - 1: score = score + 1
  28.  
  29.     END IF
  30.  
  31.  
  32.     IF KH& = -19712 THEN 'right
  33.         IF screenmem%(mx% + 1, my%) = 32 OR screenmem%(mx% + 1, my%) = 176 THEN mx% = mx% + 1
  34.         IF screenmem%(mx% + 1, my%) = 79 AND screenmem%(mx% + 2, my%) = 32 THEN screenmem%(mx% + 2, my%) = 79: screenmem%(mx% + 1, my%) = 32: mx% = mx% + 1
  35.         IF screenmem%(mx% + 1, my%) = 4 THEN mx% = mx% + 1: score = score + 1
  36.  
  37.     END IF
  38.  
  39.     _LIMIT 400
  40. LOOP UNTIL _KEYDOWN(27) 'escape
  41.  

It steps beautifully at any _LIMIT!

PMACKAY will have to fill in code when SB% and when SHFT% keys are also being held at time of arrow key release.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 11:10:45 am
this is the keyboard routine

 k = INP(&H60): kbd(k AND 127) = keystate(k)
    xv = kbd(77) - kbd(75)
    yv = kbd(80) - kbd(72)
    GOSUB animate
    screenmem%(mx%, my%) = 32
    IF xv = -1 AND screenmem%(mx% - 1, my%) = 32 THEN mx% = mx% - 1
    IF xv = 1 AND screenmem%(mx% + 1, my%) = 32 THEN mx% = mx% + 1
    IF yv = -1 AND screenmem%(mx%, my% - 1) = 32 THEN my% = my% - 1
    IF yv = 1 AND screenmem%(mx%, my% + 1) = 32 THEN my% = my% + 1
    IF xv = -1 AND screenmem%(mx% - 1, my%) = 176 THEN mx% = mx% - 1: GOTO skp
    IF xv = 1 AND screenmem%(mx% + 1, my%) = 176 THEN mx% = mx% + 1: GOTO skp
    IF yv = -1 AND screenmem%(mx%, my% - 1) = 176 THEN my% = my% - 1: GOTO skp
    IF yv = 1 AND screenmem%(mx%, my% + 1) = 176 THEN my% = my% + 1: GOTO skp
    IF xv = -1 AND screenmem%(mx% - 1, my%) = 79 AND screenmem%(mx% - 2, my%) = 32 THEN screenmem%(mx% - 2, my%) = 79: screenmem%(mx% - 1, my%) = 32: mx% = mx% - 1
    IF xv = 1 AND screenmem%(mx% + 1, my%) = 79 AND screenmem%(mx% + 2, my%) = 32 THEN screenmem%(mx% + 2, my%) = 79: screenmem%(mx% + 1, my%) = 32: mx% = mx% + 1
    IF xv = -1 AND screenmem%(mx% - 1, my%) = 4 THEN mx% = mx% - 1: score = score + 1
    IF xv = 1 AND screenmem%(mx% + 1, my%) = 4 THEN mx% = mx% + 1: score = score + 1
    IF yv = 1 AND screenmem%(mx%, my% + 1) = 4 THEN my% = my% + 1: score = score + 1
    skp:
    _DELAY 0.10

i am just not sure how to mod it to accept the left control and arrow together

    IF xv = -1 AND (cntrl pressed) and screenmem%(mx% + 1, my%) = 79 AND screenmem%(mx% - 1, my%) = 32 THEN 'control + left to pull rock on right  (i can work out what to swap myself)
    IF xv = 1 AND (cntrl pressed) and screenmem%(mx% - 1, my%) = 79 AND screenmem%(mx% +1, my%) = 32 THEN 'control + right to pull rock on left    (just the keyboard routine im lost)
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 11:15:00 am
your programing is so nice....
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 15, 2018, 11:22:27 am
:)  PMACKAY do you know where the key code numbers are coming from?

I think we might have worked out way to get the control you want in post #40, catch all the individual keys you want to do combos with _KEYDOWN(keycode number)  when you get the KH& =_KEYHIT  number and still make steps with each arrow key press (and release).

It was tricky business.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 11:26:44 am
i think i kind of know where the key codes are. i could work out the arrows and stuff but could not work out multi key.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 11:39:46 am
ok understood now.. great work. thank you for your help....
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 15, 2018, 11:45:18 am
OK so if an arrow key was released (negative number)

Check in a gauntlet that goes from most conditions to least:
(this is all under KH& = -arrow code)
if the BS% then ' spacebar
     do arrow + spacebar was also down, if so do the diamond grabbing
elseif SHFT% then
     do arrow + shift stuff
elseif Ctrl% then
     do arrow + ctrl stuff
else
     do all stuff that wasn't a combo key press
end if

If you want 3 key combo's check that first in the gauntlet of: IF THEN ELSEIF THEN... ELSE ENDIF

Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 12:31:16 pm
all standard single key stuff replaced, no working on duel key... shift and arrows
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 12:46:13 pm
this is cool. now i can pull a rock out of the way. working great thank you.... by the way i have autism spectrum desorder... cannot do maths. so me doing this stuff is pretty cool. :)   ///thats why my code looks old/// learning new things is great.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 12:51:34 pm
hold shift to pull the rock... there are four maps sofar... just pick which one with n$.... i have made a booboo with my data somewhere with print #1, input#1 to read colors and map data for exit to next map which e1$-e4$ are the exit doors to file n$.. chr$(219) will be exit and will flash once diamonds collected. have to work on the m and M sometime. which are going to be monsters
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 01:02:53 pm
only simple to get levels started. not serious yet. in test
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 01:09:20 pm
screenshot
Title: Re: Poke to screen 0 for speed
Post by: bplus on August 15, 2018, 01:46:16 pm
Hey PMACKAY,

Shift + left or right arrow works great!

This is nice little game you've got started, I look forward to future updates.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 15, 2018, 02:05:10 pm
thank you. its is 4am in australia and time for my bed.  thank you for the insight. i am happy with how its going.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 16, 2018, 02:48:34 am
zip. lots more to write (code) but this is a good start

This is the First major Download of the file that is sort of stage one complete. it is running correctly so far (will iron out bugs now before next stage which will be changing maps by walking through the doors)

it will be not necessary to collect all diamonds on each map but you cannot complete the entire game if you leave a diamond behind

minus monsters, music and sound and level auto select . read me file will suggest how to change a level. but this is in the first part of coding. so nothing very exciting

the rocks do fall and the diamonds can be collected, score is working but primitive at the moment. map builder is working. but getting excited so will have to create an easy map builder later.
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 16, 2018, 07:38:41 am
****progressing


Linux compiled version included


****       not complete
 ****        CODE IN PROGRESS
  ****
 ****
****
Title: Re: Poke to screen 0 for speed
Post by: PMACKAY on August 17, 2018, 04:19:48 am
Just curious.. should i have a variable amount of monsters on levels (eg hard level like 2-3 and easy level 0-8) depending of degree of puzzle

was thinking of monsters as a timer will be lost to boredom


    whip to kill monsters     Ctrl to whip (whip to go around man)

     O man normal
    |
  -O-
     |       Whipping monsters
Text Only | Text with Attachments