Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: SMcNeill on February 17, 2021, 10:46:20 am

Title: QPrint (falcon.h simplified)
Post by: SMcNeill on February 17, 2021, 10:46:20 am
There's several programs out there that make use of falcon.h by now, but I wanted to take a shot at tossing in my own personal version of a simplified wrapper for the command -- QPRINT.

Code: QB64: [Select]
  1. DECLARE LIBRARY "falcon"
  2.     SUB uprint_extra (BYVAL x&, BYVAL y&, BYVAL chars%&, BYVAL length%&, BYVAL kern&, BYVAL do_render&, txt_width&, BYVAL charpos%&, charcount&, BYVAL colour~&, BYVAL max_width&)
  3.     FUNCTION uprint (BYVAL x&, BYVAL y&, chars$, BYVAL txt_len&, BYVAL colour~&, BYVAL max_width&)
  4.     FUNCTION uprintwidth (chars$, BYVAL txt_len&, BYVAL max_width&)
  5.     FUNCTION uheight& ()
  6.     FUNCTION uspacing& ()
  7.     FUNCTION uascension& ()
  9.  
  10. SCREEN _NEWIMAGE(640, 480, 32)
  11. _FONT _LOADFONT("cyberbit.ttf", 20)
  12.  
  13. LOCATE 1, 100
  14. QPrint "This is a whole bunch of crap." + CHR$(10) + "What happens to my crap, when there's too much crap to be printed on the screen, as I told it to be?  Will it wrap, or be truncated? Or what the heck will happen to my text when I have a crapload of it to print to the screen?"
  15. SLEEP: QPrint "And what happens if I follow up with another line of crap?  Will it print below the other as it should, or is my positioning all wrong?"
  16. SLEEP: QPrint "This is a whole bunch of crap.  What happens to my crap, when there's too much crap to be printed on the screen, as I told it to be?  Will it wrap, or be truncated? Or what the heck will happen to my text when I have a crapload of it to print to the screen?"
  17. SLEEP: QPrint "And what happens if I follow up with another line of crap?  Will it print below the other as it should, or is my positioning all wrong?"
  18. SLEEP: QPrint "This is a whole bunch of crap.  What happens to my crap, when there's too much crap to be printed on the screen, as I told it to be?  Will it wrap, or be truncated? Or what the heck will happen to my text when I have a crapload of it to print to the screen?"
  19. SLEEP: QPrint "And what happens if I follow up with another line of crap?  Will it print below the other as it should, or is my positioning all wrong?"
  20. SLEEP: QPrint "This is a whole bunch of crap.  What happens to my crap, when there's too much crap to be printed on the screen, as I told it to be?  Will it wrap, or be truncated? Or what the heck will happen to my text when I have a crapload of it to print to the screen?"
  21. SLEEP: QPrint "And what happens if I follow up with another line of crap?  Will it print below the other as it should, or is my positioning all wrong?"
  24.  
  25. QPrint "This is a whole bunch of crap.  What happens to my crap, when there's too much crap to be printed on the screen, as I told it to be?  Will it wrap, or be truncated? Or what the heck will happen to my text when I have a crapload of it to print to the screen?"
  26. QPrint "And what happens if I follow up with another line of crap?  Will it print below the other as it should, or is my positioning all wrong?"
  27.  
  28.  
  29. LOCATE 7, 1
  30. COLOR _RGB32(255, 255, 0), _RGB32(0, 0, 255) 'Yellow on Blue
  31. QPrint "Foo"
  32. COLOR _RGB32(255, 0, 0) 'Red
  33. QPrint "Bar"
  34. COLOR _RGB32(0, 255, 0) ' Green
  35. LOCATE 15, 1: PRINT "(For comparison, a normal PRINT statement)  ";
  36.  
  37. PRINT "This is a whole bunch of crap.  What happens to my crap, when there's too much crap to be printed on the screen, as I told it to be?  Will it wrap, or be truncated? Or what the heck will happen to my text when I have a crapload of it to print to the screen?"
  38.  
  39. COLOR _RGB(255, 0, 0), 0 '_RGB32(0, 0, 0)
  40. FOR i = 1 TO 15
  41.     SLEEP
  42.     LOCATE i, 1
  43.     QPrint STR$(i) + "To showcase locate at work with p's and q's and t's"
  45.  
  46.  
  47. SUB QPrint (temp$)
  48.     STATIC m AS _MEM: m = _MEMIMAGE(0)
  49.     DIM BreakPoint AS STRING
  50.     BreakPoint = ",./- ;:!" 'I consider all these to be valid breakpoints.  If you want something else, change them.
  51.     text$ = _TRIM$(temp$)
  52.     count = -1
  53.     DO
  54.         'first find the natural length of the line
  55.         x = POS(0): IF _FONTWIDTH THEN x = x * _FONTWIDTH
  56.         y = CSRLIN
  57.         wide% = _WIDTH - x - 1
  58.         FOR i = 1 TO LEN(text$)
  59.             IF ASC(text$, i) = 10 OR ASC(text$, i) = 13 THEN i = i - 1: EXIT FOR
  60.             p = uprintwidth(text$, i, 0)
  61.             IF p > wide% THEN EXIT FOR
  62.         NEXT
  63.         'IF i < LEN(text$) THEN lineend = i - 1 ELSE
  64.         lineend = i
  65.  
  66.         t$ = RTRIM$(LEFT$(text$, lineend)) 'at most, our line can't be any longer than what fits the screen.
  67.         FOR i = lineend TO 1 STEP -1
  68.             IF INSTR(BreakPoint, MID$(text$, i, 1)) THEN lineend = i: EXIT FOR
  69.         NEXT
  70.         out$ = RTRIM$(LEFT$(text$, lineend))
  71.         text$ = LTRIM$(MID$(text$, lineend + 1))
  72.         IF LEFT$(text$, 2) = CHR$(13) + CHR$(10) THEN text$ = MID$(text$, 3)
  73.         IF LEFT$(text$, 2) = CHR$(10) + CHR$(13) THEN text$ = MID$(text$, 3)
  74.         IF LEFT$(text$, 1) = CHR$(13) THEN text$ = MID$(text$, 2)
  75.         IF LEFT$(text$, 1) = CHR$(10) THEN text$ = MID$(text$, 2)
  76.         IF _BACKGROUNDCOLOR <> 0 THEN
  77.             LINE (x - 1, (y - 1) * uheight)-STEP(uprintwidth(out$, LEN(out$), 0), uheight), _BACKGROUNDCOLOR, BF
  78.         END IF
  79.         w& = uprint(x - 1, (y - 1) * uheight, out$, LEN(out$), _DEFAULTCOLOR, 0)
  80.         x = 1
  81.         IF y + 1 >= _HEIGHT / uheight THEN 'scroll up
  82.             w = uheight * _WIDTH * 4
  83.             t$ = SPACE$(m.SIZE - w)
  84.             _MEMGET m, m.OFFSET + w, t$
  85.             CLS , 0
  86.             _MEMPUT m, m.OFFSET, t$
  87.             LOCATE y, x
  88.         ELSE
  89.             LOCATE y + 1, x
  90.         END IF
  91.  
  92.     LOOP UNTIL text$ = ""
  93.     clean_exit:
  95.  

Instead of trying to track all sorts of parameters for uprint  -- (x&, y&, chars$, txt_len&, colour~&, max_width&)  -- I've written a wrapper to break it down to one little command QPrint text$.

If you want colors, simply use QB64's normal COLOR command.  If you want to position your text, simply use LOCATE, like you normally would with your code.  It word wraps automatically, as well as scrolls the screen for us if we end up printing down on the bottom line of the screen.   Basically, use it more or less like you would a simplified PRINT statement that can only handle a single string output.

The advantage to this little command?  (And to falcon.h, in general?)

No cutting off parts of your characters.  Some fonts are terrible about having half the letter cut off (I was using a script font the other day that lost the whole top half of my T's and F's, and their flourishes.), and you should be able to see the difference and the problem with the example code, which relies on cyberbit.ttf. 

One thing of note here:  QB64 v1.4 comes with cyberbit.ttf packaged with it.  V1.5 (the latest development build) doesn't.  If you're running the latest development build, you may want to download the file below and toss it in your folder for testing purposes. 

NOTE 2:  QPrint's LOCATE and PRINT's LOCATE are two completely different areas of your screen.  Don't expect the two to match at all for you.   With the example, QPRINT is printing a character 26 pixels high, whereas PRINT cuts off segments of it and only prints a character 20 pixels high... That difference is going to naturally lead to the rows being at different heights, so don't expect to LOCATE y,x and then QPRINT, and then LOCATE y,x and PRINT, and have the numbers match up at all.
Title: Re: QPrint (falcon.h simplified)
Post by: SpriggsySpriggs on February 17, 2021, 10:57:09 am
Ooooo I shall save this for use when I decide to start making graphical applications again haha
Title: Re: QPrint (falcon.h simplified)
Post by: Pete on February 17, 2021, 12:45:07 pm
Quote from: SpriggsySpriggs on February 17, 2021, 10:57:09 am
Ooooo I shall save this for use when I decide to start making graphical applications again haha

Go to the dark side and leave SCREEN 0? No way!

Well I can finally say, I ran one of Steve's programs, and it was full of crap! :D :D :D

Next time, use foo. I think that's Latin for crap.

Pete

Title: Re: QPrint (falcon.h simplified)
Post by: SMcNeill on February 23, 2021, 07:44:57 pm
Now that I'm finally home and able to work on things once again, here's an updated version of QPrint, and a couple of screenshots showcasing it:

Code: QB64: [Select]
  1. $IF FALCON = UNDEFINED THEN
  2.     $LET FALCON = TRUE
  3.     DECLARE LIBRARY "falcon"
  4.         SUB uprint_extra (BYVAL x&, BYVAL y&, BYVAL chars%&, BYVAL length%&, BYVAL kern&, BYVAL do_render&, txt_width&, BYVAL charpos%&, charcount&, BYVAL colour~&, BYVAL max_width&)
  5.         FUNCTION uprint (BYVAL x&, BYVAL y&, chars$, BYVAL txt_len&, BYVAL colour~&, BYVAL max_width&)
  6.         FUNCTION uprintwidth (chars$, BYVAL txt_len&, BYVAL max_width&)
  7.         FUNCTION uheight& ()
  8.         FUNCTION uspacing& ()
  9.         FUNCTION uascension& ()
  10.     END DECLARE
  11.     DIM SHARED QPrintTextType AS STRING
  12.     QPrintTextType = "ASCII"
  14.  
  15.  
  16. SCREEN _NEWIMAGE(1024, 720, 32)
  17. _FONT _LOADFONT("cyberbit.ttf", 16, "monospace")
  18.  
  19. QPrintTextType = "UTF8"
  20.  
  21. OPEN "test.txt" FOR INPUT AS #1
  23.     LINE INPUT #1, temp$
  24.     QPrint temp$
  25.     SLEEP
  28.  
  29.  
  30. FOR y = 0 TO 15
  31.     FOR x = 0 TO 15
  32.         QPrintString x * 30, y * uheight, CHR$(count)
  33.         count = count + 1
  34.     NEXT
  37.  
  38. SUB QPrint (temp$)
  39.     STATIC m AS _MEM: m = _MEMIMAGE(0)
  40.     DIM BreakPoint AS STRING
  41.     BreakPoint = ",./- ;:!" 'I consider all these to be valid breakpoints.  If you want something else, change them.
  42.     IF QPrintTextType = "ASCII" OR QPrintTextType = "" THEN text$ = _TRIM$(AnsiTextToUtf8Text$(temp$)) ELSE text$ = temp$
  43.     count = -1
  44.     DO
  45.         'first find the natural length of the line
  46.         x = POS(0): IF _FONTWIDTH THEN x = x * _FONTWIDTH
  47.         y = CSRLIN
  48.         wide% = _WIDTH - x - 1
  49.         FOR i = 1 TO LEN(text$)
  50.             IF ASC(text$, i) = 10 OR ASC(text$, i) = 13 THEN i = i - 1: EXIT FOR
  51.             p = uprintwidth(text$, i, 0)
  52.             IF p > wide% THEN EXIT FOR
  53.         NEXT
  54.         'IF i < LEN(text$) THEN lineend = i - 1 ELSE
  55.         lineend = i
  56.  
  57.         t$ = RTRIM$(LEFT$(text$, lineend)) 'at most, our line can't be any longer than what fits the screen.
  58.         FOR i = lineend TO 1 STEP -1
  59.             IF INSTR(BreakPoint, MID$(text$, i, 1)) THEN lineend = i: EXIT FOR
  60.         NEXT
  61.         out$ = RTRIM$(LEFT$(text$, lineend))
  62.         text$ = LTRIM$(MID$(text$, lineend + 1))
  63.         IF LEFT$(text$, 2) = CHR$(13) + CHR$(10) THEN text$ = MID$(text$, 3)
  64.         IF LEFT$(text$, 2) = CHR$(10) + CHR$(13) THEN text$ = MID$(text$, 3)
  65.         IF LEFT$(text$, 1) = CHR$(13) THEN text$ = MID$(text$, 2)
  66.         IF LEFT$(text$, 1) = CHR$(10) THEN text$ = MID$(text$, 2)
  67.         IF _BACKGROUNDCOLOR <> 0 THEN
  68.             LINE (x - 1, (y - 1) * uheight)-STEP(uprintwidth(out$, LEN(out$), 0), uheight), _BACKGROUNDCOLOR, BF
  69.         END IF
  70.         w& = uprint(x - 1, (y - 1) * uheight, out$, LEN(out$), _DEFAULTCOLOR, 0)
  71.         x = 1
  72.         IF y + 1 >= _HEIGHT / uheight THEN 'scroll up
  73.             h = uheight * _WIDTH * 4
  74.             t$ = SPACE$(m.SIZE - h)
  75.             _MEMGET m, m.OFFSET + h, t$
  76.             CLS , 0
  77.             _MEMPUT m, m.OFFSET, t$
  78.             LOCATE y, x
  79.         ELSE
  80.             LOCATE y + 1, x
  81.         END IF
  82.  
  83.     LOOP UNTIL text$ = ""
  84.     clean_exit:
  86.  
  87. FUNCTION QPrintWidth& (out$)
  88.     QPrintWidth = uprintwidth(out$, LEN(out$), 0)
  90.  
  91. FUNCTION QFontHeight
  92.     QFontHeight = uheight
  94.  
  95. SUB QPrintString (x, y, text$)
  96.     IF QPrintTextType = "ASCII" OR QPrintTextType = "" THEN temp$ = _TRIM$(AnsiTextToUtf8Text$(text$)) ELSE temp$ = text$
  98.         LINE (x, y)-STEP(uprintwidth(temp$, LEN(temp$), 0), uheight), _BACKGROUNDCOLOR, BF
  99.     END IF
  100.     w& = uprint(x, y, temp$, LEN(temp$), _DEFAULTCOLOR, 0)
  102.  
  103. FUNCTION AnsiTextToUtf8Text$ (text$)
  104.     DIM chi&, ascii%, unicode&, aci%
  105.     FOR chi& = 1 TO LEN(text$)
  106.         '--- get ANSI char code, reset Unicode ---
  107.         unicode& = _MAPUNICODE(ASC(text$, chi&))
  108.         IF unicode& = 0 THEN unicode& = 65533 'replacement character
  109.         AnsiTextToUtf8Text$ = AnsiTextToUtf8Text$ + UnicodeToUtf8Char$(unicode&)
  110.     NEXT chi&
  112.  
  113. FUNCTION UnicodeToUtf8Char$ (unicode&)
  114.     '--- option _explicit requirements ---
  115.     DIM uc&, first%, remain%, conti%
  116.     '--- UTF-8 encoding ---
  117.     IF unicode& < 128 THEN
  118.         '--- standard ASCII (0-127) goes as is ---
  119.         UnicodeToUtf8Char$ = CHR$(unicode&)
  120.         EXIT FUNCTION
  121.     ELSE
  122.         '--- encode the Unicode into UTF-8 notation ---
  123.         UnicodeToUtf8Char$ = "": uc& = unicode& 'avoid argument side effect
  124.         first% = &B10000000: remain% = 63
  125.         DO
  126.             first% = &B10000000 OR (first% \ 2): remain% = (remain% \ 2)
  127.             conti% = &B10000000 OR (uc& AND &B00111111): uc& = uc& \ 64
  128.             UnicodeToUtf8Char$ = CHR$(conti%) + UnicodeToUtf8Char$
  129.             IF uc& <= remain% THEN
  130.                 first% = (first% OR uc&): uc& = 0
  131.             END IF
  132.         LOOP UNTIL uc& = 0
  133.         UnicodeToUtf8Char$ = CHR$(first%) + UnicodeToUtf8Char$
  134.     END IF
  136.  

  [ This attachment cannot be displayed inline in 'Print Page' view ]  

  [ This attachment cannot be displayed inline in 'Print Page' view ]  

Now, the first image above, is using QPrint to print Unicode (UTF-8) formatted text.  The image on the left is test.txt opened in Microsoft Word, and the image on the right is what we generate using QPrint.  As you can see, the font sizes and windows might be a little different resolution, but all the characters are displaying and matching properly for us.  We're printing valid unicode to the screen.

The second image, you guys might recognize as our ASCII chart.  It's the whole ASCII range of characters mapped over and converted from QB64's codepages over to UTF8 format, and then printed to the screen for us. 

By default, QPrint is set to print ASCII-code pages, but it can be converted to use UTF-8 code pages with a simple variable change:

QPrintTextType = "ASCII"  <-- This sets us to our default printing using the ASCII code page.  (Or just leave it blank as "" does the same.)

QPrintTextType = <ANYTHING ELSE> and we try to print it as UTF-8 formatted text. 

Change the global variable, change how you're printing...

It's now THAT simple to display UTF-8 code on to the screen.


NOTE:  To use QPrint, you have to load a custom font with it.  QB64's in-built fonts currently aren't working as you'd think they should with it, so be certain to load your own font.


Now all I need to do is tie these into my Extended Keyboard library, and add them to our functionality there, and we'll not only have a way to print the full UTF8 character set, but also a means to input from keyboards which use such extended keys.  (That is, after someone takes the time to map the proper keys to their specific keyboard layout.  At the moment, the library only supports US, German, Italian, and UK keyboard layouts, if I remember correctly.)

File test.txt is included below for those who'd like to test it for themselves.  ;)

Title: Re: QPrint (falcon.h simplified)
Post by: SMcNeill on October 29, 2021, 11:00:13 am
Code: QB64: [Select]
  1. $If FALCON = UNDEFINED Then
  2.     $Let FALCON = TRUE
  3.     Declare Library "./falcon"
  4.         Sub uprint_extra (ByVal x&, Byval y&, Byval chars%&, Byval length%&, Byval kern&, Byval do_render&, txt_width&, Byval charpos%&, charcount&, Byval colour~&, Byval max_width&)
  5.         Function uprint (ByVal x&, Byval y&, chars$, Byval txt_len&, Byval colour~&, Byval max_width&)
  6.         Function uprintwidth (chars$, Byval txt_len&, Byval max_width&)
  7.         Function uheight& ()
  8.         Function uspacing& ()
  9.         Function uascension& ()
  10.     End Declare
  11.     Dim Shared QPrintTextType As String
  12.     QPrintTextType = "ASCII"
  14.  
  15.  
  16. Screen _NewImage(1024, 720, 32)
  17. f = _LoadFont("cyberbit.ttf", 20, "monospace")
  19.  
  20.  
  21. QPrintTextType = "ASCII"
  22.  
  23.  
  24.  
  25. For y = 0 To 15
  26.     For x = 0 To 15
  27.         QPrintString x * 30, y * uheight, Chr$(count)
  28.         count = count + 1
  29.     Next
  32.  
  33. Sub QPrint (temp$)
  34.     Static m As _MEM: m = _MemImage(0)
  35.     Dim BreakPoint As String
  36.     BreakPoint = ",./- ;:!" 'I consider all these to be valid breakpoints.  If you want something else, change them.
  37.     If QPrintTextType = "ASCII" Or QPrintTextType = "" Then text$ = _Trim$(AnsiTextToUtf8Text$(temp$)) Else text$ = temp$
  38.     count = -1
  39.     Do
  40.         'first find the natural length of the line
  41.         x = Pos(0) - 1: If _FontWidth Then x = x * _FontWidth
  42.         y = CsrLin
  43.         wide% = _Width - x - 1
  44.         For i = 1 To Len(text$)
  45.             If Asc(text$, i) = 10 Or Asc(text$, i) = 13 Then i = i - 1: Exit For
  46.             p = uprintwidth(text$, i, 0)
  47.             If p > wide% Then Exit For
  48.         Next
  49.         'IF i < LEN(text$) THEN lineend = i - 1 ELSE
  50.         lineend = i
  51.  
  52.         t$ = RTrim$(Left$(text$, lineend)) 'at most, our line can't be any longer than what fits the screen.
  53.         For i = lineend To 1 Step -1
  54.             If InStr(BreakPoint, Mid$(text$, i, 1)) Then lineend = i: Exit For
  55.         Next
  56.         out$ = RTrim$(Left$(text$, lineend))
  57.         text$ = LTrim$(Mid$(text$, lineend + 1))
  58.         If Left$(text$, 2) = Chr$(13) + Chr$(10) Then text$ = Mid$(text$, 3)
  59.         If Left$(text$, 2) = Chr$(10) + Chr$(13) Then text$ = Mid$(text$, 3)
  60.         If Left$(text$, 1) = Chr$(13) Then text$ = Mid$(text$, 2)
  61.         If Left$(text$, 1) = Chr$(10) Then text$ = Mid$(text$, 2)
  62.         If _BackgroundColor <> 0 Then
  63.             Line (x - 1, (y - 1) * uheight)-Step(uprintwidth(out$, Len(out$), 0), uheight), _BackgroundColor, BF
  64.         End If
  65.         w& = uprint(x - 1, (y - 1) * uheight, out$, Len(out$), _DefaultColor, 0)
  66.         x = 1
  67.         If y + 1 >= _Height / uheight Then 'scroll up
  68.             h = uheight * _Width * 4
  69.             t$ = Space$(m.SIZE - h)
  70.             _MemGet m, m.OFFSET + h, t$
  71.             Cls , 0
  72.             _MemPut m, m.OFFSET, t$
  73.             Locate y, x
  74.         Else
  75.             Locate y + 1, x
  76.         End If
  77.  
  78.     Loop Until text$ = ""
  79.     clean_exit:
  81.  
  82. Function QPrintWidth& (out$)
  83.     QPrintWidth = uprintwidth(out$, Len(out$), 0)
  85.  
  86. Function QFontHeight
  87.     QFontHeight = uheight
  89.  
  90. Sub QPrintString (x, y, text$)
  91.     If QPrintTextType = "ASCII" Or QPrintTextType = "" Then temp$ = _Trim$(AnsiTextToUtf8Text$(text$)) Else temp$ = text$
  93.         Line (x, y)-Step(uprintwidth(temp$, Len(temp$), 0), uheight), _BackgroundColor, BF
  94.     End If
  95.     w& = uprint(x, y, temp$, Len(temp$), _DefaultColor, 0)
  97.  
  98. Function AnsiTextToUtf8Text$ (text$)
  99.     Dim chi&, ascii%, unicode&, aci%
  100.     For chi& = 1 To Len(text$)
  101.         '--- get ANSI char code, reset Unicode ---
  102.         unicode& = _MapUnicode(Asc(text$, chi&))
  103.         If unicode& = 0 Then unicode& = 65533 'replacement character
  104.         temp$ = temp$ + UnicodeToUtf8Char$(unicode&)
  105.     Next chi&
  106.     AnsiTextToUtf8Text$ = temp$
  108.  
  109. Function UnicodeToUtf8Char$ (unicode&)
  110.     '--- option _explicit requirements ---
  111.     Dim uc&, first%, remain%, conti%
  112.     '--- UTF-8 encoding ---
  113.     If unicode& < 128 Then
  114.         '--- standard ASCII (0-127) goes as is ---
  115.         UnicodeToUtf8Char$ = Chr$(unicode&)
  116.         Exit Function
  117.     Else
  118.         '--- encode the Unicode into UTF-8 notation ---
  119.         temp$ = "": uc& = unicode& 'avoid argument side effect
  120.         first% = &B10000000: remain% = 63
  121.         Do
  122.             first% = &B10000000 Or (first% \ 2): remain% = (remain% \ 2)
  123.             conti% = &B10000000 Or (uc& And &B00111111): uc& = uc& \ 64
  124.             temp$ = Chr$(conti%) + temp$
  125.             If uc& <= remain% Then
  126.                 first% = (first% Or uc&): uc& = 0
  127.             End If
  128.         Loop Until uc& = 0
  129.         UnicodeToUtf8Char$ = Chr$(first%) + temp$
  130.     End If
  132.  

Functions updated to work in version 2.0+, without any glitches from the recursive function fix causing things to error out on us.  ;)
Text Only | Text with Attachments