Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: SpriggsySpriggs on March 10, 2021, 12:39:09 pm

Title: For those who need to do basic HTTP/HTTPS downloading (Windows Only)
Post by: SpriggsySpriggs on March 10, 2021, 12:39:09 pm
Below is a function I made up that tries to take a dynamic approach to the very complex WinInet API functions. It is set up to dissect the URL you pass it so it can be sent to the functions correctly as well as call the functions with the right flags based on the security of the URL (HTTP or HTTPS). This just simply downloads the URL and stores it in the string. You could use this for downloading things other than text files or HTML files but depending on the size, you shouldn't. Here is the code:

Code: QB64: [Select]
  1. Option _Explicit 'not necessary, just to show that the code is Option _Explicit compatible
  2. $Console:Only 'Not necessary, just allows for scrolling
  3.  
  4. Print WebToString("http://www.schoolfreeware.com/Home.html")
  6.  
  7. Function WebToString$ (URL As String)
  8.     Const INTERNET_OPEN_TYPE_DIRECT = 1
  9.     Const INTERNET_DEFAULT_HTTP_PORT = 80
  10.     Const INTERNET_DEFAULT_HTTPS_PORT = 443
  11.     Const INTERNET_SERVICE_HTTP = 3
  12.     Const INTERNET_FLAG_SECURE = &H00800000
  13.     Const INTERNET_FLAG_RELOAD = &H80000000
  14.     Declare Dynamic Library "Wininet"
  15.         Function InternetOpen%& Alias InternetOpenA (ByVal lpszAgent As _Offset, Byval dwAccessType As Long, Byval lpszProxy As _Offset, Byval lpszProxyBypass As _Offset, Byval dwFlags As Long)
  16.         Function InternetConnect%& Alias InternetConnectA (ByVal hInternet As _Offset, Byval lpszServerName As _Offset, Byval nServerPort As Integer, Byval lpszUserName As _Offset, Byval lpszPassword As _Offset, Byval dwService As Long, Byval dwFlags As Long, Byval dwContext As _Offset)
  17.         Function HTTPOpenRequest%& Alias HttpOpenRequestA (ByVal hConnect As _Offset, Byval lpszVerb As _Offset, Byval lpszObjectName As _Offset, Byval lpszVersion As _Offset, Byval lpszReferrer As _Offset, Byval lpszAcceptTypes As _Offset, Byval dwFlags As Long, Byval dwContext As _Offset)
  18.         Function HTTPSendRequest%% Alias HttpSendRequestA (ByVal hRequest As _Offset, Byval lpszHeaders As _Offset, Byval dwHeadersLength As Long, Byval lpOptional As _Offset, Byval dwOptionalLength As Long)
  19.         Function InternetCloseHandle%% (ByVal hInternet As _Offset)
  20.         Function InternetReadFile%% (ByVal hFile As _Offset, Byval lpBuffer As _Offset, Byval dwNumberOfBytesToRead As Long, Byval lpdwNumberOfBytesRead As _Offset)
  21.     End Declare
  22.     Dim As _Offset hsession, httpsession, httpRequest
  23.     hsession = InternetOpen(0, INTERNET_OPEN_TYPE_DIRECT, 0, 0, 0)
  24.     Dim As String baseurl, location
  25.     If InStr(URL, "www") Then
  26.         baseurl = Mid$(URL, InStr(URL, "www") + Len("www."))
  27.     ElseIf InStr(URL, "//") Then
  28.         baseurl = Mid$(URL, InStr(URL, "//") + 2)
  29.     Else
  30.         baseurl = URL
  31.     End If
  32.     baseurl = Mid$(baseurl, 1, InStr(baseurl, "/") - 1)
  33.     location = Mid$(URL, InStr(URL, baseurl) + Len(baseurl))
  34.     baseurl = baseurl + Chr$(0)
  35.     location = location + Chr$(0)
  36.     If InStr(URL, "https") Then
  37.         httpsession = InternetConnect(hsession, _Offset(baseurl), INTERNET_DEFAULT_HTTPS_PORT, 0, 0, INTERNET_SERVICE_HTTP, 0, 0)
  38.     Else
  39.         httpsession = InternetConnect(hsession, _Offset(baseurl), INTERNET_DEFAULT_HTTP_PORT, 0, 0, INTERNET_SERVICE_HTTP, 0, 0)
  40.     End If
  41.     Dim As String sessiontype, accepttypes
  42.     sessiontype = "GET" + Chr$(0)
  43.     accepttypes = "*/*" + Chr$(0)
  44.     If InStr(URL, "https") Then
  45.         httpRequest = HTTPOpenRequest(httpsession, _Offset(sessiontype), _Offset(location), 0, 0, _Offset(accepttypes), INTERNET_FLAG_RELOAD Or INTERNET_FLAG_SECURE, 0)
  46.     Else
  47.         httpRequest = HTTPOpenRequest(httpsession, _Offset(sessiontype), _Offset(location), 0, 0, _Offset(accepttypes), INTERNET_FLAG_RELOAD, 0)
  48.     End If
  49.     Dim As _Byte sendrequest
  50.     sendrequest = HTTPSendRequest(httpRequest, 0, 0, 0, 0)
  51.     Dim As String szBuffer
  52.     szBuffer = Space$(4096)
  53.     Dim As Long dwRead
  54.     Dim As String webstring
  55.     While InternetReadFile(httpRequest, _Offset(szBuffer), Len(szBuffer), _Offset(dwRead)) And dwRead <> 0
  56.         webstring = webstring + Mid$(szBuffer, 1, dwRead)
  57.     Wend
  58.     Dim As _Byte closeh
  59.     closeh = InternetCloseHandle(hsession)
  60.     WebToString = webstring

Enjoy
Title: Re: For those who need to do basic HTTP/HTTPS downloading (Windows Only)
Post by: SpriggsySpriggs on March 10, 2021, 01:01:24 pm
I've edited the original post because I realize I forgot to include the variable for what types to accept. It probably isn't needed but it's for just-in-case
Title: Re: For those who need to do basic HTTP/HTTPS downloading (Windows Only)
Post by: NOVARSEG on March 12, 2021, 02:57:42 am
Is this preliminary TCP/IP setup?
Text Only | Text with Attachments