Print Page - Compilation failed, log shows PUT fixed length string array

Well, with a file opened for BINARY, a PUT #1, , ms_name() seems to have failed. dim shared ms_name(100) as string * 64 in the header.

Quote

In file included from qbx.cpp:2208:
..\\temp\\main.txt: In function 'void SUB_SAVE_FILE(qbs*)':
..\\temp\\main.txt:624:110: error: lvalue required as unary '&' operand
sub_put( 1 ,NULL,byte_element((uint64)(&(qbs_new_fixed(&((uint8*)(__ARRAY_STRING64_MS_NAME[0]))[(0)*64],64,1))),(64*(__ARRAY_STRING64_MS_NAME[2]&1)*__ARRAY_STRING64_MS_NAME[5])-(64*(0)),byte_element_26),0);
^
compilation terminated due to -Wfatal-errors.

In the text file, the caret is pointing at that red close-paren.

This isn't crucial to my program's function - it's a script editor, and this is the name of each script, which is handy for exporting code blocks as I don't have to retype the script names in several places. But it would be nice to get this to work. Don't think I've ever tried to PUT an array of fixed-length strings before.

Open for Random was made for Fixed length Records, but Steve may tell you how to do it with Binary.

If try to do it Unary, you might go blind.

Is STRING * 64 not fixed length? I was getting the variable length error before compiling, so I changed from variable length string to fixed.

Yes string * n is fixed, did it help?

You wanna try one big long string?

Quote

Yes string * n is fixed, did it help?

I was already using string * n at the start of this thread, that's the whole point. The compiler is failing despite that.

Random so much easier to use for fixed length stuff

Code: QB64: [Select]

_TITLE "Bplus Gets Random" 'B+ 2021-02-26
OPEN "bplus.txt" FOR RANDOM AS #1 LEN = 64
REDIM bplus AS STRING * 64
FOR i = 1 TO 100
    B$ = "B"
    FOR j = 1 TO i
        MID$(bplus, j, 1) = "B"
    NEXT
    FOR j = i + 1 TO 64
        MID$(bplus, j, 1) = "+"
    NEXT
    PUT #1, i, bplus
NEXT
 
DO
    'r = INT(RND * 100) + 1
    r = r + 1
    IF r > 100 THEN r = 1
    GET #1, r, bplus
    PRINT bplus
    _LIMIT 30
LOOP UNTIL _KEYDOWN(27)
CLOSE
SYSTEM
 
 

Can you share the code that fails? Or a simplified demonstration of the problem. It’s hard to debug without something to test.

EDIT: Tested the following code -- it does, indeed, give a C++ compilation failure, as you describe.

Code: QB64: [Select]

DIM test(100) AS STRING * 64
OPEN "temp.txt" FOR BINARY AS #1
PUT #1, , test()
CLOSE
 

This used to work, at one time in the past, I think, but it doesn't currently. Someone will probably need to look into it when they have time.

EDIT 2: For now, I'd use the following as a quick and easy method for a workaround:

Code: QB64: [Select]

DIM test(100) AS STRING * 64
DIM m AS _MEM: m = _MEM(test())
temp$ = SPACE$(m.SIZE)
_MEMGET m, m.OFFSET, temp$
 
OPEN "temp.txt" FOR BINARY AS #1
PUT #1, , temp$
CLOSE
 
_MEMFREE m: temp$ = ""
 
 

Yeah I got same crappy message from same kind of test, I'm tell'n ya Random is easier.

Just pick your line number and get it, Plus it actually works!

Quote from: bplus on February 27, 2021, 01:21:15 am

Yeah I got same crappy message from same kind of test, I'm tell'n ya Random is easier.

Just pick your line number and get it, Plus it actually works!

Binary works too, if you GET/PUT a single record at a time like with RANDOM. The glitch comes when trying to put the whole array at once.

Code: QB64: [Select]

DIM test(100) AS STRING * 64
 
OPEN "temp.txt" FOR BINARY AS #1
FOR i = 0 TO 100
    PUT #1, , test(i)
NEXT
CLOSE
 
[/code

There is a way. Evidently it is doable in C but here is what I found

Code: QB64: [Select]

DIM A(100) AS STRING * 64
 
PRINT LEN(A())        
DIM B AS _OFFSET
 
 
B = _OFFSET(A(0))
PRINT B
 
B = _OFFSET(A(1))
PRINT B
 
B = _OFFSET(A(2))
PRINT B

Notice that the array elements are contiguous in memory.

The address of A(0) is known so that must be the start of the arrray's memory block. So how do we write to that memory block?

Size of memory block is fixed at 6464 bytes

fghsh

Quote

Binary works too, if you GET/PUT a single record at a time like with RANDOM. The glitch comes when trying to put the whole array at once.

Thanks, tried that and it worked. Guess I'm 2 for 2 now, on finding QB64 bugs!

Here's the full code, in case you're still interested. It's a script editor for my main game project, to cut down on the math I've been having to do by hand. Line 77 has the fixed string declaration, lines 219 and 236 have the get/put of the array, which I have now enclosed in a for loop.

Code: QB64: [Select]

const true = -1
const false = 0
 
const screenw = 800
const screenh = 600
const hud_top = 513
dim shared fullscreen as _unsigned long
fullscreen = _newimage(screenw, screenh, 32)
screen fullscreen
 
_source fullscreen ' Prevent handles from ever being null
_dest   fullscreen
 
type coordinate_dec ' for stage-wide position coordinates, needs to handle large values with decimals
   x as double
   y as double
end type
type coordinate_int
   x as integer
   y as integer
end type
 
dim shared hue(6) as _unsigned long
const hue_transparent = 0
hue(hue_transparent) = _rgba32(  0,   0,   0,   0)
const hue_black      = 1
hue(hue_black)       = _rgba32(  0,   0,   0, 255)
const hue_white      = 2
hue(hue_white)       = _rgba32(255, 255, 255, 255)
const hue_red        = 3
hue(hue_red)         = _rgba32(255,   0,   0, 255) ' Only used for enemy health bars
const hue_green      = 4
hue(hue_green)       = _rgba32(  0, 255,   0, 255) ' Only used in debug menu
const hue_dkblue     = 5
hue(hue_dkblue)      = _rgba32(  0,  74, 149, 223) ' Windows
const hue_ltblue     = 6
hue(hue_ltblue)      = _rgba32(  0, 124, 249, 255)
 
color hue(hue_black), hue(hue_white)
 
const up    = 1
const down  = 2
const left  = 3
const right = 4
dim shared arrow(4) as string * 2
arrow(up)    = chr$(0) + chr$(72)
arrow(right) = chr$(0) + chr$(77)
arrow(down)  = chr$(0) + chr$(80)
arrow(left)  = chr$(0) + chr$(75)
 
const aim_e  = 0
const aim_se = 1 * atn(1)
const aim_s  = 2 * atn(1)
const aim_sw = 3 * atn(1)
const aim_w  = 4 * atn(1)
const aim_nw = 5 * atn(1)
const aim_n  = 6 * atn(1)
const aim_ne = 7 * atn(1)
 
const script_limit = 100
 
type movescript_structure
   angle       as single
   speed       as single
   angle_abs   as _byte   ' true overwrites previous angle, false adds to it, false by default
   speed_abs   as _byte   ' true overwrites previous speed, false adds to it, false by default
 
   ' Vector addition
   accel_abs_a as single  ' "Absolute" - added vector related to basis angle
   accel_abs_v as single     ' Magnitude of absolute vector
   accel_rel_a as single  ' "Relative" - added vector relative to current angle
   accel_rel_v as single     ' Magnitude of relative vector
 
   length      as integer ' duration of script in frames
end type
dim shared ms(script_limit) as movescript_structure
dim shared ms_name(script_limit) as string * 64
dim shared mss$(script_limit) ' Preview of what script contains
dim shared ms_count as _byte
 
type entity_structure
   pos      as coordinate_dec ' Position relative to stage, not screen
   angle    as single         ' Angle of movement, or angle of normal aim for a weapon
   speed    as single         ' Pixels of movement per frame
 
   ' Vector addition
   accel_abs_a as single  ' Absolute angle - relative to standard angles
   accel_abs_v as single  '    Magnitude
   accel_rel_a as single  ' Relative angle - added to current angle
   accel_rel_v as single  '    Magnitude
 
   size as coordinate_int
end type
dim shared entity as entity_structure
entity.size.x = 20
entity.size.y = 15
 
dim shared start as coordinate_dec
start.x = -600
start.y = 0
 
ms_count = 0
 
 
 
 
 
c = 1
 
do
   _limit 60
   cls , hue(hue_white)
   locate 1, 3: print "Options"
   locate 2, 3: print "Start:"; start.x; ","; start.y
   for n = 1 to ms_count
      locate n + 2, 3: print trim$(n); " "; mss$(n)
   next n
   locate c, 1: print ">"
   _display
 
   k$ = inkey$
 
   if k$ = arrow(down) then c = wrap(c + 1, 1, ms_count + 2)
   if k$ = arrow(up)   then c = wrap(c - 1, 1, ms_count + 2)
 
   if k$ = chr$(13) then
      select case c
         case 1: call option_menu
         case 2
            call clear_row(c)
            locate 2, 3: input "Start x: ", start.x
            call clear_row(c)
            locate 2, 3: input "Start y: ", start.y
         case else: call edit_script(c - 2)
      end select
   end if
 
   if k$ = "-" then ms_count = plus_limit(ms_count, -1, 0)
   if k$ = "=" then
      ms_count = plus_limit(ms_count,  1, script_limit)
      call get_mss(ms_count)
   end if
 
   if k$ = " " then call run_scripts
 
   if k$ = chr$(27) then
      locate 1, 20: print "Enter to exit, any other key to cancel"
      do
         _limit 60
         _display
         k$ = inkey$
         if k$ = chr$(13) then system
      loop while k$ = ""
   end if
loop
 
 
 
 
 
sub option_menu
 
c = 1
 
do
   _limit 60
   cls , hue(hue_white)
   locate 1, 3: print "Entity width: "; entity.size.x
   locate 2, 3: print "Entity height:"; entity.size.y
   locate 3, 3: print "Save to file"
   locate 4, 3: print "Load from file"
   locate 5, 3: print "Export to code"
   locate c, 1: print ">"
   line(100, 100)-step(entity.size.x, entity.size.y), hue(hue_black), b
   _display
 
   k$ = inkey$
 
   if k$ = arrow(down) then c = wrap(c + 1, 1, 5)
   if k$ = arrow(up)   then c = wrap(c - 1, 1, 5)
 
   d = 0
   if k$ = arrow(left)  or k$ = "-" then d = -1
   if k$ = arrow(right) or k$ = "=" then d =  1
 
   if c = 1 then entity.size.x = wrap(entity.size.x + d, 2, 100)
   if c = 2 then entity.size.y = wrap(entity.size.y + d, 2, 100)
 
   if k$ = chr$(13) and c = 3 then
      input "Save filename: ", f$
      call save_file(f$)
   end if
 
   if k$ = chr$(13) and c = 4 then
      input "Load filename: ", f$
      call load_file(f$)
   end if
 
   if k$ = chr$(13) and c = 5 then
      input "Export filename: ", f$
      call export_code(f$)
   end if
 
loop until k$ = chr$(27)
 
end sub
 
 
sub save_file(f$)
 
open f$ for binary as #1
put #1, 1, entity.size.x
put #1, , entity.size.y
put #1, , start.x
put #1, , start.y
put #1, , ms_count
put #1, , ms()
for s = 1 to script_limit
   put #1, , ms_name(s)
next s
close #1
 
end sub
 
 
sub load_file(f$)
 
open f$ for binary as #1
get #1, 1, entity.size.x
get #1, , entity.size.y
get #1, , start.x
get #1, , start.y
get #1, , ms_count
get #1, , ms()
for s = 1 to script_limit
   get #1, , ms_name(s)
next s
close #1
 
for s = 1 to ms_count
   call get_mss(s)
next s
 
end sub
 
 
sub edit_script(s)
 
c = 1
 
do
   _limit 60
   cls , hue(hue_white)
   locate 1, 3: print "Name     :"; crop$(ms_name(s))
   locate 2, 3: print "Angle    :"; ms(s).angle;
      if ms(s).angle_abs = false then print "(Rel)" else print
   locate 3, 3: print "Speed    :"; ms(s).speed;
      if ms(s).speed_abs = false then print "(Rel)" else print
   locate 4, 3: print "Length   :"; int(ms(s).length / 60); "."; trim$(ms(s).length mod 60)
   locate 5, 3: print "Abs acc a:"; ms(s).accel_abs_a
   locate 6, 3: print "Abs acc v:"; ms(s).accel_abs_v
   locate 7, 3: print "Rel acc a:"; ms(s).accel_rel_a
   locate 8, 3: print "Rel acc v:"; ms(s).accel_rel_v
   locate c, 1: print ">"
   _display
 
   k$ = inkey$
 
   if k$ = arrow(down) then c = wrap(c + 1, 1, 8)
   if k$ = arrow(up)   then c = wrap(c - 1, 1, 8)
 
   if k$ = "r" and c = 2 then ms(s).angle_abs = toggle(ms(s).angle_abs, true, false)
   if k$ = "r" and c = 3 then ms(s).speed_abs = toggle(ms(s).speed_abs, true, false)
 
   if k$ = chr$(27) then exit do
 
   if k$ = chr$(13) then
      select case c
         case 1
            call clear_row(c)
            locate c, 3: input "Name     : ", t$
            for n = 1 to len(ms_name(s))
               mid$(ms_name(s), l) = " "
            next n
            mid$(ms_name(s), 1) = t$
         case 2
            call clear_row(c)
            locate 9, 3: print "Shortcuts: up, down, left, right, n, s, w, e, nw, ne, sw, se"
            locate c, 3: input "Angle    : ", a$
            ms(s).angle = angle_shortcut(a$)
         case 3
            call clear_row(c)
            locate c, 3: input "Speed    : ", ms(s).speed
         case 4
            call clear_row(c)
            locate c, 3: input "Length   : ", l
            ms(s).length = frames(l)
         case 5
            call clear_row(c)
            locate 9, 3: print "Shortcuts: up, down, left, right, n, s, w, e, nw, ne, sw, se"
            locate c, 3: input "Abs acc a: ", a$
            ms(s).accel_abs_a = angle_shortcut(a$)
         case 6
            call clear_row(c)
            locate c, 3: input "Abs acc v: ", ms(s).accel_abs_v
            if ms(s).accel_abs_v <> 0 then
               ms(s).accel_rel_a = 0
               ms(s).accel_rel_v = 0
            end if
         case 7
            call clear_row(c)
            locate 9, 3: print "Shortcuts: up, down, left, right, n, s, w, e, nw, ne, sw, se"
            locate c, 3: input "Rel acc a: ", a$
            ms(s).accel_rel_a = angle_shortcut(a$)
         case 8
            call clear_row(c)
            locate c, 3: input "Rel acc v: ", ms(s).accel_rel_v
            if ms(s).accel_rel_v <> 0 then
               ms(s).accel_abs_a = 0
               ms(s).accel_abs_v = 0
            end if
      end select
   end if
loop
 
call get_mss(s)
 
end sub
 
 
sub run_scripts
 
entity.pos.x = start.x
entity.pos.y = start.y
 
entity.angle = 0
entity.speed = 0
 
entity.accel_abs_a = 0
entity.accel_abs_v = 0
entity.accel_rel_a = 0
entity.accel_rel_v = 0
 
cls , hue(hue_white)
 
for s = 1 to ms_count
 
   ' Execute script
 
   entity.angle = wrap_a(entity.angle + ms(s).angle)
   if ms(s).angle_abs = true then entity.angle = ms(s).angle
   entity.speed = entity.speed + ms(s).speed
   if ms(s).speed_abs = true then entity.speed = ms(s).speed
 
   entity.accel_abs_a = ms(s).accel_abs_a
   entity.accel_abs_v = ms(s).accel_abs_v
 
   if ms(s).accel_rel_v <> 0 then
      a = entity.angle
      entity.accel_abs_a = wrap_a(a + ms(s).accel_rel_a)
      entity.accel_abs_v = ms(s).accel_rel_v
   end if
 
   for f = 1 to ms(s).length
      _limit 60
 
      line(entity.pos.x, entity.pos.y)-step(entity.size.x, entity.size.y), hue(hue_ltblue), b
 
      ' ----- Update position -----
 
      entity.pos.x = entity.pos.x + vector_x(entity.angle, entity.speed)
      entity.pos.y = entity.pos.y + vector_y(entity.angle, entity.speed)
 
      ' ----- Acceleration -----
 
      ' Get vector to be added
      if entity.accel_rel_v <> 0 then
         a = entity.angle
         a = wrap_a(a + entity.accel_rel_a)
         v = entity.accel_rel_v
      end if
      ' Absolute overrides relative
      if entity.accel_abs_v <> 0 then
         a = entity.accel_abs_a
         v = entity.accel_abs_v
      end if
 
      ' Add vector to entity
      if entity.accel_rel_v <> 0 or entity.accel_abs_v <> 0 then
         x = vector_x(entity.angle, entity.speed) + vector_x(a, v)
         y = vector_y(entity.angle, entity.speed) + vector_y(a, v)
         entity.angle = arctan(y, x)
         entity.speed = hypo(x, y)
      end if
 
      line(entity.pos.x, entity.pos.y)-step(entity.size.x, entity.size.y), hue(hue_black), b
      _display
 
      k$ = inkey$
 
      if k$ = chr$(27) then exit sub
   next f
next s
 
do
   _limit 60
   _display
   k$ = inkey$
loop until k$ = chr$(27)
 
end sub
 
 
function shorten_dec$(n)
shorten_dec$ = left$(trim$(n), 6)
end function
 
 
function trim$(n)
trim$ = mid$(str$(n), 2)
end function
 
 
sub clear_row(n)
locate n, 1
print "                                                                      "
end sub
 
 
function toggle(v, p, q)
if v = p then toggle = q
if v = q then toggle = p
end function
 
 
function frames(s)
' Pass in a decimal in seconds.frames, returns integer frames
f = int(s) * 60
frames = int(f + ((s - int(s)) * 100))
end function
 
 
function wrap(n, l1, h1)
' n is adjusted back within lower(l) and upper(h) bounds similar to mod operator
l = l1: h = h1 ' make sure h is never less than l, this also prevents division by zero
if h1 < l1 then
   l = h1: h = l1
end if
x = (l - n) / ((h - l) + 1)
if x <> int(x) then x = x + 1
wrap = n + (int(x) * ((h - l) + 1))
end function
 
 
function wrap_a(a)
' angle a is adjusted back within 0 and 2pi, 2pi noninclusive
x = -a / atn1(8)
if x <> int(x) then x = x + 1
wrap_a = a + (int(x) * atn1(8))
end function
 
 
function vector_x(a, v)
vector_x = 0
if a = aim_n or a = aim_s then exit function ' Protect against undefined cos()
vector_x = v * cos(a)
end function
function vector_y(a, v)
vector_y = 0
if a = aim_w or a = aim_e then exit function ' Protect against undefined sin()
vector_y = v * sin(a)
end function
 
 
function hypo(a, b)
hypo = sqr(sq(a) + sq(b))
end function
 
 
function arctan(y, x)
arctan = 0
if x = 0 and y = 0 then exit function
a = atn1(2)
if x <> 0 then ' prevent division by zero
   a = abs(atn(y / x))
   if x < 0 then a = atn1(4) - a
end if
if y < 0 then a = flip_y(a)
arctan = a
end function
 
 
function angle_shortcut(a$)
 
select case a$
   case "e":  angle_shortcut = aim_e
   case "se": angle_shortcut = aim_se
   case "s":  angle_shortcut = aim_s
   case "sw": angle_shortcut = aim_sw
   case "w":  angle_shortcut = aim_w
   case "nw": angle_shortcut = aim_nw
   case "n":  angle_shortcut = aim_n
   case "ne": angle_shortcut = aim_ne
   case else: angle_shortcut = val(a$)
end select
 
end function
 
 
function plus_limit(n, p, l)
q = n + p
if sgn(q - l) = sgn(p) then q = l
plus_limit = q
end function
 
 
function half(n)
half = n * 0.5
end function
 
 
sub get_mss(s)
 
mss$(s) = "'" + crop$(ms_name(s)) + "' L: " + trim$(ms(s).length)
 
mss$(s) = mss$(s) + " a:" + string_angle$(ms(s).angle)
   if ms(s).angle_abs = false then mss$(s) = mss$(s) + "(r)"
 
mss$(s) = mss$(s) + " v:" + trim$(ms(s).speed)
   if ms(s).speed_abs = false then mss$(s) = mss$(s) + "(r)"
 
if ms(s).accel_abs_v <> 0 then mss$(s) = mss$(s) + " abs a:" + string_angle$(ms(s).accel_abs_a) + " v: " + trim$(ms(s).accel_abs_v)
if ms(s).accel_rel_v <> 0 then mss$(s) = mss$(s) + " rel a:" + string_angle$(ms(s).accel_rel_a) + " v: " + trim$(ms(s).accel_rel_v)
 
end sub
 
 
function string_angle$(a)
 
string_angle$ = shorten_dec$(a)
 
select case a
   case aim_e:  string_angle$ = "aim_e"
   case aim_se: string_angle$ = "aim_se"
   case aim_s:  string_angle$ = "aim_s"
   case aim_sw: string_angle$ = "aim_sw"
   case aim_w:  string_angle$ = "aim_w"
   case aim_nw: string_angle$ = "aim_nw"
   case aim_n:  string_angle$ = "aim_n"
   case aim_ne: string_angle$ = "aim_ne"
end select
 
end function
 
 
sub export_code(f$)
 
open f$ for output as #1
 
for s = 1 to ms_count
   print #1, "   msd.angle       = "; string_angle$(ms(s).angle)
   if ms(s).angle_abs = true then print #1, "   msd.angle_abs   = true"
   print #1, "   msd.speed       = "; trim$(ms(s).speed)
   if ms(s).speed_abs = true then print #1, "   msd.speed_abs   = true"
 
   if ms(s).accel_abs_v <> 0 then
      print #1, "   msd.accel_abs_a = "; string_angle$(ms(s).accel_abs_a)
      print #1, "   msd.accel_abs_v = "; trim$(ms(s).accel_abs_v)
   end if
 
   if ms(s).accel_rel_v <> 0 then
      print #1, "   msd.accel_rel_a = "; string_angle$(ms(s).accel_rel_a)
      print #1, "   msd.accel_rel_v = "; trim$(ms(s).accel_rel_v)
   end if
 
   sc$ = trim$(int(ms(s).length / 60))
   fr$ = trim$(ms(s).length mod 60)
   print #1, "   msd.length      = frames("; sc$; "."; fr$; ")"
 
   if s <> ms_count then
      print #1, "   msd.next_script = "; crop$(ms_name(s + 1))
   end if
 
   print #1, "call set_movescript("; crop$(ms_name(s)); ")"
   print #1, "   call clear_msd"
   print
next s
 
close #1
 
end sub
 
 
function crop$(t$)
p = instr(t$, " ")
crop$ = left$(t$, p - 1)
end function
 

I've pinpointed the issue in our code, but I have no clue how the heck to implement any fixes in the source for this yet...

Here's a simple little QB64 program for illustration purposes:

Code: QB64: [Select]

$CHECKING:OFF
DIM b(100) AS _BYTE
DIM s(100) AS STRING * 1
FOR i = 1 TO 100
    b(i) = i
    s(i) = CHR$(i)
NEXT
OPEN "temp.txt" FOR BINARY AS #1
PUT #1, , b()
PUT #1, , s()

Now, this produces code with the glitch in it for us, which looks like this:

Code: C++: [Select]

S_0:;
 
 
fornext_value2= 1 ;
fornext_finalvalue2= 100 ;
fornext_step2= 1 ;
if (fornext_step2<0) fornext_step_negative2=1; else fornext_step_negative2=0;
if (new_error) goto fornext_error2;
goto fornext_entrylabel2;
while(1){
fornext_value2=fornext_step2+(*__SINGLE_I);
fornext_entrylabel2:
*__SINGLE_I=fornext_value2;
if (fornext_step_negative2){
if (fornext_value2<fornext_finalvalue2) break;
}else{
if (fornext_value2>fornext_finalvalue2) break;
}
fornext_error2:;
tmp_long=(qbr(*__SINGLE_I))-__ARRAY_BYTE_B[4];
if (!new_error) ((int8*)(__ARRAY_BYTE_B[0]))[tmp_long]=qbr_float_to_long(*__SINGLE_I);
tmp_long=(qbr(*__SINGLE_I))-__ARRAY_STRING1_S[4];
if (!new_error) qbs_set(qbs_new_fixed(&((uint8*)(__ARRAY_STRING1_S[0]))[tmp_long*1],1,1),func_chr(qbr(*__SINGLE_I)));
qbs_cleanup(qbs_tmp_base,0);
fornext_continue_1:;
}
fornext_exit_1:;
sub_open(qbs_new_txt_len("temp.txt",8), 2 ,NULL,NULL, 1 ,NULL,0);
qbs_cleanup(qbs_tmp_base,0);
sub_put( 1 ,NULL,byte_element((uint64)(&(((int8*)(__ARRAY_BYTE_B[0]))[0])),(1*(__ARRAY_BYTE_B[2]&1)*__ARRAY_BYTE_B[5])-(1*(0)),byte_element_3),0);
//sub_put( 1 ,NULL,byte_element((uint64)(&(qbs_new_fixed(&((uint8*)(__ARRAY_STRING1_S[0]))[(0)*1],1,1))),(1*(__ARRAY_STRING1_S[2]&1)*__ARRAY_STRING1_S[5])-(1*(0)),byte_element_4),0);
sub_put( 1 ,NULL,byte_element((uint64)(&(((uint8*)(__ARRAY_STRING1_S[0]))[(0)*1])),(1*(__ARRAY_STRING1_S[2]&1)*__ARRAY_STRING1_S[5])-(1*(0)),byte_element_4),0);
qbs_cleanup(qbs_tmp_base,0);
sub_end();
return;
}
 

Now, you might notice that there's a line already commented out for us above -- that's the line that's producing the glitch for us. Let me grab it and the line above it and below it to highlight the issue...

Here's the line above it, which works for _BYTE arrays:
sub_put( 1 ,NULL,byte_element((uint64)(&(((int8*)(__ARRAY_BYTE_B[0]))[0])),(1*(__ARRAY_BYTE_B[2]&1)*__ARRAY_BYTE_B[5])-(1*(0)),byte_element_3),0);

And here's our problem line, as we're currently translating it:
sub_put( 1 ,NULL,byte_element((uint64)(&(qbs_new_fixed(&((uint8*)(__ARRAY_STRING1_S[0]))[(0)*1],1,1))),(1*(__ARRAY_STRING1_S[2]&1)*__ARRAY_STRING1_S[5])-(1*(0)),byte_element_4),0);

And, if we change it to match the previous syntax, it works as it should for us with:
sub_put( 1 ,NULL,byte_element((uint64)(&(((uint8*)(__ARRAY_STRING1_S[0]))[(0)*1])),(1*(__ARRAY_STRING1_S[2]&1)*__ARRAY_STRING1_S[5])-(1*(0)),byte_element_4),0);

The issue is in the colored sections which I'll highlight here, which really don't seem to be needed at all in the code:
sub_put( 1 ,NULL,byte_element((uint64)(&(qbs_new_fixed(&((uint8*)(__ARRAY_STRING1_S[0]))[(0)*1],1,1))),(1*(__ARRAY_STRING1_S[2]&1)*__ARRAY_STRING1_S[5])-(1*(0)),byte_element_4),0);

If someone can find the segment in our source (QB64.BAS, I'd imagine) that's adding the section above to our output, and we can remove it, I think the issue will disappear for us. Unfortunately, as you can tell from the code above, the source for this translation is kinda a mess, and so far, I haven't been able to locate the line(s) that are producing this extra, unneeded information for us.

I think I've zoomed in and found the problem, but I'm still looking for where the shooting range is, before I can even take a shot at fixing the glitch itself. :P

And for those that want to test the fix for themselves, you can manually go into main.txt and make the changes to your own code, and then run recompile.bat to create an EXE which works without issue while putting a whole string * 1 array to file.

In QB64.bas, lines 14154 - 14168

Code: QB64: [Select]

            If cmemlist(idn + 1) Then
                id.t = id.t + ISINCONVENTIONALMEMORY
                If f Then Print #13, "if(" + n$ + "==NULL){"
                If f Then Print #13, "cmem_sp-=" + str2(bytes) + ";"
                If f Then Print #13, "if (cmem_sp<qbs_cmem_sp) error(257);"
                If f Then Print #13, n$ + "=qbs_new_fixed((uint8*)(dblock+cmem_sp)," + str2(bytes) + ",0);"
                If f Then Print #13, "memset(" + n$ + "->chr,0," + str2(bytes) + ");"
                If f Then Print #13, "}"
            Else
                If f Then Print #13, "if(" + n$ + "==NULL){"
                o$ = "(uint8*)mem_static_malloc(" + str2$(bytes) + ")"
                If f Then Print #13, n$ + "=qbs_new_fixed(" + o$ + "," + str2$(bytes) + ",0);"
                If f Then Print #13, "memset(" + n$ + "->chr,0," + str2$(bytes) + ");"
                If f Then Print #13, "}"
            End If

Dug a little deeper into this issue -- it's a problem which is a little beyond my pay grade.

Down around line 24800 in FUNCTION refer$, you'll see this bit of code:

Code: QB64: [Select]

        IF (typ AND ISSTRING) THEN
            IF (typ AND ISFIXEDLENGTH) THEN

IF we change what's after that to the following, we then have GET and PUT working properly with fixed length strings:

Code: [Select]

                offset$ = "((uint8*)(" + n$ + "[0]))[(" + a$ + ")*" + str2(id.tsize) + "]"
                r$ = offset$

The problem with this, however, is that we then end up breaking other things, where we reference the array by individual elements. Stuff like array(1) = "H" will give us the c++ compilation failure.

Seems to me that we need two different outputs here -- one for when the array is indexed (X(1), for example) vs one for the whole array (which would be X(), from the previous example).

I'm not proficient enough in c to sort out exactly what has to be done to get this to work in both cases here, so I'll pass off the baton at this point and leave it up to someone else to carry us over the finish line.

I can make GET/PUT work, *OR* I can have arrays work with indexes (as it currently exists), but I can't make it do both. :P

Related to this thread.

Quote

DIM X AS INTEGER
DIM B(3) AS STRING * 1

B() = "ABCD"

FOR X = 0 TO 3

PRINT B(X)

NEXT X

So the compiler is saying that B() = B(0) ???

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: johannhowitzer on February 26, 2021, 04:31:26 pm